一个好玩的指挥官erm增强

akgod

其实说来说去我觉得很多人都误解我意思了
我本意是说，麻痹会削弱凝视的效果，因而才想到了这个该法……不否认我更喜欢最求“暴力”，但我的这个帖子的出发点就是很简单的想法：“没道理越学越弱吧？，但麻痹和凝视的同事拥有的确是越学越弱了，所以才想着能否改改”

首先声明，我不是作者……原作者是谁我也不知道了……
这个erm我个人感觉很有意思，比大多数指挥官增强都好玩，可惜一直被埋没，没有在太多的地方被提到
现在贴上来，大家可以试试，很有意思
注意，请自己把rar改为erm……因为我这边没有rar压缩文件，而论坛又限制上传类型，so……

另，哪位朋友可以帮忙改改，不知道wog的技能出现是否有顺序？我发现死亡凝视的效果似乎会被麻痹影响，只有死亡凝视时能瞪死好几个，但有了麻痹后就只能瞪死1~3个了，最要命的是经常先麻痹再凝视……能否改成先凝视后麻痹，或者干脆把麻痹换成毒液之类的不影响凝视效果的技能？（例如双倍？）


ZVSE
ERMS_PoweredBy=ERM Scripter v. 2004.6.29.918
ERMS_ScriptDate=13.5(May).2005
_WARNING_#1=IMPORTANT! This file is not in a plain text format. NEVER use any editor except ERM_S for making any kind of changes!
ERMS_PoweredBy=ERM Scripter v. 2004.6.29.918
** ENHANCED COMMANDERS - ERM script 51

** By Arstahd
** Version: 1.11 updated October 2 2004
** Updated September 15, 2004 to change local y variables in instructions to v variables
** Special Thanks to Hermann the Weird for help with bug fixing and script maintenance

** Note: Commander Enhancements are disabled for network human-to-human battles.

** Variables used:
** V variables: v7080-v7092 v7177, v7185
** Y variables: y1-y9
** Functions used: 7070-7074
** Timers used: none

*** commander stats are calculated to new formulae
** display will be inaccurate when hero levels up, re-open commander screen to update stat display, ignore skill descriptions
** attack - base 5 + 1/2 x level - skill adds +25%,+50%,+75%,+100%,+125%
** defence - base 5 + 1/2 x level - skill adds +25%,+50%,+75%,+100%,+125%
** hit points - base 30 + 15 x level - skill adds +25%,+50%,+75%,+100%,+125%
** damage - base 10 + 5 x level - skill adds +25%,+50%,+75%,+100%,+125%
** magic power - base 3 + 3 x skill level (Soul Eater & Astral Spirit: base 1 + 1 x skill level)
** magic resistance- base 0 + 10 x skill level
** speed - base 5 - skill adds normal bonus
** spell quantity - functions as normal (increased by magic power skill)
*** commanders each start with a special ability
** paladin - endless retaliation
** heirophant - magic mirror (fire shield)
** temple guardian - shoot
** succubus - fly
** soul eater - fear
** brute - no retaliation
** ogre leader - block
** shaman - 50% poison (death stare)
** astral spirit - ignore 50% defense
*** commander spells improved, most apply an additional spell (at adv. level) after they cast a spell
** paladin - cure/bless
** heirophant - shield/mirth
** temple guardian - prayer (precision removed)
** succubus - fire shield/bloodlust (displays Sacrifice animation)
** soul eater - animate dead (no change)
** brute - bloodlust/stoneskin
** ogre leader - stoneskin/counterstrike
** shaman - haste/fortune
** astral spirit - summon elemental (counterstrike removed)
*** commanders (except soul eater &astral spirit) are now living and can be resurrected (soul eater can still be raised with animate dead)
*** commanders are town based if bought, type depends on town not hero when you buy a new commander (dismiss old commander to buy a new one)
*** "Death Stare" ability replaced with 50% chance to cast Poison - attack or shoot
*** "Fire Shield" ability replaced with expert Magic Mirror

*** commander stones now give skills:
** opal - gives random special ability
** ruby - gives either +1 to Attack skill or Damage skill
** sapphire - gives either +1 to Defense skill or Hit Points skill
** emerald - gives either +1 to Magic skill or Speed skill


** initialization
!#UN:P51/?v7185; [check if Enhanced Commanders is enabled in WoGify Options]
!#UN:P186/?v7177; [check if Choose Commanders is enabled in WoGify Options]
!#UN:P3/?v1; [check if Commanders are enabled]
!#VRv7185&v1=1:S0; [disable if Commanders aren't enabled]

!#CO-2&v7185=1:P1; [enable custom primary skill control]

!#UN:B6/1; [set new chest 6 to advanced setting (disabled)]


** function to make commanders alive
!?FU7072;

!!MA:Xx16/?i; [get flags]
!!VRi:+16; [add alive bit]
!!VRi|x16=178/x16=187:-16; [remove alive bit if soul eater]
!!MA:Xx16/i; [reset flags]
** end of function **

!#DO7072/174/191/1&v7185=1:P; [iterate through all commander types and make alive]
** end of initialization

** commander screen open trigger
!?CO0&v7185=1; [check if Enhanced Commanders is enabled]
!!HE-1:N?y-1; [get hero's (commander's) number]
!!FU7070:Py-1;
** end of hero level trigger

