怎样改变雷暴的魔法伤害

碳妖

紫龙放雷暴太逆天。想把雷暴伤害降低，否则太逆天了啊啊啊，用什么代码呢。
刚才写的脚本，出错了n多次，不断修改之后才有些像样。

碳妖

难度是!#SP18：P **?

碳妖

果断出错

贤知有您

雷鸣弹爆
本来就是杀伤力强大的魔法,用紫龙来放肯定要逆天.

你这紫龙是怪物强化下的紫龙吧.本身放什么杀伤魔法都跟自身数量有关,很BT的.

十三木人

!?MR0&1000;
!!FU4443:P-1;
!?FU4443&x1=-1;
!!BG:A?y40 N?y41 E?y42 Q?y43;
!!MR:F?y44 M?y45 N?y46 S?y47 D?y48;  ～沧海附加注释：把这两判断删除，不然会有可能引起堆栈错误，寻梦人发现
!!BMy41&y41>-1:T?y49 N?y50;
!!BMy42&y42>-1:T?y59 N?y60;
!!FU4443&y40=6/y49=129/y47=21:P-2/y50/24;  雷神闪电伤害为数量*100
!!FU4443&y40=6/y59=129/y47=21:P-2/y60/24;
!!FU4443&y40=6/y49=121/y47=60:P-2/y50/40;雷鸟闪电伤害为数量*50
!!FU4443&y40=6/y59=121/y47=60:P-2/y60/40;
!!FU4443&y40=6/y49=127/y47=17:P-2/y50/32;雷元素闪电伤害为数量*40～这个就是用经验特技添加的
!!FU4443&y40=7/y49=127/y47=17:P-2/y50/32; ～动作前远程也有效果
*!FU4443&y40=6/y59=127/y47=17:P-2/y60/32;   ～用经验特技攻击前施法反击貌似没效果
!!FU4443&y40=6/y49=123/y47=16:P-2/y50/28;   雷元素闪电伤害为数量*40～这个就是用经验特技添加的
!!FU4443&y40=7/y49=123/y47=16:P-2/y50/28;   ～动作前远程也有效果
*!FU4443&y40=6/y59=123/y47=16:P-2/y60/28;   ～用经验特技攻击前施法反击貌似没效果
!!FU4443&y40=6/y49=158/y47=22:P-2/y50/180;  雷神闪电伤害为数量*100
!!FU4443&y40=6/y59=158/y47=22:P-2/y60/180;

!?FU4443&x1=-2;
!!VRx4:Sx2*x3;
!!MR:Dx4;
这是沧海以前写的改变闪电威力的脚本，改威力就是这个原理

[ 本帖最后由 沧海一粟 于 2012-8-21 11:39 编辑 ]

碳妖

那个0&1000是什么意思

十三木人

!?MR0&1000;
当某个单位受到魔法伤害之前触发，且人类玩家必须参与

碳妖

试着详细注释，结果不会

兽哥哥

这两天越来越对妖妹的身份感兴趣了，背景及其神秘，一经出道就技术贴连绵不断，神马生物MOD，游戏皮肤，ERM的制作好像都有种信手拈来的感觉。而且老是感到有种强大的气场存在......

贤知有您

楼主不要焦急.
你需要从基本的学起,一时间很难接受过多的语法语句.
你可以把你的整体要求(尽量不要太复杂)说出来,有人帮你做出来就好了.
然后你从别人的代码中慢慢体会.(因为你能看到测试出来的效果)
否则你问一个空泛的问题,别人也只能答一个大概.

碳妖

很简单，就是单纯改变紫龙的雷鸣爆弹伤害。把原先的680+伤害改为200+。紫龙数量永远是1个

PS：这不是生物经验技能放出来的，而是紫龙施法放出来的

[ 本帖最后由 碳妖 于 2012-8-21 11:46 编辑 ]

碳妖

情况如图

[ 本帖最后由 碳妖 于 2012-8-21 11:43 编辑 ]

贤知有您

其实我有个不明白.
你这个改变紫龙雷暴是从何说起的.
紫龙的魔法是随机出来的.
为何紫龙的数量永远要1个?
开怪物强化还是不开怪物强化的?

沧版来了,等沧版参详参详.

碳妖

情况就像12楼。打算做个通关的图，没个关卡都有boss。
自方永远是那四个人（生物）。紫龙是用超级紫龙系统来施法的

贤知有您

既然你调用了别人的ERM代码,需要把别人关于紫龙的这段代码也发上来的.
看看能不能帮你修改一下.

碳妖

姆q的拉屎魔法逆天了，打出570+伤害
这叫二妹的100+攻击伤害情何以堪
目前在研究修改拉屎魔法伤害
http://tieba.baidu.com/p/1807434305

碳妖

