【非MOD】仿组合宝物演示（从此组宝无限~）

wgnbb · 发表于昨天 17:31

本帖最后由 wgnbb 于 2026-9-1 17:31 编辑

UN:A是有极限的，且这个极限不仅非常小还公用！
对此我曾询问过A大，组宝编号就不能像属性一样再加点？
答案是NO~

于是，不断精进代码的我，最终还是在写出了这个演示。
仿照真正的组合宝物，一共有两个触发，分别负责拆和组。
非要说有什么问题的话，那就是我偷懒了。
组合时，宝物必须都在行囊里。。。

360截图20260901172601232.png

ZVSE
ERMS_PoweredBy=2026.8.29
ERMS_ScriptName=仿组合宝物演示
ERMS_ScriptERMVersion=2.70
ERMS_ScriptLanguage=中文(简体，中国)
**************融合宝物的拆开提示框-模拟组宝**************
!?CM2;
!!CM:I?y1 F?y2;
!!VRy3&y1>=2/y1<=20:S1; 头-行囊5--代表身上装备时
!!VRy3&y1>=40/y1<=44:S2; 行囊1-5位置
!!FU|y3<1/y3>=3/y2<>512:E; 不是这两个位置+右击退出
!!VRy6&y3=1:Sy1-2; -2得到英雄A1位置数字
!!VRy6&y3=2:Sy1-21; -21得到英雄A1位置数字
!!HE-1:A1/?y4/y6 N?y5;
!!FU&y4>=1000:E;!!FU&y5<0:E; 魔法书-全魔法卷轴/英雄号
!!VRy21&y4=161:S1; 这次演示要用到的自定义仿组宝--空白盾(161)拆开=窥镜+望远镜---|后面还可以继续增加自定义组宝
!!FU&y21<>1:E;
!!UN:C6687592/4/?y20; 宝物描述-基底
!!VRy30:Sy4*32+y20+16;
!!UN:Cy30/4/?y40;
!!SN:X?y50 Xy40 X?z-1 Xy50;
!!CM:R0;
//拆开-文字
!!IF&y21=1:Q1^%Z-1
你想拆开这件融合宝物吗？^;
!!FU&-1:E; 选否退出
///拆开-给宝
!!if&y4=161; 空白盾-拆开2
!!HE-1:A1/?y10/81;!!HE-1:A1/?y11/82; 检测行囊最后2格是否还有空位
!!FU(UnequipArtFromSlot)&y10=-1/y11=-1/y3=1:Py5/y6; X1=英雄编号 X2=位置仅支持英雄身上已装备的宝物-会有一个脱下的过程
!!HE-1&y10=-1/y11=-1/y3=2:A3/y4/1/0; 拆除行囊里的融合宝物时就没有顾及了-用A3直接删除
!!HE-1&y10=-1/y11=-1:A4/52 A4/53; 给与组件并自动装备-其实只需要1个行囊空位有就可执行--但防BUG还是不要那么极限了
!!IF|y10<>-1/y11<>-1:M^{~R}行囊最后2格未清空！
{~deepskyblue}无法拆开融合宝物！！{~w}^; 文字提示
!!UN:R3/-1;
!!en;
**************融合宝物的组合提示框-模拟组宝**************
!?CM2;
!!CM:I?y1 F?y2;
!!VRy3&y1>=2/y1<=20:S1; 头-行囊5--代表身上装备时
!!VRy3&y1>=40/y1<=44:S2; 行囊1-5位置
!!FU|y3<1/y3>=3/y2<>512:E; 不是这两个位置+右击退出
!!VRy6&y3=1:Sy1-2; -2得到英雄A1位置数字
!!VRy6&y3=2:Sy1-21; -21得到英雄A1位置数字
!!HE-1:A1/?y4/y6 N?y5;
!!FU&y4>=1000:E;!!FU&y5<0:E; 魔法书-全魔法卷轴/英雄号
!!VRy41|y4=52/y4=53:S1; 这次演示要用到的自定义仿组宝--窥镜+望远镜=空白盾(161)---|后面还可以继续增加组件
!!FU&y41<>1:E;!!VRy8:S0;!!VRy21:S0;!!VRy22:S0;!!VRy31:S0; 先清零
!!UN:C6687592/4/?y20; 宝物描述-基底
!!VRy30:Sy4*32+y20+16;
!!UN:Cy30/4/?y40;
!!SN:X?y50 Xy40 X?z-1 Xy50;
!!CM:R0;
!!VRy8&y4=52:S53;!!VRy8&y4=53:S52; Y8=点击的另外一个组件--2件套时-双筒
!!HE-1:A2/y4/?y21/d; 全身检测点击的组件A
!!HE-1:A2/y8/?y22/d; 组件B--2件套以上自己继续加
!!VRy7|y4=52/y4=53:S161; 点击双筒组件-Y7转到组宝名
!!UN&y7=161:N0/10/52;!!UN&y7=161:N0/11/53; 反过来-通过Y7获得其组件的名字--z10/z11
!!VRy31&y7=161/y21>0:+1;!!VRy31&y7=161/y22>0:+1; y31-组件计数
!!UN:N0/1/y7;!!VRz2:Sz1; 获得融合宝物名称Z1/获得z2白字的组宝名
!!VRz1&y3=1:S^{~lightgreen}%z1^;!!VRz1&y3=2:S^{~Gray}%z1^; 点击宝物在行囊变灰
!!VRz3:S^^;!!VRz4:S^^; 清空/2以上才开始发生改变
!!VRz3&y4=52/y21>1:S^(%y21)^;!!VRz4&y4=52/y22>1:S^(%y22)^;
!!VRz3&y4=53/y22>1:S^(%y22)^;!!VRz4&y4=53/y21>1:S^(%y21)^;
!!VRz10&y4=52:S^{~o}%z10 %z3{~lightgreen}^;!!VRz11&y4=52:S^%z11 %z4{~lightgreen}^; 点击的橙色/后续计数
!!VRz11&y4=53:S^{~o}%z11 %z4{~lightgreen}^;!!VRz10&y4=53:S^%z10 %z3{~lightgreen}^;
!!VRz10&y4=53/y22<=0:S^{~Gray}%z10{~lightgreen}^; 检查其他组件的数量-没有时也变灰-不存在计数问题
!!VRz11&y4=52/y22<=0:S^{~Gray}%z11{~lightgreen}^;
*****************仿组宝-凑齐时文字说明******************
//集齐(2件通用)
!!VRz1&y7=161/y21>0/y22>0:S^%z1 (%y31/2){~lightgreen}
%z10
%z11{~w}
你得到了%z2的所有配件，你想把它们组合起来吗？^;
//未集齐(2件通用)
!!VRz1&y7=161/y31<=1:S^%z1 (%y31/2){~lightgreen}
%z10
%z11{~w}^;
//组合-集齐(2件通用)
!!if&y7=161/y31=2;
!!IF|y4=52/y4=53:Q1^%Z-1
%z1^;
!!en;
//组合-未集齐(2件通用)
!!if&y7=161/y31<=1;
!!IF|y4=52/y4=53:M/4/^%Z-1
%z1^;
!!en;
*****************仿组宝-文字说明结束******************
//结果
!!FU&-1:E; 选否退出
//组合-2件套
!!if&y7=161/y31=2; 双筒-组合--仅在行囊里合成---怕BUG
!!HE-1:A2/y8/d/?y1; 检查组件B是否在身上
!!HE-1&y3=2/y1=0:A3/y4/1/0; 拆除行囊里的融合宝物时就没有顾及了-用A3直接删除
!!HE-1&y3=2/y1=0:A3/y8/1/0; 组件B-在行囊时--直接删除
!!HE-1&y3=2/y1=0:A4/161; 组合-直接装备
!HE-1&y3=2/y1=0:A3/y4/1/0 A3/y8/1/0 A4/161; 上面3行条件一样-可以连写
!!IF|y1<>0/y3<=1:M^{~R}融合宝物必须全在行囊中才能组合！^; 文字提示
!!UN:R3/-1;
!!en;

复制代码

仿组合宝物演示.erm (4.05 KB, 下载次数: 0)

yck994057513 · 发表于 4 小时前

期待后续的成品作，楼主太给力了

账号		自动登录	找回密码
密码			英雄注册\|Register