查看受身魔法和回合数脚本

fastarrow

ZVSE

!?BR&v997>-1;
!!VRz23:S^{第%V997回合开始}^;
!!MM:Sz23;


我忘了打双叹号。加上就可以了。

追风

原帖由 fastarrow 于 2011-3-24 01:12 发表
ZVSE

!?BR&v997>-1;
!!VRz23:S^{第%V997回合开始}^;
!!MM:Sz23;


我忘了打双叹号。加上就可以了。

第一回合进不去
如果改为
ZVSE

!?BR&v997>0;
!!VRz23:S^{第%V997回合开始}^;
!!MM:Sz23;

则可以不出错，不过数字对不上，可能要再加一个变量。

fastarrow

布阵时，v997=-1,第一回合，v997＝0，如此类推，所以：
ZVSE

!?BR&v997>0;
!!VRv2210:Sv997 +1;
!!VRz23:S^{第%V2210回合开始}^;
!!MM:Sz23;

沧海一粟

原帖由 songfx 于 2011-3-23 22:12 发表

一共31种状态魔法，其中有4组是相反魔法，加上缠绕，麻痹，中毒，衰老，疾病等，不超过40种，有没有可能显示在一页上呢？

风大你说得也不完全对，除了状态魔法外，其它魔法也是可以受身的，但不一定有效果，比如说猪版一追的回城之类的（我印象中好像除了召船跟毁船还有那些死亡凝视、雷击之类的，其它魔法都可以加），也就是说你可能要检查0~80左右最少70+的魔法了，呵呵，所以说要完全实现想法还是很罗嗦的。

[ 本帖最后由 沧海壹粟 于 2011-3-24 09:28 编辑 ]

fastarrow

应该只检查最关心的几种。
加减速，祈祷，失明、麻痹，魔镜，火盾，疯狂，纠缠然后一个最简单的IF对话框就完了。

追风

加减速（最主要的，要知道谁先手）
祈祷（最主要的，要知道谁先手）
缠绕（一般很容易区分）
抗魔大法（对魔法攻击的兵种比较关键）
失忆（攻城时可能会需要知道剩余回合数）
失明（打持久战时就怕敌人突然醒了）
蛊惑人心（打持久战时就怕敌人突然醒了）
丧心病狂（一般一回合就醒了，通常都会显示在生物状态栏）
麻痹（基本上都是三回合，通常都会显示在生物状态栏）
石化（基本上都是三回合，通常都会显示在生物状态栏）
衰老（基本上都是三回合，通常都会显示在生物状态栏）
中毒（基本上都是三回合，通常都会显示在生物状态栏）

[ 本帖最后由 追风 于 2011-3-24 19:41 编辑 ]

fastarrow

请测试看看。

ZVSE
!?CM4;
!!CM:D?y30 F?y31 S?y32;获取鼠标位置，标志，动作子类型
!!FU48&y31=512/y32=14:Py30;调用函数
!?FU48;
!!BU:Dx1/?y-1;检查鼠标所在位置怪物是否生存
!!FU&y-1=-1:E;死亡时中止
!!BU&y-1=-2:Ex1/?y-2;生存时获取堆栈
!!FU&y-2<0:E;无堆栈时中止
!!BMy-2&y-2>-1:T?y-3 N?y-4;获取栈内怪物类型数量
!!FU|y-3<0/y-4<1:E;怪物类型<0或数量<1时中止
!!BMy-2:G53/?y1/d G54/?y2/d G48/?y3/d G36/?y14/d;检查魔法持续时间
!!BMy-2:G70/?y4/d G71/?y5/d G72/?y6/d G74/?y7/d G75/?y8/d;检查魔法持续时间
!!BMy-2:G34/?y9/d G60/?y10/d G61/?y11/d G59/?y12/d G62/?y13/d;检查魔法持续时间

!!UN:N3/24/y-3/0;获取目标怪物名称

!!IF&y6>0:M^{%Z24}  当前受身魔法：
减速：%Y2    加速：%Y1
祈祷：%Y3    抗魔：%Y9
失忆：%Y11    失明：%Y13
催眠：%Y10    发狂：%Y12
麻痹：%Y7    石化：%Y4
衰老：%Y8    中毒：%Y5
缠绕：Y    魔镜：%Y14^;
!!IF&y6=0:M^{%Z24} 当前受身魔法：
减速：%Y2    加速：%Y1
祈祷：%Y3    抗魔：%Y9
失忆：%Y11    失明：%Y13
催眠：%Y10    发狂：%Y12
麻痹：%Y7    石化：%Y4
衰老：%Y8    中毒：%Y5
缠绕：N    魔镜：%Y14^;

