超级美杜莎erm (见25L)

cxc00000 · 发表于 2011-10-31 07:56:51

使用地下城的英雄：耿纳（后勤学的那个），获得美杜莎强化的技能

美杜莎强化：带领美杜莎女王时，获得以下技能

1.与英雄对战时在行动时偷取魔法（同幽灵）
2.射击时也有几率造成敌方石化
3.被近身攻击时出现火盾反击（同火精灵）
4.近身攻击吸血（同吸血鬼王）
5.被攻击无限反击（同狮鹫）
6.被魔法攻击减少伤害（同钻石人）
7.被杀死后复活一次（同凤凰）
8.提高美杜莎的生命80点

不知道复不复杂..本人小白，有没有哪位大大有时间帮我写下，比较感兴趣的技能都在里面，以后就可以自己研究了

[ 本帖最后由沧海壹粟于 2011-11-9 17:07 编辑 ]

兽哥哥 · 发表于 2011-10-31 08:31:28

除了射击有机率石化之外其他都相当简单

cxc00000 · 发表于 2011-10-31 08:39:58

求教

沧海一粟 · 发表于 2011-10-31 08:55:48

其实射击后石化这个更简单，起码比吸血那些简单多了。不过这个生物变态太过全面，没有鲜明特点，我不喜欢。

兽哥哥 · 发表于 2011-10-31 09:42:26

那就帮楼主写一个吧，其实我看了也觉得没特点，都是一些普通的技能。吸血不是可以参考吸吸或者吸魂脚本吗？射击后石化《麻痹》二追脚本都没有实现，我还以为很难呢。

沧海一粟 · 发表于 2011-10-31 10:40:56

原帖由 兽哥哥 于 2011-10-31 09:42 发表
那就帮楼主写一个吧，其实我看了也觉得没特点，都是一些普通的技能。吸血不是可以参考吸吸或者吸魂脚本吗？射击后石化《麻痹》二追脚本都没有实现，我还以为很难呢。

吸血是可以解决的，不管是直接实现还是间接实现，但各有各的优劣，都不会很完美，至于射击石化，10分钟后发上。

沧海一粟 · 发表于 2011-10-31 10:55:45

ZVSE
!?BG0;
!!VRv1800:C-1/-1/-1;
!!BG:A?v1800 E?v1801 N?v1802;
!?BG1;
!!FU18000&v1800=7:P180/v1800/v1801/v1802;
!?FU18000&x1=180;
!!FU&x2<>7:E;
!!BMx3:T?x5 N?x6;
!!BMx4:T?x7;
!!FU|x3=-1/x5<0/x6<1/x7<>136:E;
!!UN:N3/-3/x5/1;
!!UN:N3/-2/x7/1;
!!VRx8:S0 R99;
!!FU&x8>30:E;
!!BMx3:K0 M70/3/1;
!!VRz-4:S^{%Z-2射击后使%Z-3被石化了。}^;
!!MM:Sz-4;
!!BU:R;

兽哥哥 · 发表于 2011-10-31 12:51:45

兽哥哥 · 发表于 2011-10-31 12:54:02

看来射击后麻痹，失明都可以搞定的了

手上魔术师 · 发表于 2011-10-31 13:08:52

远程带这些技能玩着也太没意思了！

骷髅召唤师 · 发表于 2011-10-31 19:23:08

你试试吧。射击时也有几率造成敌方石化根据沧海版主的。
不知道有没有BUG，如果有请提出。

ZVSE
*模拟幽灵偷取魔法时有BUG，最终敌方英雄魔法值会出现负值。
*如果设置敌方英雄魔法值为0时终止，会出现花屏，故取消设定敌方英雄魔法值为0时终止

*变量使用：v2800~v2807 v84 v9555 v9560
*函数使用：FU2800
*地下城的英雄耿纳获得美杜莎强化的技能
*美杜莎强化：带领美杜莎女王时，获得以下技能
*1.与英雄对战时在行动时偷取魔法（同幽灵）
*2.射击时也有几率造成敌方石化
*3.被近身攻击时出现火盾反击（同火精灵）
*4.近身攻击吸血（同吸血鬼王）
*5.被攻击无限反击（同狮鹫）
*6.被魔法攻击减少伤害（同钻石人）
*7.被杀死后复活一次（同凤凰）
*8.提高美杜莎的生命80点

