新图<WOG群英传>脚本合集<不断更新中>请关注!

寻梦人

2345

140%

????????????

可以这样吗?

兽哥哥

你现在的几率不是1234吗？我想改成2345

兽哥哥

哦，我明白你的意思了。不好意思。真丢人

寻梦人

ZVSE

*********************************************

函 数 FU111 x1=18---19   
*********************************************

!?MF1|v9555=0/v9560=0;
!!BG:A?y-1 N?y-2 Q?y-3;
!!MF:N?y-4 F?y-10;
!!BMy-2:T?y-6;
!!BMy-4:T?y-7 P?y-8 N?y-9;
!!FU111&y-6=156/y-1=6/y-3=0/v9555=0:P19/y-10/y-6/y-7/y-2;
!!FU111&y-6=156/y-1=6/y-3=1/v9560=0:P19/y-10/y-6/y-7/y-2;
!!FU&y-7<>134/y-7<>193:E;
!!IF:V407/0;
!!DO111/1/6/1&v9555=0:P18/y-8/0;
!!DO111/1/6/1&v9560=0:P18/y-8/1;
!!FU&-407:E;
!!BMy-4:V84;
!!MF:E0;
!!UN&y-7>-1:N3/-3/y-7/1;
!!VRz10&y-7>-1:S^{兽哥哥之庇护} 使 {%Z-3} 免受伤害^;
!!MM&y-7>-1:Sz10;


*********************************
!?FU111&x1=18;
!!VRy-80:Sx2 :17 +1;                  
!!VRy-81:S0;                          
!!VRy-82:S0;
!!VRy-81|y-80=1/y-80=3/y-80=5/y-80=7/y-80=9/y-80=11:S1;
!!VRy-82|y-80=2/y-80=4/y-80=6/y-80=8/y-80=10:S1;

!!VRy20&x16=1:Sx2 +1;                  
!!VRy20&x16=2:Sx2 +16 +y-81;
!!VRy20&x16=3:Sx2 +17 +y-81;
!!VRy20&x16=4:Sx2 -1;
!!VRy20&x16=5:Sx2 -16 -y-82;
!!VRy20&x16=6:Sx2 -17 -y-82;
!!FU|y20<0/y20>186:E;
!!BU:Ey20/?y88;
!!BMy88&y88>-1:T?y-60 I?y60;
!!FU&y60<>x3:E;
!!IF&y-60=156:V407/1;

!?FU111&x1=19;
!!UN:N3/-1/x3/1;
!!UN:N3/-2/x4/1;
!!VRy1:S0 R99;
!!VRy2&y1<10:S10;
!!VRy2&y1>9/y1<30:S8;
!!VRy2&y1>29/y1<60:S4;
!!VRx2&y1<60:*y2;
!!VRz10&y1<10:S^{%Z-1 之 幽冥鬼爪} 造成 {%Z-2 10倍伤害：%X2}。 ^;
!!VRz10&y1>9/y1<30:S^{%Z-1 之 幽冥鬼爪} 造成 {%Z-2 8倍伤害：%X2}。^;
!!VRz10&y1>29/y1<60:S^{%Z-1 之 幽冥鬼爪} 造成 {%Z-2 4倍伤害：%X2}。^;
!!BMx5&y1<60:V0 V28;
!!MM&y1<60:Sz10;

兽哥哥

谢谢寻梦

寻梦人

ZVSE

***************************
风侠之侠义双全
FU111  x1=20---21
v变量  v4456

!#MA:S161/15;
***************************
!?BG;

!!DO111/0/20/1&v5016=161/v9560=0:P20;选择堆栈
!!DO111/21/41/1&v5016=161/v9555=0:P20;选择堆栈
!!VRv4456:-1;
!!VRy-51:S1 Rv4456;
!!DO111/vy-51/vy-51/1&v4456>-1:P21/v5003;风侠之侠义双全

!?FU111&x1=20;堆栈选择
!!BMx16:N?y1 F?y2;
!!FU&y1<1:E;
!!VRy2:&67108864;
!!FU&y2>0:E;
!!VRv4456:+1;
!!VRvv4456:Sx16;

!?FU111&x1=21;
!!BMx16:F?y1 T?y2;
!!VRy-1&y1>0:Sy1 |67108864;
!!BMx16:Fy-1;
!!BMx2:V18;
!!BMx16:V30;
!!BMx2:T?y3;
!!UN:N3/-1/y2/1;
!!UN:N3/-2/y3/1;
!!VRz10:S^{%Z-2 之侠义双全} 使 {%Z-1 拒绝参加战斗}。^;
!!BU:Mz10;

寻梦人

ZVSE

