新手关于生物经验等级修改的求助

xipha

生物长经验太麻烦，合并啊升级啊战役过关啊的又没了，尤其是越高级的兵越难升，而低级兵打仗死得快，一加新兵等级又没了，变态图打着打着就负了。
所以我觉得，干脆改成和英雄的等级和特长挂钩：（上限为满级，下限为一级），这样德肯塞尔伦什么的也好翻身了。
选项1，生物等级=英雄等级-部队等级， 特长英雄对应部队等级=英雄等级-部队等级+4，,目的是10级英雄可以享受一级兵双剑，17级以上的英雄就可以享受全双剑。
选项2，生物等级=英雄等级-部队等级*2， 特长英雄对应部队等级=英雄等级-部队等级，,目的是24级以上的英雄就可以享受全双剑，18级时4级兵双剑。
选项3，生物等级=英雄等级/2-部队等级， 特长英雄对应部队等级=英雄等级-部队等级，,目的是35级以上的英雄可以享受全双剑，供变态地图用。
同时保留野兵的经验增长设置。

由于找不到到底是哪个已有的erm在管生物等级。所以如果要添加新的erm，目前想到的思路有：（第一天让选择）
1，设经验上限，根据英雄初始等级给部队加经验，每次升级再加经验，特长英雄多加经验。
2，每场战斗开始前重设双方有英雄带领的部队等级。
3，每天初始化部队等级。
4，第一天初始化部队等级，每战后按英雄等级多还少补。升级或者合兵或者新部队加入的时候重置等级。

在下erm小白，搞不清楚用什么变量才不会和系统冲突，也不知道部队每一级的经验应该是多少。
请各位大大帮忙写下这个脚本。先多谢了！

[ 本帖最后由 xipha 于 2012-4-4 11:09 编辑 ]

灰狼王子

生物经验系统正是为了如实反映实际战斗情况，久经沙场的精英部队不管谁带领都应该比新兵蛋子要NB才对，老兵带新兵也有有限制的，多了肯定会降低整体的战斗力。
LZ的想法则是“强将手下无弱兵”，突出了英雄的作用。

沧海一粟

楼主的想法应该不难实现，至于想法，有些貌似没意义而且写起来啰嗦，如果不是战斗时可将生物经验全部清0，战斗时再根据英雄的等级或经验结合不同的生物等级加上不同的经验就行了（野兵也可以根据英雄等级分别提高这才平衡嘛），容易写又不会发生错误。建议你召唤一下召唤师解决。

xipha

关键是特长英雄怎么办？
还有就是，能不能让战术技能在每级增加部队等级半级，让学习术技能同时增加部队获得的经验，航海术在海战增加部队等级一级，学术每级增加英雄部队的施法次数？

骷髅召唤师

这个是你要的，我没有添加英雄技能的因素。
有BUG请指出
ZVSE
******ERM名称*****生物经验获取方式
******ERM内容*****
**选项1，不改变原有的生物经验获取方式，根据战斗胜利后来增加生物经验
**选项2，生物等级=英雄等级-部队等级， 特长英雄对应部队等级=英雄等级-部队等级+4
**选项3，生物等级=英雄等级-部队等级*2，特长英雄对应部队等级=英雄等级-部队等级
**选项4，生物等级=英雄等级/2-部队等级，特长英雄对应部队等级=英雄等级-部队等级
**野兵经验设置为进攻方英雄的生物等级+2
******ERM作者*****骷髅召唤师
******FU变量 *****FU2800 x1=50~52
******V变量  *****V10
******Z变量  *****Z10~Z19
!?PI;
!!VRz10:S^请选择你的生物经验的增长方式^;
!!VRz11:S^By-骷髅召唤师^;
!!VRz12:S^选项1-不改变原有的生物经验获取方式^;
!!VRz13:S^选项2-生物经验等级=英雄等级-部队等级^;
!!VRz14:S^选项3-生物经验等级=英雄等级-部队等级*2^;
!!VRz15:S^选项4-生物经验等级=英雄等级/2-部队等级^;
!!VRz16:S^生物经验根据战斗胜利后来增加生物经验^;
!!VRz17:S^特长英雄对应生物级=英雄等级-部队等级+4^;
!!VRz18:S^特长英雄对应生物级=英雄等级-部队等级^;
!!VRz19:S^特长英雄对应生物级=英雄等级-部队等级^;
!!IF:D5/10//11/////////12/13/14/15;
!!IF:F5/16/17/18/19/0;
!!IF:E10/5;

!?BA0&v10>=2/v10<=4;
!!BA:H0/?v9555 H1/?v9560;

!?BF&v10>=2/v10<=4;
!!DO2800/0/20/1&v9555>-1:P50/v9555/v10;
!!DO2800/21/41/1&v9560>-1:P50/v9560/v10;
!!DO2800/21/41/1&v9560<0:P51/v9555/v10;

