【基本解决】求解释自由升级生物特长与生物关联

独孤求败

用法是在英雄的界面，用Shift+鼠标左键跳出高山堡垒，或者用Ctrl+鼠标左键点击英雄带领的部队。

－－－－－－－－－－－－－－－在跳出高山堡垒的的升级的价格和生物升级关联不是很合理。求高手指点一下下面如何修改生物升级的价格，以及生物升级之间的关联关系。我们新手就可以自己关联生物了。

ZVSE
!?CM2;
!!HE-1:N?y4;

!!CM:I?y1 F?y2;
!!FU&y2<>4:E;
!!FU|y1<68/y1>74:E;
!!VRy3:Sy1 -68;
!!HE-1:C0/y3/?y4/?y5;
!!FU|y4<0/y5<1:E;

!!FU1444&y4>=150/y4<=158:Py3/y4/y5;
!!FU1444&y4=196:Py3/y4/y5;

!!EX-1/y3:E?y6;
!!EX-1/y3:R?y7/d/d/d;
!!VRy8:S-1;
!!EX-1/y3&y7=1:R156/?y8;
!!VRy2:Sy4;
!!VRy4&y4=154:S69;血龙-鬼龙
!!FU1445&y4>=0/y4<=111:Py3/y2/y5/y6/y8;
!!FU1445&y4>=112/y4<=115:Py3/y2/y5/y6/y8;
!!FU1445&y4>=118/y4<=131:Py3/y2/y5/y6/y8;

!?FU1445;
!!VRy1&x2<111:Sx2 +1;

!!VRy1&y1=102/x2=101:S104;野牛-蜥蜴勇士-毒蝇
!!VRy1&y1=108/x2=107:S102;飞龙-巨蜥-野牛
!!VRy1&y1=104/x2=103:S108;毒蝇-蛮牛-飞龙

!!VRy1&x2=13:S150;大天使-至高大天使
!!VRy1&x2=27:S151;金龙-钻石龙
!!VRy1&x2=41:S152;泰坦巨人-雷神领主
!!VRy1&x2=55:S153;大恶魔-地狱男爵
!!VRy1&x2=69:S154;鬼龙-血龙
!!VRy1&x2=83:S155;黑龙-暗黑龙
!!VRy1&x2=97:S156;比蒙巨兽-幽灵比蒙
!!VRy1&x2=111:S157;终极九头怪-地狱九头蛇
!!VRy1&x2=154:S196;血龙-龙巫妖
!!VRy1&x2=118:S119;小精灵-精灵
!!VRy1&x2=119:S112;精灵-气元素
!!VRy1&x2=112:S127;气元素-雷元素
!!VRy1&x2=127:S115;雷元素-水元素
!!VRy1&x2=115:S123;水元素-冰元素
!!VRy1&x2=123:S114;冰元素-火元素
!!VRy1&x2=114:S129;火元素-烈火元素
!!VRy1&x2=129:S113;烈火元素-土元素
!!VRy1&x2=113:S125;土元素-石元素
!!VRy1&x2=125:S120;石元素-精神元素
!!VRy1&x2=120:S121;精神元素-魔法元素
!!VRy1&x2=121:S130;魔法元素-火鸟
!!VRy1&x2=130:S131;火鸟-凤凰
!!VRy1&x2=131:S158;凤凰-神圣凤凰

!!UN:N3/4/x2/0 N3/5/y1/0;
!!VRz1:S^你想将%Z4转变为%Z5吗?^;
!!VRz2:S^%Z4的总生命不够!^;
!!VRz3:S^你的钱或者资源不够!^;
!!IF:D1///1////////////;
!!IF:F1/////1;
!!IF:E1/1;
!!FU&v1<>5:E;

!!MA:Px2/?y2 Cx2/6/?y61 Cx2/1/?y11;
!!MA:Cx2/3/?y31 Cx2/4/?y41 Cx2/5/?y51;

!!MA:Py1/?y3 Cy1/6/?y62 Cy1/1/?y12;
!!MA:Cy1/3/?y32 Cy1/4/?y42 Cy1/5/?y52;

