求助~关于怪物之周!

3300330033

怪物之周为什么没有生成8级生物和那些几个资料篇的龙(圣龙之类的)的野兵呢 ? 但却有龙巫妖!
如果可以实现需要修改ERM么?
求大神解答

[ 本帖最后由 3300330033 于 2013-4-21 11:46 编辑 ]

zdx47

没遇到过龙巫妖之周，只遇到过常见兵种的

灰狼王子

普通地图应该不会出现龙巫妖之周吧，这个变数对游戏的影响太大了，尤其前期碰上这个生成的龙巫妖堵住了重要通道可就惨大了。

3300330033

有的,我玩的是超大地图....连龙巫妖都有了 但就是没有生成8级的生物和那些资料龙,
王子有办法么?

灰狼王子

那就修改一下官方的怪物之周脚本SCRIPT20吧，应该不难的。

3300330033

>>[Function 180 gets number for new "Week of" monster and stores in v180]
!?FU180;

!!VRx16:S1000; [Initialize x16 to 1000 so it will exit the Function if not changed]
!!VRv180:S-100;  [Initialize new monster number to -100]
!!VRy9:S0;

!!IF:V172/0;  [Initialize flag 172 to false]

[Check previous monster week for a given player]
!!VRy3:S1200 +v372;
!!VRy4:Svy3;

