听木瓜大哥的发到这里来：部分英雄特长设想

ofxking

[wiki]WoG[/wiki]给[wiki]英雄[/wiki]特长额外强化，但其中有些英雄仍然是废渣……
首先，航海术特长仍然渣，海图本来就需要航海，而非海图即使强化也没什么用。
其次，鹰眼特长是个好特长（1、2级兵会飞），但塔城的Serena仍然弱（塔城1级小[wiki]鬼[/wiki]升级后远程。。。2级石像鬼本来就是飞兵。。。）

于是想通过[wiki]ERM[/wiki]给她们（都是女的耶~）加点额外的能力，让她们能有一点特色。。。。


设想：
1、Voy，驯兽师航海英雄。
特长：Perdue，敢死队。
效果：战斗中英雄A/D加倍，但所有部队反击次数为0。
介绍：Being a witch, Voy has special interest in training her troops. She tried to make the army more ferocious against the enemy. She suceeded, however, such ferocity doesn't come from nothing. Being more capable to deal damage and protect themselves from fighting, her troops focus on the "critical strike" tactics and lose the ability to organize effective retaliations.


ERM：

这里就是请教部分了……天知道会有多少错  

**Voy: Gain double A/D in the battle but creatures lose retaliations

!?BA0; Before Battle
!!HE122:F?v4401/?v4402/?y-92/?y-93/1; Get Voy A/D without artifacts
!!HE122:F?y-94/?y-95/?y-92/?y-93; Get Voy A/D with artifacts
!!VRy-94:+v4401;
!!VRy-95:+v4402;
!!HE122:Fy-94/y-95/y-92/y-93; Gain extra A/D


!?BA1; After Battle
!!HE122:F?y-94/?y-95/?y-92/?y-93;
!!VRy-94:-v4401;
!!VRy-95:-v4402;
!!HE122:Fy-94/y-95/y-92/y-93; Release extra A/D


!?BR;
!!BH0:N?y-31; set v4411 as number of left hero
!!BH1:N?y-32;
!!DO4401/0/20/1&y-31=122:P1; Only do when hero is Voy
!!DO4401/21/41/1&y-32=122:P1; Only do when hero is Voy

!?FU4401;
!!BMx16:R0; Set Stack reliations to 0

**End of Voy

指数的测试正常了，不能反击的效果也达到了，问题是……
只有第一回合有效  
这是为什末？我明明用的是BR吖……不解ING。。。:==:

————————————————————————————————————————————————————


2、Sylvia，人类航海英雄。
特长：Spoil of war，掠夺
效果：战后获得金钱，类似于地下城宠物的特技。数量为经验的20%，每级额外+1%
介绍：Once a pirate, always a pillager. Sylvia's no longer a pirate, but her enthuasiam in wealth does not decrease. As a succesful patrol, she can always find out the pirates' hiding treasures. The kingdom's looking forward to her performance in future battles.

ERM：

**Sylvia: Get spoils of war after battle. Money equals (20+Level)%*Battle Exp

!?BA0;
!!HE-1:N?y-1; get hero number
!!HEy-1&y-1=3:E?v4403/?y-80/1; save Sylvia's Level and Exp pre-battle

!?BA1;
!!HE-1:N?y-1; get hero number

!!HEy-1&y-1=3:E?y-81/?y-80/1; get current exp
!!VRy-81:-v4403; Calculate exp gained in the battle
!!VRy-80:+20; Percent of money
!!VRy-81:Sy-81 * y-80 : 100; Money=(20+Level)%*Battle Exp
!!IF&y-1=3:M^Your troops get spoils of war : %Y-81 gold.^;
!!OW&y-1=3:R-1/6/dy-81; Gain Money

**End of Sylvia


测试通过，应该没问题了~:victory:

————————————————————————————————————————————————————


3、Serena，塔城鹰眼英雄。
特长：Eagle insight，洞察
效果：所有远程部队速度+1，每10级再+1。
介绍：People always say that Serena's got an eagle eye. With that insight, Serena can mobilize her archer troops even before their enemy can spot them. "Who shoots first prevails" is her regular motto.


ERM：

**Serena: All shooter stacks get +1 to speed every 10 level of Serena.
!?BF; trigger when battlefield is prepared.
!!BH0:N?v4411; set v4411 as number of left hero
!!BH1:N?v4412;
!!HE-1:N?y-1; get hero number
!!HEy-1&y-1=42:E?y-81/?y-80/1; get current Lvl
!!BG:Q?y-96; get side
!!DO4402/0/20/1&v4411=42:Py-80; Only do when hero is Serena
!!DO4402/21/41/1&v4412=42:Py-80; Only do when hero is Serena




!?FU4402;

