[原创]可用于地图事件中的秘银ERM汉化版。

暗黑龙守护神

原来有一个英文版的，现在汉化了一下。

ZVSE
AUTO_PoweredBy=ERM Scripter v. 2002.9.26.1
Mithril Script v1.0 by Anders Jonsson
Mithril Display Script by Timothy Pulver
The Mithril Script lets a player enhance certain buildings the player owns, and some others, by
right-clicking on their yellow entrance square and paying some Mithril.
Mine- enhance it to produce twice the normal amount of resources each day for one week. Works with
Timothy Pulver's "Week of" Script, giving up to four times the normal production.
Monster Dwelling- enhance it to produce upgraded creatures instead of normal. Does not work with new,
neutral creatures(from AB/SoD or Wog) or Golem Factory. Does work with old Elemental Conflux dwelling.
Castle- put a special terrain(Magic Plains, Holy Ground, Lucid Pools etc.) at castle to enhance it in
sieges.
Spell shrines- change spell to a new, random one.*
Witch Hut- change skill to a new, random one.*
Shipyard- place a Lighthouse at one of the red squares.
Windmill, Water Wheel- double weekly production.*
Monoliths- see area around exits.*
(*- Requires that the player have visited them before, and has a selected hero standing at a position
from which he can reach the entrance square with one step)

