ERM新嫩菜鸟求助

dadds

多谢大大帮忙了

沧海一粟

由于酒精使然，头有点晕，没认真测试不知道有没有错误，如果看不懂，明天我再加注释。
**ERM实现功能：英雄在施放霹雳寒冰魔法后可按自身水系技能等级机率（无=20%，1级=30%，2级=40%，3级=50%）使目标冻结，被冻结后的生物本回合无法行动，且本回合受到伤害按英雄水系技能等级加成（无+20%，1级+30，2级+40%，3级+50%）。


ZVSE

!?BG&1000;
!!VRv1360:C-1/-1/-1/-1/-1/-1/-1/-1;
!!BG:A?v1360 D?v1361 E?v1362;
!!BG:H?v1363 N?v1364 Q?v1365 S?v1366;
!!BHv1365:N?v1367;

!?BG1&1000;
!!FU2600&v1360=1:P-100/v1362/v1366/v1367;

!?FU2600&x1=-100;
!!FU|x2<0/x2>41/x3<>16/x4<0:E;
!!BMx2:T?x5 N?x6 F?i G16/?x7/d;
!!VRi:&67108864;
!!FU|x5<0/x6<1/x7>0:E;
!!HEx4:B0/?z-1 S16/?x10;
!!VRx8:S0;
!!VRx9:S1 R99;
!!VRx8&x10<=0:S20;
!!VRx8&x10=1:S30;
!!VRx8&x10=2:S40;
!!VRx8&x10>=3:S50;
!!FU&x9>x8:E;
!!UN:N3/-3/x5/1;
!!UN:N1/-4/16/1;
!!VRz-9:S^Weakness.wav^;
!!SN:Pz-9;
!!BMx2:V56 M16/1/x10;   这里就是这个脚本的妙处
!!BMx2&i=0:Fd67108864;
!!VRz-10:S^{%Z-3受到%Z-1的%Z-4魔法打击后竟然被冻结了。} ^;
!!BU:Mz-10 R;

!?MF1&1000;
!!FU2600:P-99;

!?FU2600&x1=-99;
!!MF:F?x2 N?x3;
!!FU|x3<0/x3>41:E;
!!BG:A?x4 N?x5 Q?x6;
!!BHx6:N?x7;
!!FU&x4<>6/x4<>7:E;
!!BMx5:T?x8 N?x9;
!!BMx3:T?x10 N?x11;
!!FU|x9<1/x11<1/x8<0/x10<0:E;
!!FU2600&x6=0/x7>-1/x3>20:P-98/x2/x3/x8/x10;
!!FU2600&x6=1/x7>-1/x3<21:P-98/x2/x3/x8/x10;

!?FU2600&x1=-98;
!!BMx3:G16/?x6/?x7;
!!FU&x6<1:E;
!!UN:N3/-2/x4/1;
!!UN:N3/-3/x5/1;
!!VRx8:S0;
!!VRx8&x7<=0:Sx2*1:5;   20%
!!VRx8&x7=1:Sx2*1:3;     30%
!!VRx8&x7=2:Sx2*2:5;     40%
!!VRx8&x7>=3:Sx2*1:2;   50%
!!VRx9:Sx2+x8;
!!VRz-9:S^Deathblo.wav^;
!!SN:Pz-9;
!!BMx3:V73;
!!MF:Fx9;
!!VRz-10:S^{冰冻状态下脆弱的%Z-3受%Z-2伤害增加%X8。} ^;
!!BU:Mz-10 R;

***收工***

dadds

多谢帮助 呵呵，先对着ERM帮助自己理解体会一下先

dadds

原帖由 沧海一粟 于 2012-3-25 23:21 发表
由于酒精使然，头有点晕，没认真测试不知道有没有错误，如果看不懂，明天我再加注释。
**ERM实现功能：英雄在施放霹雳寒冰魔法后可按自身水系技能等级机率（无=20%，1级=30%，2级=40%，3级=50%）使目标冻结，被冻结 ...