** start of pre-battle trigger **
!?BA0&v7185=1/-998; [check if Enhanced Commanders is enabled]
!!VRv7080:C-1/-1/-1/-1/-1/-1/-1/-1/-1/-1; [initialize variables]
!!BA:H0/?v7083; [get hero (commander) number - attacker]
!!BA:H1/?v7085; [get hero (commander) number - defender]

!!FU7070&v7083>-1:Pv7083; [modify commander stats - attacker]
!!FU7070&v7085>-1:Pv7085; [modify commander stats - defender]

!!COv7083&v7083>-1:B0/?y-1 T?v7088; [check skill bits, get type - attacker]
!!COv7085&v7085>-1:B0/?y-2 T?v7089; [check skill bits, get type - defender]


!!VRv7084&v7083>-1:Sy-1 &1; [check death stare bit - attacker]
!!VRv7086&v7085>-1:Sy-2 &1; [check death stare bit - defender]
!!COv7083&v7083>-1/v7084=1:B1/0/1; [remove death stare - attacker]
!!COv7085&v7085>-1/v7086=1:B1/0/1; [remove death stare - defender]

!!VRv7090&v7083>-1:Sy-1 &2; [check fire shield bit - attacker]
!!VRv7091&v7085>-1:Sy-2 &2; [check fire shield bit - defender]
!!COv7083&v7083>-1/v7090=2:B1/1/1; [remove fire shield - attacker]
!!COv7085&v7085>-1/v7091=2:B1/1/1; [remove fire shield - defender]

!!VRv9101&v7083>-1:Sy-1 &2048; [check fire shield bit - attacker]
!!VRv9102&v7085>-1:Sy-2 &2048; [check fire shield bit - defender]
!!COv7083&v7083>-1/v9101=2048:B1/11/0; [remove fire shield - attacker]
!!COv7085&v7085>-1/v9102=2048:B1/11/0; [remove fire shield - defender]

!!VRv9103&v7083>-1:Sy-1 &4; [check fire shield bit - attacker]
!!VRv9104&v7085>-1:Sy-2 &4; [check fire shield bit - defender]
!!COv7083&v7083>-1/v9103=4:B1/2/1; [remove fire shield - attacker]
!!COv7085&v7085>-1/v9104=4:B1/2/1; [remove fire shield - defender]
** end of function

---------------------------------------------------------------------
** pre-action trigger **
!?BG&v7185=1/-998; [continue if enabled]
!!BG:N?v7080 A?v7081 E?v7082; [get current stack, action type, destination stack]
!!BMv7082&v7082>-1:R?v7087; [get retaliations of target creature stack]
!!BMv7080&v7080>-1:T?v7092; [get type of current creature stack]


!!VRy-2&v7092=182/v7081=10:S66 T3; [if astral spirit is casting - choose random elemental spell]
!!BMv7080&v7092=182/v7081=10:U4/y-2; [if astral spirit is casting - change spell to summon elemental]
!!VRy-2&v7092=191/v7081=10:S66 T3; [if astral spirit is casting - choose random elemental spell]
!!BMv7080&v7092=191/v7081=10:U4/y-2; [if astral spirit is casting - change spell to summon elemental]

** end of pre-action trigger **
===============================================================================
** post-action trigger **
!?BG1&v7185=1/-998; [continue if enabled]
!!BMv7080&v7080>-1:T?y-3 I?y-4; [get acting monster type and side]
!!FU7071&y-3>=174/y-3<=191/v7081=10:Pv7080/y-3; [cast extra spell if commander cast]