!?PI;
!!VRv84:S85;
!!VRz990:S^在后勤学上每级得到5%的额外奖励。
战场上带领美杜莎女王拥有额外的特技奖励。^;
!!UN:G2/85/2/990;  设置特长说明

!?BA0;
!!BA:H0/?v9555;    进攻方英雄ID
!!BA:H1/?v9560;    防守方英雄ID

!?BF;
!!DO2800/0/20/1&v9555=v84:P1;
!!DO2800/21/41/1&v9560=v84:P1;

***火盾+魔法抵抗+复活一次+无限反击+生命加80点
!?FU2800&x1=1;
!!FU&x1<>1:E;
!!BMx16:T?y1 H?y2;
!!VRy3&y1=77:Sx16 +1 *-1;
!!EAy3&y1=77:B8/1/115/29/1/1/1/1/2/2/2/3/3/3/3;  火盾
!!EAy3&y1=77:B9/1/103/37/95/95/95/95/95/95/95/95/95/95/95; 魔法抵抗
!!EAy3&y1=77:B10/1/102/114/1/1/1/1/1/1/1/1/1/1/1; 重生
!!EAy3&y1=77:B11/1/80/61/1/1/1/1/1/1/1/1/1/1/1;  施法次数
!!EAy3&y1=77:B12/1/82/43/10/10/10/10/10/10/10/10/10/10/15;  反击次数
!!VRy2:+80;
!!BMx16&y1=77:Hy2;

!?BG0;
!!VRv2800:C-1/-1/-1/-1/-1/-1/-1/-1;
!!BG:A?v2800 N?v2801 E?v2802 Q?v2806;
!!BHv2806:N?v2807;
!!BMv2801&v2801>-1:T?v2803;
!!BMv2802&v2802>-1:T?v2804 R?v2805;

*****主动近身攻击时吸血
!?MF1;
!!FU2800&v2800=6/v2803=77/v2807=v84:P2/v2801/v2803/v2802/v2804;
!?FU2800&x1=2;
!!FU&x1<>2:E;
!!BMx2:N?y1 B?y2 H?y3 L?y4;
!!FU&y1>=y2/y4=0:E;
!!UN:N3/-1/x3/1;
!!BMx4:F?i;
!!VRi:&16;
!!FU&i=0:E;
!!UN:N3/-2/x5/1;
!!MF:F?y5;
!!VRy6:Sy2 -y1;
!!VRy7:Sy5 :y3;
!!VRy7&y7>y6:Sy6;
!!VRy8:Sy4 *-1;
!!BMx2:V79 Ndy7 Ldy8;
!!VRz900&y7=0:S^{%Z-1吸走%Y4点%Z-2的生命值。}^;
!!VRz900&y7>0:S^{%Z-1吸走%Y5点%Z-2的生命值。并且%Y7个复活了。}^;
!!BU:Mz900 R;

****射击后30%造成敌方石化
!?BG1;
!!FU2800&v2800=7/v2803=77/v2807=v84:P3/v2800/v2801/v2802/v2803/v2804;
!?FU2800&x1=3;
!!FU&x1<>3:E;
!!FU&x2<>7:E;
!!BMx4:T?x7 N?x8;
!!FU|x7<0/x8<1:E;
!!UN:N3/-1/x5/1;
!!UN:N3/-2/x6/1;
!!VRx9:S0 R99;
!!FU&x9>30:E;
!!BMx4:M70/3/1;
!!VRz900:S^{%Z-1射击后使%Z-2被石化了。}^;
!!BU:Mz900 R;

***动作后偷取魔法
!?BG1;
!!FU2800&v2800>5/v2800<8/v2803=77/v2806=0/v2807=v84/v9560>-1:P4/v2807/v9560/v2801/v2803;
!!FU2800&v2800>5/v2800<8/v2803=77/v2806=1/v9555>-1/v2807=v84:P4/v2807/v9555/v2801/v2803;
!?FU2800&x1=4;
!!FU&x1<>4:E;
!!UN:N3/-1/x5/1;
!!HEx3:B0/?z-2;
!!BMx4:V77;
!!HEx2:Id2/1;
!!HEx3:Id-2/1;
!!VRz900:S^{%Z-1吸取了%Z-2的2点魔法值。}^;
!!BU:Mz900 R;

[ 本帖最后由骷髅召唤师于 2011-10-31 19:24 编辑 ]