!?BA0&1000;      （战斗开始）
!!BA:H0/?v9660; 保存进攻方英雄到v9660
!!BA:H1/?v9666; 防守方hero到v9666
!?BF&1000;     （战场生成）
!!DO1012/0/20/1&v9660=153:P; （是巨龙茉莉尔，即153号英雄则执行）
!!DO1012/21/41/1&v9666=153:P;
!?FU1012&x1=17;
!?BG0&1000;  （战斗开始前，且是人类玩家）
!!BG:H?x2;  （取得英雄代码）
!!FU|x2<>153/x2<>x3/x16=57:E; （不是153英雄、魔法编号是57号则中止）
!!HEx2:Mx16/1;  （给予魔法，编号放进x16？？）
!?OB98; （这个貌似很关键，但是在帮助文件中木有看明白……98指城镇类型？）
!?CM4&1000; （鼠标操作，人类玩家）
!!FU&v9660<>153/v9666<>153:E; （同样是判断英雄是否153号，是不是重复？）
!!FU1040&v9660=153:P0;
!!FU1040&v9666=153:P1;
!?FU1040&x1>=0/x1<=1;
!!CM:D?x4 F?x3; （x3：鼠标操作类型；x4：战场上执行鼠标操作的对象）
!!FU|x4<1/x4>185/x3<>32:E;（x3＝32就是alt+左键啦）
!!BU:Ex4/?x5; （x5:执行鼠标动作的对象的状态，呃，就是是否活着什么的；大概吧？？）
!!FU|x5<0/x5>41:E;（不在战场中止）
!!FU&x1=0/x5>20:E;（攻击方时，若属于防守方则中止）
!!FU&x1=1/x5<21:E;（防守方时，若属于攻击方则中止）
!!BMx5:T?x6 E?x7; （x6:生物代码；x7:生物施法次数）
!!FU|x6<>134/x7<1:E;（不是紫龙或施法次数为0则中止）
!!CM&x6=134/x7>=1:R0;（这个意思懂，但是不知道该如何明确表达…… ）
!!FU1040&x6=134/x7>=1:P2/x5/x2;（这句我没弄懂）
!?FU1040&x1=2;
!!BMx2:U4/?x6;（改变生物魔法的关键命令啊）
!!FU&x6<10:E;
!!UN:N1/24/x6;
*!HEx3:I?x5/1;
!!VRv10:S0;
!!VRz9:S^请选择帕秋莉本回合释放的魔法:^;
!!VRz22:S^当前魔法为%Z24,不改变,退出^;
!!VRz23:S^水火符「可燃之雨」在敌人头上下起燃烧的雨^;
!!VRz24:S^金水符「水银之毒」使敌人中毒^;
!!VRz25:S^土符「慵懒三石塔」 在敌人头上拉屎^;
!!VRz26:S^火符「火神闪光」在队友身上施展火盾^;
!!VRz27:S^日符「皇家烈焰」灼热的火焰 ^;
!!VRz28:S^月符「沉默的女神」为队友疗伤^;
!!VRz29:S^木符「风精的角笛」缠绕敌人^;
!!VRz30:S^水符「湖中的水葬」把敌人泡成石头？^;
!!VRz31:S^金符「金属疲劳」双目失明^;
!!VRz32:S^火水木金土符「贤者之石」祈祷^;
!!VRz33:S^月符「静寂的小夜曲」催眠敌人^;
!!IF:G1/10/1/9/22/23/24/25/26/27/28/29/30/31/32/33;
!!VRx4:Sv10;
!!VRv10:S0;
!!FU&x4<2:E;
!!BMx2&x4=2:U4/23;
!!BMx2&x4=4:U4/71;
!!BMx2&x4=8:U4/18;
!!BMx2&x4=16:U4/29;
!!BMx2&x4=32:U4/22;
!!BMx2&x4=64:U4/37;
!!BMx2&x4=128:U4/72;
!!BMx2&x4=256:U4/70;
!!BMx2&x4=512:U4/62;
!!BMx2&x4=1024:U4/48;
!!BMx2&x4=2048:U4/59;
!!FU&x4>0:E;

碳妖

顺手帮我看下能不能把指定英雄巨龙莫利亚改为任意英雄啊。153直接改为-1不行

贤知有您

大致改写了一下.看看是否OK.

1. ZVSE
   
2. **V9999**存储战斗时人类玩家的位置(0左1右)
   
3. 
   
4. !?BA0&1000; [战斗开始前,&1000表示有人类玩家参与的战斗]
   
5. !!VRv9999:S-1;
   
6. !!BA:H0/?v9660; 保存进攻方英雄到v9660
   
7. !!BA:H1/?v9666; 防守方hero到v9666
   
8. !!BA:O?y-2/?y-3; [攻击方: y-2, 防御: y-3]检测玩家颜色
   
9. !!OW:Iy-2/?y-4; [检测进攻方是人类玩家(0)还是AI(1)]
   
10. !!VRv9999&y-4=0:S0; [攻击方是人类玩家](v9999=0左边是人类/=1右边是人类]
    
11. !!VRv9999&y-4=1:S1; [防守方是人类玩家](&1000因为战斗一定有人类玩家参与]
    
12. 
    
13. !?CM4&1000; （鼠标操作，人类玩家）
    
