求大神制作公会首领可以和攻守城英雄交换职业的ERM

cs3300330033

原版封魔1.05我方公会首领进攻电脑城里(不是来访英雄,是守城英雄)的已转职英雄,发现不能互换职业!
现求大神定制一个我方公会首领进攻可以和守城英雄互换职业，而且我方守城的公会首领英雄也可以和进攻方英雄互换职业的公会首领ERM！！！！

cs3300330033

没有大神光临么？

cs3300330033

!-?FU77010;取消
!-!SN:W^DaoZei.1^/0 W^DaoZei.2^/0 W^DaoZei.Flag^/0;取消
!-!SN:X?y1/?y2  取消


修改部分
!?BA0;
!!BA:H1/?y22;
!!FU&y22=-2:E;
!!BA:H0/?y1;
!!BA:H1/?y2;
修改部分

!!HEy1:O?y3;  左
!!OW:Iy3/?y5;
!!HEy2:O?y4;  右
!!OW:Iy4/?y6;
!!IF:Wy1;
!!VRy13:Sw185;   左方英雄职业
!!IF:Wy2;
!!VRy14:Sw185;   右方英雄职业
!!FU&y13<>23/y14<>23:E;   没有盗贼参战退出
!!FU&y13=y14:E;           双方都是盗贼退出
!!FU&y13=23/y14=0:E;      对方没有转职退出
!!FU&y14=23/y13=0:E;
!-!FU&y5=1/y6=1:E;         AI之间的战斗退出
!!if&y13=23:;   左边为盗贼
!!VRy15:S222030 +y13;
!!VRz4:Szy15;
!!VRy16:S222030 +y14;
!!VRz5:Szy16;
!!HEy2:B0/?z6;
!!if&y5=0:;
!!VRz9:S^Darkdevil.wav^;
!!SN:Pz9;
**修改内存
!!VRz7:S^^;
!!VRz8:Sz222116;
!!UN:A44/9/7 A44/10/8;
!!SN:E7824928/1/222313; //HerSklB.def
!!UN:C5200101/4/v1 C5200147/4/v1;
!!IF:Q2/8/44/2^%Z222422^;  Q2
*还原内存*
!!UN:C5200101/4/6685204 C5200147/4/6685204;
!!UN:A44/9/0 A44/10/0 ;
!!en:;
!!VRy17:S0;
!!VRy17&y5=0/2:S1;
!!VRy17&y5=1:S1;  AI直接选择
!!if&y17=1:;
!!IF:Wy1;
!!VRw185:Sy14;
!!IF:Wy2;
!!VRw185:Sy13;
!!SN:W^DaoZei.1^/y13 W^DaoZei.2^/y14 W^DaoZei.Flag^/1;
!!en:;
!!en:;

!!if&y14=23:;   右边为盗贼
!!VRy15:S222030 +y14;
!!VRz4:Szy15;
!!VRy16:S222030 +y13;
!!VRz5:Szy16;
!!HEy1:B0/?z6;
!!if&y6=0:;
!!VRz9:S^Darkdevil.wav^;
!!SN:Pz9;
**修改内存
!!VRz7:S^^;
!!VRz8:Sz222116;
!!UN:A44/9/7 A44/10/8;
!!SN:E7824928/1/222313; //HerSklB.def
!!UN:C5200101/4/v1 C5200147/4/v1;
!!IF:Q2/8/44/2^%Z222422^;  Q2
*还原内存*
!!UN:C5200101/4/6685204 C5200147/4/6685204;
!!UN:A44/9/0 A44/10/0 ;
!!en:;
!!VRy17:S0;
!!VRy17&y6=0/2:S1;
!!VRy17&y6=1:S1;  AI直接选择
!!if&y17=1:;
!!IF:Wy1;
!!VRw185:Sy14;
!!IF:Wy2;
!!VRw185:Sy13;
!!SN:W^DaoZei.1^/y13 W^DaoZei.2^/y14 W^DaoZei.Flag^/1;
!!en:;
!!en:;

-------------------------------------------------------
!?BA1;
!!SN:W^DaoZei.1^/?y1 W^DaoZei.2^/?y2 W^DaoZei.Flag^/?y3;
!!SN:W^DaoZei.1^/0 W^DaoZei.2^/0 W^DaoZei.Flag^/0;
!!FU|y1=0/y2=0/y3=0:E;

!!if&v9555>-1:;
!!IF:Wv9555;
!!VRw185:Sy1;
!!en:;
!!if&v9560>-1:;
!!IF:Wv9560;
!!VRw185:Sy2;
!!en:;

