魔力加油站

fly123 · 发表于 2011-12-15 10:30:02

最近写了个小脚本，功能是英雄可以用魔法值交换移动力，最高换5000点，所有英雄每天都有一次机会。
ZVSE
!#TM59:S1/360/1/255;    设定59号计时器
第一天开始/持续360天/每天执行/对所有颜色都有效
!?TM59&1000             59号计时器只对玩家起作用
!!DO1051/0/155/1:P; 每天循环历遍所有英雄
!?FU1051;                      启用FU变量1051
!!IF:Wx16;                   启用英雄变量
!!VRw90:S0;       设定变量w90每天重置为0
!?CM2&1000;       调用英雄界面触发器只对玩家起作用
!!CM:I?y1 S?y2 T?y3; 检查鼠标动作
!!FU|y1<>53/y2<>14/y3<>512:E; 不是右键点击英雄界面的知识(图标)则退出
!!HE-1:N?y5;       检查当前英雄编号，把ID保存到Y5存储
!!FU&y5<0/y5>155:E; 不是英雄ID0-155以内的则退出
!!FU5256:Py5;       对话框显示
!!CM:R0;             禁用标准反应。
!?FU5256:
!!HEx1:I?x2/1 W?x3/1;          X1对应英雄为Y5的值，检查英雄魔法值和移动力。保存在X2和X3中
!!FU&x2<1:E;                                     魔法值为0则退出
!!IF:Wx1;                                           启用当前英雄变量
!!IF&w90<>0:M^今天你已经转换过了，明天再来吧。^;          w90的值不为0则显示信息
!!FU&w90<>0:E;w90的值不为0则退出
!!HEx1:B0/?z-4; [得到英雄名字]
!!IF:Q1/8/138/1^欢迎来到 {魔力加油站}！！！    信息显示
{%Z-4}当前魔法值%X2，当前移动力%X3。^;
!!VRz-1:S^输入你想转换的魔法值{输入上限500}^;       启用D型对话框
!!VRz-2:S^移动力转换教室
增加移动力={转换魔法值*10}^;
!!VRz-3:S^..\data\p\s044_emerald.gif^;
!!IF:D1/z-2/z-1/0/z-3 ;
!!IF:F1/////1;
!!IF:E1/1;                变量交换
!!FU&v1=-1:E;       输入对话框选择否则退出
!!VRx4:Vz1;          X4保存当前输入对话框的数字
!!IF&x4<1:M^输入错误，请重新输入。^;          输入对话框的数字小于0则显示提示信息
!!FU&x4<1:E;输入对话框的数字小于0则退出
!!IF&x4>500:M^超出输入上限，请重新输入。^;输入对话框的数字超过500则显示提示信息
!!FU&x4>500:E;                                                    输入对话框的数字超过500则退出
!!IF&x4>x2:M^输入错误，请重新输入。^;输入对话框的数字超过当前英雄剩下的魔法值则显示提示信息
!!FU&x4>x2:E;                                        输入对话框的数字超过当前英雄剩下的魔法值则显示退出
!!VRx2:-x4;                                  X2的值等于当前英雄魔法值减去输入的数字X4
!!VRx3:Sx4*10;                X3的值等于输入的数字X4乘以10
!!HEx1:Ix2/1;                   设置英雄剩下的魔法值为X2
!!HEx1:Wdx3/1;                设置英雄剩下的移动力增加X3
!!VRw90:+1;                      变量W90的值加1
!!UN:R3/-1;                      在触发器CM2中重画当前英雄屏幕