***************************
离弦箭之嗜血成狂
FU111  x1=22---23
v变量  v4455
***************************
!?BG;
!!VRv4455:C0/0;
!!DO111/0/20/1&v5016=160/v5006<>0/v9560=0:P22;选择堆栈
!!DO111/21/41/1&v5016=160/v5006<>0/v9555=0:P22;选择堆栈
!!VRv4455:-1;
!!VRy-52:S1 Rv4455;
!!DO111/vy-52/vy-52/1&v4455>-1:P23/v5003;离弦箭之嗜血成狂

!?FU111&x1=22;堆栈选择已经动作统计
!!BMx16:N?y1 F?y2;
!!FU&y1<1:E;
!!VRy2:& 67108864 ;
!!FU&y2=0:E;
!!VRv4455:+1;
!!VRvv4455:Sx16;

!?FU111&x1=23;
!!BMx16:F?y1 T?y2;
!!VRy1&y1>0:-67108864;
!!BMx16:Fy1;
!!BMx2:V18;
!!BMx16:V20;
!!BMx2:T?y3;
!!UN:N3/-1/y2/1;
!!UN:N3/-2/y3/1;
!!VRz10:S^{%Z-2 之嗜血成狂} 使 {%Z-1 有了再次进攻的机会}。^;
!!BU:Mz10;

兽哥哥

老离是什么来着？忘了，好像不是报名的生物

无心云

兽，老离，战神

这些都是野怪吗？
看着ERM好像不是英雄啊

格鲁

必杀：火炎之怒：我方全体加嗜血，祝福，2倍伤害，并给对方加丧心病狂。看看还有什么要改的

无心云

为什么你们都可以有必杀呢
我也要有必杀，大招我也要有

神鬼莫测，以狮鹫王为中心，向外扩散，技术圈上的敌方队伍50%几率消失

寻梦人

老离搞什么学习术,没有什么意思!

所以给他一个战争之神的位置!

提高一下知名度!

兽哥哥

无心云那个太离谱了，把我们主角都消失了你们还玩什么啊？你们的思考方向都错了，现在不是说要大家都设计一个生物出来单挑，知道吗？你们再怎么厉害，最后都会被我们搞死，别得瑟！还是平常心接受现实吧！哇哈哈哈哈哈哈哈！

寻梦人

你这不是要我们变成镜像吗?

不过可以让你使用一次!

只有一次机会让我们其中之一变成镜像!

就让你有这个绝招!

寻梦人

ZVSE

*********************************************

函 数 FU111 x1=24--25   灭顶之灾函数
*********************************************

!?BG;

!!DO111/0/20/1&v5016=5/v9560=32/v5006=32/v5000=6/v4457=0:P24/v5016;
!!DO111/21/41/1&v5016=5/v9555=32/v5006=32/v5000=6/v4457=0:P24/v5016;


!?FU111&x1=24;
!!BMx16:N?y1 F?y2 F?y3 F?y4 T?y5;
!!FU&y1<1:E;
!!VRy2:&4194304;
!!FU&y2>0:E;
!!VRy3:&8388608;
!!FU&y3>0:E;
!!VRy4:|8388608;
!!VRy-56:S0 R99;
!!FU&y-56<>50:E;
!!BMx16:Fy4;
!!UN:N3/-1/x2/1;
!!UN:N3/-2/y5/1;
!!VRz10:S^{%Z-1 之灭顶之灾} 使 {%Z-2 只剩下一具躯壳}。^;
!!BU:Mz10;
!!VRv4457:+1;

[ 本帖最后由 寻梦人 于 2011-11-10 13:10 编辑 ]

寻梦人

无心云每场战斗可以有一次机会让对方一支部队变成镜像!

几率很小,不知道谁会这么倒霉!

兽哥哥

应该不可能是我，因为------嘿嘿，战后恢复是吧？一碰就消失了

寻梦人

ZVSE

*********************************************

函 数 FU111 x1=25--27   火炎之怒函数
*********************************************

!?BG;
!!VRv4458:C0;

!!FU111&v5016=171/v5006=0/v5000=7:P25/v5016/v5003;火炎之怒函数
!!DO111/0/20/1&v5016=171/v9560=0/v5000=7/v5006=0:P26;选择堆栈
!!DO111/21/41/1&v5016=171/v9555=0/v5000=7/v5006=0:P26;选择堆栈

!!VRv4458:-1;
!!VRy-53:S1 Rv4458;
!!DO111/vy-53/vy-53/1&v4458>-1:P27/v5003;格鲁之火炎之怒函数


!?FU111&x1=25;火炎之怒函数
!!HEv5006:I?y1/1;
!!VRy30&v9555=0:S0;
!!VRy30&v9560=0:S1;
!!BMx3:V0;
!!BHy30:C41/-1/3/0;
!!BHy30:C43/-1/3/0;
!!HEv5006:Iy1/1;
!!UN:N3/-1/x2/1;
!!VRz10:S^{%Z-1 之火炎之怒}  {施放魔法：全体祝福、嗜血 }。^;
!!BU:Mz10;





