战马系统-ERA平台1.0正式版

fly123 · 发表于 2013-6-2 17:58:21

本人现在宣布，本人正是转战Era平台，以后的脚本，基本都会以Era平台为运载基础。也是响应贤知号召，否则咱这Era平台的版主真是个摆设。刚才把仙剑战马系统转换到Era版本，感觉真不好写，先写个Era初搞，虽然困难重重，不过，这第一步也算是迈出啦。呵呵。
现在把完成脚本贴出来，已经修正好，下面有压缩的Erm附件。可以加入到Era自制Erm中。请帮忙测试。直接将压缩文件解压到Era根目录下，然后通过ERM脚本激活器，激活编号130的Erm。
效果：玩家所有英雄将会拥有属于自己的独特的战马，就像二追一样。使用方法：大地图右键点击，英雄移动图标出现提问 .
Ps：可以和二追并存。第一次写。确实很多还搞不明白，同时写的也比较繁琐，还请各位多海涵。

ZVSE
ERMS_ScriptDate=3.6(June).2013
_WARNING_#1=IMPORTANT! This file is not in a plain text format. NEVER use any editor except ERM_S for making any kind of changes!
ERMS_PoweredBy=ERM Scripter v. 2004.6.29.918
!?PI;
!!SN:M-1/156/0/1 W^激活^/v1; 0#
!!SN:M-1/1560/0/1 W^悍马^/v1; 1# [申请 156*10=1560元素的数值型数组(存于游戏中，存档必须为1),转换数组名为悍马]
!!VRy1:S0; 2#
!!VRy10:Sy1 *10 +0; 3# [y10-y19用10个位置，分别保存0-155英雄的战马10个状态]
!!VRy11:Sy1 *10 +1;
!!VRy12:Sy1 *10 +2;
!!VRy13:Sy1 *10 +3;
!!VRy14:Sy1 *10 +4;
!!VRy15:Sy1 *10 +5;
!!VRy16:Sy1 *10 +6;
!!VRy17:Sy1 *10 +7;
!!VRy18:Sy1 *10 +8;
!!VRy19:Sy1 *10 +9;
!!VRv1:C0; 战斗次数
!!VRv2:S0; 开启标志
!!VRv3:S16; 攻防
!!VRv4:S8; 速度
!!VRv5:S110; 生命
!!VRv6:S21; 伤害
!!VRv7:S0; 移动力奖励
!!VRv8:S-1; 类型
!!VRv9:S-1; 堆栈
!!VRv10:S1; 标记生存
!!SN:W^悍马^/?y99;
!!SN:My99/y10/v1; [分别设置索引位置的值]
!!SN:My99/y11/v2; [y99就是代表这个新增数组(可以想象成数组大集合的索引),而y10-y19则是这个数组下的索引]
!!SN:My99/y12/v3;
!!SN:My99/y13/v4;
!!SN:My99/y14/v5;
!!SN:My99/y15/v6;
!!SN:My99/y16/v7;
!!SN:My99/y17/v8;
!!SN:My99/y18/v9;
!!SN:My99/y19/v10;
!!SN:W^激活^/?y98;
!!SN:My98/y1/-1;
!!VRy1:+1;
!!SN&y1<156:G3; 从第3个位置开始循环，一直到155号英雄结束
!?CM0; 大地图右键点击，英雄移动图标出现提问
!!CM:I?y1 F?y2;
!!OW:A-1/?g; 取当前激活英雄为零时变量g，方便调用
!!SN:W^激活^/?y98;
!!SN:My98/g/?v10;
!!if&y1=7/v10<0:; 如果鼠标动作为右键点击，英雄移动图标
!!IF:Q1/21/195/2^请问您想要激活战马系统吗？^;
!!if&1:; 如果回答YES,该英雄将启用战马系统
!!VRz11:S^一级坐骑^;!!VRz12:S^二级坐骑^;
!!VRz13:S^三级坐骑^;!!VRz14:S^四级坐骑^;
!!UN:G1/25/1/z11;
!!UN:G1/195/1/z12;
!!UN:G1/172/1/z13;
!!UN:G1/131/1/z14;
!!HEg:B0/?z1;
!!IF:N21/25/21/195/21/172/21/131;
!!IF:N^%Z1 坐骑升级顺序图 ^;
!!UN:G1/25/1/0;!!UN:G1/195/1/0;
!!UN:G1/172/1/0;!!UN:G1/131/1/0;
!!IF:Q2/21/195/1^{粉丝}
一匹强壮的战马崇拜你的伟大
名声，毫不迟疑地加入了你。^;
!!VRz4:S^killfade.82M^;
!!SN:Pz4;
!!VRz2:S^奖励额外移动力^;
!!UN:A98/9/2;!!UN:A98/10/2;
!!IF:Q2/8/98/1^{坐骑养成系统开启}
坐骑不仅是战场上的得力助手，而且随着坐骑的成长，%Z1每天能得到额外的移动力，坐骑会顺次表现为4种外貌：独角-烈火马-梦魇兽-凤凰。英雄界面 {SHIFT+左键} 点神的祝福图标，可以查看坐骑当前的属性。
{注意：}
坐骑所加的移动力是耗费黄金的，如果黄金数量低于坐骑所能提供的移动力，则得到的额外移动力数量为当天所剩余的黄金数量。你不能又要马儿不吃草，又要马儿跑得快。如果坐骑不幸战死，你可以在建有马厩的人类城堡或者野外马厩复活它。^;
!!UN:A98/9/0;!!UN:A98/10/0;
!!SN:W^悍马^/?y99;
!!VRy11:Sg *10 +1; 开启标志
!!VRy12:Sg *10 +7; 类型
!!VRv1:S1;
!!VRv2:S25;
!!VRv10:S1;
!!SN:My98/g/v10;
!!SN:My99/y11/v1;
!!SN:My99/y12/v2;
!!IF:M^“我还能挖宝么？”%Z1问
“能吧”，独角一边啃着嫩草一边含糊地回答。^;
!!FU20000:P2/g;
!!en:;
!?CM2&1000; 英雄界面战马状态查看
!!CM:H?g/?f; 当前英雄ID存入g
!!VRy11:Sg *10 +1; 开启标志
!!VRy12:Sg *10 +7; 类型
!!SN:W^悍马^/?y99;
!!SN:My99/y11/?v9;
!!SN:My99/y12/?v10;
!!CM:I?y30 S?y31 F?y32;
!!FU20000&y30=139/y31=12/y32=1/v9=1:P2/g;战马养成系统
!!CM&y30=139/y31=12/y32=1/v9=1:R0;
!!IF&y30=139/y31=14/y32=512/v9=1:Q2/21/v10/4^SHIFT+左键点击这里可以查看坐骑的状态。^;
!!CM&y30=139/y31=14/y32=512/v9=1:R0;
!?BA1&1000;
!!HE-1:O?i N?g;
!!if&i>-1:;
!!VRy11:Sg *10 +0; 战斗次数
!!VRy12:Sg *10 +1; 开启标志
!!VRy13:Sg *10 +9; 标记生存
!!SN:W^悍马^/?y99;
!!SN:My99/y11/?v1;
!!SN:My99/y12/?v2;
!!SN:My99/y13/?v3;
!!IF&v1=120:Q2/21/25/21/195/1^坐骑升级了。^;
!!IF&v1=100:Q2/21/25/1^坐骑学会吸魔
{每回合额外消耗敌方英雄魔法值}^;
!!IF&v1=240:Q2/21/195/21/131/1^坐骑升级了。^;
!!IF&v1=360:Q2/21/131/21/132/1^坐骑升级了。^;
!!FU20000&v2=1/v3=1:P3/v1/g;
!!VRv1&v2=1/v3=1:+1;
!!SN:My99/y11/v1;
!!en:;
!?FU20000; 战马属性和状态
!!if&x1=2:;
!!VRy1:Sx2 *10 +9; 标记生存
!!VRy2:Sx2 *10 +2; 攻防
!!VRy3:Sx2 *10 +3; 速度
!!VRy4:Sx2 *10 +4; 生命
!!VRy5:Sx2 *10 +5; 伤害
!!VRy6:Sx2 *10 +6; 移动力奖励
!!VRy7:Sx2 *10 +7; 类型
!!SN:W^悍马^/?y99;
!!SN:My99/y1/?v1;
!!SN:My99/y2/?v2;
!!SN:My99/y3/?v3;
!!SN:My99/y4/?v4;
!!SN:My99/y5/?v5;
!!SN:My99/y6/?v6;
!!SN:My99/y7/?v7;
!!VRz10&v1=1:S^生存^;
!!VRz10&v1=0:S^死亡^;
!!IF:Q2/21/v7/1^{坐骑}
状态：%Z10
攻击奖励：%V2
防御奖励：%V2
生命奖励：%V4
伤害奖励：%V5
速度奖励：%V3
当前给予额外移动力：+%V6^;
!!en:;
!!if&x1=3:; 战马养成
!!VRy1:Sx3 *10 +0; 战斗次数
!!VRy2:Sx3 *10 +2; 攻防
!!VRy3:Sx3 *10 +3; 速度
!!VRy4:Sx3 *10 +4; 生命
!!VRy5:Sx3 *10 +5; 伤害
!!VRy6:Sx3 *10 +7; 类型
!!VRy7:Sx3 *10 +6; 移动力奖励
!!SN:W^悍马^/?y99; [获得数组名在数组层的索引](注意这个索引跟数组元素的索引类似)
!!SN:My99/y2/?v1; 攻防
!!SN:My99/y3/?v2; 速度
!!SN:My99/y4/?v3; 生命
!!SN:My99/y5/?v4; 伤害
!!SN:My99/y6/?v5; 类型
!!SN:My99/y7/?v6; 移动力奖励
!!VRv1&v5=25:Sx2 :5 +15; AD
!!VRv2&v5=25:Sx2 :10 +9; S
!!VRv3&v5=25:Sx2 *10 +110; H
!!VRv4&v5=25:Sx2 +22; EM
!!VRv1&v5=195:Sx2 :5 +16; AD
!!VRv2&v5=195:Sx2 :10 +10; S
!!VRv3&v5=195:Sx2 *10 +120; H
!!VRv4&v5=195:Sx2 +24; EM
!!VRv1&v5=172:Sx2 :5 +21; AD
!!VRv2&v5=172:Sx2 :10 +21; S
!!VRv3&v5=172:Sx2 *10 +200; H
!!VRv4&v5=172:Sx2 +40; EM
!!VRv1&v5=131:Sx2 :5 +50; AD
!!VRv2&v5=131:Sx2 :10 +22; S
!!VRv3&v5=131:Sx2 *10 +1000; H
!!VRv4&v5=131:Sx2 +80; EM
!!VRv6:Sx2 *5; W
!!VRv5&x2>=0/x2<120:S25;
!!VRv5&x2>119/x2<240:S195;
!!VRv5&x2>239/x2<360:S172;
!!VRv5&x2>359:S131;
!!SN:My99/y2/v1; 攻防
!!SN:My99/y3/v2; 速度
!!SN:My99/y4/v3; 生命
!!SN:My99/y5/v4; 伤害
!!SN:My99/y6/v5; 类型
!!SN:My99/y7/v6; 移动力奖励
!!en:;
!!if&x1=4:; 召唤坐骑参战
!!VRy1:Sx4 *10 +1; 开启标志
!!VRy2:Sx4 *10 +9; 标记生存
!!VRy3:Sx4 *10 +7; 类型
!!VRy4:Sx4 *10 +2; 攻防
!!VRy5:Sx4 *10 +3; 速度
!!VRy6:Sx4 *10 +4; 生命
!!VRy7:Sx4 *10 +5; 伤害
!!VRy8:Sx4 *10 +8; 堆栈
!!SN:W^悍马^/?y99;
!!SN:My99/y1/?v1;
!!SN:My99/y2/?v2;
!!SN:My99/y3/?v3;
!!SN:My99/y4/?v4;
!!SN:My99/y5/?v5;
!!SN:My99/y6/?v6;
!!SN:My99/y7/?v7;
!!if&v1>0/v2>0:;
!!BU:E2/?y10;
!!VRx2&y10>20:S161;
!!BU:Sv3/1/x2/x3/-1/0;
!!BU:Ex2/?v10;获取堆栈
!!VRx5&v10>-1:Sv10 +1 *-1;
!!EAx5&v10>-1:B0/1/65/43/0/1/2/3/4/5/6/7/8/9/10; A+
!!EAx5&v10>-1:B1/1/68/43/0/1/2/3/4/5/6/7/8/9/10; D+
!!EAx5&v10>-1:B2/1/109/43/0/1/2/3/4/5/6/7/8/9/10; min+
!!EAx5&v10>-1:B3/1/77/43/0/1/2/3/4/5/6/7/8/9/10; max+
!!EAx5&v10>-1:B4/1/72/37/0/5/10/15/20/25/30/35/40/45/50; H+
!!EAx5&v10>-1:B5/1/83/43/0/0/0/1/1/2/2/3/3/4/4; S+
!!EAx5&v10>-1/v3<>172:B6/1/102/102/0/0/0/0/0/0/0/0/0/0/1; 无惧
!!EAx5&v10>-1/v3=172:B6/1/119/48/0/0/0/0/0/0/0/0/0/0/1; 接受
!!EAx5&v10>-1:B7/1/119/53/0/0/0/0/0/0/0/0/0/0/1; 免疫1-5级
!!EAx5&v10>-1:B8/1/102/98/0/0/0/0/0/0/0/0/0/0/1; 攻返
!!EAx5&v10>-1:B9/1/66/61/0/5/10/15/20/25/30/35/40/45/50; 格挡
!!EAx5&v10>-1:B10/1/97/80/0/0/0/0/0/0/20/40/60/80/100; 酸液
!!EAx5&v10>-1:B11/1/99/75/0/5/10/15/20/25/30/35/40/45/50; 衰老
!!EAx5&v10>-1:B12/1/99/71/0/5/10/15/20/25/30/35/40/45/50; 中毒
!!EAx5&v10>-1:B13/1/76/79/0/5/10/15/20/25/30/35/40/45/50; 偏移
!!EAx5&v10>-1:L79400;
!!EAx5&v10>-1:E79400/2/d/d;
!!EAx5&v10>-1:R156/7;
!!BMv10&v10>-1:Adv4 Ddv4 Sdv5 Hdv6 U1/dv7 U2/dv7 F902147;ADSHEMX
!!SN&v10>-1:My99/y8/v10;
!!en:;
**********************
**********************
!?BA0&1000;
!!BA:H0/?m H1/?n; 注意采用变量需避免变量冲突
!!SN:W^攻id^/m;
!!SN:W^防id^/n;
!!BA:O?g/?h;
!!SN:W^攻属^/g W^防属^/h;
**********************
!?BF&1000;
!!SN:W^攻id^/?v1;
!!SN:W^防id^/?v2;
!!FU20000:P4/139/0/v1;召唤战马参战
!!FU20000&v2>-1:P4/149/1/v2;召唤战马参战
**********************
******************奖励额外移动力*********************
!#TM5:S1/999/1/255;
!?TM5&1000;
!!FU20000:P5;
**********移动力奖励函数************
!?FU20000;
!!if&x1=5:;
!!VRy1:S0;
!!HEy1:O?i;
!!OW:C?h;
!!SN:W^悍马^/?y99;
!!VRy16:Sy1 *10 +6;
!!SN:My99/y16/?x2; 移动力奖励
!!if&x2>0/i=h:;
!!OW:Ri/6/?x3;
!!VRx4:Sx3 -x2;
!!HEy1:W?y10;
!!VRy11&x4>=0:Sy10 +x2;
!!HEy1&x4>=0:Wy11 Gy11;
!!OW:Ri/6/x4;
!!VRy11&x4<0:Sy10 +x3;
!!HEy1&x4<0:Wy11 Gy11;
!!OW&x4<0:Ri/6/0;
!!VRy1:+1;
!!SN&y1<156:G2;
!!en:;
**********************
!?BG0;
!!BG:A?y1 S?y2 H?y3 Q?y4 D?y5 E?y6 N?y7;
!!SN:W^动作^/y1; !!SN:W^施放魔法^/y2;
!!SN:W^动作英雄^/y3; !!SN:W^出手方^/y4;
!!SN:W^魔法目标^/y5; !!SN:W^目标堆栈^/y6;
!!SN:W^动作堆栈^/y7;
!!VRy11&y3>-1:Sy3 *10 +1; 开启标志
!!SN:W^悍马^/?v9;
!!SN:Mv9/y11/?v10;
!!if&y3>-1/v10=1:;
!!FU20000:P11/y3;检查生存
!!en:;
*****攻击后施法*******
!?BG1;
!!SN:W^动作^/?y1; !!SN:W^施放魔法^/?y2;
!!SN:W^动作英雄^/?y3; !!SN:W^出手方^/?y4;
!!SN:W^魔法目标^/?y5; !!SN:W^目标堆栈^/?y6;
!!SN:W^动作堆栈^/?y7;
!!VRy11&y3>-1:Sy3 *10 +1; 开启标志
!!SN:W^悍马^/?y9;
!!SN:My9/y11/?v1;
!!if&v1=1/y3>-1:;
!!VRy50:S0 R99;
!!FU20000&y50<50:P-1/y1/y7/y3/y6/54; 减速
!!FU20000&y50>=50:P-1/y1/y7/y3/y6/78; 驱散有益
!!FU20000&y50>=30/y50<50:P-1/y1/y7/y3/y6/70; stone
!!FU20000&y50>=50/y50<70:P-1/y1/y7/y3/y6/75; 老化
!!FU20000&y50>=70/y50<90:P-1/y1/y7/y3/y6/74; 麻痹
!!FU20000&y50<30:P-1/y1/y7/y3/y6/62; 失明
!!FU20000&y50>=90:P-1/y1/y7/y3/y6/72;束缚
!!FU20000:P11/y3; 检查生存
!!en:;
!?OB98&1000;
!!FU20000:P12/1;
!?OB94;
!!FU20000:P12/2;
!?FU20000;
!!if&x1=-1:;
!!VRy1:Sx4 *10 +8; 堆栈
!!SN:W^悍马^/?y99;
!!SN:My99/y1/?v10;
!!if&x2=6/x3=v10/x3>-1:;
!!BMx5&x5>-1:T?g P?t N?y-1;
!!if&y-1>0|g<145/g>149:;
!!HEx4:Fd/d/?y9/d/1;
!!BMx3&x3>-1:Cx6/t/2/y9/1;
!!BU:R;
!!en:;
***战死和复活***
!!if&x1=11:;
!!VRy1:Sx2 *10 +8; 堆栈
!!VRy2:Sx2 *10 +9; 标记生存
!!SN:W^悍马^/?y99; [获得数组名在数组层的索引](注意这个索引跟数组元素的索引类似)
!!SN:My99/y1/?v1;
!!SN:My99/y2/?v2;
!!BMv1&v1>-1:P?y10; 取坐骑位置
!!BU&v1>-1:Ey10/?y11; 检查坐骑否生存
!!VRv2&y11<0:S0; 标记死亡
!!VRv2&y11=v1:S1; 标记复活
!!SN:My99/y2/v2;
!!en:;
!!if&x1=12:; 战马在城镇或马房复活
!!HE-1:N?y10;
!!VRy1:Sy10 *10 +1; 开启标志
!!VRy2:Sy10 *10 +9; 标记生存
!!VRy3:Sy10 *10 +0; 战斗次数
!!VRy4:Sy10 *10 +7; 类型
!!SN:W^悍马^/?y99;
!!SN:My99/y1/?v1;
!!SN:My99/y2/?v2;
!!SN:My99/y3/?v3;
!!SN:My99/y4/?v4;
!!if&v1=1/v2=0/v3>0:;
!!CA998&x2=1:T?y11;
!!if&x2=1/y11=0:;
!!CA998&x2=1:B3/21;
!!if&x2=1/1:;
!!VRy12:Sv3 :10 +1;
!!IF:Q2/21/v4/7/y12/2^你的坐骑不幸战死，当地的马术师说只要你支付%Y12条秘银，就可以帮你复活它，你要复活它吗？^;
!!if&2:;
!!OW:R-1/7/?y13;
!!IF&y13<y12:Q3/7/y13/1^你只有%y13条秘银，不够支付复活费用！^;
!!if&y13>=y12:;
!!IF:Q4/21/v4/1^你的坐骑复活了！^;
!!VRv2:S1;
!!VRy13:-y12;
!!OW:R-1/7/y13;
!!SN:My99/y2/v2;
!!en:;
***战死和复活***
***吸魔***
!?BR&1000;
!!if&v997>0:;
!!SN:W^攻id^/?v1;
!!SN:W^防id^/?v2;
!!SN:W^攻属^/?y1 W^防属^/?y2;
**IF:M^v1=%V1 v2=%V2 攻=%Y1 防=%Y2^;
!!if&v2>-1:;
!!FU20000:P13/v1/v2;
!!en:;
!?FU20000;
!!if&x1=13:;
!!OW:C?i;
!!HEx2:O?m;
!!HEx3&x3>-1:O?n;
!!HEx2:I?y10/1;
!!HEx3&x3>-1:I?y11/1;
!!VRy1:Sx2 *10 +1; 开启标志
!!VRy2:Sx2 *10 +9; 标记生存
!!VRy3:Sx2 *10 +7; 类型
!!VRy4:Sx2 *10 +8; 堆栈
!!VRy5:Sx2 *10 +0; 战斗次数
!!SN:W^悍马^/?y99;
!!SN:My99/y1/?v1;
!!SN:My99/y2/?v2;
!!SN:My99/y3/?v3;
!!SN:My99/y4/?v4;
!!SN:My99/y5/?v5;
!!if&v1=1/v2=1/v4>-1/x3>-1/v5>99:;
!!VRy-1:Sv5 :10;
!!VRy-1|y10=0/y11=0:S0;
!!if&y-1>0:;
!!BMv4&v4>-1:V77;
!!VRz9:S^Manadrai.wav^;
!!SN:Pz9;
!!VRy10&m=i:+y-1;
!!VRy11&m=i:-y-1;
!!VRy10&n=i:-y-1;
!!VRy11&n=i:+y-1;
!!VRy10&y10<0:S0;
!!VRy11&y11<0:S0;
!!HEx2:Iy10/1;
!!HEx3&x3>-1:Iy11/1;
!!HEx2:B0/?z7;
!!HEx3&x3>-1:B0/?z8;
!!UN:N3/6/v3/0;
!!VRz2&m=i:S^{%Z6吸取了%Z8%Y-1点魔法值给%Z7!}^;
!!VRz2&n=i:S^{%Z6吸取了%Z7%Y-1点魔法值给%Z8!}^;
!!MM&v997>0:Sz2;
!!en:;
***吸魔***