!!BMv7082&v7082>-1:F?y-7 P?y-8; [get target's flags, position]

!!VRy-10&y-3>=174/y-3<=191/v7081>=6/v7081<=7/v7084=1/y-4=0:S0 R99; [random roll - attacker]
!!VRy-11&y-3>=174/y-3<=191/v7081>=6/v7081<=7/v7086=1/y-4=1:S0 R99; [random roll - defender]
!!FU7073&y-3>=174/y-3<=191/v7081>=6/v7081<=7/v7084=1/y-4=0/y-10<100:Py-7/y-8; [50% cast poison if commander with death stare attacked or shot - attacker]
!!FU7073&y-3>=174/y-3<=191/v7081>=6/v7081<=7/v7086=1/y-4=1/y-11<100:Py-7/y-8; [50% cast poison if commander with death stare attacked or shot - defender]

!!BMv7080&v7092=182/v7081=10:U4/58; [astral spirit - revert spell to counterstrike]
!!BMv7080&v7092=191/v7081=10:U4/58; [astral spirit - revert spell to counterstrike]

** retaliation attack
!!BMv7082&v7082>-1:T?y-3 I?y-4 P?y-5; [get target monster type, side, position]
!!BU&v7082>-1:Ey-5/?y-6; [check if target is still alive]

!!BMv7080&v7080>-1:F?y-9; [get flags of attacking creature stack]
!!VRy-9&v7080>-1:&65536; [check for no retaliation]

!!BMv7080&v7080>-1:F?y-7 P?y-8; [get acting creature's flags, position]
!!VRy-10&y-3>=174/y-3<=191/v7081=6/v7084=1/v7087>0/y-4=0/y-6>-1/y-9=0:S0 R99; [random roll - attacker]
!!VRy-11&y-3>=174/y-3<=191/v7081=6/v7086=1/v7087>0/y-4=1/y-6>-1/y-9=0:S0 R99; [random roll - defender]
!!FU7073&y-3>=174/y-3<=191/v7081=6/v7084=1/v7087>0/y-4=0/y-10<100/y-6>-1/y-9=0:Py-7/y-8; [50% cast poison if commander with death stare retaliates - attacker]
!!FU7073&y-3>=174/y-3<=191/v7081=6/v7086=1/v7087>0/y-4=1/y-11<100/y-6>-1/y-9=0:Py-7/y-8; [50% cast poison if commander with death stare retaliates - defender]

!!BU:C?y-1; [check for end of battle]
!!COv7083&v7083>-1/v7084=1/y-1=1:B1/0/1; [restore death stare - attacker]
!!COv7085&v7085>-1/v7086=1/y-1=1:B1/0/1; [restore death stare - defender]
** end of post-action trigger **


---------------------------------------------------------------
** post-action trigger **
!?BG1&v7185=1/-998; [continue if enabled]
!!BMv7080&v7080>-1:T?y-3 I?y-4; [get acting monster type and side]
!!FU7071&y-3>=174/y-3<=191/v7081=10:Pv7080/y-3; [cast extra spell if commander cast]

!!BMv7082&v7082>-1:F?y-7 P?y-8; [get target's flags, position]

!!VRy-10&y-3>=174/y-3<=191/v7081>=6/v7081<=7/v7090=2/y-4=0:S0 R99; [random roll - attacker]
!!VRy-11&y-3>=174/y-3<=191/v7081>=6/v7081<=7/v7091=2/y-4=1:S0 R99; [random roll - defender]
!!FU7074&y-3>=174/y-3<=191/v7081>=6/v7081<=7/v7090=2/y-4=0/y-10<50:Py-7/y-8; [50% cast poison if commander with death stare attacked or shot - attacker]
!!FU7074&y-3>=174/y-3<=191/v7081>=6/v7081<=7/v7091=2/y-4=1/y-11<50:Py-7/y-8; [50% cast poison if commander with death stare attacked or shot - defender]

!!BMv7080&v7092=182/v7081=10:U4/58; [astral spirit - revert spell to counterstrike]
!!BMv7080&v7092=191/v7081=10:U4/58; [astral spirit - revert spell to counterstrike]

** retaliation attack
!!BMv7082&v7082>-1:T?y-3 I?y-4 P?y-5; [get target monster type, side, position]
!!BU&v7082>-1:Ey-5/?y-6; [check if target is still alive]

!!BMv7080&v7080>-1:F?y-9; [get flags of attacking creature stack]
!!VRy-9&v7080>-1:&65536; [check for no retaliation]

!!BMv7080&v7080>-1:F?y-7 P?y-8; [get acting creature's flags, position]
!!VRy-10&y-3>=174/y-3<=191/v7081=6/v7090=2/v7087>0/y-4=0/y-6>-1/y-9=0:S0 R99; [random roll - attacker]
!!VRy-11&y-3>=174/y-3<=191/v7081=6/v7091=2/v7087>0/y-4=1/y-6>-1/y-9=0:S0 R99; [random roll - defender]
!!FU7074&y-3>=174/y-3<=191/v7081=6/v7090=2/v7087>0/y-4=0/y-10<50/y-6>-1/y-9=0:Py-7/y-8; [50% cast poison if commander with death stare retaliates - attacker]
!!FU7074&y-3>=174/y-3<=191/v7081=6/v7091=2/v7087>0/y-4=1/y-11<50/y-6>-1/y-9=0:Py-7/y-8; [50% cast poison if commander with death stare retaliates - defender]

!!BU:C?y-1; [check for end of battle]
!!COv7083&v7083>-1/v7090=2/y-1=1:B1/1/1; [restore death stare - attacker]
!!COv7085&v7085>-1/v7091=2/y-1=1:B1/1/1; [restore death stare - defender]
** end of post-action trigger **


-----------------------------------

** post-action trigger **
!?BG1&v7185=1/-998; [continue if enabled]
!!BMv7080&v7080>-1:T?y-3 I?y-4; [get acting monster type and side]
!!FU7071&y-3>=174/y-3<=191/v7081=10:Pv7080/y-3; [cast extra spell if commander cast]

!!BMv7082&v7082>-1:F?y-7 P?y-8; [get target's flags, position]

!!VRy-10&y-3>=174/y-3<=191/v7081>=6/v7081<=7/v9101=2048/y-4=0:S0 R99; [random roll - attacker]
!!VRy-11&y-3>=174/y-3<=191/v7081>=6/v7081<=7/v9102=2048/y-4=1:S0 R99; [random roll - defender]
!!FU9075&y-3>=174/y-3<=191/v7081>=6/v7081<=7/v9101=2048/y-4=0/y-10<40:Py-7/y-8; [50% cast poison if commander with death stare attacked or shot - attacker]
!!FU9075&y-3>=174/y-3<=191/v7081>=6/v7081<=7/v9102=2048/y-4=1/y-11<60:Py-7/y-8; [50% cast poison if commander with death stare attacked or shot - defender]

!!BMv7080&v7092=182/v7081=10:U4/58; [astral spirit - revert spell to counterstrike]
!!BMv7080&v7092=191/v7081=10:U4/58; [astral spirit - revert spell to counterstrike]

** retaliation attack
!!BMv7082&v7082>-1:T?y-3 I?y-4 P?y-5; [get target monster type, side, position]
!!BU&v7082>-1:Ey-5/?y-6; [check if target is still alive]

!!BMv7080&v7080>-1:F?y-9; [get flags of attacking creature stack]
!!VRy-9&v7080>-1:&65536; [check for no retaliation]

!!BMv7080&v7080>-1:F?y-7 P?y-8; [get acting creature's flags, position]
!!VRy-10&y-3>=174/y-3<=191/v7081=6/v9101=2048/v7087>0/y-4=0/y-6>-1/y-9=0:S0 R99; [random roll - attacker]
!!VRy-11&y-3>=174/y-3<=191/v7081=6/v9102=2048/v7087>0/y-4=1/y-6>-1/y-9=0:S0 R99; [random roll - defender]
!!FU9075&y-3>=174/y-3<=191/v7081=6/v9101=2048/v7087>0/y-4=0/y-10<40/y-6>-1/y-9=0:Py-7/y-8; [50% cast poison if commander with death stare retaliates - attacker]
!!FU9075&y-3>=174/y-3<=191/v7081=6/v9102=2048/v7087>0/y-4=1/y-11<60/y-6>-1/y-9=0:Py-7/y-8; [50% cast poison if commander with death stare retaliates - defender]

!!BU:C?y-1; [check for end of battle]
!!COv7083&v7083>-1/v9101=2048/y-1=1:B1/11/1; [restore death stare - attacker]
!!COv7085&v7085>-1/v9102=2048/y-1=1:B1/11/1; [restore death stare - defender]
** end of post-action trigger **


---------------------------------------------------------------------------
** post-action trigger **
!?BG1&v7185=1/-998; [continue if enabled]
!!BMv7080&v7080>-1:T?y-3 I?y-4; [get acting monster type and side]
!!FU7071&y-3>=174/y-3<=191/v7081=10:Pv7080/y-3; [cast extra spell if commander cast]

!!BMv7082&v7082>-1:F?y-7 P?y-8; [get target's flags, position]

!!VRy-10&y-3>=174/y-3<=191/v7081>=6/v7081<=7/v9103=4/y-4=0:S0 R99; [random roll - attacker]
!!VRy-11&y-3>=174/y-3<=191/v7081>=6/v7081<=7/v9104=4/y-4=1:S0 R99; [random roll - defender]
!!FU9076&y-3>=174/y-3<=191/v7081>=6/v7081<=7/v9103=4/y-4=0/y-10<50:Py-7/y-8; [50% cast poison if commander with death stare attacked or shot - attacker]
!!FU9076&y-3>=174/y-3<=191/v7081>=6/v7081<=7/v9104=4/y-4=1/y-11<50:Py-7/y-8; [50% cast poison if commander with death stare attacked or shot - defender]

!!BMv7080&v7092=182/v7081=10:U4/58; [astral spirit - revert spell to counterstrike]
!!BMv7080&v7092=191/v7081=10:U4/58; [astral spirit - revert spell to counterstrike]

** retaliation attack
!!BMv7082&v7082>-1:T?y-3 I?y-4 P?y-5; [get target monster type, side, position]
!!BU&v7082>-1:Ey-5/?y-6; [check if target is still alive]

!!BMv7080&v7080>-1:F?y-9; [get flags of attacking creature stack]
!!VRy-9&v7080>-1:&65536; [check for no retaliation]

!!BMv7080&v7080>-1:F?y-7 P?y-8; [get acting creature's flags, position]
!!VRy-10&y-3>=174/y-3<=191/v7081=6/v9103=4/v7087>0/y-4=0/y-6>-1/y-9=0:S0 R99; [random roll - attacker]
!!VRy-11&y-3>=174/y-3<=191/v7081=6/v9104=4/v7087>0/y-4=1/y-6>-1/y-9=0:S0 R99; [random roll - defender]
!!FU9076&y-3>=174/y-3<=191/v7081=6/v9103=4/v7087>0/y-4=0/y-10<50/y-6>-1/y-9=0:Py-7/y-8; [50% cast poison if commander with death stare retaliates - attacker]
!!FU9076&y-3>=174/y-3<=191/v7081=6/v9104=4/v7087>0/y-4=1/y-11<50/y-6>-1/y-9=0:Py-7/y-8; [50% cast poison if commander with death stare retaliates - defender]

!!BU:C?y-1; [check for end of battle]
!!COv7083&v7083>-1/v9103=4/y-1=1:B1/2/1; [restore death stare - attacker]
!!COv7085&v7085>-1/v9104=4/y-1=1:B1/2/1; [restore death stare - defender]
** end of post-action trigger **
----------------------------------------------------------------
** function to cast poison x1=flags x2=position
!?FU7073;
!!VRx1:&16; [just check alive bit]
!!BG:N?y1;
!!BMy1:C78/x2/3/1/1;
!!BMy1:C80/x2/3/3/1;
!!VRi:S0 T4;
!!VRy12&i=0:S42;
!!VRy12&i=1:S45;
!!VRy12&i=2:S47;
!!VRy12&i=3:S54;
!!VRy12&i=4:S73;
!!BMy1:Cy12/x2/1/9/1; [if target is alive have current stack cast poison]
** end of function **


** function to cast poison x1=flags x2=position
!?FU7074;
!!VRx1:&16; [just check alive bit]
!!BG:N?y1; [get current stack #]
!!BMy1&x1<>16:C71/x2/1/9/1;
!!BMy1&x1=16:C75/x2/1/9/1; [if target is alive have current stack cast poison]
** end of function **


** function to cast poison x1=flags x2=position
!?FU9075;
!!VRx1:&16; [just check alive bit]
!!BG:N?y1; [get current stack #]
!!BMy1:C70/x2/1/5/1; [if target is alive have current stack cast poison]
** end of function **

** function to cast poison x1=flags x2=position
!?FU9076;
!!VRx1:&16; [just check alive bit]
!!BG:N?y1; [get current stack #]
!!VRi:S0 R99;
!!VRy12&i>=0/i<35:S16;
!!VRy12&i>=35/i<65:S17;
!!VRy12&i>=65/i<85:S57;
!!VRy12&i>=85/i<100:S18;
!!BMy1:Cy12/x2/2/9/1; [if target is alive have current stack cast poison]
** end of function **
-----------------------------------------------------------------------------
==============================================================================
** post-buy commander trigger **
!?CO2&v7185=1/v7177<>1; [continue if enabled and "choose commanders" isn't]
!!HE-1:P?y-1/?y-2/?y-3; [get hero position]
!!OBy-1/y-2/y-3:U?y-4; [get subtype of town]
!!CO-1:Ty-4; [set commander type]
** end of post-buy commander trigger **

** function to edit commander stats
!?FU7070; x1=hero number

!!COx1:X2/?y2 T?y5; [get commander level & type]
** attack - base 5 + 1/2 x level - skill adds +25%,+50%,+75%,+100%,+125%
!!COx1:S0/?y3; [get attack level]
!!VRy4&y3=0:Sy2 :2 +5; [if attack=0 set attack to 5 + 1/2 level]
!!VRy4&y3=1:Sy2 :2 +5 *125 :100 -2; [if attack=1 set attack to 5 + 1/2 level x 125%]
!!VRy4&y3=2:Sy2 :2 +5 *150 :100 -5; [if attack=2 set attack to 5 + 1/2 level x 150%]
!!VRy4&y3=3:Sy2 :2 +5 *175 :100 -9; [if attack=3 set attack to 5 + 1/2 level x 175%]
!!VRy4&y3=4:Sy2 :2 +5 *2 -15; [if attack=4 set attack to 5 + 1/2 level x 200%]
!!VRy4&y3=5:Sy2 :2 +5 *225 :100 -25; [if attack=5 set attack to 5 + 1/2 level x 225%]
!!COx1:P0/y4; [set attack]
** defense - base 5 + 1/2 x level - skill adds +25%,+50%,+75%,+100%,+125%
!!COx1:S1/?y3; [get defence level]
!!VRy4&y3=0:Sy2 :2 +5; [if defence=0 set defence to 5 + 1/2 level]
!!VRy4&y3=1:Sy2 :2 +5 *125 :100 -4; [if defence=1 set defence to 5 + 1/2 level x 125%]
!!VRy4&y3=2:Sy2 :2 +5 *150 :100 -10; [if defence=2 set defence to 5 + 1/2 level x 150%]
!!VRy4&y3=3:Sy2 :2 +5 *175 :100 -18; [if defence=3 set defence to 5 + 1/2 level x 175%]
!!VRy4&y3=4:Sy2 :2 +5 *2 -30; [if defence=4 set defence to 5 + 1/2 level x 200%]
!!VRy4&y3=5:Sy2 :2 +5 *225 :100 -50; [if defence=5 set defence to 5 + 1/2 level x 225%]
!!COx1:P1/y4; [set defence]
** hit points - base 30 + 15 x level - skill adds +25%,+50%,+75%,+100%,+125%
!!COx1:S2/?y3; [get hit points level]
!!VRy4&y3=0:Sy2 *20 +40; [if hit points=0 set hit points to 40 + 20 x level]
!!VRy4&y3=1:Sy2 *20 +40 *125 :110; [if hit points=1 set hit points to 40 + 20 x level x 125%]
!!VRy4&y3=2:Sy2 *20 +40 *150 :125; [if hit points=2 set hit points to 40 + 20 x level x 150%]
!!VRy4&y3=3:Sy2 *20 +40 *175 :145; [if hit points=3 set hit points to 40 + 20 x level x 175%]
!!VRy4&y3=4:Sy2 *20 +40 *200 :170; [if hit points=4 set hit points to 40 + 20 x level x 200%]
!!VRy4&y3=5:Sy2 *20 +40 *225 :200; [if hit points=5 set hit points to 40 + 20 x level x 225%]
!!COx1:P2/y4; [set hit points]
** damage - base 10 + 5 x level - skill adds +25%,+50%,+75%,+100%,+125%
!!COx1:S3/?y3; [get damage level]
!!VRy4&y3=0:Sy2 *5 +10; [if damage=0 set damage to 10 + 5 x level]
!!VRy4&y3=1:Sy2 *5 +10 *125 :110; [if damage=1 set damage to 10 + 5 x level x 125%]
!!VRy4&y3=2:Sy2 *5 +10 *150 :125; [if damage=2 set damage to 10 + 5 x level x 150%]
!!VRy4&y3=3:Sy2 *5 +10 *175 :145; [if damage=3 set damage to 10 + 5 x level x 175%]
!!VRy4&y3=4:Sy2 *5 +10 *200 :170; [if damage=4 set damage to 10 + 5 x level x 200%]
!!VRy4&y3=5:Sy2 *5 +10 *225 :200; [if damage=5 set damage to 10 + 5 x level x 225%]
!!COx1:P3/y4; [set damage]
** magic power - base 3 + 3 x skill level (Soul Eater: base 1 + 1 x skill level)
!!COx1:S4/?y3; [get MP level]
!!VRy6:Sy3 +1 *3; [set power to (MP+1)x3]
!!VRy6&y5=4:Sy3 +1; [if Soul Eater set power MP+1]
!!VRy6&y5=8:Sy3 +1; [if Astral Spirit set power MP+1]
!!VRy4&y3=0:Sy6; [if MP=0 set power]
!!VRy4&y3=1:Sy6 -1; [if MP=1 set power]
!!VRy4&y3=2:Sy6 -3; [if MP=2 set power]
!!VRy4&y3=3:Sy6 -7; [if MP=3 set power]
!!VRy4&y3=4:Sy6 -14; [if MP=4 set power]
!!VRy4&y3=5:Sy6 -29; [if MP=5 set power]
!!COx1:P4/y4; [set power]
** magic resistance - base 0 + 10 x skill level
!!VRy4&y3=0:S0; [if MP=0 set magic resistance to 0]
!!VRy4&y3=1:S5; [if MP=1 set magic resistance to 10]
!!VRy4&y3=2:S5; [if MP=2 set magic resistance to 20]
!!VRy4&y3=3:S5; [if MP=3 set magic resistance to 30]
!!VRy4&y3=4:S5; [if MP=4 set magic resistance to 40]
!!VRy4&y3=5:S5; [if MP=5 set magic resistance to 50]
!!COx1:P6/y4; [set magic resistance]
** speed - base 5 - skill adds normal bonus
!!COx1:P5/5; [set base speed to 5]

** starting special bonus

!!COx1&y5=0:B1/13/1; [give paladin - endless retaliation]
!!COx1&y5=1:B1/11/1; [give hierophant - magic mirror (fire shield)]
!!COx1&y5=2:B1/4/1; [give temple guardian - shoot]
!!COx1&y5=3:B1/14/1; [give succubus - fly]
!!COx1&y5=4:B1/1/1; [give soul eater - fear]
!!COx1&y5=5:B1/2/1; [give brute - no retaliation]
!!COx1&y5=6:B1/3/1; [give ogre leader - block]
!!COx1&y5=7:B1/0/1; [give shaman - poison (death stare)]
!!COx1&y5=8:B1/7/1; [give astral spirit - ignore 50% defense]

!!VRx1:+1; [increment hero number]
** end of function


========================================================================
-----------------------------------------------------------------------

** object trigger - opal
!?OB101/7&v7185=1;
!!HE-1:N?y-1;
!!VRy-4:S0 T14; [random roll 0-14]
!!VRz2&y-4=0:Sz151000; [set string]
!!VRz2&y-4=1:Sz151001; [set string]
!!VRz2&y-4=2:Sz151002; [set string]
!!VRz2&y-4=3:Sz151003; [set string]
!!VRz2&y-4=4:Sz151004; [set string]
!!VRz2&y-4=5:Sz151005; [set string]
!!VRz2&y-4=6:Sz151006; [set string]
!!VRz2&y-4=7:Sz151007; [set string]
!!VRz2&y-4=8:Sz151008; [set string]
!!VRz2&y-4=9:Sz151009; [set string]
!!VRz2&y-4=10:Sz151010; [set string]
!!VRz2&y-4=11:Sz151011; [set string]
!!VRz2&y-4=12:Sz151012; [set string]
!!VRz2&y-4=13:Sz151013; [set string]
!!VRz2&y-4=14:Sz151014; [set string]

!!COy-1:B1/y-4/?y-5 D?y-6 E?y-7 N?z1; [check if commander has skill, is alive, is enabled, get name]
!!OB998&y-6=0/y-7=1:T101 U6; [set to chest 6 if commander is alive, enabled]
!!COy-1&y-5=0/y-6=0/y-7=1:B1/y-4/1; [give skill if commander doesn't have it and is alive, enabled]

!!IF&y-5=0/y-6=0/y-7=1/1000:M1/z151015;
!!IF&y-5=1/1000:M1/z151016;

** end of object trigger


** object trigger - ruby
!?OB101/8&v7185=1;
!!HE-1:N?y-1;
!!COy-1:S0/?y-2 S3/?y-3 D?y-6 E?y-7 N?z1; [get Attack / Damage levels, check if alive, enabled, get name]
!!OB998&y-6=0/y-7=1:T101 U6; [set to chest 6 if commander is alive, enabled]
!!COy-1&y-6=0/y-7=1/y-2>y-3:S3/d1; [if Attack > Damage add 1 to Damage level]
!!COy-1&y-6=0/y-7=1/y-2<y-3:S0/d1; [if Attack < Damage add 1 to Attack level]
!!VRy-4&y-6=0/y-7=1/y-2=y-3/y-2<5:S0 T99; [percentage roll]
!!COy-1&y-6=0/y-7=1/y-2=y-3/y-2<5/y-4<50:S3/d1; [if Attack = Damage and < 6 and roll is < 50 add 1 to Damage level]
!!COy-1&y-6=0/y-7=1/y-2=y-3/y-2<5/y-4>49:S0/d1; [if Attack = Damage and < 6 and roll is < 50 add 1 to Attack level]

!!IF&1000/y-6=0/y-2>y-3:M1/z151017;
!!IF&1000/y-6=0/y-2<y-3:M1/z151018;
!!IF&1000/y-6=0/y-2=y-3/y-2<5/y-4<50:M1/z151019;
!!IF&1000/y-6=0/y-2=y-3/y-2<5/y-4>49:M1/z151020;
!!IF&1000/y-6=0/y-2=y-3/y-2>4:M1/z151021;
** end of object trigger


** object trigger - sapphire
!?OB101/9&v7185=1;
!!HE-1:N?y-1;
!!COy-1:S1/?y-2 S2/?y-3 D?y-6 E?y-7 N?z1; [get Defense / Hit Points levels, check if alive, enabled, get name]
!!OB998&y-6=0/y-7=1:T101 U6; [set to chest 6 if commander is alive, enabled]
!!COy-1&y-6=0/y-7=1/y-2>y-3:S2/d1; [if Defense > Hit Points add 1 to Hit Points level]
!!COy-1&y-6=0/y-7=1/y-2<y-3:S1/d1; [if Defense < Hit Points add 1 to Defense level]
!!VRy-4&y-6=0/y-7=1/y-2=y-3/y-2<5:S0 T99; [percentage roll]
!!COy-1&y-6=0/y-7=1/y-2=y-3/y-2<5/y-4<50:S2/d1; [if Defense = Hit Points and < 6 and roll is < 50 add 1 to Hit Points level]
!!COy-1&y-6=0/y-7=1/y-2=y-3/y-2<5/y-4>49:S1/d1; [if Defense = Hit Points and < 6 and roll is < 50 add 1 to Defense level]

!!IF&1000/y-6=0/y-2>y-3:M1/z151022;
!!IF&1000/y-6=0/y-2<y-3:M1/z151023;
!!IF&1000/y-6=0/y-2=y-3/y-2<5/y-4<50:M1/z151024;
!!IF&1000/y-6=0/y-2=y-3/y-2<5/y-4>49:M1/z151025;
!!IF&1000/y-6=0/y-2=y-3/y-2>4:M1/z151026;
** end of object trigger


** object trigger - emerald
!?OB101/10&v7185=1;
!!HE-1:N?y-1;
!!COy-1:S4/?y-2 S5/?y-3 D?y-6 E?y-7 N?z1; [get Magic Power / Speed levels, check if alive, enabled get name]
!!OB998&y-6=0/y-7=1:T101 U6; [set to chest 6 if commander is alive, enabled]
!!COy-1&y-6=0/y-7=1/y-2>y-3:S5/d1; [if Magic Power > Speed add 1 to Speed level]
!!COy-1&y-6=0/y-7=1/y-2<y-3:S4/d1; [if Magic Power < Speed add 1 to Magic Power level]
!!VRy-4&y-6=0/y-7=1/y-2=y-3/y-2<5:S0 T99; [percentage roll]
!!COy-1&y-6=0/y-7=1/y-2=y-3/y-2<5/y-4<50:S5/d1; [if Magic Power = Speed and < 6 and roll is < 50 add 1 to Speed level]
!!COy-1&y-6=0/y-7=1/y-2=y-3/y-2<5/y-4>49:S4/d1; [if Magic Power = Speed and < 6 and roll is < 50 add 1 to Magic Power level]

!!IF&1000/y-6=0/y-2>y-3:M1/z151027;
!!IF&1000/y-6=0/y-2<y-3:M1/z151028;
!!IF&1000/y-6=0/y-2=y-3/y-2<5/y-4<50:M1/z151029;
!!IF&1000/y-6=0/y-2=y-3/y-2<5/y-4>49:M1/z151030;
!!IF&1000/y-6=0/y-2=y-3/y-2>4:M1/z151031;
** end of object trigger



宠物加强 script51
（宠物抗魔只到95%了）
在原有加强上加上一些效果
"降防"技能:加上了"驱散有益魔法","酸液腐蚀","随机状态魔法攻击(女巫)"------100%
"恐惧"技能:加上了"老化"(活的)和"中毒"(不活的)----------50%
"最大伤害"技能:加上了"随机攻击魔法攻击(闪电\冰箭)"------------50%
"回复血"技能:（屏蔽）
加上了"石化"-----------50%(有时会反击）

[ 本帖最后由 akgod 于 2011-9-7 06:35 编辑 ]

灰狼王子

这个还算有意思，但是石化没有麻痹实惠，受伤害减半。老化和中毒则比恐惧实惠多了。

文兄

再接再厉！

沧海一粟

这个指挥官加强的ERM我们论坛上很早就有了啊。

akgod

论坛上早有了不假，但是貌似没有被推广过，现在的置顶帖里的集合或者指挥官erm增强都没这个

yingzi612

x先试试看

songfx

关于楼主提到的麻痹和死眼的问题。
我试着解释一下：

首先，指挥官技能是硬编码，不过也可能通过辅助脚本对其进行修正，比如指挥官加强脚本里就将死眼改成中毒了。但总之是比较麻烦的。

其次，指挥官先出死眼还是麻痹，并没有先后顺序，而是每次攻击时计算概率，而不管是攻击一下或两下。有可能两次都死眼，也可能两次都麻痹，甚至两次都没反应。如果你非要硬性规定第一次100%死眼，第二次100%麻痹，这也太无耻了。

最后，我想说一下，作弊或近似作弊只会缩短游戏的生命力。不要把所有的技能都设计得太完美，留一点缺憾，才有取舍的乐趣。

genman

唔....

lz既然跟我一样喜欢死眼
那我就把这个放出来把

原本开启"指挥官加强",会导致
火盾->魔法神镜          死眼->中毒

本erm将技能"射击"改为中毒(远程也可以触发)
保留火盾,同时增加魔法神镜

如果需要射击,可以开启修改器,给英雄添加宝物"搜寻之弓"
来达到远程的目的

akgod

原帖由 genman 于 2011-9-6 19:55 发表
唔....

lz既然跟我一样喜欢死眼
那我就把这个放出来把

原本开启"指挥官加强",会导致
火盾->魔法神镜          死眼->中毒

本erm将技能"射击"改为中毒(远程也可以触发)
保留火盾,同时增加魔法神镜

如果 ...

感谢楼上的朋友
这个erm是修改我放出的那个还是朋友你自己做的？具体效果都有什么啊

akgod

原帖由 songfx 于 2011-9-6 19:32 发表
关于楼主提到的麻痹和死眼的问题。
我试着解释一下：

首先，指挥官技能是硬编码，不过也可能通过辅助脚本对其进行修正，比如指挥官加强脚本里就将死眼改成中毒了。但总之是比较麻烦的。

其次，指挥官先出死眼 ...

感谢风侠的回复，其实有时候想得到是一回事，玩不玩是另外一回事了
wog好玩的地方就在于比h3有更多的选择性，我个人认为，作弊耍赖，也是一种选择

兽哥哥

原帖由 akgod 于 2011-9-6 21:56 发表

感谢楼上的朋友
这个erm是修改我放出的那个还是朋友你自己做的？具体效果都有什么啊

他是原创作者。寻梦和召唤师是协助修改的。

akgod

原帖由 兽哥哥 于 2011-9-6 22:13 发表
他是原创作者。寻梦和召唤师是协助修改的。

恩，我的意思是，他的erm是否和这个一样的，打完有很多状态……因为指挥官增强太多了，所以我才想问详细些

Huadong

原帖由 akgod 于 2011-9-6 21:57 发表

感谢风侠的回复，其实有时候想得到是一回事，玩不玩是另外一回事了
wog好玩的地方就在于比h3有更多的选择性，我个人认为，作弊耍赖，也是一种选择

有想法是挺好的。
不过我觉得这个想法不够创意，而是有点贪心。
我觉得与其这么纠结倒不如换个思路，让玩家随时可以在宠物界面指定宠物的附魔方式从下面四个选项里选择
1. 保持原始模式不变
2. 只允许死眼
3. 只允许麻痹
4. 如果学会双击或三击（残忍之斧），那么第一击为麻痹时，自动停止攻击

***********
自从有人写了魔法天尊的脚本，就有人纠结，想把这个脚本加入到TDS里，让英雄既拥有魔法天尊特长，又拥有原本的BT特长。
或者想将魔法天尊里的四特长集于一身。

我估计想要实现这些想法也不会很难，但意义不是很大。

akgod

原帖由 herohua9999 于 2011-9-7 03:59 发表


有想法是挺好的。
不过我觉得这个想法不够创意，而是有点贪心。
我觉得与其这么纠结倒不如换个思路，让玩家随时可以在宠物界面指定宠物的附魔方式从下面四个选项里选择
1. 保持原始模式不变
2. 只允许死眼
...

其实说来说去我觉得很多人都误解我意思了
我本意是说，麻痹会削弱凝视的效果，因而才想到了这个该法……不否认我更喜欢最求“暴力”，但我的这个帖子的出发点就是很简单的想法：“没道理越学越弱吧？，但麻痹和凝视的同事拥有的确是越学越弱了，所以才想着能否改改”

genman

原帖由 兽哥哥 于 2011-9-6 22:13 发表
他是原创作者。寻梦和召唤师是协助修改的。

您太高看我了= =
应该说是多亏了寻梦人最初的脚本雏形
然后我修改而成

我放的那个指挥官脚本并没有任何数据上的强化
只是开启指挥官加强后会取消"火盾"和"死神之眼"
我觉得不妥
就改了回来,现在开启指挥官加强后仍然后这两个技能效果
其他的没有任何bt化

顺佢自燃

顶风大，我就觉得，太完美反而变得不完美了。。。就是因为不完美，所以才能动力去追求完美！嘿嘿，有点矛盾的说法

akgod

原帖由 genman 于 2011-9-7 12:45 发表



您太高看我了= =
应该说是多亏了寻梦人最初的脚本雏形
然后我修改而成

我放的那个指挥官脚本并没有任何数据上的强化
只是开启指挥官加强后会取消"火盾"和"死神之眼"
我觉得不妥
就改了回来,现在开启指 ...

哦，感谢你的erm，不过我更想的是把这个erm能修改完善一下……其实即使完善了，也远远达不到所谓的bt，无耻的地步……