电脑玩家加强ERM求教

myfistl

下面是ERM，放入WOG国庆版中经常报错（错误信息看最后面贴图），请教大神看看是不是有变量冲突什么的。
ZVSE
ERMS_ScriptName=script98
ERMS_ScriptAuthor=GB
ERMS_ScriptVersion=1.0.0
ERMS_ScriptDate=22.3(March).2005
ERMS_ScriptERMVersion=2.70
ERMS_ScriptLanguage=简体中文 or 中文(简体) (native)
ERMS_ScriptUsedVariables=v75
ERMS_AdditionalFiles=在其他ERM中不要修改v75的值
ERMS_ScriptUsedTimers=55
ERMS_ScriptUsedFunctions=6800-6802
_WARNING_#1=IMPORTANT! This file is not in a plain text format. NEVER use any editor except ERM_S for making any kind of changes!
ERMS_PoweredBy=ERM Scripter v. 2004.6.29.918
;说明:(本ERM目的是增强随机和一般地图里的电脑实力.)
;本ERM在第一天触发,玩家可以选择对电脑的奖励,或禁用
;选择后,每周二电脑英雄所带兵力会增加相应数量,四围也会增加
;只对前三名英雄有效,而且只是增加原有部队的数量,不会凭空多出新部队.
;实力增加的意思就是电脑英雄部队每队兵力都增加10%到30%而已,也就是玩家需面对更多兵力的电脑.
;每个颜色的前三名电脑英雄同时获得每周二增加1-3点四围的奖励.

;开始游戏后,玩家可以随时右键点击睡眠按钮来重新设置
;(睡眠按钮就是英雄头像右边第二排第二个,显示为帐篷图样)
;新的设置值在下周二生效,已经生效的奖励不可撤销.
;---------------------------------------------------------------------
!?TM19&1000;     调用系统Time,第一天触发
!!FU6801:P;

!?CM0;           玩家右击睡眠按钮时也触发
!!CM:I?y10;
!!FU6801&y10=6:P;
!!CM&y10=6:R0;   屏蔽原解释对话框
;---------------------------------------------------------------------
;弹出对话框,让玩家设置
!?FU6801;
!!VRz3:S^电脑实力增强^;
!!VRz4:S^每周二增加电脑前三名英雄的兵力,四围^;
!!VRz5:S^..\Data\zvs\Lib1.res\WoGoption.bmp^;
!!VRz6:S^电脑实力增加 10%%^;
!!VRz7:S^电脑实力增加 20%%^;
!!VRz8:S^电脑实力增加 30%%^;
!!VRz9:S^停止增强^;

!!VRz10:S^每周电脑英雄所带的兵力每队增加10%,四围各加一点.^;
!!VRz11:S^每周电脑英雄所带的兵力每队增加20%,四围各加二点.^;
!!VRz12:S^每周电脑英雄所带的兵力每队增加30%,四围各加三点.^;
!!IF:D12/3//4/5////////6/7/8/9;
!!IF:F12/10/11/12//0;
!!IF:E75/12;
;---------------------------------------------------------------------

!#TM55:S2/360/7/255;  时间触发器,每星期二触发一次给电脑加兵
!?TM55&1000;
!!FU&v75=4:E;         禁用该ERM的话则退出
!!DO6802/0/7/1:P;     对所有颜色历遍

!?FU6802;
!!OW:Ix16/?y11/?y12;  判断
!!FU|y11=0/y12=1:E;   该颜色为真人玩家或不存在的电脑时退出

;只增加电脑前三名英雄的兵力,防止电脑合兵后过强.
!!OW:Ox16/0/?y14;             取电脑的第一个英雄
!!HEy14:A2/49/?y50/?y51;      奖励勇气徽章
!!HEy14&y51<>1:A4/49;
!!DO6800/0/6/1&y14>-1:Py14;   不为空时调用加兵函数

!!OW:Ox16/1/?y14;             取第二个
!!DO6800/0/6/1&y14>-1:Py14;
!!OW:Ox16/2/?y14;             第三个
!!DO6800/0/6/1&y14>-1:Py14;
;---------------------------------------------------------------------
;加兵函数
!?FU6800;
!!HEx1:C0/x16/?y15/d;     取英雄1-6格的兵ID到y15
!!FU&y15<0:E;             该格无兵时退出
!!HEx1:C0/x16/y15/?y18;
!!VRy17:Sy18;
!!VRy17:*v75:10;        
!!VRy18:+y17;              兵基数增加10%乘增长因子v75
!!VRy18&y18>10000:S10000;      兵数最多不超过10000
!!HEx1:C0/x16/y15/y18;        令该英雄的兵增加
!!HEx1&v75>0/v75<4/x16=0:Fdv75/dv75/dv75/dv75;  增加四围

;---------------------------END------------------------------------

nzhgfzqsb

这个好啊 为什么没懂的大神回复呢