如何设置英雄开始初试宝物和4围分配。

游戏人的家

如何通过ERM实现这些功能，给个代码吧。
英雄的代码我知道100多少  宝物代码。。。。。。

刀巴犬良

宝物中文代码
http://bbs.h3wog.com/thread-21248-1-1.html

贤知有您

楼主不如下载个 ERM帮助手册吧.
我的签名有.
里面的右侧格式,就包含了所有相关信息.

游戏人的家

007.
比如欧玲 4围 3 3 0 0
我应该怎么弄。

!!HE-0:3300;
这样？
还是!!HE-0:3/3/0/0;
还有宝物，比如让欧玲自带黄金弓。
怎么弄。
给我个样本吧，这样我只要替换代码就行了。

[ 本帖最后由 游戏人的家 于 2013-1-9 12:02 编辑 ]

游戏人的家

!!HE4:C0/0/0/5 C0/1/2/5 C0/2/4/5;
代表初始生物。

我应该怎么替换呢。
变成设置初始属性和初始宝物。
代码已经有了。
就是不知道怎么替换，给一个样品吧。007

游戏人的家

!!HE4:F/3/3/0/0
代码欧玲初始3 3 0 0吗？

贤知有您

你看看官方的
41 wog - rebalanced factions
脚本.
里面有很多重新平衡的英雄范例

贤知有您

查看ERM帮助的格式.看到
格式 H  英雄编号
这里就是英雄的各种编号了.
欧灵是编号0, 要使用 !!HE0..来改变他的属性.

你看官方脚本就有很多范例了.

[HERO TWEAKING]
!?FU4852;