-------------------------------------------------------
!?CM0&1000;   &魔手1
!!OW:A-1/?y10;
!!FU&y10<0:E;
!!IF:Wy10;
!!if&y10<>84:;  黛玛克天生可盗取宝物
!!FU&w185<>23:E;
!!en:;
!!CM:I?y11;
!!FU&y11<>37:E;
!!HEy10:P?y12/?y13/?y14;
!!CM:P?y15/?y16/?y17;
!!FU17042:P1/y10/2;
!!OBy15/y16/y17:T?y18;
!!FU&y14<>y17:E;
!!VRy19&y12>y15:Sy12-y15;
!!VRy19&y15>y12:Sy15-y12;
!!FU&y19>10:E;   十格限制
!!VRy20&y13>y16:Sy13-y16;
!!VRy20&y16>y13:Sy16-y13;
!!FU&y20>10:E;
!!FU17042&y18=5:P2/y10/y12/y13/y14/y15/y16/y17;  盗宝~与巫术加强是否冲突

!?FU17042&x1=1;  自带透视
!!HEx2:A2/0/d/?y10 I?y11/1;
!!FU&y10<1:E;
!!UN:C6919480/4/?y12;
!!VRy13:Sx2 *1170 +297 +136736 +y12;
!!UN:Cy13/4/2; ..0,1,2 - 透视之眼的等级 By 007
!!HEx2:Iy11/1;

!?FU17042&x1=2;  盗阵图
!!HEx2:Ed/?y9 I?y10/1 B0/?z6;
!!if&y10<25:;
!!VRz9:S^Default.wav^;
!!SN:Pz9;
!!IF:Q1/35/y10/4^%Z222423^;   25mp
!!FU&y10<25:E;
!!en:;
!!OBx6/x7/x8:U?y11 C?y12;  物体子类型.控制字符
!!UN:N0/7/y11; 宝物名字跟编号
!!UN:Ay11/3/?y99;检测宝物级别
!!VRy90&y9<10:S4;
!!VRy90&y9>11/y9<20:S8;
!!VRy90&y9>21:S16;
!!if&y90>=y99:;可以盗宝 20级+可以盗取所有宝物
!!IF:Q2^%Z222424^;   Q2
!!if&-2:;
!!VRz9:S^timeover.wav^;
!!SN:Pz9;
!!FU&-2:E;
!!en:;
!!VRv9:C0;
!!DO17042/19/82/1:P3/x2;    检查英雄行囊v9
!!VRy13:Sv9;
!!VRv9:C0;
!!if&y13>63:;
!!VRz9:S^Default.wav^;
!!SN:Pz9;
!!IF:M^%Z222425^;   64件宝物限制
!!FU&y13>63:E;
!!en:;
!!VRv10:C0;
!!DO17042/0/6/1&y12<>0:P4/x6/x7/x8;  检查是否设置守卫v10
!!VRy16:Sv10;
!!VRv10:C0;
!!if&y16>0:;
!!VRz9:S^Default.wav^;
!!SN:Pz9;
!!IF:M^%Z222426^;  守卫限制
!!FU&y16>0:E;
!!en:;
!!VRz9:S^treasure.wav^;
!!SN:Pz9;
!!IF:Q1/8/y11/1:^%Z222427^;
!!UN:Ox6/x7/x8;
!!VRz9:S^pickup01.82M^;
!!SN:Pz9;
!!VRy17:Sy10-25;
!!HEx2:Iy17/1 A4/y11;
!!el:;
!!IF:M^抱歉，您的等级不足以盗取这么贵重的宝物!^;
!!FU:E;
!!en:;
!!CM:R0;
!!UN:R1;

!?FU17042&x1=3;
!!HEx2:A1/?y13/x16;
!!VRv9&y13>-1:+1;
!!VRv9&y13<0:+0;

!?FU17042&x1=4;
!!ARx2/x3/x4:Gx16/?y14/?y15;
!!VRv10&y14<>-1/y15>0:+1;

-------------------------------------------------------
!?BA0&1000;
!!SN:W^DaoQie.1^/0 W^DaoQie.2^/0;
!!FU17042&v9555>-1:P5/v9555/0;  &魔手2
!!FU17042&v9560>-1:P5/v9560/1;

!?FU17042&x1=5;
!!HEx2:O?y10;
!!VRv10:S0;
!!DO17042/0/155/1&x3=0:P-5/x2/0/y10;
!!DO17042/0/155/1&x3=1:P-5/x2/1/y10;
!!if&v10>0:;
!!VRy13:Sv10;  取得盗贼ID
!!VRv10:S0;
!!SN&x3=0:W^DaoQie.1^/y13;
!!SN&x3=1:W^DaoQie.2^/y13;
!!en:;

!?FU17042&x1=-5;
!!HEx16:O?y11 N?y12;
!!FU|y11<>x4/v10>0:E;
!!IF:Wx16;
!!if&w185=23:;
!!VRv10:Sy12;  取得盗贼ID
!!en:;