!!BMx16:F?y-2; read the flags into a 32-bit variable
!!VRy-2:&4; check if current stack is shooter
!!VRy-4:Sx1 : 10;
!!VRy-4:+1;
!!BMx16&y-2=4:Sdy-4; Add Speed

**End of Serena

测试成功！对兵种和宠物都有效~~~~:g:


接下来只剩把Voy的问题解决了…………

题外话：
测试时用Voy试了一把
结果升到十多级，一点A/D也没涨过。。。。
不愧是5% 5%的强者女巫啊。。。。:==:

[ 本帖最后由 ofxking 于 2006-2-10 17:45 编辑 ]

匿名生存

关于Voy……我的推想是这样的……

触发器发生顺序是

→ BA0
→ BF
→ BR
→ BG
（第二回合）
→ BR
→ 硬编码的每回合触发（为双方部队恢复反击，附身魔法剩余回合数-1）
→ BG
…………
→ HL（如果英雄升级的话）
→ 硬编码的英雄升级
→ BA1
→ 硬编码的战斗结束

意思是说，同等效力的触发程序中[wiki]ERM[/wiki]永远赶在硬编码的前面……
战斗开始后的第一个回合每个生物的反击次数是早就定义好的，你用BR改完以后自然就没了。但从第二回合起你是先把反击次数改没，然后硬编码的回合开始才触发，又给你改回来了…………

修改意见么。。。如果追求这个效果的话用BG比较妥当
!?BG;
!!BG:N?y1;
!!FU&y1<=20:E;
......
意思是每当敌人的部队行动时触发……但我觉得就你现在这样的负面程度已经差不多了，毕竟她的AD本来就低得可怜，每战的第一回合不能反击足够了。。。

P S：Voy作为手无缚鸡之力的女巫却有个AD加倍的特技，Sylvia MM是正义的骑士却有个掠夺技能……尽管你已经用背景叙述作了解释但偶觉得还是感觉非常别扭。。。

恩，总的来说创意还是满不错的。。。辛苦了……

[ 本帖最后由 匿名生存 于 2006-2-10 19:52 编辑 ]

ofxking

谢谢，大致明白了~

关于设定……
要是把力量英雄做成AD加倍。。。。那才比较严重吧= =
当然，Voy的AD还是使我非常“惊喜”
而Sylvia本来就是海盗出身，对金钱有兴趣也不奇怪吧……介绍也说了，她在打海盗时比较能发现隐藏的财宝嘛~
或许可以把特长的名字改一改……比如……Fortune Finder？

woodmelon

**Voy: Gain double A/D in the battle but creatures lose retaliations

!?BA0; Before Battle
!!HE122:F?v4401/?v4402/?y-92/?y-93/1; Get Voy A/D without artifacts
!!HE122:F?y-94/?y-95/?y-92/?y-93; Get Voy A/D with artifacts
!!VRy-94:+v4401;
!!VRy-95:+v4402;
!!HE122:Fy-94/y-95/y-92/y-93; Gain extra A/D


!?BA1; After Battle
!!HE122:F?y-94/?y-95/?y-92/?y-93;
!!VRy-94:-v4401;
!!VRy-95:-v4402;
!!HE122:Fy-94/y-95/y-92/y-93; Release extra A/D


!?BR;
!!BH0:N?y-31; set v4411 as number of left hero
!!BH1:N?y-32;
!!DO4401/0/20/1&y-31=122:P1; Only do when hero is Voy
!!DO4401/21/41/1&y-32=122:P1; Only do when hero is Voy

!?FU4401;
!!BMx16:R0; Set Stack reliations to 0

**End of Voy

!?BA0; Before Battle
!!HE122:F?v4401/?v4402/d/d/1; Get Voy A/D without artifacts
!!HE122:Fdv4401/dv4402/d/d; Gain extra A/D

这部分这样就行了，不必写那么多

!?BR有问题，说是每回合触发，其实很多时候都是不能用的．不知道为何，可能是对!!BM支持不好
改成!?BG就行了．

!?BG;
!!BG:A?y-31  E?y-32; 动作和目标
!!FU&y-31<>6:E; 　近身攻击有效
!!BMy-32:I?y-31;　检查目标所属
!!BHy-31:N?y-33;   检查英雄ID
!!BMy-32&y-33=122:R0;　无反击

这个特技没什么用，攻防超过99就无意义了

woodmelon

Sylvia的脚本你测试应该没错的吧
应该用!!BA:H0 和!!BA:H1 来找英雄ＩＤ，而不是用!!HE-1:N
否则Sylvia作为ＰＣ时可能无效

!?BA1后面应该检查战斗后是否还有英雄，如果打怪中死掉或者逃跑
程序仍然会执行，但已经无意义了

woodmelon

