【微型脚本】AI英雄500%经验

去日苦多

AI英雄战斗、访问祭坛、潘多拉盒子、智慧石、宝箱、智慧树会获得500%经验。
单人游戏使用。
潘多拉之盒如果有守卫，访问的英雄会获得极多的经验（貌似25倍），
幸好随机地图的潘多拉盒子是没有守卫的。
标准变量使用了v9900-9904，标志、z变量、FU命令没有使用。

ZVSE
_WARNING_#1=IMPORTANT! This file is not in a plain text format. NEVER use any editor except ERM_S for making any kind of changes!
ERMS_PoweredBy=ERM Scripter v. 2004.6.29.918
ERMS_ScriptDate=3.4(April).2013

** WoG AI hero experiences expander by Jack
** Script78.erm
** Last Updated April 3,2013
** Previously Updated: April 2, 2013

** Variables Used: v9900-v9904
** Flags: None
** z variaables: None
** Functions: None

** Heroes controlled by AI can get 500% experieces.
** ONE human only.
** DO NOT set guards for Pandora's Box.


!#OW:I0/?y1;
!#VRv9900&y1=0:S0;
!#OW:I1/?y1;
!#VRv9900&y1=0:S1;
!#OW:I2/?y1;
!#VRv9900&y1=0:S2;
!#OW:I3/?y1;
!#VRv9900&y1=0:S3;
!#OW:I4/?y1;
!#VRv9900&y1=0:S4;
!#OW:I5/?y1;
!#VRv9900&y1=0:S5;
!#OW:I6/?y1;
!#VRv9900&y1=0:S6;
!#OW:I7/?y1;
!#VRv9900&y1=0:S7;                          [find which player is human]

!?BA52;                                     [any battles start]
!!BA:H0/?v9901;                             [get the attacking hero number]
!!BA:H1/?v9902;                             [get the defending hero number]
!!HEv9901:E?v9903;                          [get the attacking hero exp.]
!!HEv9902&v9902>-1:E?v9904;                 [get the defending hero exp.]

!?BA53;                                     [any battles end]
!!HEv9901:E?y1 O?y3;                        [get the attacking hero exp. & his player]
!!HEv9902&v9902>-1:E?y2 O?y4;               [get the defending hero exp. & his player]
!!VRy1:-v9903;                              [calculate change of att. hero exp.]
!!VRy2:-v9904;                              [calculate change of def. hero exp.]
!!VRy1:*4;                                  [multiplied by 4]
!!VRy2:*4;                                  [multiplied by 4]
!!HEv9901&y3<>v9900:Edy1;                   [amplify the att. hero exp. to 500% if not human]
!!HEv9902&v9902>-1/y4<>v9900:Edy2;          [amplify the def. hero exp. to 500% if not human]


!?OB2;                                      [any heroes visit sacrificial altar]
!!HE-1:E?v9903;                             [get hero exp.]

!$OB2;                                      [any heroes have visited sacrificial altar]
!!HE-1:E?y1 O?y3;                           [get hero exp. & his player]
!!VRy1:-v9903;                              [calculate the change]
!!VRy1:*4;                                  [multiplied by 4]
!!HE-1&y3<>v9900:Edy1;                      [amplify to 500% if not human]


!?OB6;                                      [any heroes pick Pandora's Box]
!!HE-1:E?v9903;                             [get hero exp.]

!$OB6;                                      [any heroes have picked Pandora's Box]
!!HE-1:E?y1 O?y3;                           [get hero exp. & his player]
!!VRy1:-v9903;                              [calculate the change]
!!VRy1:*4;                                  [multiplied by 4]
!!HE-1&y3<>v9900:Edy1;                      [amplify to 500% if not human]


!?OB100;                                    [any heroes visit a stone]
!!HE-1:E?v9903;                             [get hero exp.]

!$OB100;                                    [any heroes have visited a stone]
!!HE-1:E?y1 O?y3;                           [get hero exp. & his player]
!!VRy1:-v9903;                              [calculate the change]
!!VRy1:*4;                                  [multiplied by 4]
!!HE-1&y3<>v9900:Edy1;                      [amplify to 500% if not human]


!?OB101;                                    [any heroes pick a chest]
!!HE-1:E?v9903;                             [get hero exp.]

!$OB101;                                    [any heroes have picked a chest]
!!HE-1:E?y1 O?y3;                           [get hero exp. & his player]
!!VRy1:-v9903;                              [calculate the change]
!!VRy1:*4;                                  [multiplied by 4]
!!HE-1&y3<>v9900:Edy1;                      [amplify to 500% if not human]


!?OB102;                                    [any heroes visit a tree]
!!HE-1:E?v9903;                             [get hero exp.]

!$OB102;                                    [any heroes have visited a tree]
!!HE-1:E?y1 O?y3;                           [get hero exp. & his player]
!!VRy1:-v9903;                              [calculate the change]
!!VRy1:*4;                                  [multiplied by 4]
!!HE-1&y3<>v9900:Edy1;                      [amplify to 500% if not human]

[ 本帖最后由 去日苦多 于 2013-4-3 19:25 编辑 ]

去日苦多

按兽哥哥的建议，重新把这段发到一个新的帖子里。
lz是erm新手，本来想求助写这样一个脚本的，结果运气非常好，
乱碰着就一知半解地写了出来。初步测试过。

英雄获得经验还有地下城的战术学院、事件、先知小屋奖励、其他erm脚本等方式，
这些方式获得的经验不会被放大到5倍。

潘多拉盒子如果有守卫，访问的英雄会获得极多的经验，应该是被访问盒子的触发器和战斗的触发器嵌套作用了。
如果是多人游戏，除去选择颜色最靠后的玩家，其他玩家也会获得5倍经验。

不清楚以前是否有高人写过，如果已经重复请说明。

踏雪无痕

78号脚本没被占用？

去日苦多

我的wog没加78号以后的脚本，随便换个名字吧

灰狼王子

还要注意一种特殊情况，就是70几级的AI英雄由于500%经验被搞得爆棚而废掉（四围变1的废物）

去日苦多

七十几级 吓尿，不加脚本40级的英雄，加了脚本之后，经验*5，是48、9级的样子，
正常图应该达不到，我也疏忽了这一点。

在每个最终的命令：
!!HE-1&y3<>v9900:Edy1;                      [amplify to 500% if not human]
加个条件：v9903<1810034207（75级的经验），变成
!!HE-1&y3<>v9900/v9903<1810034207:Edy1;                      [amplify to 500% if not human]

这样应该可以了

中泽伴行

VRy1*4再Edy1应该是四倍吧。。
其实英雄的属性超过127之后就归0（1）了
这点我在测试阿肯恩塔和指挥官宝物的BUG的时候发现的
不过靠正常升级一般英雄四围不会那么爆棚吧

去日苦多

加上本来得到的就是5倍啊

这是玩随机图用来自虐的脚本，当初也没考虑这么多……
随机图，AI英雄就算是5倍经验，四维也不会到127。
6#又加了个经验值上限的设定，应该没问题。

沧海一粟

谢谢楼主分享，严重支持下

去日苦多

谢支持