!!VRy8:Sy2 *x3 :y3;
!!VRy9:Sy2 *x3 %y3 :y2;
!!IF&y8=0:D1///2////////////;
!!IF&y8=0:F1/////0;
!!IF&y8=0:E1/1;
!!FU&y8=0:E;


!!VRy62:-y61;


!!VRy12:-y11;
!!VRy32:-y31;
!!VRy42:-y41;
!!VRy52:-y51;


!!VRy62:*y8;

!!VRy12:*y8;
!!VRy32:*y8;
!!VRy42:*y8;
!!VRy52:*y8;


!!OW:R-1/6/?y61;

!!OW:R-1/1/?y11;
!!OW:R-1/3/?y31;
!!OW:R-1/4/?y41;
!!OW:R-1/5/?y51;


!!IF|y61<y62/y11<y12/y31<y32/y41<y42/y51<y52:D1///3////////////;
!!IF|y61<y62/y11<y12/y31<y32/y41<y42/y51<y52:F1/////0;
!!IF|y61<y62/y11<y12/y31<y32/y41<y42/y51<y52:E1/1;
!!FU|y61<y62/y11<y12/y31<y32/y41<y42/y51<y52:E;


!!VRz1:S^花费%Y5金币得到%Y8个%Z5,是否继续?^;
!!VRz1&y12>0:S^花费%Y5金币和%Y12水银得到%Y8个%Z5,是否继续?^;
!!VRz1&y32>0:S^花费%Y5金币和%Y32硫磺得到%Y8个%Z5,是否继续?^;
!!VRz1&y42>0:S^花费%Y5金币和%Y42水晶得到%Y8个%Z5,是否继续?^;
!!VRz1&y52>0:S^花费%Y5金币和%Y52宝石得到%Y8个%Z5,是否继续?^;

!!IF:D1///1////////////;
!!IF:F1/////1;
!!IF:E1/1;
!!FU&v1<>5:E;


!!VRy12:*-1;
!!VRy32:*-1;
!!VRy42:*-1;
!!VRy52:*-1;
!!VRy62:*-1;


!!OW:R-1/6/dy62 R-1/1/dy12 R-1/3/dy32;
!!OW:R-1/4/dy42 R-1/5/dy52;

!!VRy4:Sy8 *65536 +y1;
!!VRy5&y9>0:Sy9 *65536 +x2;
!!IF&y9=0:Q1/21/y4/1^^;
!!IF&y9>0:Q1/21/y4/21/y5/1^^;
!!HE-1:C0/x1/y1/y8;
!!EX-1/x1:Ex4;
!!EX-1/x1&x5>-1:R156/x5;
!!HE-1&y9>0:C2/x2/y9/1;
!!UN:R3/-1;
****************************************************

!?FU1444;
!!VRy99:S10;
!!UN:N3/9/x2/0;
!!UN:N3/10/x2/1;
!!VRz1:S^你想用%Y99个%Z10换5攻击/5防御/1速度/20%伤害/20%生命吗?^;
!!IF:D1///1////////////;
!!IF:F1/////1;
!!IF:E1/1;
!!FU&v1<>5:E;
!!VRz1&x3<y99:S^英雄,%Z9的数目好像不够!^;
!!IF&x3<y99:D1///1////////////;
!!IF&x3<y99:F1/////0;
!!IF&x3<y99:E1/1;
!!FU&x3<y99:E;
!!VRz1:S^5 攻击^;
!!VRz2:S^5 防御^;
!!VRz3:S^1 速度^;
!!VRz4:S^20% 伤害^;
!!VRz5:S^20% 生命^;
!!VRz6:S^取消^;
!!VRz7:S^你想为%Z9增加哪个属性?^;
!!IF:G1/1/32/7/1/2/3/4/5/6;
!!FU&v1=32:E;
!!EX-1/x1:E?y-1;
!!MA&v1=1:Ax2/d5;
!!MA&v1=2:Dx2/d5;
!!MA&v1=4:Sx2/d1;
!!MA&v1=8:Mx2/?y1;
!!VRy1&v1=8:*20 :100;
!!VRy1&v1=8/y1=0:S1;
!!MA&v1=8:Mx2/dy1 Ex2/dy1;
!!MA&v1=16:Px2/?y1;
!!VRy1&v1=16:*20 :100;
!!VRy1&v1=16/y1=0:S1;
!!MA&v1=16:Px2/dy1;
!!VRz8&v1=1:Sz1;
!!VRz8&v1=2:Sz2;
!!VRz8&v1=4:Sz3;
!!VRz8&v1=8:Sz4;
!!VRz8&v1=16:Sz5;
!!VRz8:S^恭喜!%Z9已经增加了%Z8!^;
!!IF:D1///8////////////;
!!IF:F1/////0;
!!IF:E1/1;
!!HE-1:C0/x1/x2/?y-2;
!!VRy-2:-y99;
!!HE-1:C0/x1/x2/y-2;
!!EX-1/x1:Ey-1;
!!UN:R3/-1;