It also replaces 1 in 10 resource stacks with stacks with the same amount of mithril(Half amount if
it's wood, ore or gold), and 1 in 10 campfires contain mithril. To disable this feature, remove the
following line:
!#IF:V870/1;

It also sets up Windmills and Mystical Gardens so that one in ten contain Mithril. To disable this
feature, remove the following line:
!#IF:V873/1;

Mithril Display scripts shows a message when a player picks up a pile of Mithril, showing how much
Mithril that pile contained, and how much Mithril the player has right now. It also shows how much
Mithril the player has if (s)he right-clicks on the Kingdom Overwiev button.

Variables used:
v1-v6 (can be used in other scripts, but will be thrashed by this), v205(from week of monsters script)
z1-z9 (can be used in other scripts, but will be thrashed by this)
z805-z815

Flags:
1,9,10 (can be used in other scripts, but will be thrashed by this)
172, 410, 870-874

Timers:
TM99

Functions:
FU709, FU8170-FU8186

Sets up PO:N numbers at Mine, Water Wheel and Windmill entrance squares.

!#UN:P36/?y1;
!#UN&y1=1:B0/1;           (Enable Mithril)
!#IF&y1=1:V410/0;         (For Sorcery/Mithril)
!#TM99&y1=1:S1/999/1/255; (setup Mine Timer)
!#VRv550:C1/2/4/8/16/32/64/128/256/512; (Setup table of bit values)
!#VRz805&y1=1:S^升级的水车^;
!#VRz806&y1=1:S^升级的风车^;
!#HT109/-1&y1=1:P2/805;
!#HT112/-1&y1=1:P2/806;  (Setup Hint text)
!#VRz814&y1=1:S^升级的水车(已访问)^;
!#VRz815&y1=1:S^升级的风车(已访问)^;
!#IF&y1=1:V871/0;
!#HT109/-1&y1=1:P3/814;
!#HT112/-1&y1=1:P3/815;  (Setup Hint text)
!#IF&y1=1:V874/0;
!#IF&y1=0:V870/1;
!#IF&y1=0:V873/1;        (security measure)


*---Display Mithril on Rightclick on Kingdom Overview---*
!?CM;
!!IF:V10/0;   (Setup Flag 10)
!!UN:P36/?y1;
!!IF&y1=0:V10/1;  (Abort if script isn't active)
!!CM:I?y1; [Store right-click location in y1]
!!IF&y1<>3:V10/1;

!!OW&-10:C?y1; [Store number of current player in y1]
!!OW&-10:Ry1/7/?y2; [Store current player's Mithril in y2]
!!VRz-1:S^条^;
!!VRz-1&y2=1:S^条^;

[Check if current player is the one who's turn it is]
!!OW&-10:Gy1/?y3;

[Display current player's Mithril amount in a text box unless it's not this  player's turn]
!!IF&-10:V1/0; (Reset flag, used in price List)
!!IF&-10/y3=1:Q1/7/y2/2^{秘银}

%Y2%Z-1闪闪发亮的秘银。

你想不想知道你可以用它来干什么呢？^;

!!VRz5&-10/1:S^../data/zvs/lib1.res/mithril_price_list.gif^; [File and path name for Mithril Price List gif]
!!IF&-10/1:B1/5/0; [Set up dialogue box for displaying Mithril price list]
!!IF&-10/1:P1; [Display Mithril price list]

! !IF&-10/1:M^{秘银}
秘银可以增强冒险地图上大部分建筑。想要增强某个建筑，请右击该建筑的入口处。
对于矿山，城镇，生物巢穴，船坞等，你必须是该建筑的拥有者。
对于风车、女巫小屋、水车、传送门、学院等，右击时你必须有个英雄在其附近。
-升级野外巢穴，使其可招升级兵种： 1-3 秘银
-升级宝石，水晶，水银和硫磺矿，使其产量加倍（维持一周）： 1-7 秘银
-放置魔法地形以保护你的城镇：3或5 秘银
-升级风车或水车，使其产量加倍： 5 秘银
-随机转变一个魔法圣殿的魔法： 1-3 秘银
-随机转变女巫小屋的技能： 2 秘银
-在船坞边建一个灯塔： 3 秘银
-查看传送门可能通向何处： 3 秘银^;

!!CM&-10/y3=1:R0; [Disable standard right-click info. for Kingdom Overview button]

*---Display when Mithril is picked up---*
!?OB79/7;  [Mithril is trigger]
!!HE-1:B0/?z1; [Store hero's name in z1]

!!ARv998/v999/v1000:V?y1; [Store value of Mithril bars in v1]

!!OW:R-1/7/?y2; [Store current player's previous total Mithril in v2]
!!VRy2:+y1; [Add new Mithril to previous Mithril - store in v2]

!!VRz2&y2=1:S^^;
!!VRz2&y2>1:S^^;
!!VRz3&y1=1:S^^;
!!VRz3&y1>1:S^^;
!!VRz4:S^%Y1^;
!!UN:P3/?y3;
!!VRz4&y1=1/y3=1:S^一^; (setup varius strings for use depening if one or more than one bar of Mithril)

[Display amount of Mithril picked up and total amount owned]
!!IF&-410/1000:Q1/7/y1/1^{秘银}

%Z1捡起%Z4%Z3闪闪发亮的秘银。

{你现在总共有%Y2条秘银。}

(右击王国概况按钮，你可随时查看你所拥有的秘银概况。)^;
!!IF:V410/0;

*---Adventure map Objects---*
!?CM;
!!IF:V10/0;                (General abort)
!!IF:V9/0;                 (special abort)
!!IF&-1000:V10/1;          (check if it's AI)
!!UN:P36/?y1;
!!IF&y1=0:V10/1;           (Abort if script is deactived)
!!CM:I?y1;
!!IF&y1<>37:V10/1;         (Check if clicked on Adventure Map)
!!CM&-10:P?v4/?v5/?v6;     (Get location)
!!TRv4/v5/v6&-10:E?y20;
!!IF&-10/y20=1:V10/1;      (check if entrance)

!!OBv4/v5/v6&-10:T?v1;     (get type of object)
!!OBv4/v5/v6&-10:U?v2;     (Get Subtype)

!!IF&-10/v1<>43/v1<>45/v1<>88/v1<>89/v1<>90/v1<>109/v1<>112/v1<>113:V9/1;  (Don't do checks if not Monolith entrance, Shrine, Windmill, Water Wheel or Witch Hut)
!!OBv4/v5/v6&-9/-10:C?y32; (get control word of object)
!!VRy31&-9/-10:Sy32;       (copy to y31 for checking later)
!!OW&-9/-10:C?y30;         (get current player)
!!VRy30&-9/-10:+550;
!!VRy30&-9/-10:Svy30;
!!VRy30&-9/-10:*32;        (Set to bit value for checking Control Word)
!!VRy32&-9/-10:|y30;       (Try to or with current player's bit)
!!IF&-9/-10/y32<>y31:V9/1; (Check if not same, then abort)
!!IF|v1=43/v1=45/v1=109/v1=112:V9/0;   (Override above if Monolith, Water Wheel or Windmill)

!!OW&-10/-9:A-1/?y21;         (Check which hero is selected)
!!IF&-10/y21=-1:V9/1;      (special abort if no hero selected)
!!HEy21&-9/-10:P?y4/?y5/?y6;(Get Hero Location- for Shrine or Witch Hut)

!!IF&-9/-10/y6<>v6:V9/1; (check if on same level)
!!VRy10&-9/-10:Sv4;
!!VRy10&-9/-10:-1;
!!VRy11&-9/-10:Sv4;
!!VRy11&-9/-10:+1;
!!VRy13&-9/-10:Sv5;
!!VRy13&-9/-10:+1;
!!IF&-9/-10/y4<>v4/y4<>y10/y4<>y11:V9/1;
!!IF&-9/-10/y5<>v5/y5<>y13:V9/1; (check if location is within range)

!!IF&-10:V3/0;
!!FU8170&-10/v1=17:P;         (Normal Creature Generator)
!!FU8171&-10/v1=20/v2=00:P;   (Conflux dwelling)
!!FU8185&-9/-10/v1=43:P1/y21;
!!FU8185&-9/-10/v1=45:P2/y21; (Monolith(with instruction on which type and what hero))
!!FU8172&-10/v1=53:P;         (Mine)
!!FU8183&-10/v1=87:P;         (Shipyard)
!!FU8173&-9/-10/v1=88:P;      (Shrine level 1)
!!FU8174&-9/-10/v1=89:P;      (Shrine level 2)
!!FU8175&-9/-10/v1=90/v2=0:P; (Shrine level 3)
!!FU709&-10/v1=98:P4;         (check for "Heroes Create Magic Plains each day" rule)
!!FU8176&-3/-10/v1=98:P;      (Town)
!!FU8181&-9/-10/v1=109:P;     (Water Wheel)
!!FU8182&-9/-10/v1=112:P;     (Windmill)
!!FU8177&-9/-10/v1=113:P;     (Witch Hut)

*---Upgrade Dwelling---*
!?FU8170;
!!DWv4/v5/v6:O?y1; (check who owns dwelling)
!!OW:C?y2;         (check current player)
!!IF&y1<>y2:V10/1; (abort if not same)
!!DWv4/v5/v6&-10:M0/?y2/?y3;
!!VRy4&-10/y2<111:Sy2;
!!VRy4&-10/y2<111:%2;
!!IF&-10/y4=1/y2<111:V10/1; (Divide Monster Number with 2 to see if it's already is upgraded)
!!VRy6&-10/y2<111:Sy2;
!!VRy6&-10/y2<111::2;
!!VRy6&-10/y2<111:+1;
!!VRy6&-10/y2<111:%7;    (y6 is now monster level)
!!VRy6&-10/y2<111/y6<4/y6>0:S1;
!!VRy6&-10/y2<111/y6>3:S2;
!!VRy6&-10/y2<111/y6=0:S3;  (y6 is now cost)

!!VRy6&-10/y2=118:S1;
!!VRy6&-10/y2=112:S1;
!!VRy6&-10/y2=113:S2;
!!VRy6&-10/y2=114:S2;
!!VRy6&-10/y2=115:S1;
!!VRy6&-10/y2=120:S2;
!!VRy6&-10/y2=130:S3;
!!VRy8:S-1;
!!VRy8&-10/y2=118:S119;
!!VRy8&-10/y2=112:S127;
!!VRy8&-10/y2=113:S125;
!!VRy8&-10/y2=114:S129;
!!VRy8&-10/y2=115:S123;
!!VRy8&-10/y2=120:S121;
!!VRy8&-10/y2=130:S131;          (Special table for Conflux)

!!IF|y2=116/y2=117/y2>130:V10/1; (abort if non-upgradeable creature)
!!OW&-10:R-1/7/?y7;              (get amount of mithril)
!!IF&-10/y7<y6:V10/1;            (check if has enough mithril)
!!VRy8&-10/y2<111:Sy2;
!!VRy8&-10/y2<111:+1;
!!IF&y8=-1:V10/1;                (abort if no creature selected)
!!UN&-10:N3/z1/y8/1;             (Get new creature name- plural)
!!UN&-10:N3/z2/y2/1;             (Get old creature name- plural)
!!UN&-10:N3/z3/y2/0;             (Get old creature name- singular)
!!CM&-10:R0;                     (disable standard popup)

!!IF:V1/0;                       (To be sure)
!!IF&-10/y6>1:Q1/7/y6/2^{%Z3巢穴}

在这个巢穴里训练年轻的%Z2的老师声称，他们可改为训练%Z1，但前提是他们需要%Y6条秘银来制作新的教具。

你有%Y7条秘银。

你想如教师所愿，给他们%Y6条秘银吗？^;

!!IF&-10/y6=1:Q1/7/y6/2^{%Z3巢穴}

在这个巢穴里训练年轻的%Z2的老师声称，他们可改为训练%Z1，但前提是他们需要1条秘银来制作新的教具。

你有%Y7条秘银。

你想如教师所愿，给他们1条秘银吗？^;

!!IF&-1:V10/1;
!!VRy6&-10:*-1;
!!OW&-10:R-1/7/dy6;               (take Mithril)
!!DWv4/v5/v6&-10/y2<111:M0/d1/y3; (Upgrade dwelling if non-conflux)
!!DWv4/v5/v6&-10/y2>110:M0/y8/y3; (Upgrade dwelling if conflux)

!?FU8171;
!!DWv4/v5/v6:O?y1;   (check who owns dwelling)
!!OW:C?y2;           (check current player)
!!IF&y1<>y2:V10/1;   (abort if not same)
!!OW&-10:R-1/7/?y7;  (get amount of mithril)
!!IF&-10/y7<4:V10/1; (check if has enough mithril)
!!DWv4/v5/v6&-10:M0/?y1/d0;
!!IF&y1<>112/-10:V10/1;(abort oif not Air elementals in first slot)
!!CM&-10:R0;         (disable standard popup)
!!IF&-10:Q1/7/4/2^{元素汇流}

在这个元素汇流里培训年轻的风，水，火，土元素的老师声称，他们可改为培训雷，冰，烈火，岩石元素。但前提是他们需要4条秘银来制作新的教具。

你有%Y7条秘银。

你想如教师所愿，给他们4条秘银吗？^;
!!IF&-1/-10:V10/1;
!!OW&-10:R-1/7/d-4;        (take Mithril)
!!DWv4/v5/v6&-10:M0/127/d0;
!!DWv4/v5/v6&-10:M1/123/d0;
!!DWv4/v5/v6&-10:M2/129/d0;
!!DWv4/v5/v6&-10:M3/125/d0;(Upgrade dwelling)

*---Upgrade Mine---*
!?FU8172;
!!FU709&-10:P12;          (check for "Mines change Resource every week" rule)
!!IF&3:V10/1;
!!FU8184&-3/-874:P;       (Setup hint text)
!!MNv4/v5/v6:O?y1;        (check who owns Mine)
!!OW:C?y2;                (check current player)
!!IF&y1<>y2:V10/1;        (abort if not same)
!!POv4/v5/v6&-10:N?y3;
!!IF&-10/y3<>0:V10/1;     (see if mine has been upgraded earlier)
!!IF&-10:V3/0;
!!MNv4/v5/v6&-10:R?y4;    (Get resource produced)
!!VRy5&-10:S5;            (Set base Cost)
!!VRy5&-10/y4<>1/y4<3:S3; (Set cost for ore/wood)
!!VRy5&-10/y4=6:S7;       (Set Cost for Gold Mine)
!!OW&-10:R-1/7/?y7;       (get amont of mithril)
!!IF&-10/y7<y5:V10/1;     (check if has enough mithril)
!!IF&-10:V1/0;
!!CM&-10:R0;              (disable standard popup)
!!IF&-10/y4=0:Q1/7/3/2^{锯木厂}

锯木厂的工人声称，如果向锯木之神献祭3条秘银，他们就能一周内生产出双倍的木材。

你有%Y7条秘银。

你想如工人们所愿，给他们3条秘银吗？^;

!!IF&-10/y4=1:Q1/7/5/2^{提炼室}
这个提炼室的炼金术士听说你拥有一些秘银，便声称提炼水银的过程可添加秘银，如果他能得到5条秘银，他可使一周的水银产量加倍。

你有%Y7条秘银。

你想如炼金术士所愿，给他5条秘银吗？^;

!!IF&-10/y4=2:Q1/7/3/2^{矿石坑}

矿石坑里的矿工声称，如果混些秘银（3条足够了）在他们的矿产里，他们就能骗那些猎宝者进入矿坑免费干活，这样矿石产量整周都会提高一倍。

你有%Y7条秘银。

你想如矿工所愿，给他们3条秘银吗？^;

!!IF&-10/y4=3:Q1/7/5/2^{硫磺沙丘}

小怪物喜欢有臭味的硫磺就象喜欢神奇的秘银一样，它们喜欢在硫磺沙丘玩耍。可是它们喜欢作恶作剧骚扰工人以致硫磺的产能减半。小怪物比那讨厌的蟑螂还难除去，但可以用5条秘银贿赂它们，请它们离开硫磺沙丘一周。

你有%Y7条秘银。

你想如小怪物所愿，给它们5条秘银吗？^;

!!IF&-10/y4=4:Q1/7/5/2^{水晶石窟}

这个水晶石窟的矿工懂得如何用那些无用的水晶碎片合并成一块大水晶，从而令水晶产量加倍。5条秘银就足够他们使用一整周。

你有%Y7条秘银。

你想如矿工所愿，给他们5条秘银吗？^;

!!IF&-10/y4=5:Q1/7/5/2^{宝石池塘}

这个宝石池塘的采珠者声称，为了产量加倍，他们可以用秘银诱捕一些水精灵做帮工。5条秘银便可以诱捕水精灵一整周。

你有%Y7条秘银。

你想如采珠者所愿，给他们5条秘银吗？^;

!!IF&-10/y4=6:Q1/7/7/2^{金矿}

一群矮人带着一台大如河马的奇异装置聚集在你的金矿外。他们请求你给7条秘银作为这台奇异装置的动力，并声称这样他们能令金矿产量加倍一整周。

你有%Y7条秘银。

你想如矮人所愿，给他们7条秘银吗？^;

!!IF&-1/-10:V10/1;
!!VRy5&-10:*-1;      (set amount to negative)
!!OW&-10:R-1/7/dy5;  (take mithril)
!!POv4/v5/v6&-10:N7; (set flag so mine is upgraded)
!!IF:V10/1;

*---Special if Mines change resources every week is in effect---*
!!FU709:P12;              (check for "Mines change Resource every week" rule)
!!IF&3:V10/0;
!!MNv4/v5/v6&-10:O?y1;    (check who owns Mine)
!!OW&-10:C?y2;            (check current player)
!!IF&y1<>y2/-10:V10/1;    (abort if not same)
!!POv4/v5/v6&-10:N?y3;
!!IF&-10/y3<>9:V10/1;     (see if mine has been upgraded earlier)
!!MNv4/v5/v6&-10:R?y4/1;  (Get resource produced)
!!VRy5&-10:S3;            (Set base Cost)
!!VRy5&-10/y4<>1/y4<3:S1; (Set cost for ore/wood)
!!VRy5&-10/y4=6:S5;       (Set Cost for Gold Mine)
!!OW&-10:R-1/7/?y7;       (get amount of mithril)
!!IF&-10/y7<y5:V10/1;     (check if has enough mithril)
!!VRz1&-10/y4=0:S^锯木厂^;
!!VRz1&-10/y4=1:S^提炼室^;
!!VRz1&-10/y4=2:S^矿石坑^;
!!VRz1&-10/y4=3:S^硫磺沙丘^;
!!VRz1&-10/y4=4:S^水晶石窟^;
!!VRz1&-10/y4=5:S^宝石池塘^;
!!VRz1&-10/y4=6:S^金矿^;
!!CM&-10:R0;              (disable standard popup)
!!IF&-10:Q1/7/y5/2^{%Z1}

（当设置每周矿随机改变时）你可以花费%Y5条秘银保护%Z1一周内不被改变。

你有%Y7条秘银。

你想进行保护吗？^;
!!IF&-1:V10/1;
!!VRy5&-10:*-1;
!!OW&-10:R-1/7/dy5;   (take mithril)
!!POv4/v5/v6&-10:Ny4; (set flag so mine is protected)
!!IF:V10/0;

*---Mine produce Extra, AI gets gold & Replace resource piles and campfires with Mithril---*
!?TM99;
!!IF:V9/0;
!!IF:V10/0;
!!UN:P36/?y1;
!!IF&y1=0:V10/1;           (Abort if script is deactived)
!!VRy1&870/-10:S1;
!!VRy1&870/-10:R7;           (Draw random number to see what pile to start with)
!!UN&870/-10:U79/-1/?v1;     (Get number of resource piles on map(for replacing with Mithril))
!!DO8179/y1/v1/1&870/-10:P; (Cycle through all resource piles, replace one in ten)

*---Campfires---*
!!IF:V9/1;
!!VRy1&870/-10:S1;
!!VRy1&870/-10:R7;          (Draw random number to see what fire to start with)
!!UN&870/-10:U12/-1/?v1;    (Get number of campfires on map(for replacing with Mithril))
!!DO8179/y1/v1/1&870/-10:P;(Cycle through all Campfires, replace one in ten)

!!IF:V870/0;            (set Flag to indicate that Mithril has been added)
!!IF:V9/0;

*---AI Gets Gold---*
!!OW&-1000/-10:R-1/7/?y7; (get amount of mithril if AI)
!!VRy7&-1000/-10:*100;
!!OW&-1000/-10:R-1/6/dy7; (Give mithril*100 in gold to AI)

*---Mines---*
!!FU709&-10:P12;       (check for "Mines change Resource every week" rule)
!!VRy20&-10:Sc0;
!!VRy20&-10:%7;        (get day of week)

!!IF:V9/0;
!!IF&-10/y20=2:V872/0; (If day 2 of week, reset flag)
!!IF&-10/3/872:V9/1;
!!IF&-10/3/y20<>1:V9/1;  (Don't do anything about mines if it already have been done or it's not day 1 of the week)
!!UN&-10:U53/-1/?v5;   (Get number of Mines on the map)
!!DO8178/1/v5/1&-10/v5>0/-9:P; (Cycle through all mines)
!!IF&3:V871/1;   (set that mines have been set up if mines rule is in effect- at map start)
!!IF:V9/0;

!!VRy20&-10:Sc0;
!!VRy20&-10:%7;      (get day of week)
!!IF&-10/y20=1:V9/1; (Check for Windmills, Mystical Gardens and Water Weels, so they only work on day one of the week and if it hasn't been done earlier)

*---Mystical Gardens---*
!!UN&-10:U55/-1/?v5;                (Get number of Mystical Gardens on the map)
!!DO8180/1/v5/1&-10/9/-872/873/v5>0:P55;(Cycle through all Gardens)

*---Water Weels---*
!!UN&-10:U109/-1/?v5;                (Get number of Water Weels on the map)
!!DO8180/1/v5/1&-10/9/-872/v5>0:P109;(Cycle through all Weels)

*---Windmills---*
!!UN&-10:U112/-1/?v5;                (Get number of Windmills on the map)
!!DO8180/1/v5/1&-10/9/-872/v5>0:P112;(Cycle through all Windmills)
!!VRy20&-10:Sc0;
!!VRy20&-10:%7;        (get day of week)
!!IF&y20=1:V872/1;   (set that mines have been set up if mines rule is in effect- every week)
!!IF:V9/0;

!?FU8180;                    (Mystical Gardens, Water Weels and Windmills)
!!IF:V1/0;
!!UN:Ux1/-1/x16/1;           (get location in v1, v2 and v3)
!!VRy2:S0;
!!VRy2:R9;                   (Random number to see if to replace normal resource)
!!GD1&x1=55:B?y7;            (Get if it is gold or resource)
!!GD1&x1=55/y7=7:B5;         (resource is normally Gems)
!!GD1&x1=55/873/y2=9:B7;
!!GD1&x1=55/873/y2=9:T1;     (In one in ten, resource is Mithril)
!!POv1/v2/v3:N?y1;           (Get PO number at position)
!!IF&y1<>2/y1<>3:V1/1;       (abort if wrong number)
!!POv1/v2/v3&y1=3:N2;        (reset hint text)
!!ML1&x1=112/873/y2=9:B7/d0; (One in ten contains Mithril)
!!ML1&-1/x1=112:Bd0/?y3;     (Get number produced)
!!ML1&-1/x1=112:Bd0/dy3;     (Windmill now contains new value)
!!WM1&-1/x1=109:B?y3;        (Get Gold value in Water Wheel)
!!WM1&-1/x1=109:Bdy3;        (Water Wheel now contains new value)

!?FU8178;
!!IF:V1/0;
!!FU709:P12;            (check for "Mines change Resource every week" rule)
!!IF&3:V1/1;
!!UN:U53/-1/x16/1;      (Get location of mine)
!!MNv1/v2/v3:R?y1/1;    (Get resource produced)
!!OBv1/v2/v3:U?y17;     (get Type of mine(only for abandoned/not abandoned))
!!IF&y17=7:V1/1;        (abort if abandoned mine)
!!MNv1/v2/v3&-1:O?y5/1; (get owner of mine without redrawing)
!!OW:C?y20;             (Get Current Player)
!!IF&-1/y5<>y20:V1/1;   (abort if not current player)
!!POv1/v2/v3&-1:N?y6;   (get custom number)
!!IF&-1/y6=0:V1/1;      (abort if set to 0)
!!VRy7&-1:S1;
!!VRy7&-1/y1=0:S2;
!!VRy7&-1/y1=2:S2;
!!VRy7&-1/y1=6:S1000;
!!VRy8&-1/v205>173:Sv205;
!!VRy8&-1/v205>173:-174;    (If resource week, get what resource)
!!VRy7&-1/v205>173/y1=y8:*2;(double resource if resource week)
!!OW&-1:R-1/y1/dy7;
!!POv1/v2/v3&-1:Nd-1;       (set custom number to one less)
!!IF:V1/1;

*---Special if mine change resource every week---*
!!FU709:P12;            (check for "Mines change Resource every week" rule)
!!IF&3:V1/0;

!!POv1/v2/v3&-1/-871:N9;        (Set that mine is not upgraded if it's Day 1)
!!POv1/v2/v3&-1:N?y21;          (Get custom number)
!!POv1/v2/v3&-1/y21=8:N9;       (set custom number if mine stayed last week)
!!MNv1/v2/v3&-9/-1/y21<8:Ry21/1;(Set resource produced)
!!POv1/v2/v3&-1/y21<8:N8;       (Set Custom Number if mine stays)

*---Upgrade Shrines---*
!?FU8173;
!!SRv4/v5/v6:S?y1;   (Get Spell Number)
!!OW&-10:R-1/7/?y2;  (Get amount of mithril)
!!IF&-10/y2<1:V10/1; (check if has enough mithril)
!!UN&-10:N1/z1/y1;   (get Spell name)
!!CM&-10:R0;         (disable standard popup)
!!IF&-10:Q1/7/1/2^        {初级魔法圣殿}

这个魔法圣殿的侍僧抱怨说，他们已经厌倦向经过这里的每位英雄传授%Z1了，但如果他们能有1条秘银献祭给他们的神，他们便有幸获得一个新魔法来替代现时所教的那个魔法。

你有%Y2条秘银。

你想捐赠1条秘银给侍僧吗？^;
!!IF&-1/-10:V10/1;
!!OW&-10:R-1/7/d-1; (Take Mithril)

!!VRy4&-10/y1=3:S1;
!!VRy4&-10/y1=5:S2;
!!VRy4&-10/y1=15:S3;
!!VRy4&-10/y1=27:S4;
!!VRy4&-10/y1=31:S5;
!!VRy4&-10/y1=32:S6;
!!VRy4&-10/y1=35:S7;
!!VRy4&-10/y1=37:S8;
!!VRy4&-10/y1=41:S9;
!!VRy4&-10/y1=42:S10;
!!VRy4&-10/y1=43:S11;
!!VRy4&-10/y1=46:S12;
!!VRy4&-10/y1=53:S13;
!!VRy4&-10/y1=54:S14;
!!VRy3&-10:S0;
!!UN&-10:P147/?y8;
!!VRy7&-10:S0;
!!UN&-10/y8=1:P152/?y7;
!!VRy3&-10:T13;
!!VRy3&-10/y7=1:S1;
!!VRy3&-10/y7=1:T12;  (if summon boat is disabled)
!!VRy3&y3=>y4:+1; (Draw random spell that's not the same as before)

!!VRy4&-10/y3=1:S3;
!!VRy4&-10/y3=2:S5;
!!VRy4&-10/y3=3:S15;
!!VRy4&-10/y3=4:S27;
!!VRy4&-10/y3=5:S31;
!!VRy4&-10/y3=6:S32;
!!VRy4&-10/y3=7:S35;
!!VRy4&-10/y3=8:S37;
!!VRy4&-10/y3=9:S41;
!!VRy4&-10/y3=10:S42;
!!VRy4&-10/y3=11:S43;
!!VRy4&-10/y3=12:S46;
!!VRy4&-10/y3=13:S53;
!!VRy4&-10/y3=14:S54; (y4 now contains Random Spells number)
!!SRv4/v5/v6&-10:Sy4; (Setup new Spell)
!!IF:V10/0;

!?FU8174;
!!SRv4/v5/v6:S?y1;   (Get Spell Number)
!!OW&-10:R-1/7/?y2;  (Get amount of mithril)
!!IF&-10/y2<2:V10/1; (check if has enough mithril)
!!UN&-10:N1/z1/y1;   (get Spell name)
!!CM&-10:R0;         (disable standard popup)
!!IF&-10:Q1/7/2/2^{中级魔法圣殿}

这个魔法圣殿的胖僧侣抱怨说，他们已经厌倦向经过这里的每位英雄传授%Z1了，但如果他们能有2条秘银献祭给他们的神，他们便有幸获得一个新魔法来替代现时所教的那个魔法。

你有%Y2条秘银。

你想捐赠2条秘银给僧侣吗？^;
!!IF&-1/-10:V10/1;
!!OW&-10:R-1/7/d-2; (Take Mithril)
!!VRy4&-10/y1=1:S0;
!!VRy4&-10/y1=2:S1;
!!VRy4&-10/y1=4:S2;
!!VRy4&-10/y1=10:S3;
!!VRy4&-10/y1=13:S4;
!!VRy4&-10/y1=16:S5;
!!VRy4&-10/y1=17:S6;
!!VRy4&-10/y1=24:S7;
!!VRy4&-10/y1=30:S8;
!!VRy4&-10/y1=44:S9;
!!VRy4&-10/y1=45:S10;
!!VRy4&-10/y1=47:S11;
!!VRy4&-10/y1=51:S12;
!!VRy4&-10/y1=62:S13;
!!VRy4&-10/y1=64:S14;
!!VRy3&-10:S0;
!!VRy3&-10:T13;
!!VRy3&y3=>y4:+1; (Draw random spell that's not the same as before)

!!VRy4&-10/y3=0:S1;
!!VRy4&-10/y3=1:S2;
!!VRy4&-10/y3=2:S4;
!!VRy4&-10/y3=3:S10;
!!VRy4&-10/y3=4:S13;
!!VRy4&-10/y3=5:S16;
!!VRy4&-10/y3=6:S17;
!!VRy4&-10/y3=7:S24;
!!VRy4&-10/y3=8:S30;
!!VRy4&-10/y3=9:S44;
!!VRy4&-10/y3=10:S45;
!!VRy4&-10/y3=11:S47;
!!VRy4&-10/y3=12:S51;
!!VRy4&-10/y3=13:S62;
!!VRy4&-10/y3=14:S64; (y4 now contains Random Spells number)
!!SRv4/v5/v6&-10:Sy4; (Setup new Spell)
!!IF:V10/0;

!?FU8175;
!!SRv4/v5/v6:S?y1;   (Get Spell Number)
!!OW:R-1/7/?y2;      (Get amount of mithril)
!!IF&-10/y2<3:V10/1; (check if has enough mithril)
!!UN&-10:N1/z1/y1;   (get Spell name)
!!CM&-10:R0;         (disable standard popup)
!!IF&-10:Q1/7/3/2^{高级魔法圣殿}

这个魔法圣殿的高级牧师抱怨说，他们已经厌倦向经过这里的每位英雄传授%Z1了，但如果他们能有3条秘银献祭给他们的神，他们便有幸获得一个新魔法来替代现时所教的那个魔法。

你有%Y2条秘银。

你想捐赠3条秘银给牧师吗？^;

!!IF&-1/-10:V10/1;
!!OW&-10:R-1/7/d-3; (Take Mithril)
!!VRy4&-10/y1=11:S0;
!!VRy4&-10/y1=12:S1;
!!VRy4&-10/y1=14:S2;
!!VRy4&-10/y1=20:S3;
!!VRy4&-10/y1=21:S4;
!!VRy4&-10/y1=25:S5;
!!VRy4&-10/y1=28:S6;
!!VRy4&-10/y1=33:S7;
!!VRy4&-10/y1=34:S8;
!!VRy4&-10/y1=39:S9;
!!VRy4&-10/y1=49:S10;
!!VRy4&-10/y1=52:S11;
!!VRy4&-10/y1=60:S12;
!!VRy4&-10/y1=61:S13;
!!VRy4&-10/y1=63:S14;
!!VRy3&-10:S0;
!!VRy3&-10:T13;
!!VRy3&y3=>y4:+1; (Draw random spell that's not the same as before)

!!VRy4&-10/y3=0:S11;
!!VRy4&-10/y3=1:S12;
!!VRy4&-10/y3=2:S14;
!!VRy4&-10/y3=3:S20;
!!VRy4&-10/y3=4:S21;
!!VRy4&-10/y3=5:S25;
!!VRy4&-10/y3=6:S28;
!!VRy4&-10/y3=7:S33;
!!VRy4&-10/y3=8:S34;
!!VRy4&-10/y3=9:S39;
!!VRy4&-10/y3=10:S49;
!!VRy4&-10/y3=11:S52;
!!VRy4&-10/y3=12:S60;
!!VRy4&-10/y3=13:S61;
!!VRy4&-10/y3=14:S63; (y4 now contains Random Spells number)
!!SRv4/v5/v6&-10:Sy4; (Setup new Spell)
!!IF:V10/0;

*---Castles---*
!?FU8176;
!!IF:V10/0;
!!CAv4/v5/v6:O?y1;    (Check owner of castle)
!!OW:C?y2;            (check current player)
!!IF&y1<>y2:V10/1;
!!OW-10:R-1/7/?y2;    (Get amount of mithril)
!!IF&-10:V9/0;        (Special for Magic Plains and Cursed Ground)
!!IF&-10/y2<1:V10/1;
!!IF&-10/y2<3:V9/1;
!!CAv4/v5/v6&-10:N?z1;(Get Town Name)
!!CM&-10:R0;          (disable standard popup)
!!IF&-9/-10:Q1^%Z1的市长声称他认识一个花费少量秘银就能用各种途径提高城镇防御的强力巫师，花费1条秘银，巫师能把%Z1变成以下一种地形：圣地，草地，邪恶之雾，燃烧之地，小溪，魔法云雾，岩石地带。花费3条秘银，巫师能把%Z1变成魔法平原或被诅咒的大地。

你有%Y2%Z-5秘银。

你想雇用这个巫师吗？^;

!!IF&9/-10:Q1/7/3/2^%Z1的市长声称他认识一个花费少量秘银就能用各种途径提高城镇防御的强力巫师，花费1条秘银，巫师能把%Z1变成以下一种地形：圣地，草地，邪恶之雾，燃烧之地，小溪，魔法云雾，岩石地带。

你有%Y2%Z-5秘银。

你想雇用这个巫师吗？^;

!!IF&-1/-10:V10/1;
!!VRz1&-10:S^圣地  (花费 1 秘银)^;
!!VRz2&-10:S^草地  (花费 1 秘银)^;
!!VRz3&-10:S^邪恶之雾  (花费 1 秘银)^;
!!VRz4&-10:S^燃烧之地  (花费 1 秘银)^;
!!VRz5&-10:S^小溪  (花费 1 秘银)^;
!!VRz6&-10:S^魔法云雾  (花费 1 秘银)^;
!!VRz7&-10:S^岩石地带  (花费 1 秘银)^;
!!VRz8&-9/-10:S^魔法平原  (花费 3 秘银)^;
!!VRz9&-9/-10:S^受诅之地  (花费 3 秘银)^;  (setup z variables)
!!VRz-1&-10:S^指定你要制造的特殊地形：^;
!!IF&-9/-10:G1/1/0/-1/z1/z2/z3/z4/z5/z6/z7/z8/z9/0/0/0;
!!IF&9/-10:G1/1/0/-1/z1/z2/z3/z4/z5/z6/z7/0/0/0/0/0;
!!OW&-10/v1<65:R-1/7/d-1;
!!OW&-10/v1>64:R-1/7/d-3; (take Mithril)
!!VRy5&-10/v1=1:S227;
!!VRy5&-10/v1=2:S222;
!!VRy5&-10/v1=4:S224;
!!VRy5&-10/v1=8:S226;
!!VRy5&-10/v1=16:S228;
!!VRy5&-10/v1=32:S229;
!!VRy5&-10/v1=64:S231;
!!VRy5&-10/v1=128:S230;
!!VRy5&-10/v1=256:S223; (set y5 to type of magic terrain)
!!VRy3&-10:Sv4;
!!VRy4&-10:Sv5;
!!VRy4&-10/v1<>256:+2; (setup were to place terrain)
!!VRy3&-10/v1=256:+2;
!!VRy4&-10/v1=256:+1;  (Special for Cursed Ground)
!!UN&-10:Iy3/y4/v6/y5/0/y5/0/-1/0; (Place terrain)
!!VRy3&-10/v1<>256:+1;
!!UN&-10/v1<>256:Iy3/y4/v6/y5/0/y5/0/-1/0; (Place second patch(unless Cursed Ground))

!?FU8177;              (Witch Hut)
!!OW:R-1/7/?y2;        (Get amount of mithril)
!!IF&y2<2:V10/1;       (Check if enough Mithril)
!!WHv4/v5/v6&-10:S?y1; (Get skill)
!!UN&-10:N4/z1/y1;     (Get skill name)
!!CM&-10:R0;           (disable standard popup)
!!IF&-10:Q1/7/2/2^{女巫小屋}

生活在这个小屋里的老女巫告诉你，自她懂事起就在这里传授%Z1，现在她觉得很厌烦了。她有方法学习其它的技能，但需要2条秘银。你很聪明地没有追问她要秘银干什么。

你有%Y2条秘银。

你想如女巫所愿，给她2条秘银吗？^;
!!IF&-1/-10:V10/1;
!!OW&-10:R-1/7/d-2;   (Take Mithril)
!!VRy2:S0;            (Set to 0)
!!VRy2&-10:T26;
!!VRy2&-10/y2=>y1:+1; (Draw random skill)
!!WHv4/v5/v6&-10:Sy2; (Set skill)

!?FU8181;            (Water Wheel)
!!IF:V10/0;
!!POv4/v5/v6:N?y1;   (Get PO number)
!!IF|y1=2/y1=3:V10/1;(Abort if Upgraded earlier)
!!OW&-10:R-1/7/?y2;  (Get amount of mithril)
!!IF&-10/y2<5:V10/1; (Check if enough)

希望大家能捧个场。谢了。

[ 本帖最后由 暗黑龙守护神 于 2009-6-23 11:57 编辑 ]

szx_9933

好ＤＤ啊

黄花菜

这个俺喜欢 入来支援

songfx

大[wiki]神[/wiki]又复活了
呃
我是说大神又恢复活力了

暗黑龙守护神

呵呵。电脑刚修好嘛。
说修不太恰当。因为主板都换了

噬魂恶魔

那能帮忙解决关卡的毛病吗？

szx_9933

下了，谢谢。

老虎

六位数的秘银……
第一次看到。

szx_9933

开了2个一样的帖？

暗黑龙守护神

不一样，一个是秘银，一个是追

szx_9933

看错了！

szx_9933

楼主还有别的什么地图事件脚本能共享给我们吗？

szx_9933

楼主，这个脚本不能升级船坞和风车啊，右击和CTRL+左键都试过了，不行啊。