孤注一掷+吸血还是没搞定，放上个学者的技能erm吧

希望创师

原本是想学到了火系魔法想爽爽的，可惜孤注一掷太不稳定了。
这个erm的作用是让英雄依学者技能等级，在升级时有几率可以花1000金来提升元素魔法技能。如果已经到顶，则加P（火、气）或K（水、土）。

对塔城thane做了点小加强

**********************以下为erm代码。

ZVSE
_WARNING_#1=IMPORTANT! This file is not in a plain text format. NEVER use any editor except ERM_S for making any kind of changes!
ERMS_ScriptDate=10.16(October).2012  by willbuilder
**scholar upgrade
!#HE33:M15/0 M56/1; Magic Arrow is instead by Frenzy
!#HE33:H2/37/1/1;

-------------------------------------------------------------
**ERM说明*拥有学术技能的英雄每次升级时有最高50%的几率花1000金提升一种元素魔法技能或加一点力量/知识
** hero level-up trigger
!?HL-1;
!!HE-1:S18/?y-1; [check for scholar level]
!!VRy-2:Sy-1 *15 +5 R99;
!!FU&y-2<100:E;
!!VRy1:S0 R1 +14;     [pick a random magic skill to offer]
!!VRy2:S0 R1 +16;     [pick another random magic skill to offer]
!!HE-1:Sy1/?y10; [check for 1magic level]
!!HE-1:Sy2/?y20; [check for 2magic level]
!!HE-1:B0/?z352; [get hero name]
!!UN:N4/353/y1; [get skill name]
!!UN:N4/354/y2; [get skill name]
!!VRz-10:S^学者%Z352可以花费1000金提升%Z353或者%Z354技能^;
!!VRy3&y10<3:S20;            [get picture of skill]
!!VRy3&y10=3:S33;            [get picture of skill]
!!VRy4&y10<3:Sy1 *3 +3 +y10; [get picture of skill]
!!VRy4&y10=3:S1; [get picture of skill]
!!VRy5&y20<3:S20;            [get picture of skill]
!!VRy5&y20=3:S34;            [get picture of skill]
!!VRy6&y20<3:Sy2 *3 +3 +y20; [get picture of skill]
!!VRy6&y20=3:S1; [get picture of skill]
!!IF:V6/0; [assume won't learn skill]
!!IF&1000:Q2/y3/y4/y5/y6/10/z-10;
!!IF&-1000:V2/0; [AI always not learns it]
!!VRy10&v2=1:+1;
!!VRy20&v2=2:+1;
!!OW:R-1/6/?y8; [get gold number ]
!!IF&v2<>0/y8<1000:M^对不起，你的金钱不足^;
!!FU&y8<1000:E;
!!OW:R-1/6/d-1000; [cost gold ]
!!HE-1&v2=1/y10<=3:Sy1/y10; [give skill]
!!HE-1&v2=1/y10>3:Fd/d/d1/d; [give power]
!!HE-1&v2=2/y20<=3:Sy2/y20; [give skill]
!!HE-1&v2=2/y20>3:Fd/d/d/d1; [give knowledge]
** end of function
---------------------------------------------------------------

****************************导师系统********************
**ERM说明*拥有学术技能的英雄在英雄相遇屏幕右键点击双向箭头可以把最多自身50%的经验值教给己方英雄
!?CM3;
!!CM:I?y20 S?y21;
!!FU|y20<>301/y21<>14:E;      英雄相遇屏幕右键点击双向箭头
!!CM:R1;
!!CM:H?y20/?y21;              取双方英雄ID
!!HEy20:S18/?y22;             获得左方英雄学术技能等级
!!HEy21:S18/?y23;             获得右方英雄学术技能等级
!!HEy20:E?y24;                获得左方英雄经验
!!HEy20:B0/?z355;             获得左方英雄名字
!!HEy21:E?y25;                获得右方英雄经验
!!HEy21:B0/?z356;             获得右方英雄名字
!!VRy26:Sy24*y22:6-y25;
!!IF&y26>0:M^博学多才的%Z355和%Z356分享了自己的学习心得，%Z356获得%Y26点经验^;
!!HEy21&y26>0:Edy26;
!!VRy26:Sy25*y23:6-y24;
!!IF&y26>0:M^博学多才的%Z356和%Z355分享了自己的学习心得，%Z355获得%Y26点经验^;
!!HEy20&y24<y25:Edy26;
!!DO7912/0/69/1:Py20/y21/0/y22/y23;
!?FU7912;
!!HEx1:Mx3/?y1;
!!HEx2:Mx3/?y2;
!!HEx1&y1<>y2/x4=3:Mx3/1;
!!HEx2&y1<>y2/x5=3:Mx3/1;
!!VRx3:+1;

[ 本帖最后由 希望创师 于 2012-10-21 09:21 编辑 ]

小翼

我不敢试试。。。。。。。。。你这ERM。。。。。

十三木人

介绍erm时最好说全套，不是每个人都会打开erm看看里面有什么的

希望创师

原帖由 十三木人 于 2012-10-21 08:23 发表
介绍erm时最好说全套，不是每个人都会打开erm看看里面有什么的

嗯嗯？我说的不够详细吗？ 有学者技能的英雄在升级时有20%/35%/50%的几率获得元素魔法学习机会（要花1000金）。如果已经有专家元素魔法，那么加p或者K。

同时，友方英雄相遇时，右键点击英雄相遇界面中间的三个双向大箭头部分，可以让低级英雄分享学者英雄的经验值（类似h5的导师技能）

塔城thane初始有一定几率带出1个高级灯神。

自己电脑上测试无问题。~~~~

我是用这个erm学到了火系魔法后，才想到改孤注一掷的。

十三木人

不是每个人都会打开erm文件看看里面有什么的，而你的介绍是放在erm文件里的
所以在帖子里就该说明白

希望创师

OK，那个介绍其实是给自己看的，呵呵。那么我修改一下原帖，把代码贴上吧

雨风月影

你说的这个英雄被我修改为初级寻路术+初级后勤术....

希望创师

原帖由 雨风月影 于 2012-10-21 10:50 发表
你说的这个英雄被我修改为初级寻路术+初级后勤术....

这么修改有什么缘故吗？他是塔城的资深炼金术老师，所以又学习和学术啊。寻路和后勤，准备做驴友？