!?CM2;

!!CM:I?y1 F?y2;
!!HE-1&y1>=68/y1<=74/y2=1:D;
!!CM&y1>=68/y1<=74/y2=1:R0;

!!HE-1:C0/x16/?y1/?y2;
!!FU|y1<0/y2<1:E;

!!VRy3&y1<111:Sy1 %2;
!!VRy4&y3=0/y1<111:Sy1 +1;
!!HE153&y3=0/y1<111:C0/x16/y4/y2;

!!VRy4&y1=113:S127;土元素-雷元素
!!VRy4&y1=114:S125;火元素-石元素
!!VRy4&y1=115:S129;水元素-烈火元素
!!VRy4&y1=116:S123;金人-冰元素
!!HE153&y1>=113/y1<=116:C0/x16/y4/y2;

!!VRy4&y1=111:S157;终极九头怪-地狱九头蛇
!!VRy4&y1=130:S131;火鸟-凤凰
!!VRy4&y1=131:S158;凤凰-神圣凤凰
!!HE153|y1=111/y1=130/y1=131:C0/x16/y4/y2;

!!FU&y3=0:E;
!!VRy4&y1=9:S169;祭司-战争狂热者
!!VRy4&y1=13:S150;大天使-至高大天使
!!VRy4&y1=27:S151;金龙-钻石龙
!!VRy4&y1=41:S152;泰坦巨人-雷神领主
!!VRy4&y1=55:S153;大恶魔-地狱男爵
!!VRy4&y1=69:S154;鬼龙-血龙
!!VRy4&y1=83:S155;黑龙-暗黑龙
!!VRy4&y1=97:S156;比蒙巨兽-幽灵比蒙
!!HE153|y1=9/y1=13/y1=27/y1=41/y1=55/y1=69/y1=83/y1=97:C0/x16/y4/y2;

[ 本帖最后由 独孤求败 于 2012-5-17 19:46 编辑 ]

兽哥哥

ERM我是外行 完全看不懂

灰狼王子

LZ你参考一下元老殿堂里的上帝之手脚本，估计能解决你的问题吧
要不就等一下ERM大大们前来会诊

十三木人

!!VRy1&x2=13:S150;
!!VRy1&x2=27:S151;
!!VRy1&x2=41:S152;
........
!!VRy1&x2=131:S158;
这一段代码就是升级关系x2=?表示升级前兵种，S?表示升级后兵种
修改后对ctrl+左键的升级有效
价格什么的不知道

沧海一粟