兽哥哥 · 发表于 2011-10-31 19:56:22

召唤师就是新人们的福音大使！！！

cxc00000 · 发表于 2011-10-31 21:43:44

太感谢了！！！下午刚上线就有大大出手了

cxc00000 · 发表于 2011-10-31 22:44:00

好像吸血是主动攻击吸血，如果想改成反击也吸血应该怎样操作？

[ 本帖最后由 cxc00000 于 2011-10-31 22:50 编辑 ]

骷髅召唤师 · 发表于 2011-11-1 08:14:57

不好意思，反击也吸血我不会。

骷髅召唤师 · 发表于 2011-11-2 20:36:16

解决模拟幽灵偷取魔法时的BUG，最终敌方英雄魔法值会出现负值的问题。
增加反击也吸血，但有个问题，反击时出现两次吸血，就是美杜莎女王的火盾也会吸血，我不知道如何解决？
ZVSE

*变量使用：v2800~v2807 v84 v9555 v9560
*函数使用：FU2800
*地下城的英雄耿纳获得美杜莎强化的技能
*美杜莎强化：带领美杜莎女王时，获得以下技能
*1.与英雄对战时在行动时偷取魔法（同幽灵）
*2.射击时也有几率造成敌方石化
*3.被近身攻击时出现火盾反击（同火精灵）
*4.近身攻击吸血（同吸血鬼王）
*5.被攻击无限反击（同狮鹫）
*6.被魔法攻击减少伤害（同钻石人）
*7.被杀死后复活一次（同凤凰）
*8.提高美杜莎的生命80点

!?PI;
!!VRv84:S85;
!!VRz990:S^在后勤学上每级得到5%的额外奖励。
战场上带领美杜莎女王拥有额外的特技奖励。^;
!!UN:G2/85/2/990;  设置特长说明

!?BA0;
!!BA:H0/?v9555;    进攻方英雄ID
!!BA:H1/?v9560;    防守方英雄ID

!?BF;
!!DO2800/0/20/1&v9555=v84:P1;
!!DO2800/21/41/1&v9560=v84:P1;

***火盾+魔法抵抗+复活一次+无限反击+生命加80点
!?FU2800&x1=1;
!!FU&x1<>1:E;
!!BMx16:T?y1 H?y2;
!!VRy3&y1=77:Sx16 +1 *-1;
!!EAy3&y1=77:B8/1/115/29/1/1/1/1/2/2/2/3/3/3/3;  火盾
!!EAy3&y1=77:B9/1/103/37/95/95/95/95/95/95/95/95/95/95/95; 魔法抵抗
!!EAy3&y1=77:B10/1/102/114/1/1/1/1/1/1/1/1/1/1/1; 重生
!!EAy3&y1=77:B11/1/80/61/1/1/1/1/1/1/1/1/1/1/1;  施法次数
!!EAy3&y1=77:B12/1/82/43/10/10/10/10/10/10/10/10/10/10/15;  反击次数
!!VRy2:+80;
!!BMx16&y1=77:Hy2;

!?BG0;
!!VRv2800:C-1/-1/-1/-1/-1/-1/-1/-1;
!!BG:A?v2800 N?v2801 E?v2802 Q?v2806;
!!BHv2806:N?v2807;
!!BMv2801&v2801>-1:T?v2803;
!!BMv2802&v2802>-1:T?v2804 R?v2805;

*****近身攻击时吸血
!?MF1;
!!FU2800&v2800=6/v2803=77/v2807=v84:P2/v2801/v2803/v2802/v2804;
!!FU2800&v2800=6/v2803>-1/v2803<197/v2804=77/v2805>0/v2807<>v84:P3/v2802/v2804/v2805/v2801/v2803;

!?FU2800&x1=2;
!!FU&x1<>2:E;
!!BMx2:N?y1 B?y2 H?y3 L?y4;
!!FU&y1>=y2/y4=0:E;
!!UN:N3/-1/x3/1;
!!BMx4:F?i;
!!VRi:&16;
!!FU&i=0:E;
!!UN:N3/-2/x5/1;
!!MF:F?y5;
!!VRy6:Sy2 -y1;
!!VRy7:Sy5 :y3;
!!VRy7&y7>y6:Sy6;
!!VRy8:Sy4 *-1;
!!BMx2:V79 Ndy7 Ldy8;
!!VRz900&y7=0:S^{%Z-1吸走%Y4点%Z-2的生命值。}^;
!!VRz900&y7>0:S^{%Z-1吸走%Y5点%Z-2的生命值。并且%Y7个复活了。}^;
!!BU:Mz900 R;