很多地方看不明白，求沧海大大注释，看懂的地方也不知道对不

ZVSE
!?BG&1000;   在动作发生前触发
!!VRv1360:C-1/-1/-1/-1/-1/-1/-1/-1; 这个应该是个简化写法吧？直接定义v1360~v1367变量
!!BG:A?v1360 D?v1361 E?v1362; 检查英雄各动作参数：动作种类 目的位置 目标怪物的堆栈
!!BG:H?v1363 N?v1364 Q?v1365 S?v1366; 英雄所属玩家的编号 堆栈编号 当前攻击方 施放魔法的编号
!!BHv1365:N?v1367;  当前攻击方的英雄编号
!?BG1&1000;  在动作发生后触发
!!FU2600&v1360=1:P-100/v1362/v1366/v1367; 涉及到函数了，看不大懂
!?FU2600&x1=-100;
!!FU|x2<0/x2>41/x3<>16/x4<0:E; 这里应该是魔法编号不是16（霹雳寒冰）时退出吧（还有2个条件看不出来）
!!BMx2:T?x5 N?x6 F?i G16/?x7/d;   怪物的类型x6  怪物标志i  冻结特效x7
!!VRi:&67108864;  这个应该是给目标生物添加已行动的生物标志模拟冻结效果吧(本来我没想要实现这个效果的）
!!FU|x5<0/x6<1/x7>0:E;   目标数量等于0时退出? 身上已有冻结效果退出?
!!HEx4:B0/?z-1 S16/?x10;到这里看不懂下面的就一头雾水了，只是大概明白是设定与水系技能挂钩的
!!VRx8:S0;
!!VRx9:S1 R99;
!!VRx8&x10<=0:S20;
!!VRx8&x10=1:S30;
!!VRx8&x10=2:S40;
!!VRx8&x10>=3:S50;
!!FU&x9>x8:E;
!!UN:N3/-3/x5/1;
!!UN:N1/-4/16/1;
!!VRz-9:S^Weakness.wav^;
!!SN:Pz-9;
!!BMx2:V56 M16/1/x10;   这里就是这个脚本的妙处（前面到那都看不懂了这个妙处也不用说了）
!!BMx2&i=0:Fd67108864;
!!VRz-10:S^{%Z-3受到%Z-1的%Z-4魔法打击后竟然被冻结了。} ^;
!!BU:Mz-10 R;
!?MF1&1000;
!!FU2600:P-99;
!?FU2600&x1=-99;
!!MF:F?x2 N?x3;
!!FU|x3<0/x3>41:E;
!!BG:A?x4 N?x5 Q?x6;
!!BHx6:N?x7;
!!FU&x4<>6/x4<>7:E;
!!BMx5:T?x8 N?x9;
!!BMx3:T?x10 N?x11;
!!FU|x9<1/x11<1/x8<0/x10<0:E;
!!FU2600&x6=0/x7>-1/x3>20:P-98/x2/x3/x8/x10;
!!FU2600&x6=1/x7>-1/x3<21:P-98/x2/x3/x8/x10;
!?FU2600&x1=-98;
!!BMx3:G16/?x6/?x7;
!!FU&x6<1:E;
!!UN:N3/-2/x4/1;
!!UN:N3/-3/x5/1;
!!VRx8:S0;
!!VRx8&x7<=0:Sx2*1:5;   20%
!!VRx8&x7=1:Sx2*1:3;     30%
!!VRx8&x7=2:Sx2*2:5;     40%
!!VRx8&x7>=3:Sx2*1:2;   50%
!!VRx9:Sx2+x8;
!!VRz-9:S^Deathblo.wav^;
!!SN:Pz-9;
!!BMx3:V73;
!!MF:Fx9;
!!VRz-10:S^{冰冻状态下脆弱的%Z-3受%Z-2伤害增加%X8。} ^;
!!BU:Mz-10 R;

[ 本帖最后由 dadds 于 2012-3-26 23:03 编辑 ]

hellmatrix

贴在太技术，还是顶一个

dadds

经过差不多一个星期对ERM的学习，终于在沧海一栗和骷髅召唤师的指点下做了个自己设想的魔法效果脚本（连珠火球命中敌人之后会产生一个受身效果，每回合产生一定伤害，英雄力量与高火系技能越高伤害越高），但是现在还有1个小小的问题，对敌人造成的伤害怎么会变为2次呢？1次伤害正常，一次没有伤害，原因是什么啊？？？

!?BA0&1000;
!!BA:H0/?v9555 H1/?v9560;
!!HEv9555:Fd/d/?v55/d;
!!HEv9560&v9560>-1:Fd/d/?v56/d;
!?BG&1000;
!!VRv1360:C-1/-1/-1/-1/-1/-1/-1/-1;
!!BG:A?v1360 D?v1361 E?v1362;
!!BG:H?v1363 N?v1364 Q?v1365 S?v1366;
!!BHv1365:N?v1367;
!?BG1&1000;
!!FU2600&v1360=1/v1366=21/v9555>-1/v1365=0:P-100/v1362/v1366/v9555;
!!FU2600&v1360=1/v1366=21/v9560>-1/v1365=1:P-100/v1362/v1366/v9560;
!?FU2600&x1=-100;
!!FU|x2<0/x2>41/x4<0:E;
!!BMx2:T?x11 N?x6 G21/?x7/d;
!!FU|x11<0/x6<1/x7>0:E;
!!HEx4:B0/?z-1 S14/?x10;
!!VRx8:S0;
!!VRx9:S1 R99;
!!VRx8&x10<=0:S50;
!!VRx8&x10=1:S60;
!!VRx8&x10=2:S70;
!!VRx8&x10>=3:S99;
!!FU&x9>x8:E;
!!UN:N3/-3/x11/1;
!!UN:N1/-4/21/1;
!!VRz-9:S^Weakness.wav^;
!!SN:Pz-9;
!!BMx2:V56 M21/2/x10;
!!VRz-10:S^{%Z-3受到%Z-1的%Z-4魔法打击后燃烧起来了。} ^;
!!BU:Mz-10 R;
!?BG&1000;
!!BG:A?y1 E?y2;
!!BGy2:N?y4;
!!FU2600|y1=2/y1=3/y1=6/y1=7/y1=8:P-99/y4/v55/v9555;
!!FU2600|y1=2/y1=3/y1=6/y1=7/y1=8:P-99/y4/v56/v9560;
!?FU2600&x1=-99;
!!FU&x4<1:E;
!!BMx2:G21/?x6/?x10/N?x4/T?x12;
!!FU|x2<0/x2>41/x4<1:E;
!!FU&x6<1:E;
!!VRx5:S0;
!!VRx5&x10=0:S10;
!!VRx5&x10=1:S15;
!!VRx5&x10=2:S20;
!!VRx5&x10=3:S25;
!!VRx11:Sx3*x5;
!!BMx2:V53 Kx11;
!!UN:N3/-3/x12/1;
!!VRz-10:S^{%Z-3身上燃烧起来受到%X11的伤害。} ^;
!!BU:Mz-10 R;

[ 本帖最后由 dadds 于 2012-4-1 17:01 编辑 ]

ashero4

好像BG的触发器有点问题

沧海一粟

!?BG&1000;
!!BG:A?y1 E?y2;
!!BG:N?y3;
!!BMy3:G21/?x6/?x10/N?y4;  N?y4这是什么东西？x6的值及x10你在下面的函数没有应用根本没有意义了
!!FU2600|y1=2/y1=3/y1=6/y1=7/y1=8:P-99/y3/v55/y4;   
你的函数应该参考上段的写法，没有加入v9555v9560的判断及动作方的判断v55v56能正确吗？
!!FU2600|y1=2/y1=3/y1=6/y1=7/y1=8:P-99/y3/v56/y4;
!?FU2600&x1=-99;
!!FU|x2<0/x2>41/x4<1:E;   上面y4不知所云，这里的x4就没有意义了
!!FU&x6<1:E;  这个x6你函数里面没有加入根本没有意义
!!VRx5:S0;
!!VRx5&x10=0:S10;  同理，x10值也一样没意义吧
!!VRx5&x10=1:S15;
!!VRx5&x10=2:S20;
!!VRx5&x10=3:S25;
!!VRx10:Sx3*x5;      怎么多了一个x10？
!!BMx2:V53 Kx10;
!!VRz-10:S^{%Z-3身上燃烧起来受到%X10的伤害。} ^;
!!BU:Mz-10 R;

[ 本帖最后由 沧海一粟 于 2012-3-31 22:16 编辑 ]

dadds

额`很多地方的确错了，因为之前一直在测试中出错，改了好多忘记改回来了

沧海一粟

建议多理解FU函数的用法，函数内x1代表什么x2代表什么x3代表什么....x16代表什么一定要有个数。
其实你想表达的东西已经很清楚了，就是用法没掌握好，没定义动作方及函数用的不好，所以你下段脚本应该是没有效果才是，即使有效果应该伤害肯定不是你想要的值。还有一个，你这样写上段就没必要用两个函数定义动作方了，因为你根本不需要检查英雄的力量。

[ 本帖最后由 沧海一粟 于 2012-3-31 22:18 编辑 ]

dadds

现在只有3个问题
1. 就是上面说的会造成2次伤害（1次伤害正确，1次没伤害）
2. %Z-3的显示不正确，受到英雄魔法伤害时显示正确了，但是燃烧伤害时就不正确了
3. 部队死亡之后效果的停止问题
特效发动几率是不是可以这个理解：本来攻击一个部队是100%的几率，攻击2个部队就变成50%了？

[ 本帖最后由 dadds 于 2012-3-31 22:45 编辑 ]

沧海一粟

呵呵，你根本就没有定义%Z-3，怎么显示出来啊;
造成2次伤害我也说不清，因为本身的错误多的缘故，但我想跟你没有直接定义动作方应该多少有关系;
部队死亡后不生效，你用BM:N命令检查后判断不就行，也许你有加，但那个x4如我说的一样应该根本没有意义。

dadds

改了一下，%Z-3显示已正确。
经过测试发现2次伤害的确是因为没有定义动作方造成的（2次伤害一次为正常伤害，一次为对方英雄伤害，敌方无英雄的伤害为0）但是因为这个燃烧状态时每回合检测的，不知道该如何定义正确的动作方，还有发现动作前被燃烧状态杀死的生物会出现动画错误，该如何解决？？？


[ 本帖最后由 dadds 于 2012-4-1 17:16 编辑 ]

沧海一粟

呵呵，跟蛇妖剑舞攻击有复活技能的树妖一样，因为伤害前附加了不必要的伤害而出现了传说中的“站尸”，我个人现在想不到好的解决方法，但你这个脚本只要限制一下伤害不超过怪物的总生命*数量应该就可以了。换句话说，最多把怪物消灭到1个还1点生命去解决。
有空我也发个求助帖，请各路高人帮忙会诊如何解决“站尸”现象。

dadds

能不能帮看看还要加什么命令才能在技能效果触发时判定动作方，实在无力了，想的头都大了
还有2个问题
1.  虽然不能读取生物的士气与幸运值，但能不能判断生物此次攻击有没有触发幸运一击？
2.  如何改变原有施法生物施放的魔法，直接用!!BM..:U4/$;是否会覆盖原有魔法，还是叠加的？

[ 本帖最后由 dadds 于 2012-4-1 17:59 编辑 ]

沧海一粟

1、判断触发方其实第一段我已经给你举过例子了，非常容易的，你主要问题还是对函数应用不好，如果需要晚上有空我可以帮你写;
2、我觉得很难判断是否会出现幸运一击，没有相关命令，暂时我个人想不到好的办法;
3、BM:U4是直接更替原魔法的，不是叠加，对魔幻法师及神怪主无效。

dadds

!!FU2600|y1=2/y1=3/y1=6/y1=7/y1=8:P-99/y4/v55/v9555;
!!FU2600|y1=2/y1=3/y1=6/y1=7/y1=8:P-99/y4/v56/v9560;
我只清楚是在红字后面加上判定命令，但是这里和上段脚本的判定方式应该不一样的吧
上段脚本是：攻击方英雄存在且攻击方为左边时执行函数2600
                     防御方英雄存在且攻击方为右边时执行函数2600
!!FU2600&v1360=1/v1366=21/v9555>-1/v1365=0:P-100/v1362/v1366/v9555;
!!FU2600&v1360=1/v1366=21/v9560>-1/v1365=1:P-100/v1362/v1366/v9560;
但是现在要获得的是在上段脚本中对生物施放魔法并让生物产生受身魔法的英雄.....脑子乱了 不知该怎么定义

沧海一粟

ZVSE

!?BA0&1000;
!!BA:H0/?v9555 H1/?v9560;
!!HEv9555:Fd/d/?v55/d;
!!HEv9560&v9560>-1:Fd/d/?v56/d;

!?BG0&1000;
!!VRv1360:C-1/-1/-1/-1/-1/-1/-1/-1;
!!BG:A?v1360 D?v1361 E?v1362;
!!BG:H?v1363 N?v1364 Q?v1365 S?v1366;
!!BHv1365:N?v1367;

!!FU2600&v1364<21/v1365=0:P-99/v1360/v1364/v1365/v9560/v56;
!!FU2600&v1364>20/v1365=1:P-99/v1360/v1364/v1365/v9555/v55;

!?FU2600&x1=-99;
!!FU&x2<>2/x2<>3/x2<>6/x2<>7/x2<>8:E;
!!BMx3:T?x7 N?x8 H?x9 G21/?x10/?x11;
!!FU|x7<0/x8<1/x10<1:E;
!!UN:N3/-3/x7/1;
!!VRx12:S0;
!!VRx12&x11<=0:S10;
!!VRx12&x11=1:S15;
!!VRx12&x11=2:S20;
!!VRx12&x11>=3:S25;
!!VRx13:S0;
!!VRx13&x5>-1:Sx6;
!!VRx14:Sx12*x13;
!!VRx15:Sx8-1*x9;
!!VRx14&x14>x15:Sx15;
!!VRz-9:S^Fireball.wav^;
!!SN:Pz-9;
!!BMx3:V24 Kx14;
!!VRz-10:S^{%Z-3身上燃烧后额外受到%X14点火焰伤害。} ^;
!!BU:Mz-10 R;

!?BG1&1000;
!!FU2600&v1360=1/v1366=21:P-100/v1362/v1366/v1367;

!?FU2600&x1=-100;
!!FU|x2<0/x2>41/x3<>21/x4<0:E;
!!BMx2:T?x5 N?x6 Gx3/?x7/d;
!!FU|x5<0/x6<1/x7>0:E;
!!HEx4:B0/?z-1 S14/?x10;
!!VRx8:S0;
!!VRx9:S1 R99;
!!VRx8&x10<=0:S20;
!!VRx8&x10=1:S30;
!!VRx8&x10=2:S40;
!!VRx8&x10>=3:S50;
!!FU&x9>x8:E;
!!UN:N3/-3/x5/1;
!!UN:N1/-4/x3/1;
!!VRz-9:S^Acid.wav^;
!!SN:Pz-9;
!!BMx2:V81 Mx3/2/x10;
!!VRz-10:S^{%Z-3受到%Z-1的%Z-4魔法打击后燃烧起来了。} ^;
!!BU:Mz-10 R;

dadds

反着来写？会有什么不同么？
测试和很完美，英雄对战也没发现问题，学习下先

dadds

呵呵~发现一个小问题，生物施法不触发特殊效果，我自己添加了