你的意图我看得不是很明白，简单看了下这脚本，应该主要有两个功能：
一是Ctrl+鼠标左键点击英雄带领的部队可以使部队无限地向上升一级，比如说枪兵-戟兵-弓箭手-神射手...也就是说只要资源允许，能升到最高级别的生物，功能很变态，所以作者好像提高了生命限制及资源限制。这样觉得倒还比较公平，你想改动必须对他设置的数值进行较大改动才行，问题是不知道你想变成怎么样的数值？
二是英雄可以模拟高山堡垒升级生物，这功能好玩，但作者还相当贴心地加上了巨龙摩莉尔的升级有特别功能，呵呵。
其实如果不加巨龙的话，也许两句话应该就可以解决这功能了：
!?CM2;
!!CM:I?y1 F?y2;
!!HE-1&y1>=68/y1<=74/y2=1:D;
!!CM&y1>=68/y1<=74/y2=1:R0;

沧海一粟

升级关系主要是这些：
!!VRy1&x2<111:Sx2 +1;  最主要就是这一句，生物编号+1

!!VRy1&y1=102/x2=101:S104;  这几句是限制沼泽生物编号混乱的
!!VRy1&y1=108/x2=107:S102;
!!VRy1&y1=104/x2=103:S108;

!!VRy1&x2=13:S150;   这几句是升级为8级生物的
!!VRy1&x2=27:S151;
!!VRy1&x2=41:S152;
!!VRy1&x2=55:S153;
!!VRy1&x2=69:S154;
!!VRy1&x2=83:S155;
!!VRy1&x2=97:S156;
!!VRy1&x2=111:S157;
!!VRy1&x2=154:S196;
!!VRy1&x2=118:S119;    这几句是限制元素族编号混乱的
!!VRy1&x2=119:S112;
!!VRy1&x2=112:S127;
!!VRy1&x2=127:S115;
!!VRy1&x2=115:S123;
!!VRy1&x2=123:S114;
!!VRy1&x2=114:S129;
!!VRy1&x2=129:S113;
!!VRy1&x2=113:S125;
!!VRy1&x2=125:S120;
!!VRy1&x2=120:S121;
!!VRy1&x2=121:S130;
!!VRy1&x2=130:S131;
!!VRy1&x2=131:S158;

沧海一粟

至于价格计算懒得认真看了，应该从下面代码入手，问题是你想改成什么样，如果按原生物规则的话还是不难改的。
!!UN:N3/4/x2/0 N3/5/y1/0;
!!VRz1:S^你想将%Z4转变为%Z5吗?^;
!!VRz2:S^%Z4的总生命不够!^;
!!VRz3:S^你的钱或者资源不够!^;
!!IF:D1///1////////////;
!!IF:F1/////1;
!!IF:E1/1;
!!FU&v1<>5:E;

!!MA:Px2/?y2 Cx2/6/?y61 Cx2/1/?y11;
!!MA:Cx2/3/?y31 Cx2/4/?y41 Cx2/5/?y51;

!!MA:Py1/?y3 Cy1/6/?y62 Cy1/1/?y12;
!!MA:Cy1/3/?y32 Cy1/4/?y42 Cy1/5/?y52;

!!VRy8:Sy2 *x3 :y3;
!!VRy9:Sy2 *x3 %y3 :y2;
!!IF&y8=0:D1///2////////////;
!!IF&y8=0:F1/////0;
!!IF&y8=0:E1/1;
!!FU&y8=0:E;


!!VRy62:-y61;


!!VRy12:-y11;
!!VRy32:-y31;
!!VRy42:-y41;
!!VRy52:-y51;


!!VRy62:*y8;

!!VRy12:*y8;
!!VRy32:*y8;
!!VRy42:*y8;
!!VRy52:*y8;


!!OW:R-1/6/?y61;

!!OW:R-1/1/?y11;
!!OW:R-1/3/?y31;
!!OW:R-1/4/?y41;
!!OW:R-1/5/?y51;


!!IF|y61<y62/y11<y12/y31<y32/y41<y42/y51<y52:D1///3////////////;
!!IF|y61<y62/y11<y12/y31<y32/y41<y42/y51<y52:F1/////0;
!!IF|y61<y62/y11<y12/y31<y32/y41<y42/y51<y52:E1/1;
!!FU|y61<y62/y11<y12/y31<y32/y41<y42/y51<y52:E;