!!VRy1:S0 R155; [Random start number for choosing a hero]
!!VRy2:Sy1 -1;  [End number for second loop]
!!DO5301/y1/155/1&v372<8/v180=-100:Py4;[Random monster type is based on a hero's army stack]
!!DO5301/0/y2/1&v372<8/v180=-100/y1>0:Py4; [2nd part of loop]
!!VRy9&v372<9/v180=-100:S1; [If no monster found in hero's army choose random monster: y9=1]
!!VRy9&v372=8:S1; [If random monster week, choose random monster: y9=1]

[Random # for "Week of" monster 0..195, excluding "not used", Emissaries, Commanders]
!!VRv180|v372=8/y9=1:S0 R169; [Random number for new "Week of" monster from 0 to 169]
!!VRv180&y9=1/v180>=122:+1;   [Add 1 if "not used" result or higher]
!!VRv180&y9=1/v180>=124:+1;   [Add 1 if "not used" result or higher]
!!VRv180&y9=1/v180>=126:+1;   [Add 1 if "not used" result or higher]
!!VRv180&y9=1/v180>=128:+1;   [Add 1 if "not used" result or higher]
!!VRv180&y9=1/v180>=160:+4;   [Add 4 if "Emissary" result or higher]
!!VRv180&y9=1/v180>=174:+18;  [Add 18 if "Commander" result or higher]

!!VRv180&v372=9:S-7 R6; [Random number for resource week]

!!IF&v180<0/v180<>-100:V172/1;  [If week is less than 0 (but not -100), it's a resource week - set flag 172 to true]

!!VRy5:Sc;  [set y5 to current day]
!!VRy6:Sy5 -1; [set y6 to current day -1]
!!VRy6::7; [set y6 to current week -1]
!!VRy6:+1; [set y6 to current week]
!!VRy10:Sy6 :2; [Half of current week]
!!VRy10&y10<1:S1;

!!MA&v180>=0:Lv180/?y7; [Store monster level (0-6) in y7]
!!VRy7&v180>=0:+1;      [set y7 to "true" monster level (1-7)]

[Get a new number if monster number is same as previous week,]
["Not Used" number, Emissaries, Arrow Towers or higher level than the week divided by 2]
[Also, skip level 8 monsters and Commanders]
!!VRx16|v180=v170/v180=y4:S0; [No duplicates of previous week or previous player week]
!!VRx16|v180=122/v180=124/v180=126/v180=128/v180=149:S0; [No "not used" or arrow towers]
!!VRx16&v180>=160/v180<=163:S0; [No Emissaries]
!!VRx16&v180>=174/v180<=191:S0; [No Commanders]
!!VRx16&y9=1/v180>=132/v180<=135:S0; [No Level 8 Neutral Dragons unless in a hero's army]
!!VRx16&y9=1/v180>=150/v180<=158:S0; [No Level 8 Monsters unless in a hero's army]
!!VRx16&y9=1/y7>y10:S0; [y7=monster level, y10=current week divided by 2 (skip creatures of too high level unless in a hero's army)]

!!VRy18:+1; [Count loops: y18]
!!VRv180&y18>100:S139; [If too many loops, set it to Peasant: v180]
!!VRx16&y18>100:S1000; [If too many loops, just exit: x16]

[Keep track of previous monster weeks for each player]
!!VRvy3:Sv180;

[Place some wandering monster stacks and resources of this type unless it's the first week]
[Don't call function if it's a war machine or ghost]
!!VRy8:S1; [Assume wandering monster stacks and resources can be placed]
!!VRy8&v170=-100:S0; [Must have been a monster chosen]
!!VRy8&v170>=132/v170<=135:S0; [No Level 8 Neutral Dragons]
!!VRy8&v170>=145/v170<=159:S0; [No War Machines or Level 8 Monsters]
!!UN:P135/?y15; [y15=1 if wandering monsters are enabled]
!!UN:P136/?y16; [y16=1 if stationary monsters are enabled]
!!VRy8&v170>=0/y15=0/y16=0:S0; [Don't call if a monster week and wandering]
                               [and stationary monsters are both disabled]
!!UN:P134/?y17; [y17=1 if resource piles are enabled]
!!VRy8&v170<0/y17=0:S0; [Don't call if resource week and resource piles are disabled]

!!MA&v170>=0:Lv170/?y11; [Store monster level (0-6) in y11]
!!VRy11&v170>=0:+1;      [set y11 to "true" monster level (1-7)]
!!VRy11&v170<0:S0;       [set y11 to 0 if it's a resource week]


是修改这一段代码么？

3300330033

没有人知道么?

龙巫妖

真的有龙巫妖之周咩？

贤知有您

其实原脚本设置还是比较合理的.
看
!!VRx16&y9=1/v180>=132/v180<=135:S0; [No Level 8 Neutral Dragons unless in a hero's army]
!!VRx16&y9=1/v180>=150/v180<=158:S0; [No Level 8 Monsters unless in a hero's army]

不是说不能有8级兵和4龙.
而是当英雄部队中有这样的生物时,它才能有机会出现.这点倒是比较合理.

3300330033

有的

3300330033

但是我的英雄用女妖指挥官诱惑了很多龙堡的那些资料片的龙,还有其他英雄也带了很多8级的生物,但生物周就是没生成!比如说我的部队里有雷神,但雷神生物周就没有生成雷神,时间是第6个月第三周,但之前的第4个月就有龙巫妖!
请大神明查!

贤知有您

呵呵.
龙巫妖是有可能的.

!!VRx16|v180=122/v180=124/v180=126/v180=128/v180=149:S0; [No "not used" or arrow towers]
!!VRx16&v180>=160/v180<=163:S0; [No Emissaries]
!!VRx16&v180>=174/v180<=191:S0; [No Commanders]
!!VRx16&y9=1/v180>=132/v180<=135:S0; [No Level 8 Neutral Dragons unless in a hero's army]
!!VRx16&y9=1/v180>=150/v180<=158:S0; [No Level 8 Monsters unless in a hero's army]
脚本只是排除了战争机器,空编号,指挥官,神使
还有 4野龙和8级兵.

但没有排除192及之后的生物.

3300330033

贤知能修改一下可以实现8级生物和4龙么?

贤知有您

把
!!VRx16&y9=1/v180>=132/v180<=135:S0; [No Level 8 Neutral Dragons unless in a hero's army]
!!VRx16&y9=1/v180>=150/v180<=158:S0; [No Level 8 Monsters unless in a hero's army]
这两句删掉应该能行.

未经过测试.

3300330033

!!VRx16&y9=1/v180>=132/v180<=135:S0; [No Level 8 Neutral Dragons unless in a hero's army]
!!VRx16&y9=1/v180>=150/v180<=158:S0; [No Level 8 Monsters unless in a hero's army]
这个两句删了没用,受你的启发
我把
!!VRy8&v170>=132/v170<=135:S0; [No Level 8 Neutral Dragons]
!!VRy8&v170>=145/v170<=159:S0; [No War Machines or Level 8 Monsters]
这两句删了 终于出现8级生物和4龙了 ,就是不知道如果出现 War Machines 会有啥严重的后果么?

灰狼王子

我记得出现过战争机器之周的，至少是有帐篷之周的，地图上不会随机生成，但是本周内帐篷的各项属性（除了速度）都有提升的。

3300330033

谢谢王子

aero88

生成雷神,时间是第6个月第三周,但之前的第4个月就有龙巫妖!
楼主，这个生成的时间可以设定吗？

3300330033

是随机的！不过貌似第一个月不会在地图上生成有大于6级生物的怪物之周（即使是大于6级生物周）