!!HE3:S5/3; [Sylvia now starts with Expert Navigation]
!!HE4&v1406<>1/v1407<>1:S13/2; [Lord Haart's Estates skill upgraded to Advanced if no Estates scripts are on]
!!HE6:F3/1/1/1; [Christian starts with +1AS and -1DS]
!!HE6:A1/4/13; [Christian always starts with a Ballista]
!!HE8:A1/6/15; [Rion always starts with a First Aid Tent]
!!HE9:S4/0; [Adela's Diplomacy is replaced by Leadership]
!!HE9:S6/1;
!!HE10:S16/1; [Cuthbert starts with Basic Water Magic instead of  ->]
!!HE10:S13/0; [ -> Basic Estates]
!!HE11:S7/0; [Adelaide gets Adv. Water Magic instead of Adv. ->]
!!HE11:S16/2; [ -> Wisdom, so maybe Frost Ring gets used sometimes =)]
!!HE11&v1409<>1:M2/1; [Adelaide also starts with Visions and Cure]
!!HE11&v1409<>1:M37/1;
!!HE13&v1409<>1/v1407<>1/v1408<>1:S11/3; [Sanya starts with Expert Eagle Eye when no Eagle Eye scripts are active]
!!HE14:F0/0/2/2; [Loynis starts with one less primary skill point]
!!HE17&v1405<>1/v1406<>1:S26/2; [Ufretin starts with Adv. Resistance]
!!HE19:S4/0; [Ryland's Diplomacy is replaced by an extra level of ->]
!!HE19:S6/2; [-> Leadership]
!!HE20&v1405<>1/v1406<>1:S26/3; [Thorgrim starts with Expert Resistance when no Resistance scripts are active]
!!HE22&v1409<>1:X4/24/3/2/1; [Clancy now gives +3AS, +2DS, +1Dmg. for Unicorns when Hero Specialization Boost is off]
!!HE22&v1405<>1/v1406<>1:S26/2; [Clancy gets an extra level of Resistance when no Resistance scripts are active]
!!HE23:F1/1/1/1; [Kyrre's starts with less primary skill points because Logistics is such a powerful specialty]
!!HE25:S10/0; [Uland gets Adv Water and Basic Wisdom instead of]
!!HE25:S16/2; [-> Advanced Wisdom and Basic Ballistics]
!!HE25:S7/1;
!!HE27:A1/6/15; [Gem always starts with a First Aid Tent]
!!HE27:M0/0; [Gem no longer has Summon Boat]
!!HE27:M41/1; [Gem now starts with Bless]
!!HE28&v1403<>1/v1404<>1:M11/3; [Malcom starts with Expert Eagle Eye when no Eagle Eye scripts are active]
!!HE29:S9/0; [Melodia now starts with Basic Wisdom and Air Magic ->]
!!HE29:S15/1; [-> instead of Basic Wisdom and Basic Luck]
!!HE29:M5/1; [Melodia starts with View Air and Visions as well as Fortune]
!!HE30&v1409<>1:S16/1; [Alagar now also has Basic Water Magic (see his bio)]
!!HE30&v1409<>1:M2/1; [Alagar also starts with Visions ->
!!HE30&v1409<>1:M37/1; [-> and Cure, because he trained with Vori too =)]
!!HE36:A1/4/13; [Torosar always starts with a Ballista]
!!HE36:S20/1; [Torosar now starts with Basic Artillery instead of ->]
!!HE36:S8/0; [-> Basic Mysticism]
!!HE37&v1409<>1:X4/38/3/1/1; [Fafner now gives +3AS, +1DS and +1Dmg. to Nagas/N. Queens]
!!HE40:S7/1; [Astral now has Basic Wisdom and Air Magic instead of ->]
!!HE40:S15/1; [ -> Advanced Wisdom]
!!HE40:M17/1; [Astral now has Lightning Bolt because he deserves better =)]
!!HE45:F0/0/1/3; [Solmyr starts with one less primary skill point]
!!HE45:S25/0; [Solmyr starts with Advanced Wisdom instead of ->]
!!HE45:S7/2; [-> Basic Wisdom and Basic Sorcery]
!!HE46:S4/0; [Cyra's Diplomacy is replaced by Leadership]
!!HE46:S6/1;
!!HE49:S18/0; [Rashka now starts with Basic Wisdom and Offense ->]
!!HE49:S22/1; [-> more in keeping with his bio]
!!HE49&v1409<>1:X4/52/3/3/0; [Rashka now adds +3 AS & +3 DS to Efreeti/Efreet Sultans]
!!HE54:S2/0; [Pyre now starts with Advanced Artillery instead of Basic ->]
!!HE54:S20/2; [-> Logistics and Basic Artillery]
!!HE54:A1/4/13; [Pyre starts with a Ballista, and it is equipped]
!!HE55&v1409<>1:X4/50/2/3/1; [Nymus adds +2AS, +3DS and +1Dmg. to Pit Fiends/Lords]
!!HE57:S18/0; [Xydar now starts with Basic Wisdom and Basic Fire Magic ->]
!!HE57:S14/1; [-> since he delights with everything to do with fire and lava]
!!HE57:F1/1/1/2; [Xyron - +1K & -1SP to have enough to cast his spell]
!!HE59:S16/1; [Olema now starts with Basic Water Magic and Basic Leadership]
!!HE59:S10/0;
!!HE59:S7/0;
!!HE59:S6/1;
!!HE63&v1409<>1:S7/2; [Xarfax now starts with Adv Wisdom and Leadership since ->]
!!HE63&v1409<>1:S6/2; [-> he has such a weak specialty]
!!HE63&v1409<>1:M15/1; [Xarfax also starts with Magic Arrow and Visions]
!!HE63&v1409<>1:M2/1;
!!HE63:F1/1/1/2; [Xarfax starts with more knowledge and less spell power]
!!HE65&v1409<>1:X4/62/2/2/0; [Vokial now gives +2 AS and +2 DS to vampires/v. lords]
!!HE65:A1/4/13; [Vokial starts with a Ballista, and it is equipped]
!!HE65:F2/1/2/1; [Vokial starts with +1AS and -1DS]
!!HE67&v1409<>1:X4/60/3/3/3; [Charna gives +3 AS, +3 DS, +3 Dmg. to Wights]
!!HE68&v1409<>1:X4/66/3/3/0; [Tamika's Black/Dread Knights get +3 AS and +3 DS]
!!HE72&v1409<>1:S17/1; [Septienna now starts with Necromancy & Earth Magic ->]
!!HE72&v1409<>1:S18/0; [-> instead of Basic Necromancy and Basic Scholar]
!!HE72:M2/1; [Septienna now starts with Visions]
!!HE72:M12/1; [Septienna now starts with Force Field]
!!HE73:F0/0/1/2; [Aislinn starts with two less primary skill points]
!!HE76:M39/0; [Thant no longer starts with Animate Dead]
!!HE76:M46/1; [Thant now starts with Stone Skin]
!!HE77:F0/1/2/2; [Xsi starts with 1 Defense Skill instead of 1 Attack Skill because of her bio]
!!HE81:A1/4/13; [Arlach always starts with a Ballista]
!!HE85:F1/1/1/1; [Gunnar starts with two less primary skill points]
!!HE86&v1409<>1:X4/80/1/3/1; [Synca now gives +1AS, +3DS, and +1 Dmg. to Manticores]
!!HE88:F0/0/1/2; [Alamar now starts with two less primary skill points]
!!HE88:S18/0; [Alamar has one more level of Wisdom instead of ->]
!!HE88:S7/2; [-> Basic Scholar and Basic Wisdom]
!!HE91:F0/0/2/2; [Jeddite now starts with one less primary skill point]
!!HE91:M62/1; [Jeddite now starts with Blind instead of ->
!!HE91:M38/0; [-> Resurrection]
!!HE93:F0/0/1/2; [Deemer now starts with two less primary skill points]
!!HE93:S3/1; [Deemer has Advanced Scouting replaced by Basic Scouting ->]
!!HE93:S7/1; [-> and Basic Wisdom]
!!HE95&v1409<>1:S17/1; [Darkstorn starts with an extra SS since his specialty is so weak]
!!HE96&v1409<>1:X6/91/94/95; [Yog can now upgrade Ogre Magi and Cyclops to Cyclops Kings]
!!HE97:S20/0; [Gurnisson now starts with Basic Offense and ->]
!!HE97:S1/1; [-> Basic Archery]
!!HE99&v1409<>1:X4/92/1/3/1; [Shiva now gives +1AS, +3DS, +1 Dmg. to Rocs/Thunderbirds]
!!HE105&v1409<>1:S7/2; [Vey now starts with Advanced Wisdom and Advanced ->]
!!HE105&v1409<>1:S6/2; [-> Leadership]
!!HE106:F1/1/1/1; [Dessa now gets one less primary skill point]
!!HE108&v1409<>1:A1/4/13; [Zubin starts with a Ballista when HSB isn't active]
!!HE118:A1/4/13; [Gerwulf starts with a Ballista, and it is equipped]
!!HE118&v1409<>1:F3/1/1/1; [Gerwulf now starts with some Attack Skill]
!!HE119&v1409<>1:X4/108/0/3/1; [Broghild now gives +3 DS & +1 Dmg. to Wyverns/W. Monarchs]
!!HE120&v1409<>1:S7/0; [Mirlanda now starts with ->]
!!HE120&v1409<>1:S16/1; [Basic Water Magic and Basic Fire Magic]
!!HE120&v1409<>1:S14/1; ["She has learned to walk a fine line between good and evil"]
!!HE120&v1409<>1:M62/1; [Mirlanda now starts with Blind]
!!HE121:M41/1; [Rosic now starts with Bless]
!!HE122:S5/3; [Voy now starts with Expert Navigation]
!!HE123:A1/6/15; [Verdish always starts with a First Aid Tent]
!!HE124&v1409<>1:S17/1; [Merist starts with an extra skill because of weak specialty]
!!HE128:A1/4/13; [Pasis starts with a Ballista, and it is equipped]
!!HE129&v1407<>1/v1408<>1/v1416<>1:S13/0; [When no Estates scripts are on, Thunar has Basic Estates replaced ->]
!!HE129&v1407<>1/v1408<>1/v1416<>1:S19/2; [-> by an extra level of Tactics]
!!HE130:A1/4/13; [Ignissa starts with a Ballista, and it is equipped]
!!HE131&v1416=1:F1/0/1/1; [Lacus starts with three primary skill points when Neutral Town and Rebalanced Hero Abilities is on because Advanced Tactics and +2 speed specialty is a super powerful starting combination =)]
!!HE132:S2/0; [Monere now starts with ->
!!HE132&v1409<>1:S24/1; [-> Basic Intelligence when HSB is inactive]
!!HE132&v1409=1:S22/2; [-> or Advanced Offense when HSB is active]
!!HE133&v1407<>1/v1408<>1/v1416<>1:S13/0; [Erdamon has Basic Estates replaced by ->]
!!HE133&v1407<>1/v1408<>1/v1416<>1:S23/1; [ -> Basic Armorer when no Estates script is on]
!!HE136:F0/0/2/3; [Elementalists down to 2SP]
!!HE137:F0/0/2/3;
!!HE138:F0/0/2/3;
!!HE139:F0/0/2/3;
!!HE140:F0/0/2/3;
!!HE141:F0/0/2/3;
!!HE142:F0/0/2/3;
!!HE143:F0/0/2/3;
!!HE136&v1409<>1:M2/1; [Luna starts with Visions]
!!HE139:S7/0; [Labetha starts with just Basic Earth Magic]
!!HE140&v1409<>1:S14/2; [Inteus starts with Advanced Fire Magic and Visions]
!!HE140&v1409<>1:M2/1;
!!HE143:S7/0; [Grindan starts with just Basic Earth Magic]
!!HE144:S6/1; [Sir Mullich to start with Basic Leadership since he has one of the most powerful specialties]
!!HE144:F1/1/1/1; [Sir Mullich to start with two less primary skill points]

贤知有您

在ERM帮助里面.
上面的按钮都是触发器解释部分.
比如英雄触发器,你找到  HE,进里面看看.
再对照一下官方范例,好快就就能上手了

!!HE:A  给宝物
!!HE:C 给生物
!!HE:F 设置四维
!!HE:S 设置辅助技能

游戏人的家

F$1/$2/$3/$4

游戏人的家

OK了。
这样我就会设置了，等着我的修正主义吧。

游戏人的家

!!HEx2&y5=0:F3/3/3/3;
代表城堡所有人物 3 3 3 34围是吗？

游戏人的家

!#TM59:S8/999/7/255;

!?PI;
!!DO255/0/155/1:P-255;

!?FU255&x1=-255;
!!DO255/0/6/1:P-254/x16;

!?FU255&x1=-254;
!!HEx2:C0/x16/?y2/?y3 B2/?y4;
!!VRy5:S-1;
!!VRy5|y4=0/y4=1:S0;
!!VRy5|y4=2/y4=3:S1;
!!VRy5|y4=4/y4=5:S2;
!!VRy5|y4=6/y4=7:S3;
!!VRy5|y4=8/y4=9:S4;
!!VRy5|y4=10/y4=11:S5;
!!VRy5|y4=12/y4=13:S6;
!!VRy5|y4=14/y4=15:S7;
!!VRy5|y4=16/y4=17:S8;
!!HEx2&y5=0:F3/3/3/3;
这样行吗007

贤知有您

你要在游戏中试试效果.
看起来没什么错误.

TM函数不知道你是干什么用的.

后面
!!VRy5|y4=0/y4=1:S0;
!!VRy5|y4=2/y4=3:S1;
!!VRy5|y4=4/y4=5:S2;
!!VRy5|y4=6/y4=7:S3;
!!VRy5|y4=8/y4=9:S4;
!!VRy5|y4=10/y4=11:S5;
!!VRy5|y4=12/y4=13:S6;
!!VRy5|y4=14/y4=15:S7;
!!VRy5|y4=16/y4=17:S8;
直接用
!!VRy5:Sy4 :2;
一句话就行了.取整的.

游戏人的家

如何简化，你帮我弄个简化的，然后我好修正

游戏人的家

!#TM59:S8/999/7/255;

!?PI;
!!DO255/0/155/1:P-255;

!?FU255&x1=-255;
!!DO255/0/6/1:P-254/x16;

!?FU255&x1=-254;
!!HEx2:C0/x16/?y2/?y3 B2/?y4;
!!VRy5:S-1;
!!VRy5:Sy4 :2;
!!HEx2&y5=0:F3/3/3/3;
!!HEx2&y5=1:F3/3/3/3;
!!HEx2&y5=2:F3/3/3/3;
这样你看行吗007

贤知有您

看起来是没什么问题啊.
你要放到游戏中测试测试啦.

为什么每个城镇英雄都要固定一个初始四维呢?

游戏人的家

我要测试一下，数据会调整一些。
另外想知道，能不能同时调整一批英雄的4围，初始生物和宝物和技能。
好奇为主哟。

无心云

楼主又开始研究了，精神可嘉啊

游戏人的家

ZVSE
_WARNING_#1=IMPORTANT! This file is not in a plain text format. NEVER

use any editor except ERM_S for making any kind of changes!
ERMS_ScriptDate=15.5(May).2012
ERMS_PoweredBy=ERM Scripter v. 2004.6.29.918


!?PI; 地图开始时触发!!HE0:F2/2/1/1;!!HE1:F2/2/1/1;!!HE2:F2/2/1/1;!!

HE3:F2/2/1/1;!!HE144:F2/2/1/1;!!HE5:F2/2/1/1;!!HE6:F2/2/1/1;!!

HE7:F2/2/1/1;!!HE8:F0/0/3/3;!!HE9:F0/0/3/3;!!HE10:F0/0/3/3;!!

HE11:F0/0/3/3;!!HE12:F0/0/3/3;!!HE13:F0/0/3/3;!!HE14:F0/0/3/3;!!

HE15:F0/0/3/3;!!HE0:S1/3;!!HE0:S0/3;!!HE0:S6/0;!!HE1:S1/3;!!HE1:S0/3;!!

HE1:S6/0;!!HE2:S23/3;!!HE2:S2/3;!!HE2:S6/0;!!HE2:X4/4/4/4/4;!!

HE1:X4/2/3/6/3;!?PI; 地图开始时触发!!HE3:X0/13; **英雄[3 斯尔维亚(骑士)]特

长[理财术]**!!HE3&y1=0:S13/1; **没有则添加(低级)**!!UN:G2/3/3/4; **英雄[3

斯尔维亚(骑士)]特长图片为[黄金]**!!HE3:S13/3;!!HE3:S6/0;!!HE3:S5/0;!!

HE3:S3/3;!!HE5:X4/6/4/4/4;!!HE5:S22/3;!!HE5:S6/0;!!HE5:S23/3;!!HE6:S6/0;!!

HE6:S20/3;!!HE6:S0/3;!!HE6:X0/20;!!HE6:X4/146/7/7/14; **英雄[6 克里斯丁(骑

士)]特长[弩车:攻击+7防御+7伤害+14]**!!UN:G2/6/3/6; **英雄[6 克里斯丁(骑士)]

特长图片为[弩车]** *** END OF SCRIPT ***
* 2012/5/14 20:59:15 *