!!VRz1:S^花费%Y5金币得到%Y8个%Z5,是否继续?^;
!!VRz1&y12>0:S^花费%Y5金币和%Y12水银得到%Y8个%Z5,是否继续?^;
!!VRz1&y32>0:S^花费%Y5金币和%Y32硫磺得到%Y8个%Z5,是否继续?^;
!!VRz1&y42>0:S^花费%Y5金币和%Y42水晶得到%Y8个%Z5,是否继续?^;
!!VRz1&y52>0:S^花费%Y5金币和%Y52宝石得到%Y8个%Z5,是否继续?^;

!!IF:D1///1////////////;
!!IF:F1/////1;
!!IF:E1/1;
!!FU&v1<>5:E;

!!VRy12:*-1;
!!VRy32:*-1;
!!VRy42:*-1;
!!VRy52:*-1;
!!VRy62:*-1;

!!OW:R-1/6/dy62 R-1/1/dy12 R-1/3/dy32;
!!OW:R-1/4/dy42 R-1/5/dy52;

十三木人

受教了，还是有好多东西没注意到啊

独孤求败

由于在实战中和朋友们一起对局，朋友提到，这个脚本很好，可以充分的发挥游戏资源经营的目的，但是，亡灵一族过于强大了，因为有了招魂术，骷髅的来源就是无限，而用shift 升级路线是：骷髅－骷髅兵－僵尸－木乃伊－巫尸王，其中的价格还不到600块，比在城里招募还便宜，这就不平衡了。ctrl 的升级是用生命去换取属性的点数是比较合理的。
   我提出问题的目的是：
   1、希望至少升级的价格和招募的一样。
   2、玩家能够自主的实行生物关联。里面的关联有不少是很好的题材，可以给人自主发挥生物契约的联想，比如：a,弓箭手－－熔岩弓箭手  b,马类：游牧民、骑兵、骑士、暗黑骑士、梦魇兽；独角兽－地狱烈马  c,骷髅类：骷髅兵－－巫尸王  d,鸟类：狮鹫、大雕、凤凰  e,小怪物类：小怪物、哥革、恶鬼、长角恶鬼  f.精灵射手－－半人马射手  g.哥布林类－－食人魔王 h.小精灵类：小精灵－－烈火精灵。等等

独孤求败

我试验了几次，结果如下，
升级关系主要是这些：
!!VRy1&x2<111:Sx2 +1;  最主要就是这一句，生物编号+1

我在这个脚本后面还贴了一个关联的脚本，沧海前辈你看看是不是这个引起的：

ZVSE
_WARNING_#1=IMPORTANT! This file is not in a plain text format. NEVER use any editor except ERM_S for making any kind of changes!
ERMS_PoweredBy=ERM Scripter v. 2004.6.29.918
ERMS_ScriptDate=7.2(February).2010

    修改关联
!#MA:U1/6; !#MA:U6/10; !#MA:U9/169; !#MA:U9/35; !#MA:U35/193; !#MA:U193/136;
!#MA:U39/172; !#MA:U67/172; !#MA:U172/67; !#MA:U11/67; !#MA:U141/64;
!#MA:U29/173; !#MA:U21/24; !#MA:U43/44; !#MA:U45/48; !#MA:U73/5; !#MA:U5/92;
!#MA:U19/137; !#MA:U137/170; !#MA:U39/168; !#MA:U93/130; !#MA:U95/40;
!#MA:U32/33; !#MA:U33/116; !#MA:U116/117; !#MA:U117/165; !#MA:U165/95;
!#MA:U112/127; !#MA:U127/166; !#MA:U113/125; !#MA:U125/165; !#MA:U23/141;
!#MA:U114/129; !#MA:U129/164; !#MA:U164/53; !#MA:U37/53; !#MA:U53/55;
!#MA:U115/123; !#MA:U123/167; !#MA:U119/76; !#MA:U83/135; !#MA:U85/86;
!#MA:U15/192; !#MA:U99/194; !#MA:U134/196; !#MA:U154/196; !#MA:U25/195;
!#MA:U139/138; !#MA:U138/1; !#MA:U101/104; !#MA:U107/108; !#MA:U140/142;
!#MA:U31/62; !#MA:U17/90; !#MA:U87/88; !#MA:U47/80; !#MA:U133/132;
!#MA:U57/58; !#MA:U142/10; !#MA:U10/66;