14. !!FU1040&v9999>=0:P1;
    
15. 
    
16. !?FU1040&x1=1;
    
17. !!CM:D?x4 F?x3; （x3：鼠标操作类型；x4：战场上执行鼠标操作的对象）
    
18. !!FU|x4<1/x4>185/x3<>32:E;（x3＝32就是alt+左键啦）
    
19. !!BU:Ex4/?x5;  [检测鼠标点击的位置上,该怪物是否活动(全部死亡或没有怪物则为-1),将活动怪物堆栈存于x5]
    
20. !!FU|x5<0/x5>41:E;（不在战场中止）
    
21. !!FU&v9999=0/x5>20:E;（攻击方时，若属于防守方则中止）
    
22. !!FU&v9999=1/x5<21:E;（防守方时，若属于攻击方则中止）
    
23. !!BMx5:T?x6 E?x7; （x6:生物代码；x7:生物施法次数）
    
24. !!FU|x6<>134/x7<1:E;（不是紫龙或施法次数为0则中止）
    
25. !!CM&x6=134/x7>=1:R0;（这个意思懂，但是不知道该如何明确表达…… ）这个叫禁用标准反应
    
26. !!FU1040&x6=134/x7>=1:P2/x5/x2;（执行函数FU1040,传递函数的变量值,后面执行FU1040函数时:x1=2,x2=当前函数的x5,x3=当前函数的x2）
    
27. 
    
28. !?FU1040&x1=2;
    
29. !!BMx2:U4/?x6;（改变生物魔法的关键命令啊）
    
30. !!FU&x6<10:E;
    
31. !!UN:N1/24/x6; [获取原施放魔法的名字]
    
32. !!VRv10:S0;
    
33. !!VRz9:S^请选择帕秋莉本回合释放的魔法:^;
    
34. !!VRz22:S^当前魔法为%Z24,不改变,退出^;
    
35. !!VRz23:S^水火符「可燃之雨」在敌人头上下起燃烧的雨^;
    
36. !!VRz24:S^金水符「水银之毒」使敌人中毒^;
    
37. !!VRz25:S^土符「慵懒三石塔」 在敌人头上拉屎^;
    
38. !!VRz26:S^火符「火神闪光」在队友身上施展火盾^;
    
39. !!VRz27:S^日符「皇家烈焰」灼热的火焰 ^;
    
40. !!VRz28:S^月符「沉默的女神」为队友疗伤^;
    
41. !!VRz29:S^木符「风精的角笛」缠绕敌人^;
    
42. !!VRz30:S^水符「湖中的水葬」把敌人泡成石头？^;
    
43. !!VRz31:S^金符「金属疲劳」双目失明^;
    
44. !!VRz32:S^火水木金土符「贤者之石」祈祷^;
    
45. !!VRz33:S^月符「静寂的小夜曲」催眠敌人^;
    
46. !!IF:G1/10/1/9/22/23/24/25/26/27/28/29/30/31/32/33;
    
47. !!VRx4:Sv10;
    
48. !!VRv10:S0;
    
49. !!FU&x4<2:E;
    
50. !!BMx2&x4=2:U4/23;
    
51. !!BMx2&x4=4:U4/71;
    
52. !!BMx2&x4=8:U4/18;
    
53. !!BMx2&x4=16:U4/29;
    
54. !!BMx2&x4=32:U4/22;
    
55. !!BMx2&x4=64:U4/37;
    
56. !!BMx2&x4=128:U4/72;
    
57. !!BMx2&x4=256:U4/70;
    
58. !!BMx2&x4=512:U4/62;
    
59. !!BMx2&x4=1024:U4/48;
    
60. !!BMx2&x4=2048:U4/59;
    
61. !!FU&x4>0:E;
    
62. 
    
63. !?MR0&1000; [魔法伤害前]
    
64. !!BG:A?y1 N?y2; [动作类型]
    
65. !!MR:S?y10; [获得魔法编号]
    
66. !!FU|y1<>10/y2<0/y2>41/y10<>18:E; [不是怪物施法,或非正常堆栈,不是施放雷鸣,退出]
    
67. !!BMy2:T?y3 N?y4; [堆栈生物类型/个数]
    
68. !!FU|y3<>134/y4<1:E; [不是紫龙,退出]
    
69. !!FU&v9999=0/y2>20:E;（攻击方时，若属于防守方则中止）
    
70. !!FU&v9999=1/y2<21:E;（防守方时，若属于攻击方则中止）
    
71. !!VRy5:Sy4*200; [每个紫龙,雷鸣只造成200伤害]英雄带领下
    
72. !!MR:Dy5; [重设伤害]

复制代码

[ 本帖最后由 贤知有您 于 2012-8-21 13:19 编辑 ]

贤知有您

忘了说一句.
这样用好像很奇怪哦.
玩家直接用原来的魔法伤害不就更厉害吗.(单杀伤性来说)
非得要 ALT+左键点紫龙,选个没多少伤害的杀伤魔法 雷鸣?