复制代码

是我的失误，先前说的SN:W其实可以保存负值，只是像贤知说的无法保存小数。顺便发表个Erm文件。

战马系统.rar (4.8 KB, 下载次数: 663)

[ 本帖最后由双子于 2013-6-9 15:30 编辑 ]

fly123 · 发表于 2013-6-2 17:59:40

贤知，沧海，进来帮忙指正一下吧。

多谢啦。

玄子 · 发表于 2013-6-2 18:00:12

感谢F大分享，期待有更多ERA可用的脚本

兽哥哥 · 发表于 2013-6-2 18:01:43

我一直在担忧这个问题，就是没人写ERA的脚本来制图，看来是我心急了

fly123 · 发表于 2013-6-2 18:06:46

其实有Erm的基础，Era不难掌握。就是要多写，多试试才行。

无心云 · 发表于 2013-6-2 18:07:32

阿门，看来大家都要转行了。

嗯，我要把最后剩下的几张图打完，然后转行359

贤知有您 · 发表于 2013-6-2 18:15:14

暂时无法测试，目测发现fly大大使用if时有时没有匹配对应的结束符号en

fly123 · 发表于 2013-6-2 18:15:59

先吃饭，等下再说。

江湖情 · 发表于 2013-6-2 18:21:59

359A下载有什么要求？