意思是这样的：
!#MA:U1枪兵/6剑士; !#MA:U6剑士/10骑兵; !#MA:U9祭司/169战争狂热者; !#MA:U9祭司/35大法师; !#MA:U35大法师/193女巫; !#MA:U193女巫/136魔幻法师;
!#MA:U39铁人/172梦魇兽; !#MA:U67恐怖骑士/172梦魇兽; !#MA:U172梦魇兽/67恐怖骑士; !#MA:U11骑士/67恐怖骑士; !#MA:U141木乃伊/64尸巫;
!#MA:U29大妖精/173圣侏儒; !#MA:U21银飞马/24独角兽; !#MA:U43怪物/44歌革; !#MA:U45玛各/48恶鬼; !#MA:U73鹰身女巫/5狮鹫; !#MA:U5皇家狮鹫/92大雕;
!#MA:U19大精灵/137幻影射手; !#MA:U137幻影射手/170极地神射手; !#MA:U39蛇妖/168血污怪; !#MA:U93雷鸟/130火鸟; !#MA:U95独眼王/40巨人;
!#MA:U32石人/33铁人; !#MA:U33铁人/116金人; !#MA:U116金人/117钻石人; !#MA:U117钻石人/165土元素使者; !#MA:U165土元素使者/95独眼王;
!#MA:U112气元素/127雷元素; !#MA:U127雷元素/166气元素使者; !#MA:U113土元素/125石元素; !#MA:U125石元素/165土元素使者; !#MA:U23枯木战士/141木乃伊;!#MA:U114火元素/129烈火元素; !#MA:U129烈火元素/164火元素使者; !#MA:U164火元素使者/53烈火精灵; !#MA:U37神怪主/53烈火精灵; !#MA:U53烈火精灵/55大恶魔;!#MA:U115水元素/123冰元素; !#MA:U123冰元素/167水元素使者; !#MA:U119精灵/76美杜莎; !#MA:U83黑龙/135毒龙; !#MA:U85大耳怪王/86恶狼骑士;!#MA:U15半人马首领/192森林半人马; !#MA:U99大狼人/194变人狼; !#MA:U134紫龙/196龙巫妖; !#MA:U154血龙/196龙巫妖; !#MA:U25独角神兽/195地狱战马;!#MA:U139农民/138投石矮人; !#MA:U138投石矮人/1戟兵; !#MA:U101蜥蜴勇士/104毒蝇; !#MA:U107巨蜥/108飞龙; !#MA:U140野猪/142游牧民;
!#MA:U31石像怪/62吸血鬼; !#MA:U17战斗矮人/90食人魔; !#MA:U87恶狼斗士/88半兽人; !#MA:U47三首猎犬/80蝎狮; !#MA:U133水晶龙/132圣龙;
!#MA:U57骷髅勇士/58行尸; !#MA:U142游牧民/10骑兵; !#MA:U10骑兵/66暗黑骑士;

[ 本帖最后由 独孤求败 于 2012-5-14 01:26 编辑 ]

沧海一粟

这个生物升级功能与原升级功能不同的是，除了价格差外还加入了生物数量*生命的条件，所以感觉会比原来传统高山壁垒升级要钱多，但感觉还是这样平衡。至于你另外加的脚本，加减招募生物所需资源、加减生物的生命值这些肯定会对价格差有影响的。