!?FU111&x1=26;堆栈选择
!!BMx16:N?y1 F?y2;
!!FU&y1<1:E;
!!VRy2:&67108864;
!!FU&y2>0:E;
!!VRv4458:+1;
!!VRvv4458:Sx16;

!?FU111&x1=27;
!!VRy-1:S0 R99;
!!FU&y-1>100:E;

!!BMx16:V35 M59/1/2;
!!BMx2:T?y3;
!!BMx16:T?y2;
!!UN:N3/-1/y2/1;
!!UN:N3/-2/y3/1;
!!VRz10:S^{%Z-2 之火炎之怒} 使 {%Z-1 中了魔法：丧心病狂}。^;
!!BU:Mz10;

寻梦人

ZVSE

!?PI;
!!DO111/0/8/1:P29;
!!DO111/0/196/1:P28;

!?FU111&x1=28;
!!MA:Gx16/0;
!!MA:Cx16/1/?y1;
!!MA&y1>0:Cx16/1/20000;
!!MA:Cx16/3/?y2;
!!MA&y2>0:Cx16/3/20000;
!!MA:Cx16/4/?y3;
!!MA&y3>0:Cx16/4/20000;
!!MA:Cx16/5/?y4;
!!MA&y4>0:Cx16/5/20000;
!!MA&y1=0/y2=0/y3=0/y4=0:Cx16/5/20000;

!?FU111&x1=29;
!!VRy1&x16=0:S171;
!!VRy2&x16=0:S193;
!!VRy3&x16=0:S53;
!!VRy4&x16=0:S134;
!!VRy5&x16=0:S150;
!!VRy6&x16=0:S156;
!!VRy7&x16=0:S41;

!!VRy1&x16=1:S170;
!!VRy2&x16=1:S5;
!!VRy3&x16=1:S136;
!!VRy4&x16=1:S169;
!!VRy5&x16=1:S175;
!!VRy6&x16=1:S27;
!!VRy7&x16=1:S151;

!!VRy1&x16=2:S160;
!!VRy2&x16=2:S161;
!!VRy3&x16=2:S162;
!!VRy4&x16=2:S163;
!!VRy5&x16=2:S176;
!!VRy6&x16=2:S117;
!!VRy7&x16=2:S152;

!!VRy1&x16=3:S45;
!!VRy2&x16=3:S51;
!!VRy3&x16=3:S55;
!!VRy4&x16=3:S195;
!!VRy5&x16=3:S172;
!!VRy6&x16=3:S177;
!!VRy7&x16=3:S153;

!!VRy1&x16=4:S63;
!!VRy2&x16=4:S65;
!!VRy3&x16=4:S67;
!!VRy4&x16=4:S178;
!!VRy5&x16=4:S159;
!!VRy6&x16=4:S154;
!!VRy7&x16=4:S196;

!!VRy1&x16=5:S77;
!!VRy2&x16=5:S79;
!!VRy3&x16=5:S82;
!!VRy4&x16=5:S179;
!!VRy5&x16=5:S83;
!!VRy6&x16=5:S155;
!!VRy7&x16=5:S133;

!!VRy1&x16=6:S87;
!!VRy2&x16=6:S194;
!!VRy3&x16=6:S93;
!!VRy4&x16=6:S180;
!!VRy5&x16=6:S95;
!!VRy6&x16=6:S97;
!!VRy7&x16=6:S132;

!!VRy1&x16=7:S103;
!!VRy2&x16=7:S168;
!!VRy3&x16=7:S109;
!!VRy4&x16=7:S181;
!!VRy5&x16=7:S111;
!!VRy6&x16=7:S157;
!!VRy7&x16=7:S135;

!!VRy1&x16=8:S127;
!!VRy2&x16=8:S164;
!!VRy3&x16=8:S167;
!!VRy4&x16=8:S182;
!!VRy5&x16=8:S165;
!!VRy6&x16=8:S131;
!!VRy7&x16=8:S158;


!!UN:Tx16/0/1/y1;
!!UN:Tx16/1/1/y2;
!!UN:Tx16/2/1/y3;
!!UN:Tx16/3/1/y4;
!!UN:Tx16/4/1/y5;
!!UN:Tx16/5/1/y6;
!!UN:Tx16/6/1/y7;

!!UN:Tx16/0/0/y1;
!!UN:Tx16/1/0/y2;
!!UN:Tx16/2/0/y3;
!!UN:Tx16/3/0/y4;
!!UN:Tx16/4/0/y5;
!!UN:Tx16/5/0/y6;
!!UN:Tx16/6/0/y7;

格鲁

说实话，真看不懂生物规则是什么？