谁帮我改改？

hxc2008

请帮我改一下吧，这句话能不能削除？？

代码：

ZVSE
!?CM2&1000; [英雄场景中触发]
!!CM:F?y1 I?y2;
!!FU|y1<>512/y2<>50:E; [右键点击 攻击的图标]
!!FU509:P;
!?FU509;
!!VRv300:C-1/-1/-1/-1/-1/-1/-1/0; JHV
!!DO507/0/6/1:P300; [Build text strings for dialogue box]
!!OW:R-1/6/?y1;
!!VRz-1:S^选择一支部队将其训练至下一个等级。可用金钱：%Y1^;
!!VRz-2:S^以后再说。^;
!!VRz8:S^将所有的部队训练至下一个等级需要%V307的金钱。^;  JHV
!!VRz8&v307<1:S^^; JHV
!!IF:G1/1/256/-1/1/2/3/4/5/6/7/8/-2/0/0/0; [Display dialogue box] JHV
!!FU&v1=256:E; [Exit if player chose to come back later] JHV
!!VRy-10&v1=1:S0; [Stack 0 selected: y-10]
!!VRy-10&v1=2:S1; [Stack 1 selected: y-10]
!!VRy-10&v1=4:S2; [Stack 2 selected: y-10]
!!VRy-10&v1=8:S3; [Stack 3 selected: y-10]
!!VRy-10&v1=16:S4; [Stack 4 selected: y-10]
!!VRy-10&v1=32:S5; [Stack 5 selected: y-10]
!!VRy-10&v1=64:S6; [Stack 6 selected: y-10]
!!IF&v1=128/y1<v307:Q1/6/y-8/1^金钱不足^;
!!DO760/y-10/y-10/1&v1<>128:P300;   JHV
!!DO760/0/6/1&v1=128/y1>=v307:P300;  JHV
!!UN:R3/-1;
!!FU509:P;
!?FU760; x16=troop slot
!!VRy1:Sx1+x16; index to prices        JHV
!!VRy-8:Svy1; get price for troop x16  JHV
!!FU&y-8<0:E; exit if priceless        JHV
!!HE-1:C0/x16/?v2/?v3/?v4/2; [v2=type, v3=number, v4=exp]
!!UN&v3=1:N3/8/v2/0; [Monster name (singular): z8]
!!UN&v3>1:N3/8/v2/1; [Monster name (plural): z8]
!!MA:Lv2/?y-6; [Monster level (0..6): y-6]
!!VRy-6:+1; [Add 1 to monster level: y-6]
!!FU508:Py-6/v4/v2; [Get rank: y-20]
!!VRy-5:Sy-20 +1; [Next rank to train creatures to: y-5]
!!VRy-7:Sy-6; [Copy of monster level: y-7]
!!VRy-9:Sv2 :2 *2; [Check if monster is upgraded: y-9]
!!VRy-7&y-9<>v2/v2<=131:+1; [Add 1 more level if monster is upgraded: y-7]
!!VRy-7&v2>=150/v2<=158:+2; [Add 2 more if monster is level 8: y-7]
*!VRy-8:Sv3 *y-5 *y-6 *y-7:2; [Calculate cost: y-8]  JHV
*!VRy-8&v1975=4::2; halve cost for estates specialists JHV

!!OW:R-1/6/?y-11; [Player's gold: y-11]
!!IF&y-11<y-8:Q1/6/y-8/1^金钱不足！^;
!!FU&y-11<y-8:E; [Exit if player doesn't have enough gold]
!!IF:Q1/21/v2/6/y-8/17/y-5/1^完成！^;
!!VRy-13:Sy-11 -y-8; [Player's new gold: y-13]
!!OW:R-1/6/y-13; [Set player's new gold: y-13]
[Set new rank for troops: y-5=new rank]
!!HE-1:C0/x16/d/d/y-5/12;

[Build text strings for dialogue box]
!?FU507; x1=start of price table, price-->v[x1+x16], sum of prices-->v[x1+7]
!!HE-1:C0/x16/?y1/?y2/?y3/2; [y1=type, y2=number, y3=experience]
!!VRy4:Sx16 +1; [Index for z variable to store text strings (z1..z7)]
!!VRzy4:S^^; [Initialize z variables to empty strings]
!!FU|y1<0/y2<1:E; [Skip if no monster in this slot]
!!UN&y2=1:N3/8/y1/0; [Monster name (singular): z8]
!!UN&y2>1:N3/8/y1/1; [Monster name (plural): z8]
!!MA:Ly1/?y6; [Monster level (0..6): y6]
!!VRy6:+1; [Add 1 to monster level: y6]
!!FU508:Py6/y3/y1; [Get rank: y-20]
!!VRy5:Sy-20 +1; [Next rank to train creatures to: y5]
!!FU&y5>10:E; [Skip if stack is already at rank 10]
!!VRy7:Sy6; [Copy of monster level: y7]
!!VRy9:Sy1 :2 *2; [Check if monster is upgraded: y9]
!!VRy7&y9<>y1/y1<=131:+1; [Add 1 more to monster level if upgraded: y7]
!!VRy7&y1>=150/y1<=158:+2; [Add 2 more if monster is level 8: y7]
!!VRy8:Sy2 *y5 *y6 *y7:2; [Calculate cost: y8]
!!VRy8&v1975=4::2; estates specialists
!!VRzy4:S^训练%Y2  %Z8至%Y5级需要%Y8的金钱。^;
!!VRy9:Sx1+x16; index to price table JHV
!!VRvy9:Sy8;                         JHV
!!VRy10:Sx1+7; index to total price  JHV
!!VRvy10:+y8;                        JHV
[Get rank of stack: y-20]
[x1=monster level (1..7), x2=current experience, x3=monster number]
!?FU508;
!!VRe1:S2 :5 +8; [e1=8.4]
!!VRy1:Sx2 :x1; [Base experience for level 1..7 creatures: y1]
!!VRy1&x3>=150/x3<=163:Sx2 :e1; [Base exp. for level 8 creatures: y1]
!!VRy-20&y1<1000:S0; [Rank 0]
!!VRy-20&y1>=1000/y1<2000:S1; [Rank 1]
!!VRy-20&y1>=2000/y1<3200:S2; [Rank 2]
!!VRy-20&y1>=3200/y1<4600:S3; [Rank 3]
!!VRy-20&y1>=4600/y1<6200:S4; [Rank 4]
!!VRy-20&y1>=6200/y1<8000:S5; [Rank 5]
!!VRy-20&y1>=8000/y1<10000:S6; [Rank 6]
!!VRy-20&y1>=10000/y1<12200:S7; [Rank 7]
!!VRy-20&y1>=12200/y1<14700:S8; [Rank 8]
!!VRy-20&y1>=14700/y1<17500:S9; [Rank 9]
!!VRy-20&y1>=17500:S10; [Rank 10]
;GODS CAVES

dadds

不知道要改什么，削除哪句话啊

hxc2008

图上的对话啊：
“唔，这点黄金不够啊，朋友...这是什么，你是想哄我还是想干什么?我不是瞎的。”这个首领很不高兴。你很快的离开。

你可以在地图上试试代码。一升完级就会弹出这个。

dadds

你这个脚本里面没有这句话，使用这个脚本却会弹出这个那么应该是变量冲突了

hxc2008

能不能解决？要不我发上地图帮我看看!

dadds

自己排查一下，看看哪个脚本里面有这句话的先禁用看看

hxc2008

谢谢，算了不搞了，找了下没找成，估计不是脚本里的文本……