!!MA:Px2/?y2 Cx2/6/?y61 Cx2/1/?y11;  获得未升级前生物的生命值、价格6及是否需要水银1、硫磺3、水晶4、宝石6
!!MA:Cx2/3/?y31 Cx2/4/?y41 Cx2/5/?y51;
!!MA:Py1/?y3 Cy1/6/?y62 Cy1/1/?y12;  获得升级后生物的生命值、价格6及是否需要水银1、硫磺3、水晶4、宝石6
!!MA:Cy1/3/?y32 Cy1/4/?y42 Cy1/5/?y52;
!!VRy8:Sy2 *x3 :y3;                            升级前生物生命*数量除升级后生物生命
!!VRy9:Sy2 *x3 %y3 :y2;  
升级前生物生命*数量除升级后生物生命后的余数再除升级前生物生命～这个与价格无关联，主要是为了后面的
!!IF&y8=0:D1///2////////////;
!!IF&y8=0:F1/////0;
!!IF&y8=0:E1/1;
!!FU&y8=0:E;  这几句的意思是说如果升级前生物生命*数量除升级后生物生命的值=0时升级对话框则取消

!!VRy62:-y61; 升级后生物价格减升级前生物价格

!!VRy12:-y11; 同上，这个是水银数量
!!VRy32:-y31; 硫磺数量
!!VRy42:-y41; 水晶数量
!!VRy52:-y51; 宝石数量

!!VRy62:*y8;  升级后生物价格减升级前生物价格差*升级前生物生命乘数量除升级后生物生命的最终值

!!VRy12:*y8; 同上水银
!!VRy32:*y8; 硫磺
!!VRy42:*y8; 水晶
!!VRy52:*y8; 宝石

!!OW:R-1/6/?y61; 取当前英雄的金钱数
!!OW:R-1/1/?y11; 水银数
!!OW:R-1/3/?y31; 硫磺数
!!OW:R-1/4/?y41; 水晶数
!!OW:R-1/5/?y51; 宝石数

!!IF|y61<y62/y11<y12/y31<y32/y41<y42/y51<y52:D1///3////////////;
!!IF|y61<y62/y11<y12/y31<y32/y41<y42/y51<y52:F1/////0;
!!IF|y61<y62/y11<y12/y31<y32/y41<y42/y51<y52:E1/1;
!!FU|y61<y62/y11<y12/y31<y32/y41<y42/y51<y52:E;  这几个判断的意思是说需要资源数量少于上述条件时取消对话框

!!VRz1:S^花费%Y5金币得到%Y8个%Z5,是否继续?^;
!!VRz1&y12>0:S^花费%Y5金币和%Y12水银得到%Y8个%Z5,是否继续?^;
!!VRz1&y32>0:S^花费%Y5金币和%Y32硫磺得到%Y8个%Z5,是否继续?^;
!!VRz1&y42>0:S^花费%Y5金币和%Y42水晶得到%Y8个%Z5,是否继续?^;
!!VRz1&y52>0:S^花费%Y5金币和%Y52宝石得到%Y8个%Z5,是否继续?^;
!!IF:D1///1////////////;
!!IF:F1/////1;
!!IF:E1/1;
!!FU&v1<>5:E;  这几句的意思是说符合上述条件后但你选取消便退出函数

!!VRy12:*-1; 符合条件按确定则减去所需资源
!!VRy32:*-1;
!!VRy42:*-1;
!!VRy52:*-1;
!!VRy62:*-1;

!!OW:R-1/6/dy62 R-1/1/dy12 R-1/3/dy32;  重置玩家现在的资源（升级后）
!!OW:R-1/4/dy42 R-1/5/dy52;

沧海一粟

原帖由 独孤求败 于 2012-5-13 22:28 发表
由于在实战中和朋友们一起对局，朋友提到，这个脚本很好，可以充分的发挥游戏资源经营的目的，但是，亡灵一族过于强大了，因为有了招魂术，骷髅的来源就是无限，而用shift 升级路线是：骷髅－骷髅兵－僵尸－木乃伊－ ...

你这个按上述脚本修改一下，还是很容易可以实现你心目中理想的升级功能的。

独孤求败

OK!!
再次向沧海前辈致敬！升级比较合理了！

感觉还是便宜了，能不能帮我加上收取同等的手续费或者50%的手续费。

我试图慢慢的把生物关联联系起来，把这个生物关联关系搞得生动一点，改好了在发给你看看啊！看我能不能改的有些平衡。

