【已解决】设置人类玩家的紫水晶战场释放紫龙脚本怎么写？

水流行险

比如，很多人都埋怨封神很难，野怪很野、没有资源、开局带那几个小兵连石矿都打不下来，别提怎样在第二周被电脑端掉。都超不过十天，哪有什么乐趣？大部分人是冲着音乐、魔法、怪物形象来的，说什么发扬吃苦耐劳、扛到解放……这是都是骗小孩的。应该让我们先玩得转，再玩的好。
如何建一个开局给人类英雄增加一些甜头的脚本呢？
我要一开局就有：
1、一个本族的七级生物（还要一点功勋值保证能带着它），
2、有一个宝物，
3、有两根大门钥匙
4、有2000金币、资源各5个。

请版主和高手帮忙指点一下！！

ZVSE
!?PI;
!!HE-1:C2/134/1/1;游戏开始给英雄增加一个134紫龙
!!HE-1:A60;游戏开始给英雄增加一个160宝物
这是错误的，因为开始没有英雄编号！！！

后来我又想一下，不如在紫水晶(宝物编号143）上增加一点，让人类玩家携带的时候在战场生产生一个紫龙？要怎么来写呢？

canary

!?PI是初始化时候执行的触发器

你可以考虑放到游戏的时间触发器 比如
!#TM2:S1/999/1/255; 每天触发
!#TM2:S1/999/999/255;只有第一天触发== 自己选哪天触发 类似事件

!?TM2;

HE-1:A160 C2/134/1/1;

水流行险

canary 发表于 2019-4-2 14:03
!?PI是初始化时候执行的触发器

你可以考虑放到游戏的时间触发器 比如

高手啊！就这样，太符合我的思维了!
我做一个锁，就是那个145的锁，让它战场放置一个紫龙。
然后让人类玩家开局有持有一个，哈哈，这样就能流畅玩下去了!!
谢谢！

水流行险

canary 发表于 2019-4-2 14:03
!?PI是初始化时候执行的触发器

你可以考虑放到游戏的时间触发器 比如

下面是强化宝物的设置，可是，我要把宝物145号设置为战场召唤放置一个紫龙怎么来？
请版主指点！

;战场生成宝物设置(x1=30~35)
=========================================================
!?BF&1000;
!!FU983&v9555>-1/v6210>0:P30/v9555/105/0;  天使联盟
!!FU983&v9560>-1/v6211>0:P30/v9560/114/1;
!!DO983/0/20/1&v9555>-1/v6212>0:P31;       龙王神力
!!DO983/21/41/1&v9560>-1/v6213>0:P31;
!!DO983/0/20/1&v9555>-1/v6214>0:P32;       幻影神弓
!!DO983/21/41/1&v9560>-1/v6215>0:P32;

!?FU983&x1=30;
!!HEx2:Ed/?x5;
!!VRx6:Sx5 :5+1;
!!VRx6&x6<1:S1;
!!VRx7:S-1;
!!VRx7&x4=0:Sx3+1;
!!VRx7&x4=1:Sx3-1;
!!BU:Dx3/?x8 Dx7/?x9;
!!FU&x8<>-1/x9<>-1:E;
!!BU:S150/x6/x3/x4/-1/0;

!?FU983&x1=31;
!!BMx16:N?x2 T?x3 F?i F?j A?x6 D?x7 U1/?x8 U2/?x9 H?x10 S?x11;
!!VRi:&2;
!!VRj:&8;
!!FU|x2<1/x3=149:E;
!!BMx16&i<=0:Fd2;
!!BMx16&j<=0:Fd8;
!!VRx4:Sx16 +1 *-1;
!!EAx4:F119/48/?x5;
!!EAx4&x5>0:Bx5/1/119/48/1/1/1/1/1/1/1/1/1/1/1;
!!BMx16:Ax6 Dx7 U1/x8 U2/x9 Hx10 Sx11;

!?FU983&x1=32;
!!BMx16:N?x2 T?x3 F?i F?j;
!!VRi:&4;
!!VRj:&32768;
!!FU|x2<1/x3=149/i<=0:E;
!!BMx16&j<=0:Fd32768;
!!VRx4:S0 T7;
!!VRx5&x4=0:S41;
!!VRx5&x4=1:S44;
!!VRx5&x4=2:S48;
!!VRx5&x4=3:S49;
!!VRx5&x4=4:S44;
!!VRx5&x4=5:S51;
!!VRx5&x4=6:S53;
!!VRx5&x4=7:S55;
!!BMx16:Mx5/3/3;

水流行险

canary 发表于 2019-4-2 14:03
!?PI是初始化时候执行的触发器

你可以考虑放到游戏的时间触发器 比如

还有，这个宝物是在行囊箱里面的，还要我手动带上去。不能设置想紫水晶那样，一开始就带在身上吗？

canary

水流行险 发表于 2019-4-2 20:52
还有，这个宝物是在行囊箱里面的，还要我手动带上去。不能设置想紫水晶那样，一开始就带在身上吗？

HE-1:A4/#;这个是直接佩戴到英雄身上
你上面那楼的脚本里的v6210~v6215不知道定义的是什么

还有你这个写法，貌似AI在右边也会触发的。
你的FU接收器里面得限制得更严一点才行，不然现在打野兵是没问题，打电脑就会出现电脑也会召唤天使到113位置。
你如果只想自己触发 可以加上这句做个电脑跟玩家得区分
!!OW:C?y1;获取行动方所属势力y1（如果是你的行动轮，检测出来的就是你的势力颜色。如果是电脑行动轮，这个获得的值就是电脑的势力颜色。）
!!OW:Ay1/?y2;而这个命令可以直接获取当前行动控制的英雄编号y2(也可以直接用-1表示当前行动颜色）
!!OW:Iy1/?y3; 然后再用这个指令就可以判断行动方是电脑还是玩家  y3=1电脑 y3=0玩家
或者更简单就是直接加上条件&1000（这个算是直接限定玩家触发）
总之脚本这部分其实摸清楚脉络了很简单。
1.注意触发器触发的时机，怎么触发，什么时候触发。
2.注意接收器的触发条件限制。
3.FU函数具体操作过程。

水流行险

canary 发表于 2019-4-3 01:20
HE-1:A4/#;这个是直接佩戴到英雄身上
你上面那楼的脚本里的v6210~v6215不知道定义的是什么

老大，太难了！
我就想让编号145号的宝物设置在战场114的位置召唤放置一个紫龙（134）？能加上“如果这个宝物是人类携带就生效，非人类就不生效、”就更好了。
拜托，给我几行代码吧！神啊，救救我吧

canary

水流行险 发表于 2019-4-4 16:10
老大，太难了！
我就想让编号145号的宝物设置在战场114的位置召唤放置一个紫龙（134）？能加上“如果这 ...

你们都太懒了吧，看看帮助，你这个思路已经有了，剩下就是自己慢慢写慢慢测试了。

水流行险

canary 发表于 2019-4-5 00:14
你们都太懒了吧，看看帮助，你这个思路已经有了，剩下就是自己慢慢写慢慢测试了。

!#TM2:S1/999/1/255; 每天触发
!#TM2:S1/999/999/255;只有第一天触发== 自己选哪天触发 类似事件

!?TM2;

!!HE-1:A4/143;这个紫水晶143是直接佩戴到英雄身上


;变量准备
=========================================================
!?PI;
!!VRv6210:C0/0/0/0/0/0/0/0/0/0;    v6210~v6239变量清空
!!VRv6220:C0/0/0/0/0/0/0/0/0/0;    v6230~v6239共10个未使用
**VRv6230:C0/0/0/0/0/0/0/0/0/0;

!?BA0&1000;
!!VRv6210:C0/0/0/0/0/0/0/0/0/0;
!!VRv6220:C0/0/0/0/0/0/0/0/0/0;
**VRv6230:C0/0/0/0/0/0/0/0/0/0;

!!BA:H0/?v9555;   英雄变量同元老殿堂
!!BA:H1/?v9560;
!!HEv9555&v9555>-1:E?v9549;
!!HEv9560&v9560>-1:E?v9551;

!?BA1&1000;
!!HEv9555&v9555>-1:E?v9550;
!!HEv9560&v9560>-1:E?v9552;

--------------------------------------------------------
!?BG&1000;        动作变量同怪物强化Ⅲ
!!VRv1360:C-1/-1/-1/-1/-1/-1/-1/-1/-1/-1;
!!BG:A?v1360 D?v1361 E?v1362;
!!BG:H?v1363 N?v1364 Q?v1365 S?v1366;
!!BHv1365:N?v1367;
!!HEv1367:Ed/?v1368 I?v1369/1;


=========================================================
;战斗前宝物设置(x1=20~25)
=========================================================
!?BF&1000;
!!FU983&v9555>-1/v6210>0:P30/v9555/105/0;  天使联盟
!!FU983&v9560>-1/v6211>0:P30/v9560/114/1;

!?FU983&x1=30;     X1=30触发
!!HEx2:Ed/?x5;     X2编号的英雄 到X5
!!VRx6:Sx5 :5+1;   设置X6=X5除以5+1
!!VRx6&x6<1:S1;    当X6小于1就设置X6=1
!!VRx7:S-1;        设置X7=-1
!!VRx7&x4=0:Sx3+1;  当X4=0就设置X7=X3+1
!!VRx7&x4=1:Sx3-1;  当X4=1就设置X7=X3-1
!!BU:Dx3/?x8 Dx7/?x9;   检查X3位置的怪物堆栈数量X8是否死亡 X7位置-X9是否死亡
!!FU&x8<>-1/x9<>-1:E;   -1没有怪兽、-2存活，没有怪兽就结束

!!OW:C?y1;获取行动方所属势力y1（如果是你的行动轮，检测出来的就是你的势力颜色。如果是电脑行动轮，这个获得的值就是电脑的势力颜色。）
!!OW:Ay1/?y2;而这个命令可以直接获取当前行动控制的英雄编号y2(也可以直接用-1表示当前行动颜色）
!!OW:Iy1/?y3; 然后再用这个指令就可以判断行动方是电脑还是玩家  y3=1电脑 y3=0玩家
!!FU&y3<>1:E; 如果y3=1就结束

!!BU:S150/x6/x3/x4/-1/0;   放置bus-怪物类型编号、数量、位置、所属一方、部队编号-1无、重画1是0否

水流行险

水流行险 发表于 2019-4-5 02:41
!#TM2:S1/999/1/255; 每天触发
!#TM2:S1/999/999/255;只有第一天触发== 自己选哪天触发 类似事件

这怎么和我要的143宝物联系起来，就像脚本中根本没有提到129的天使联盟一样？

水流行险

!!HEy7:A2/166/d/?y31;  是否装备缪斯项链
!!FU90020&y31>0:P3/y6/36/50/1/0/1/166/y7;  缪斯项链

!!if&x8=166:;  缪斯项链召唤1仙女龙，HP为英雄级别*50+500
  !!HEx9:Ed/?y4;
  !!VRy5:Sy4 *50 +500;  hp
  !!FU90012:Px2/2/?y6;
  !!FU|y6=0/y11=6:E;
  !!VRz9:S^SumnElm.wav^;
  !!SN:Pz9;
  !!BU:S134/1/y6/x2/-1/0;
  !!BU:Ey6/?y7;
!!if&y7>-1:;
  !!BMy7:Hy5 Mx3/999/3;
  !!UN:N3/4/134/1;
  !!VRz10:Sz172141;
  !!MM:Sz10;
!!en:;

水流行险

HE  检查英雄的杂物位置是否配备编号143紫水晶
ow  检测英雄的是够为人类玩家
BU：S放置一个紫龙134在战场上

canary

水流行险 发表于 2019-4-5 03:15
HE  检查英雄的杂物位置是否配备编号143紫水晶
ow  检测英雄的是够为人类玩家
BU：S放置一个紫龙134在战 ...

第一 时间触发器 或者初始化触发给玩家添加宝物
!?PI; 游戏初始化触发
!!DO20190405/0/7/1:P;检测所有颜色
!?FU20190405;
!!OW:Ix16/?y1;
!!if&y1=0:;玩家
!!OW:Ox16/0/?y2;取玩家第一个英雄
!!HEy2:A4/#; #号表示你要给的宝物编号 自己填
!!en:;
好了 开局送宝部分完成
第二 战斗触发器
装备该宝物的玩家战场召唤某种生物
!?BA0&1000;仅限玩家参与的战斗开战触发
!!BA:O?y1/?y2;检测战斗双方英雄所属势力

!!OW:Iy1/?y3; 检测进攻英雄是玩家还是电脑
!!OW&y2>-1:Iy2/?y4;防守方非野兵时候检测防守英雄是玩家还是电脑
!!FU20190405&y3=0:P1/0/106;进攻英雄是玩家
!!FU20190405&y4=0:P1/1/113;防守英雄是玩家

!?FU20190405&x1=1;
!!BHx2:N?y1;检测玩家英雄编号
!!HEy1:Ed/?y2 A2/#/d/?y3;检测玩家英雄等级 以及是否装备#号宝物
!!BU:Ox3/?y4;召唤位置障碍物检测
!!BU:Ex3/?y5;召唤位置活物检测
!!FU&y3=0:E;未装备#号宝物退出召唤
!!FU&y4>0:E;召唤位置有障碍物退出召唤
!!FU&y5<>-1:E;召唤位置有活物退出召唤
!!VRy6:Sy2:5+1;召唤的数量跟玩家等级挂钩 每5级多一只召唤生物
!!BU:S150/y6/x3/x2/-1/0;在指定位置上召唤至高大天使

完了，就只需要这么点东西，我完全没看懂你整那么多V变量是干啥的 一般作为可以跨函数使用的V变量 我们都是很节省的在省着用的，函数内调用的尽量用临时变量y这些

你回头看看你写的东西是不是逻辑有点混乱了

水流行险

canary 发表于 2019-4-5 12:25
第一 时间触发器 或者初始化触发给玩家添加宝物
!?PI; 游戏初始化触发
!!DO20190405/0/7/1:P;检测所有 ...

啊!太帅气了！学会说话很难啊！

我放进去的时候进不去如图

水流行险

第一部分HE处出错，
第二部分好像与第一部分的xy挂钩，比如封神开始有了143的紫水晶，我再加就会有2个紫水晶。我把第一部分删除，能进去，可是我在打第一个野怪的时候并没有放置出150至高大天使。我怀疑是第二部分的X3处没有定义位置。


!?PI; 游戏初始化触发!!DO20190405/0/7/1:P;检测所有颜色
!?FU20190405;
!!OW:Ix16/?y1;
!!if&y1=0:;玩家
!!OW:Ox16/0/?y2;取玩家第一个英雄
!!HEy2:A4/143;   143#号表示你要给的宝物编号 自己填
!!en:;第一 时间触发器 或者初始化触发给玩家添加宝物 好了 开局送宝部分完成 第二 战斗触发器装备该宝物的玩家战场召唤某种生物

!?BA0&1000;仅限玩家参与的战斗开战触发
!!BA:O?y1/?y2;检测战斗双方英雄所属势力

!!OW:Iy1/?y3; 检测进攻英雄是玩家还是电脑
!!OW&y2>-1:Iy2/?y4;防守方非野兵时候检测防守英雄是玩家还是电脑
!!FU20190405&y3=0:P1/0/106;进攻英雄是玩家
!!FU20190405&y4=0:P1/1/113;防守英雄是玩家

!?FU20190405&x1=1;
!!BHx2:N?y1;检测玩家英雄编号
!!HEy1:Ed/?y2 A2/143/d/?y3;检测玩家英雄等级 以及是否装备#143号宝物
!!BU:Ox3/?y4;召唤位置障碍物检测
!!BU:Ex3/?y5;召唤位置活物检测
!!FU&y3=0:E;未装备#号宝物退出召唤
!!FU&y4>0:E;召唤位置有障碍物退出召唤
!!FU&y5<>-1:E;召唤位置有活物退出召唤
!!VRy6:Sy2:5+1;召唤的数量跟玩家等级挂钩 每5级多一只召唤生物
!!BU:S150/y6/x3/x2/-1/0;在指定位置上召唤至高大天使

canary

水流行险 发表于 2019-4-5 15:58
第一部分HE处出错，
第二部分好像与第一部分的xy挂钩，比如封神开始有了143的紫水晶，我再加就会有2个紫水 ...

我都给你写出来了 你把我上面那楼的代码复制下 把#号的宝物改成143试试。

你写的部分X16谁知道是啥啊
你必须开局全部检索一遍 X16才有赋值才表示各种意义
!!FU40000/0/155/1:P;这种表示全英雄编号检索
!!FU40000/0/7/1:P;全势力检索

一般的写法要么定时器触发 第一天或者每天检索所有英雄或者所有势力 然后X16才要么代表任意英雄编号或者任意势力颜色

canary

我给你写了一段 开局多送一个紫水晶

装备紫水晶按等级*5+1召唤紫龙 位置随机

!#TM2:S1/999/999/255;
!?TM2;第一天触发
!!OW:O-1/0/?y2;取玩家第一个英雄
!!HEy2:A4/143; #号表示你要给的宝物编号 自己填

!?BF&1000;仅限玩家参与的战斗战场生成后触发
!!BA:O?y1/?y2;检测战斗双方英雄所属势力
!!OW:Iy1/?y3; 检测进攻英雄是玩家还是电脑
!!OW&y2>-1:Iy2/?y4;防守方非野兵时候检测防守英雄是玩家还是电脑
!!FU20190405&y3=0:P1/0;进攻英雄是玩家
!!FU20190405&y4=0:P1/1;防守英雄是玩家

!?FU20190405&x1=1;
!!BHx2:N?y1;检测玩家英雄编号
!!HEy1:Ed/?y2 A2/143/d/?y3;检测玩家英雄等级 以及是否装备#号宝物
!!FU&y3=0:E;未装备143号宝物退出召唤
!!FU16029:P2/x2/?y4;  //调用007战场随即位置函数
!!VRy5:Sy2*5+1;召唤的数量跟玩家等级挂钩 每级5只
!!BU:S134/y5/y4/x2/-1/0;在指定位置上召唤紫龙

水流行险

canary 发表于 2019-4-5 19:03
我给你写了一段 开局多送一个紫水晶

装备紫水晶按等级*5+1召唤紫龙 位置随机

;hap;;hap;;hap;;hap;;hap;;hap;;hap;;hap;;hap;;hap;;hap;;hap;
FU20190405居然是随手写下的！！太帅气了！
终于不会被木材厂的野怪打得妈妈都不认识了!!
独孤求败终于可以抬头昂胸地所有的wog选项大胆打开，顶天立地的做人了！！
不过我要每5级一只就够了，不用每级5只。要自律来保持游戏的生态平衡嘛。呵呵！

水流行险

canary 发表于 2019-4-5 12:25
第一 时间触发器 或者初始化触发给玩家添加宝物
!?PI; 游戏初始化触发
!!DO20190405/0/7/1:P;检测所有 ...

无英雄或指挥官的野兵页会出现紫龙！！太可怕了！怎么办？

水流行险

canary 发表于 2019-4-5 19:03
我给你写了一段 开局多送一个紫水晶

装备紫水晶按等级*5+1召唤紫龙 位置随机

野兵居然也有紫龙！怎么办呀？