贤知有您 · 发表于 2013-6-2 18:29:51

召唤的问题，好像没考虑无英雄的情况？
手机没多认真看，谨作参考

crd7849 · 发表于 2013-6-2 21:17:10

这种战马系统有没有新的特点

wza111111 · 发表于 2013-6-2 21:25:42

这样就是以后玩359A的都有这个战马系统了吗

kimvsking · 发表于 2013-6-2 21:29:14

权限是指哪项指标要达到40啊

fly123 · 发表于 2013-6-2 21:29:16

现在已经修正好了，只有英雄之间吸魔还没搞好，等着更新吧。预计下个版本，每个种族，都有不同的坐骑，有5种升级形态。到时功能肯定非常强大。

pl01646085 · 发表于 2013-6-2 22:02:03

大神又出新东西了，这个要试试

fly123 · 发表于 2013-6-2 22:51:04

SN:W可以保存负数。

[ 本帖最后由 fly123 于 2013-6-3 11:25 编辑 ]

fly123 · 发表于 2013-6-2 22:53:58

现在来看，可以自己命名的方式还是不错，确实非常强大。值得深入研究。

[ 本帖最后由 fly123 于 2013-6-3 11:26 编辑 ]

月冷冰华 · 发表于 2013-6-2 23:06:47

不会写但是来支持一下

沧海一粟 · 发表于 2013-6-2 23:18:38

写得真棒，F大上手真快，向F大学习，取经。。。
我是ERA的纯小小白，小小菜，F大太抬举我了

ERA贤知大师的造诣那才是高

雨后成长 · 发表于 2013-6-2 23:22:00

期待早日能玩上

账号		自动登录	找回密码
密码			英雄注册\|Register

战马系统-ERA平台1.0正式版

评分

相关帖子

回复我回帖我光荣 4# 的帖子

回复 7# 的帖子

评分

回复鼓励多发帖 1# 的帖子

评分

退役版主

社区QQ达人

魅力之星

论坛守望者

金牌裁判

杰出贡献

TE联赛冠军

论坛元老

脚本测试狂

战马系统-ERA平台1.0正式版

评分

相关帖子

回复 我回帖我光荣 4# 的帖子

回复 7# 的帖子

评分

回复 鼓励多发帖 1# 的帖子

评分

退役版主

社区QQ达人

魅力之星

论坛守望者

金牌裁判

杰出贡献

TE联赛冠军

论坛元老

脚本测试狂

回复我回帖我光荣 4# 的帖子

回复鼓励多发帖 1# 的帖子