[ 本帖最后由 fastarrow 于 2011-3-25 08:34 编辑 ]

骷髅召唤师

大大，没有问题。就是用右键不好，显示受身魔法后又进入生物图框
我是用诅咒铠甲测试的。

[ 本帖最后由 骷髅召唤师 于 2011-3-24 21:27 编辑 ]

fastarrow

晚上试试SHIFT+左键，禁用标准反应，看看行不行。

另外，本方的还需不需要显示？

骷髅召唤师

本方需要显示一些有益的和不能驱散的就行了，如减速，失忆等都会把他用疗伤驱散掉的，

无心云

又搞新玩意

AX0221

原帖由 fastarrow 于 2011-3-25 08:31 发表
晚上试试SHIFT+左键，禁用标准反应，看看行不行。

另外，本方的还需不需要显示？

本方也要显示！！！！不然很多有益魔法的时候，颜色是覆盖的，少了一两种都不知道！

追风

这样排版可能更舒服一点

500 枪兵
当前主要受身魔法

减速：50   加速：0
.
.

追风

其中加减速，祈祷和失明，建议用金色字体表示

追风

原帖由 fastarrow 于 2011-3-25 08:31 发表
晚上试试SHIFT+左键，禁用标准反应，看看行不行。

另外，本方的还需不需要显示？

建议不要弹出确认窗口

效果就像右键显示属性那样，放开鼠标就消失。这样会方便很多。


按Alt键（Ctrl和shift经常被其它脚本使用了），鼠标显示为问号（同右键的作用），不放开Al键，并点击左键（且松开左键），弹出提示框，放开Altw键，提示框消失。这样就不会误操作了。

[ 本帖最后由 追风 于 2011-3-26 07:36 编辑 ]

fastarrow

OK了。

ALT+左键，弹出提示信息，无确认按钮，松开鼠标消失。

但鼠标指针为问号在点之前不起作用。

ZVSE
!?CM4;
!!CM:D?y30 F?y31 S?y32;获取鼠标位置，标志，动作子类型
**UN&y31=32:R5/2/5;
!!CM&y31=32:R0;
!!FU48&y31=32:Py30;调用函数
!?FU48;
!!BU:Dx1/?y-1;检查鼠标所在位置怪物是否生存
!!FU&y-1=-1:E;死亡时中止
!!BU&y-1=-2:Ex1/?y-2;生存时获取堆栈
!!FU&y-2<0:E;无堆栈时中止
!!BMy-2&y-2>-1:T?y-3 N?y-4;获取栈内怪物类型数量
!!FU|y-3<0/y-4<1:E;怪物类型<0或数量<1时中止
!!BMy-2:G53/?y1/d G54/?y2/d G48/?y3/d G36/?y14/d;检查魔法持续时间
!!BMy-2:G70/?y4/d G71/?y5/d G72/?y6/d G74/?y7/d G75/?y8/d;检查魔法持续时间
!!BMy-2:G34/?y9/d G60/?y10/d G61/?y11/d G59/?y12/d G62/?y13/d;检查魔法持续时间
!!UN:N3/24/y-3/0;获取目标怪物名称
!!IF&y6>0:Q1/21/y-3/4^{%Y-4 %Z24}
当前主要受身魔法：
{减速：%Y2     加速：%Y1}
{祈祷：%Y3     失明：%Y13}
失忆：%Y11     抗魔：%Y9
催眠：%Y10    发狂：%Y12
麻痹：%Y7    石化：%Y4
衰老：%Y8    中毒：%Y5
缠绕：有    魔镜：%Y14^;
!!IF&y6=0:Q1/21/y-3/4^{%Y-4 %Z24}
当前主要受身魔法：
{减速：%Y2     加速：%Y1}
{祈祷：%Y3     失明：%Y13}
失忆：%Y11     抗魔：%Y9
催眠：%Y10    发狂：%Y12
麻痹：%Y7    石化：%Y4
衰老：%Y8    中毒：%Y5
缠绕：无    魔镜：%Y14^;


效果图

骷髅召唤师

谢谢。

songfx

原帖由 fastarrow 于 2011-3-24 07:28 发表
布阵时，v997=-1,第一回合，v997＝0，如此类推，所以：
ZVSE

!?BR&v997>0;
!!VRv2210:Sv997 +1;
!!VRz23:S^{第%V2210回合开始}^;
!!MM:Sz23;

这样改一改可能更合理，

ZVSE

!?BR&v997>0;
!!VRz23:S^{第%V997回合结束}^;
!!MM:Sz23;

fastarrow

很有道理

songfx

这么晚还在线啊？呵呵，夜猫子