**Serena: All shooter stacks get +1 to speed every 10 level of Serena.
!?BF; trigger when battlefield is prepared.
!!BH0:N?v4411; set v4411 as number of left hero
!!BH1:N?v4412;
!!HEv4411&v4411=42:Ed/?y-80/1; get current Lvl
!!HEv4412&v4412=42:Ed/?y-80/1; get current Lvl
!!DO4402/0/20/1&v4411=42:Py-80; Only do when hero is Serena
!!DO4402/21/41/1&v4412=42:Py-80; Only do when hero is Serena

!?FU4402;
!!BMx16:N?y-1 T?y-2;
!!FU|y-1<1/y-2<0:E;
!!BMx16:F?y-2; read the flags into a 32-bit variable
!!VRy-2:&4; check if current stack is shooter
!!VRy-4:Sx1 : 10 +1;
!!BMx16&y-2=4:Sdy-4; Add Speed

**End of Serena

ofxking

继续请教………………

这回想把Voy的特长改为：如果全军等待，则自动施放全体加速。

判断方面应该问题不大了……但是很奇怪的是，照说!!BH:Cx1/x2/x3/x4这里x3代表了施法等级，不管我把
!!BH0&y-31=122/v4403=0:C53/y-43/0/0;
这一行怎么设置，施法的等级却不受影响，有时是单体，有时是全体……似乎有点随机成分= =
我觉得奇怪的是……就算判断部分出错，影响的应该是施法动作是否出现才对，而不是施法的等级。。。不解ING。。。

判定里忽略了部队是镜象的情况，还应该有攻城兵器之类的，这些等问题解决了再加上……


!?BR;
!!VRv4403:S0;                                          Set v4403 to zero
!!BH0:N?y-31;                                          set y-31 as number of left hero
!!BH1:N?y-32;
!!DO4403/0/20/1&y-31=122:P1;                           Only do when hero is Voy
!!DO4403/21/41/1&y-32=122:P1;                          Only do when hero is Voy


!?BG;                                                  check when action is taken
!!BG:A?y-41 H?y-42 N?y-43;                             get stack number
!!BMy-43:F?y-4;
!!VRy-4:&8388608;
!!FU&y-4=8388608:E;
!!BH0:N?y-31;                                          set y-31 as number of left hero
!!BH1:N?y-32;
!!VRv4403&y-41=8:-1;
!!BH0&y-31=122:M?y-50;
!!BH1&y-32=122:M?y-50;
!!BH0&y-31=122/v4403=0:C53/y-43/0/0;
!!BH1&y-32=122/v4403=0:C53/y-43/0/0;
!!VRv4403&v4403=0:S20;
!!BH0&y-31=122:My-50;
!!BH1&y-32=122:My-50;



!?FU4403;
!!BMx16:N?y-1 T?y-2 F?y-3;
!!FU|y-1<1/y-2<0:E;                                    check stack exists
!!VRy-3:&8388608;
!!FU&y-3=8388608:E;
!!VRv4403:+1;

yunings

此贴甚好，等帖子完备后将考虑加精，楼主和木瓜都要加油，呵呵

woodmelon

原帖由 ofxking 于 2006-2-11 14:31 发表
继续请教………………

这回想把Voy的特长改为：如果全军等待，则自动施放全体加速。

判断方面应该问题不大了……但是很奇怪的是，照说!!BH:Cx1/x2/x3/x4这里x3代表了施法等级，不管我把
!!BH0&y-31=12 ...

!!BH:Cx1/x2/x3/x4
这个无论你怎么设置，施法等级和回合数都是与施法英雄一样的

那个8******的标志是指什么？
查了一下没发现，可能我查的ＥＲＭ帮助版本太低了

有个问题：施加速时如果对象是魔法元素，圣龙等，就会无效

!!BG:A?y-41 H?y-42 N?y-43;
H和Q一般要连用的，否则可能会出现无效的情况

N?y-43是指堆栈，怎么变成施法位置了？

[ 本帖最后由 woodmelon 于 2006-2-11 18:20 编辑 ]

ofxking

原帖由 woodmelon 于 2006-2-11 18:16 发表

!!BH:Cx1/x2/x3/x4
这个无论你怎么设置，施法等级和回合数都是与施法英雄一样的

但是……测试中偶尔会出现群体的情况。之前还出现过先放一次单体然后紧接着放了一次群加的情况（判定的语句不一样，但BH语句一样） 所以很奇怪……-v-

等下我去试试临时改气技能。。。

那个8******的标志是指什么？
查了一下没发现，可能我查的ＥＲＭ帮助版本太低了

这段不是在flags for monsters这一项里的，是在!!BM:F里提到的……
F$
Monster flag (as for MA:X).
Comments:
Four of the previously unknown MA:X values are used to handle the flow of combat:

0x01000000 = 16777216 - set if this stack has had morale this round
0x02000000 = 33554432 - set if this stack is waiting
0x04000000 = 67108864 - set if this stack is done acting for this round
0x08000000 = 134217728 - set if this stack is defending
0x40000000 = 4194304 - set if the stack is summoned (vanishes when killed)
0x80000000 = 8388608 - set if the stack is a clone (blue colour and 1 hit kills)
0x00C00000 = 12582912 - set for a stack that is created by the Clone spell. This is the sum of the bits above (summon) + (clone).

因为我是在BR时判断部队总数，觉得镜象之类的东西会有影响，所以判断进去了……

!!BG:A?y-41 H?y-42 N?y-43;
H和Q一般要连用的，否则可能会出现无效的情况

N?y-43是指堆栈，怎么变成施法位置了？

第一条明白了，那如果BG时用了Q，是不是就不用“!!BH0:N?y-31; ”这两句了？

Position to cast;。。。这个没看懂，就以为是指堆栈了= =
是指六边形地图上的具体格子吗？[wiki]ERM[/wiki]39.erm里面施法的部分一大堆东西，实在头痛没看完。。。= =

有个问题：施加速时如果对象是魔法元素，圣龙等，就会无效

我记得当初好象是在您还是谁的ERM教程帖里看到过的，说哪个命令放魔法（当然，是群体魔法）是和施法对象有没有魔防没影响的，不是!!BH末……
其实就是想达到[wiki]天使[/wiki]联盟/诅咒铠甲那样的效果而已，哎……:ft:

匿名生存

原帖由 woodmelon 于 2006-2-11 18:16 发表

!!BH:Cx1/x2/x3/x4
这个无论你怎么设置，施法等级和回合数都是与施法英雄一样的

那个8******的标志是指什么？
查了一下没发现，可能我查的ＥＲＭ帮助版本太低了

有个问题：施加速时如果对象是魔法元素， ...

对象如果是魔法元素、圣龙的话，如果是单体魔法就会完全无效。。。如果是作用于那一方全体或者是一个面积的话，魔法是有效果的~~单个生物无效不会影响到其它生物受法。。。就算全体都不受该术但仍然会有声音效果出现

ofxking

改了一下，又出问题。。。。:ft:

!!BH0&y-31=122:M?y-50;
!!BH1&y-32=122:M?y-50;
!!HEy-31&y-31=122:S15/?y-6;                    save air magic level
!!HEy-32&y-32=122:S15/?y-6;                    save air magic level
!!HEy-31&y-31=122/v4403=0:S15/3;
!!HEy-32&y-32=122/v4403=0:S15/3;
!!BH0&y-31=122/v4403=0:C53/0/3/0;
!!BH1&y-32=122/v4403=0:C53/0/3/0;
!!VRv4403&v4403=0:S20;
!!HEy-31&y-31=122:S15/y-6;                    restore air magic level
!!HEy-32&y-32=122:S15/y-6;                    restore air magic level
!!BH0&y-31=122:My-50;
!!BH1&y-32=122:My-50;


的确每次都放全体不会错了……但出现个大问题：假如commander是最慢的一个，也就是说在等待后第一个行动，那它放的魔法“有可能”（最怪的就是这个有可能。。。）自动变成最高级……而且……！这样以后，英雄所有法术技能都会变成最高级。。。（有可能全28项都变最高级了……但战斗中看不出，战后是恢复的……）
这、这又是怎么回事咧。。。。:==:

是不是碰到英雄技能这样的东西，改用v变量比较保险？

woodmelon

原帖由 ofxking 于 2006-2-12 12:02 发表
改了一下，又出问题。。。。:ft:

!!BH0&y-31=122:M?y-50;
!!BH1&y-32=122:M?y-50;
!!HEy-31&y-31=122:S15/?y-6;                    save air magic level
!!HEy-32&y-32=122:S15/?y-6;    ...

不是，无关的．
看程序应该是没问题的
但具体怎么样你多测试几次改一下吧
加油

ofxking

烦恼的是现在根本不知道问题出在哪儿……似乎完全是随机的……连指挥官施法也是高级这也太奇怪了。。。除非是战场变成了魔法平原。。。。
饿……？有可以改战斗所处地形的函数吗？

herowog

sign，慢慢学习中。

winlong

不错，不错

yangzeng

.....................我完全看不懂..............

windwhisper

顶老帖，看得我吐血好几升，这要捐给灾区多少，可惜了

19810615

刚看到woodmelon觉得有一种亲切感，好熟悉哦
再看看标题，这才明白见到传说中的木瓜了
瞻仰风采ing~~~~
        什么时候再看到土地公就好了~~~

楼主和木瓜讨论的完全不懂~~看天书ing