-------------------------------------------------------
!?FU77006&1000/v6103=0;
!!SN:X?y1/?y2;
!!VRy3:Sy1 *21 +y2;
!!FU|y3<0/y3>41:E;
!!BMy3:T?y4 N?y5 I?y6;
!!FU|y4<0/y5<1:E;
!!BHy6:N?y7;
!!FU&y7=-1:E;
!!BU:T?y8;
!!FU&y8=1:E;
!!FU17042&y7>-1/v997<3/y6=0/v9560>-1:P6/23/y7/0/y3/v9560;  &魔手3
!!FU17042&y7>-1/v997<3/y6=1/v9555>-1:P6/23/y7/1/y3/v9555;

!?FU17042&x1=6;
!!SN:W^DaoQie.1^/?y7 W^DaoQie.2^/?y8;
!!FU&x4=0/y7=0:E;   取本方盗贼ID
!!FU&x4=1/y8=0:E;
!!IF:Wx3;
!!FU&w185=23:E;   盗贼自身战斗无效&非英雄对战无效
!!DO17042/0/20/1&x4=0:P-6;  检查本方堆栈
!!DO17042/21/41/1&x4=1:P-6;
!!VRy9:Sv9;
!!VRv9:S0;
!!FU&y9>=19:E;  超过19支部队退出
!!VRy10&x4=0:Sy7;
!!VRy10&x4=1:Sy8;  取盗贼ID
!!HEy10:B0/?z6 Ed/?y11;  姓名&等级
!!HEx6:B0/?z7;
!!FU16039:Px6/?y1/?y2/?y3/?y4/6/?y5/0;  //调用检查英雄4围金钱函数
!!VRy12:Sy11 *250;  按等级*250窃取金钱
!!VRy12&y12>y5:Sy5;
!!VRy12&y12>10000:S10000;
!!VRy6:Sy12 *-1;
!!FU90012:Px4/1/?y13;   //调用设置召唤位置函数
!!VRz9:S^TelptOut.wav^;
!!SN:Pz9;
!!BU:S143/1/y13/x4/-1/0;
!!BU:Ey13/?y14;
!!if&y14>-1:;
!!VRz2:S^Zn143NPC.def^;
!!FU16028:Py14/2; //调用通过外置DEF变换形象函数 By Oxfea &007
!!BMy14:F4194304;
!!FU16022:Py14/3;  //调用生物单体动画函数 By 007
!!FU16022:Py14/15;
!!VRz9:S^Precison.wav^;
!!SN:Pz9;
!!VRy15:S0;
!!VRy15&x4=0:S16;
!!VRz3:S^GoldCoinD.def^;   大金币
!!FU16037:P0/3/y15/150/0/0/1;  //调用更换魔法动画函数 By 007
!!FU16039:Px6/?y21/?y22/?y23/?y24/6/?y25/y6;  //调用检查英雄4围金钱函数
!!FU16039:Px3/?y31/?y32/?y33/?y34/6/?y35/y12;
!!VRz10:Sz222421;
!!MM:Sz10;
!!BMy14:K9999;
!!en:;
!!SN&x4=0:W^DaoQie.1^/0;
!!SN&x4=1:W^DaoQie.2^/0;
!!BU:R;

!?FU17042&x1=-6;
!!BMx16:T?y1 N?y2 O?y3;
!!VRv9&y1>-1:+1;    检查部队数

貌似把这段修改就可以把交换职业的步骤放在战斗开始时触发了！这样就可以解决攻守城里面的职业互换了！但有个问题就是有时候出现战斗中没有偷钱！！！有大神能给点意见么？

XEricSin

cs3300330033 发表于 2021-8-11 10:42
!-?FU77010;取消
!-!SN:W^DaoZei.1^/0 W^DaoZei.2^/0 W^DaoZei.Flag^/0;取消
!-!SN:X?y1/?y2  取消

!-!SN:W^DaoZei.1^/0 W^DaoZei.2^/0 W^DaoZei.Flag^/0;取消
这个可能需要保留吧

cs3300330033

XEricSin 发表于 2021-8-12 19:51
!-!SN:W^DaoZei.1^/0 W^DaoZei.2^/0 W^DaoZei.Flag^/0;取消
这个可能需要保留吧

这句是啥意思?大神

XEricSin

cs3300330033 发表于 2021-8-12 23:37
这句是啥意思?大神

初始化3个全局变量为0，这几个变量会在其他地方使用。

cs3300330033

XEricSin 发表于 2021-8-14 11:37
初始化3个全局变量为0，这几个变量会在其他地方使用。

谢谢大神解答!!!!!!!