!?FU2800&x1=3;
!!FU&x1<>3:E;
!!BMx2:N?y1 B?y2 H?y3 L?y4;
!!FU&y1>=y2/y4=0:E;
!!UN:N3/-1/x3/1;
!!BMx5:F?i;
!!VRi:&16;
!!FU&i=0:E;
!!UN:N3/-2/x6/1;
!!MF:F?y5 N?y-5;
!!FU&y-5<>x5:E;
!!VRy6:Sy2 -y1;
!!VRy7:Sy5 :y3;
!!VRy7&y7>y6:Sy6;
!!VRy8:Sy4 *-1;
!!BMx2:V79 Ndy7 Ldy8;
!!VRz900&y7=0:S^{%Z-1吸走%Y4点%Z-2的生命值。}^;
!!VRz900&y7>0:S^{%Z-1吸走%Y5点%Z-2的生命值。并且%Y7个复活了。}^;
!!BU:Mz900 R;

****射击后30%造成敌方石化
!?BG1;
!!FU2800&v2800=7/v2803=77/v2807=v84:P4/v2800/v2801/v2802/v2803/v2804;
!?FU2800&x1=4;
!!FU&x1<>4:E;
!!FU&x2<>7:E;
!!BMx4:T?x7 N?x8;
!!FU|x7<0/x8<1:E;
!!UN:N3/-1/x5/1;
!!UN:N3/-2/x6/1;
!!VRx9:S0 R99;
!!FU&x9>30:E;
!!BMx4:M70/3/1;
!!VRz900:S^{%Z-1射击后使%Z-2被石化了。}^;
!!BU:Mz900 R;

***动作后偷取魔法
!?BG1;
!!FU2800&v2800>5/v2800<8/v2803=77/v2806=0/v2807=v84/v9560>-1:P5/v2807/v9560/v2801/v2803;
!!FU2800&v2800>5/v2800<8/v2803=77/v2806=1/v9555>-1/v2807=v84:P5/v2807/v9555/v2801/v2803;
!?FU2800&x1=5;
!!FU&x1<>5:E;
!!UN:N3/-1/x5/1;
!!HEx3:I?y1/1;
!!FU&y1<2:E;
!!HEx3:B0/?z-2;
!!BMx4:V77;
!!HEx2:Id2/1;
!!HEx3:Id-2/1;
!!VRz900:S^{%Z-1吸取了%Z-2的2点魔法值。}^;
!!BU:Mz900 R;

[ 本帖最后由骷髅召唤师于 2011-11-2 21:31 编辑 ]

cxc00000 · 发表于 2011-11-2 20:45:25

感谢召唤大大，刚才去测试了一下
反击火盾也吸血还好，不过刚才测试了下好像是他打我多少血我就吸多少血...这个判断应该是我造成了多少伤害吸多少血才对，刚才测试的时候2个美杜莎女王打了40个十字军....他打我损失了多少，我就吸多少...这个地方是不是弄错了，应该是增加的生命是我对他造成的伤害量

[ 本帖最后由 cxc00000 于 2011-11-2 21:20 编辑 ]

骷髅召唤师 · 发表于 2011-11-2 21:34:02

这个问题我也不知道哪里错了，水平不够啊。

要不我用直接方式实现吸血试试。

无心云 · 发表于 2011-11-2 21:44:19

要BT就BT到底
物免
魔免

cxc00000 · 发表于 2011-11-2 22:06:09

直接吸血是不是会没经验？

账号		自动登录	找回密码
密码			英雄注册\|Register

超级美杜莎erm (见25L)

相关帖子

回复2#

回复 4# 的帖子

魔幻射击后有30%机率石化对方

评分

经过我测试，发现沧海这个脚本阵的实现了射击后石化

回复 1# 的帖子

评分

回复 11# 的帖子

回复 14# 的帖子

回复 14# 的帖子

回复 17# 的帖子

浏览过的版块

社区QQ达人

论坛守望者

金牌裁判

杰出贡献

魅力之星

TE联赛冠军

退役版主

脚本测试狂

论坛元老