[ 本帖最后由 独孤求败 于 2012-5-14 01:30 编辑 ]

独孤求败

沧海前辈：感谢您对我鼓励。
      另外，我表达得不够明确，令您误会了一些。所以我连夜的实验这个脚本，发现Ctrl升级奇贵无比，我用500多万升级1000个天使也无法进行。还有，您居然把shift+英雄部队模拟高山堡垒删除了，我很不满意。
      其实我的目的只有一个，就是用养成的方式去玩游戏，让游戏更加耐玩。对于养成游戏而言，资源的经营和属性的升级是最令人永远保持热情的！那么，用力的去经营资源，用资源升级部队，当你带着一个很喜欢的枪兵，其属性很牛叉的到处走，是不是很得意？：）所以，原脚本的创意是很好的。所以我的希望有两点：
       1,横向思维：shift+英雄部队模拟高山堡垒，让英雄可以随时升级生物。加上!#MA命令的使用，玩家就可以自由地定义生物关联，可以达到增加游戏乐趣的目的。我说原来的脚本是升级生物的价格为差价乘以生命系数，这个价格太低，能不能调整为10倍（最好能够指明倍数的地方，可以让我在实践中慢慢调整以达到平衡）。
       2,纵深思维：ctrl+英雄部队升级为下一级生物，其实这个创意并不是很好，倒是后面的到了八级生物以后增加属性的创意很好，很象废墟神殿的功能。所以，我希望是用金钱可加增加部队的经验以及属性，毕竟，我还没有见过5级以上的下属部队，因为他们不断的死去以及新部队的加入让等级和属性下降了，那么能不能用资源和金钱来解决呢。

[ 本帖最后由 独孤求败 于 2012-5-17 13:03 编辑 ]

沧海一粟

!?CM2;
!!CM:I?y1 F?y2;
!!HE-1&y1>=68/y1<=74/y2=1:D;
!!CM&y1>=68/y1<=74/y2=1:R0;
这两句加上去就可以使用高山堡垒了，问题是感觉功能重复没意义。另外，关于价格是你自己定的（如果连自己都不会计算那我也没办法），10倍我自己感觉都太多了，建议结合脚本功能，改成2倍还比较合适。
按你的这个算法，大天使价格5000，圣天使价格10000，正常升级需要加5000，10倍就是50000，50000的1000倍是5千万，再加上原脚本总生命计算因素，1000个大天使只能升级成500个至高，也就是5千万的1/2为2500万，你500万怎么够呢？当然一个3宝石一个4宝石，你还必须要有500个宝石。

[ 本帖最后由 沧海一粟 于 2012-5-17 14:35 编辑 ]

eva2000as

原帖由 独孤求败 于 2012-5-17 12:59 发表
沧海前辈：感谢您对我鼓励。
      另外，我表达得不够明确，令您误会了一些。所以我连夜的实验这个脚本，发现Ctrl升级奇贵无比，我用500多万升级1000个天使也无法进行。还有，您居然把shift+英雄部队模拟高山堡垒 ...

生物经验的话，虽然补兵会平均掉一些，但只要战斗无损就行了，而且WOG的无损比SOD简单太多了。

希望创师

可以直接跳出高山堡垒，能不能直接跳出其他建筑效果？比如召唤石，时间市场什么的？

eva2000as

原帖由 希望创师 于 2012-5-17 18:03 发表
可以直接跳出高山堡垒，能不能直接跳出其他建筑效果？比如召唤石，时间市场什么的？

记得是可以的。生物宝物查询ERM有一个功能就是跳梦幻殿堂改生物经验特技。

沧海一粟

你想跳什么实现什么都应该是可以的，当然前提是可以实现的功能。
关于修改生物经验属性这功能，不用梦之殿堂翡翠塔，木瓜好像在2006年就已经实现了。

[ 本帖最后由 沧海一粟 于 2012-5-18 10:47 编辑 ]

郁闷の幻想

如果做好可以发在帖子里一份吗?我也想要