!?FU2800&x1=50;
!!BMx16:T?x4 N?x5;
!!FU|x4<0/x5<1:E;
!!FU&x4>144/x4<150:E;
!!FU&x4>173/x4<192:E;
!!MA:Lx4/?x6;
!!VRx7:Sx6 +1;
!!VRx7&x7=7/x4>131/x4<136:S8;
!!VRx7&x7=7/x4>149/x4<159:S8;
!!VRx7&x7=7/x4=196:S8;
!!HEx2:Ed/?x8 X?y1/?y2/d/d/d/d/d;
!!MA|y1=1/y1=4:Ly2/?y3 Oy2/?y4;
!!UN&y4>-1:Ty4/y3/0/?y5 Ty4/y3/1/?y6;
!!VRy7:Sx7 *2;
!!VRx9&x3=2:Sx8 -x7;
!!VRx9&x3=3:Sx8 -y7;
!!VRx9&x3=4:Sx8 :2 -x7;
!!VRy8:S0;
!!VRy8|x4=y5/x4=y6:S1;
!!VRx9&x3=2/y8=1:Sx9 +4;
!!VRx9&x3=3/y8=1:Sx8 -x7;
!!VRx9&x3=4/y8=1:Sx8 -x7;
!!VRx9&x9<0:S0;
!!VRx10:S0;
**LV 1~7
!!VRx10&x9=0/x7<8:S0;
!!VRx10&x9=1/x7<8:S1000 *x7;
!!VRx10&x9=2/x7<8:S2000 *x7;
!!VRx10&x9=3/x7<8:S3200 *x7;
!!VRx10&x9=4/x7<8:S4600 *x7;
!!VRx10&x9=5/x7<8:S6200 *x7;
!!VRx10&x9=6/x7<8:S8000 *x7;
!!VRx10&x9=7/x7<8:S10000 *x7;
!!VRx10&x9=8/x7<8:S12200 *x7;
!!VRx10&x9=9/x7<8:S14700 *x7;
!!VRx10&x9>=10/x7<8:S17500 *x7;
**LV 8
!!VRx10&x9=0/x7=8:S0;
!!VRx10&x9=1/x7=8:S8400;
!!VRx10&x9=2/x7=8:S16800;
!!VRx10&x9=3/x7=8:S26880;
!!VRx10&x9=4/x7=8:S38640;
!!VRx10&x9=5/x7=8:S52080;
!!VRx10&x9=6/x7=8:S67500;
!!VRx10&x9=7/x7=8:S84000;
!!VRx10&x9=8/x7=8:S102480;
!!VRx10&x9=9/x7=8:S123480;
!!VRx10&x9>=10/x7=8:S147000;
!!VRy-1:Sx16 +1 *-1;
!!EAy-1:Ex10/2/d/d;

!?FU2800&x1=51;
!!BMx16:T?x4 N?x5;
!!FU|x4<0/x5<1:E;
!!FU&x4>144/x4<150:E;
!!FU&x4>173/x4<192:E;
!!MA:Lx4/?x6;
!!VRx7:Sx6 +1;
!!VRx7&x7=7/x4>131/x4<136:S8;
!!VRx7&x7=7/x4>149/x4<159:S8;
!!VRx7&x7=7/x4=196:S8;
!!HEx2:Ed/?x8 X?y1/?y2/d/d/d/d/d;
!!MA|y1=1/y1=4:Ly2/?y3 Oy2/?y4;
!!UN&y4>-1:Ty4/y3/0/?y5 Ty4/y3/1/?y6;
!!VRy7:Sx7 *2;
!!VRx9&x3=2:Sx8 -x7 +2;
!!VRx9&x3=3:Sx8 -y7 +2;
!!VRx9&x3=4:Sx8 :2 -x7 +2;
!!VRy8:S0;
!!VRy8|x4=y5/x4=y6:S1;
!!VRx9&x3=2/y8=1:Sx9 +4;
!!VRx9&x3=3/y8=1:Sx8 -x7;
!!VRx9&x3=4/y8=1:Sx8 -x7;
!!VRx9&x9<0:S0;
!!VRx10:S0;
**LV 1~7
!!VRx10&x9=0/x7<8:S0;
!!VRx10&x9=1/x7<8:S1000 *x7;
!!VRx10&x9=2/x7<8:S2000 *x7;
!!VRx10&x9=3/x7<8:S3200 *x7;
!!VRx10&x9=4/x7<8:S4600 *x7;
!!VRx10&x9=5/x7<8:S6200 *x7;
!!VRx10&x9=6/x7<8:S8000 *x7;
!!VRx10&x9=7/x7<8:S10000 *x7;
!!VRx10&x9=8/x7<8:S12200 *x7;
!!VRx10&x9=9/x7<8:S14700 *x7;
!!VRx10&x9>=10/x7<8:S17500 *x7;
**LV 8
!!VRx10&x9=0/x7=8:S0;
!!VRx10&x9=1/x7=8:S8400;
!!VRx10&x9=2/x7=8:S16800;
!!VRx10&x9=3/x7=8:S26880;
!!VRx10&x9=4/x7=8:S38640;
!!VRx10&x9=5/x7=8:S52080;
!!VRx10&x9=6/x7=8:S67500;
!!VRx10&x9=7/x7=8:S84000;
!!VRx10&x9=8/x7=8:S102480;
!!VRx10&x9=9/x7=8:S123480;
!!VRx10&x9>=10/x7=8:S147000;
!!VRy-1:Sx16 +1 *-1;
!!EAy-1:Ex10/2/d/d;

!?BA1&v10>=2/v10<=4;
!!HE-1:O?y1 N?y2;
!!FU&y1<0:E;
!!DO2800/0/6/1:P52/y2;

!?FU2800&x1=52;
!!HEx2:C0/x16/?x3/d;
!!FU&x3<0:E;
!!HEx2:C0/x16/d/d/0/12;

[ 本帖最后由 骷髅召唤师 于 2012-4-10 10:52 编辑 ]

xipha

多谢多谢! 这就去试试！