【已解决】new upgrade八级工会的ers如何设置以及与wog53的生物扩展的关系如何？

独孤求败

我自己摸索了一下，不过连ers都不会设置，无法进入测试ert和erm。
1、原new upgrade的补丁脚本，在era2.46中不知道如何使用ers了，迷茫中，请fly123版主指点迷津。
2、现提供的wog53号中，8级生物不在高山堡垒升级，只在城镇或巢穴升级。要求改为只有在打开扩展生物升级选项并且建造8级生物工会才能在城镇中7级升8级，另外的生物随处升级选项和7级自动变8级不与8级生物工会有关系。

————————————————————————————————————
经过一个礼拜的探索无果，经贤知有你大人的指点（本以为这个erm和他的城镇第八招募的mod有重复用处，贤知不会出手指点，谁知他很慷慨……）现明白生物关联自定义的玩法。
1、wog53中，扩展生物升级是通过高山堡垒和城镇巢穴实现的。在这可以自定义生物关联升级。我把访问高山堡垒的7级to8级屏蔽，引申出89号erm的八级生物工会的建设。把英雄界面调用的高山堡垒7级to 8级屏蔽引申出82号erm。
2、89erm是原来的new upgrade里面的八级生物工会的部分，其他的冲突太多，我不要了。我把p555改为p173（同用生物扩展升级一个选项），同时把两个脚本重复的生物关联删除。上传的是erm和ert，同一个位置的还有一个p的文件夹里面有一个声音和9张种族图片未上传。
3、82erm是英雄界面的部队处点击Shi+左键、Alt+左键、Ctrl+左键的玩法，其中Shift+左键就时调用高山堡垒。

独孤求败

我这个都没有得到版主的指点，好可怜啊！是不是版主变懒了……
看贤知的第八招募mod，不是以erm额形式出现，还没有原来的newupgrade方便。想想wog都十几年了，而在城镇里面建造八级生物建筑居然不能实现，真是令人心寒！！

贤知有您

我也不知道楼主在纠结些什么.
实际上ERA下都基本抛弃了ERS文件了.
fly123版主这段时间都忙其他了.

建议使用ERA版本的NEW UPGRADE,直接加载MOD就可以了.
新生物升级2.0（ERA版）（2013-07-18更新）
http://bbs.h3wog.com/forum.php?mod=viewthread&tid=40871

独孤求败

我就是下载了这个mod，可是发现里面的内容太多，我只想要八级建筑这一项，就把它拿出来，可是ers选项无法打开。

贤知有您

ERS主要是用于ERM菜单选项的设置.
你只要把关于 UN:P 这类涉及到选项的东西屏蔽掉,就不用管ERS了,脚本就能运行.

比如,这个MOD的ERS设置了555这个选项.
因此只要在脚本最上端加个
!#UN:P555/1;
无论选项怎么选择,无论选项有否启用,照样运行脚本.

独孤求败

贤知有您 发表于 2015-10-10 17:43
ERS主要是用于ERM菜单选项的设置.
你只要把关于 UN:P 这类涉及到选项的东西屏蔽掉,就不用管ERS了,脚本就能 ...

就是啊，我看了一个下午，我开始的时候把p555改成p173或p0，它马上就生效了。现在我在想怎么建立自己心目中的生物关联……

独孤求败

贤知有您 发表于 2015-10-10 17:43
ERS主要是用于ERM菜单选项的设置.
你只要把关于 UN:P 这类涉及到选项的东西屏蔽掉,就不用管ERS了,脚本就能 ...

下面这节对wog53中的修改，能够实现只有在城镇中建造八级建筑或者野外八级巢穴中从7级升级至8级，而不能在高山堡垒中升级吗？请贤知大人指点。

********************************************************************************
   Extended Creature Upgrades    扩展生物升级系统
********************************************************************************

[Set extra upgrades for Hill Forts or with Universal Creature Upgrades active]    在高山堡垒或者随处生物升级中增加

!#UN:P173/?v1; [Check if Extended Creature Upgrades is enabled: v1=1 if Yes]    如果扩展生物升级系统打开 那么七级升级八级打开
!#MA&v1=1:U13/150; [Archangels to Supreme Archangels] *Castle Level 8*  至高大天使
!#MA&v1=1:U27/151; [Gold Dragons to Diamond Dragons] *Rampart Level 8*  钻石龙
!#MA&v1=1:U41/152; [Titans to Lords of Thunder] *Tower Level 8*  雷神领主
!#MA&v1=1:U55/153; [Arch Devils to Antichrists] *Inferno Level 8*  地狱男爵
!#MA&v1=1:U69/154; [Ghost Dragons to Blood Dragons] *Necropolis Level 8*  血龙
!#MA&v1=1:U83/155; [Black Dragons to Darkness Dragons] *Dungeon Level 8*  暗黑龙
!#MA&v1=1:U97/156; [Ancient Behemoths to Ghost Behemoths] *Stronghold Level 8*  幽灵比蒙
!#UN:P67/?v2; [Check if Neutral Town is enabled: v2=1 if yes]    如果中立城堡选项打开
!#MA&v1=1/v2<>1:U111/168; [Chaos Hydras to Gorynyches if Neutral Town disabled] *Fortress*  终极九头怪-血污怪
!#MA&v1=1/v2<>1:U168/157; [Gorynches to Hell Hydras if Neutral Town disabled] *Fortress Level 8*  血污怪-地狱九头蛇
!#MA&v1=1/v2=1:U111/157; [Chaos Hydras to Hell Hydras if Neutral Town enabled] *Fortress Level 8*  终极九头怪-地狱九头蛇
!#MA&v1=1:U131/158; [Phoenixes to Sacred Phoenixes] *Conflux Level 8* 凤凰-神圣凤凰
!#MA&v1=1:U137/170; [Sharpshooters to Arctic Sharpshooters] *Neutral*  幻影射手-极地神射手
!#MA&v1=1:U170/171; [Arctic Sharpshooters to Lava Sharpshooters] *Neutral*  极地神射手-熔岩神射手
!#MA&v1=1:U195/172; [Hell Steeds to Nightmares] *Neutral*  地狱战马-梦魇兽

[The following can only be upgraded at Hill Forts]    只能在高山堡垒升级
[Hill Fort is trigger]    打开高山堡垒界面，高山堡垒升级最高到七级
!?OB35;
!!UN:P173/?y-1; [Check if Extended Creature Upgrades is enabled: y-1=1 if Yes]如果扩展生物升级打开，那么高山堡垒取消7to8升级
!!FU&y-1<>1:E; [Exit if script isn't enabled]
!!MA:U13/-1;                    [取消7to8升级]
!!MA:U27/-1;
!!MA:U41/-1;
!!MA:U55/-1;
!!MA:U69/-1;
!!MA:U83/-1;
!!MA:U97/-1;
!!MA:U111/-1;
!!MA:U131/-1;
!!MA:U127/166; [Storm Elementals to Air Messengers] *Conflux*[实现四元素升级]
!!MA:U125/165; [Magma Elementals to Earth Messengers] *Conflux*
!!MA:U129/164; [Energy Elementals to Fire Messengers] *Conflux*
!!MA:U123/167; [Ice Elementals to Water Messengers] *Conflux*

[Post-visit Hill Fort is trigger]    未打开高山堡垒界面，在城堡或者巢穴可以升级最高到八级，需建造八级生物工会
!$OB35;
!!UN:P173/?y-1; [Check if Extended Creature Upgrades is enabled: y-1=1 if Yes]如果扩展生物升级打开，出现生物图标出现升级图标
!!FU&y-1<>1:E; [Exit if script isn't enabled]
!!MA:U127/-1; [Remove Storm Elementals to Air Messengers] *Conflux*[取消四元素升级]
!!MA:U125/-1; [Remove Magma Elementals to Earth Messengers] *Conflux*
!!MA:U129/-1; [Remove Elementals to Fire Messengers] *Conflux*
!!MA:U123/-1; [Remove Ice Elementals to Water Messengers] *Conflux*

!!MA:U13/150; [Archangels to Supreme Archangels] *Castle Level 8*    [还原7to8升级]
!!MA:U27/151; [Gold Dragons to Diamond Dragons] *Rampart Level 8*
!!MA:U41/152; [Titans to Lords of Thunder] *Tower Level 8*
!!MA:U55/153; [Arch Devils to Antichrists] *Inferno Level 8*
!!MA:U69/154; [Ghost Dragons to Blood Dragons] *Necropolis Level 8*
!!MA:U83/155; [Black Dragons to Darkness Dragons] *Dungeon Level 8*
!!MA:U97/156; [Ancient Behemoths to Ghost Behemoths] *Stronghold Level 8*
!!MA:U111/157; [Chaos Hydras to Hell Hydras] *Fortress Level 8*
!!MA:U131/158; [Phoenixes to Sacred Phoenixes] *Conflux Level 8*

贤知有您

很抱歉,我还没看懂你上述的问题.
你这里修改后,是不是说, 如果开启了 173选项,访问高山堡垒是不能讲7级升为8级的,而在城镇则可以.(高山堡垒访问后还原为可以升级)
这不是已经达到你的要求了吗,还有什么问题呢?

独孤求败

贤知有您 发表于 2015-10-10 20:18
很抱歉,我还没看懂你上述的问题.
你这里修改后,是不是说, 如果开启了 173选项,访问高山堡垒是不能讲7级升 ...

我的思路很明确，就是把原来wog53中在高山堡垒中实现的扩展生物升级功能，其中的7级升8级的部分交给八级生物建筑来负责。我在英雄界面随身部队Shift+左键开启了高山堡垒的界面，这个界面好像不受到上述代码的制约？！代码如下：

*********************************************************

ZVSE
_WARNING_#1=IMPORTANT! This file is not in a plain text format. NEVER use any editor except ERM_S for making any kind of changes!
ERMS_PoweredBy=ERM Scripter v. 2004.6.29.918
ERMS_ScriptDate=14.5(May).2012
;ERMS_说明：英雄界面Shift+鼠标左键打开高山堡垒和城镇升级用、生物关联系统

!?FU1444;  属性变换系统-----------------不知道什么意思以及如何使用？？？
!!VRy99:S10;
!!UN:N3/9/x2/0;
!!UN:N3/10/x2/1;
!!VRz1:S^你想用%Y99个%Z10换5攻击/5防御/1速度/20%伤害/20%生命吗?^;
!!IF:D1///1////////////;
!!IF:F1/////1;
!!IF:E1/1;
!!FU&v1<>5:E;
!!VRz1&x3<y99:S^英雄,%Z9的数目不够!^;
!!IF&x3<y99:D1///1////////////;
!!IF&x3<y99:F1/////0;
!!IF&x3<y99:E1/1;
!!FU&x3<y99:E;
!!VRz1:S^5 攻击^;
!!VRz2:S^5 防御^;
!!VRz3:S^1 速度^;
!!VRz4:S^20% 伤害^;
!!VRz5:S^20% 生命^;
!!VRz6:S^取消^;
!!VRz7:S^你想为%Z9增加哪个属性?^;
!!IF:G1/1/32/7/1/2/3/4/5/6;
!!FU&v1=32:E;
!!EX-1/x1:E?y-1;
!!MA&v1=1:Ax2/d5;
!!MA&v1=2:Dx2/d5;
!!MA&v1=4:Sx2/d1;
!!MA&v1=8:Mx2/?y1;
!!VRy1&v1=8:*20 :100;
!!VRy1&v1=8/y1=0:S1;
!!MA&v1=8:Mx2/dy1 Ex2/dy1;
!!MA&v1=16:Px2/?y1;
!!VRy1&v1=16:*20 :100;
!!VRy1&v1=16/y1=0:S1;
!!MA&v1=16:Px2/dy1;
!!VRz8&v1=1:Sz1;
!!VRz8&v1=2:Sz2;
!!VRz8&v1=4:Sz3;
!!VRz8&v1=8:Sz4;
!!VRz8&v1=16:Sz5;
!!VRz8:S^恭喜!%Z9已经增加了%Z8!^;
!!IF:D1///8////////////;
!!IF:F1/////0;
!!IF:E1/1;
!!HE-1:C0/x1/x2/?y-2;
!!VRy-2:-y99;
!!HE-1:C0/x1/x2/y-2;
!!EX-1/x1:Ey-1;
!!UN:R3/-1;

!?CM2;

!!CM:I?y1 F?y2;                            Shift+鼠标左键   
!!HE-1&y1>=68/y1<=74/y2=1:D;
!!CM&y1>=68/y1<=74/y2=1:R0;                巨龙摩莉尔的升级有特别功能

!!HE-1:C0/x16/?y1/?y2;
!!FU|y1<0/y2<1:E;

!!VRy3&y1<111:Sy1 %2;
!!VRy4&y3=0/y1<111:Sy1 +1;
!!HE153&y3=0/y1<111:C0/x16/y4/y2;

!!VRy4&y1=113:S127;
!!VRy4&y1=114:S125;
!!VRy4&y1=115:S129;
!!VRy4&y1=116:S123;
!!HE153&y1>=113/y1<=116:C0/x16/y4/y2;

!!VRy4&y1=111:S157;
!!VRy4&y1=130:S131;
!!VRy4&y1=131:S158;
!!HE153|y1=111/y1=130/y1=131:C0/x16/y4/y2;

!!FU&y3=0:E;
!!VRy4&y1=9:S169;
!!VRy4&y1=13:S150;
!!VRy4&y1=27:S151;
!!VRy4&y1=41:S152;
!!VRy4&y1=55:S153;
!!VRy4&y1=69:S154;
!!VRy4&y1=83:S155;
!!VRy4&y1=97:S156;
!!HE153|y1=9/y1=13/y1=27/y1=41/y1=55/y1=69/y1=83/y1=97:C0/x16/y4/y2;

贤知有您

英雄身上直接调用高山堡垒升级,是 HE:D语法.
而7楼的代码是英雄访问高山堡垒才触发的.访问时去掉升级能力,访问后还原.
所以你只要在 HE:D 之前去掉升级为8级能力,在HE:D后还原就可以了.

其它很多代码我就不想看了.

独孤求败

帮我把后面这一段修改一下嘛！好不好？真的搞不定，麻烦您老啦！

独孤求败

贤知有您 发表于 2015-10-10 21:32
英雄身上直接调用高山堡垒升级,是 HE:D语法.
而7楼的代码是英雄访问高山堡垒才触发的.访问时去掉升级能力, ...

只是下面三四行代码就好了，一定要帮帮我啊！

!?CM2;                                    在英雄信息场景中鼠标点击触发 适用于当前英雄HE-1命令

!!CM:I?y1 F?y2;                            Shift+鼠标左键   
!!HE-1&y1>=68/y1<=74/y2=1:D;               选定英雄的7个部队框68-74，调用部队升级界面D
!!CM&y1>=68/y1<=74/y2=1:R0;                选定英雄的7个部队框68-74，禁用系统标准反应R0

贤知有您

未测试,大概是这样.
!?CM2;
!!CM:I?y1 F?y2;
!!if&y1>=68/y1<=74/y2=1:;[shift+左键]
!!MA:U13/-1; [取消7to8升级]
!!MA:U27/-1;
!!MA:U41/-1;
!!MA:U55/-1;
!!MA:U69/-1;
!!MA:U83/-1;
!!MA:U97/-1;
!!MA:U111/-1;
!!MA:U131/-1;
!!HE-1:D; 调用部队升级界面
!!MA:U13/150; [还原7to8升级]
!!MA:U27/151;
!!MA:U41/152;
!!MA:U55/153;
!!MA:U69/154;
!!MA:U83/155;
!!MA:U97/156;
!!MA:U111/157;
!!MA:U131/158;
!!CM:R0;[取消原点击功能]
!!en:;

独孤求败

贤知有您 发表于 2015-10-10 21:32
英雄身上直接调用高山堡垒升级,是 HE:D语法.
而7楼的代码是英雄访问高山堡垒才触发的.访问时去掉升级能力, ...

这样怎么样？应该可以了吧！！

!?CM2;                                  打开在英雄信息场景中鼠标点击触发 适用于当前英雄HE-1命令
!!CM:I?y1 F?y2;                            Shift+鼠标左键   
!!HE-1&y1>=68/y1<=74/y2=1:D;               选定英雄的7个部队框68-74，调用部队升级界面D
!!CM&y1>=68/y1<=74/y2=1:R0;                选定英雄的7个部队框68-74，禁用系统标准反应R0
!!MA:U13/-1;                    [取消7to8升级]
!!MA:U27/-1;
!!MA:U41/-1;
!!MA:U55/-1;
!!MA:U69/-1;
!!MA:U83/-1;
!!MA:U97/-1;
!!MA:U111/-1;
!!MA:U131/-1;
!!MA:U127/166; [Storm Elementals to Air Messengers] *Conflux*[实现四元素升级]
!!MA:U125/165; [Magma Elementals to Earth Messengers] *Conflux*
!!MA:U129/164; [Energy Elementals to Fire Messengers] *Conflux*
!!MA:U123/167; [Ice Elementals to Water Messengers] *Conflux*

!$CM2;                                  结束在英雄信息场景中鼠标点击触发 适用于当前英雄HE-1命令
!!CM:I?y1 F?y2;                            Shift+鼠标左键   
!!HE-1&y1>=68/y1<=74/y2=1:D;               选定英雄的7个部队框68-74，调用部队升级界面D
!!CM&y1>=68/y1<=74/y2=1:R0;                选定英雄的7个部队框68-74，禁用系统标准反应R0
!!MA:U127/-1; [Remove Storm Elementals to Air Messengers] *Conflux*[取消四元素升级]
!!MA:U125/-1; [Remove Magma Elementals to Earth Messengers] *Conflux*
!!MA:U129/-1; [Remove Elementals to Fire Messengers] *Conflux*
!!MA:U123/-1; [Remove Ice Elementals to Water Messengers] *Conflux*

!!MA:U13/150; [Archangels to Supreme Archangels] *Castle Level 8*    [还原7to8升级]
!!MA:U27/151; [Gold Dragons to Diamond Dragons] *Rampart Level 8*
!!MA:U41/152; [Titans to Lords of Thunder] *Tower Level 8*
!!MA:U55/153; [Arch Devils to Antichrists] *Inferno Level 8*
!!MA:U69/154; [Ghost Dragons to Blood Dragons] *Necropolis Level 8*
!!MA:U83/155; [Black Dragons to Darkness Dragons] *Dungeon Level 8*
!!MA:U97/156; [Ancient Behemoths to Ghost Behemoths] *Stronghold Level 8*
!!MA:U111/157; [Chaos Hydras to Hell Hydras] *Fortress Level 8*
!!MA:U131/158; [Phoenixes to Sacred Phoenixes] *Conflux Level 8*

贤知有您

独孤求败 发表于 2015-10-10 22:33
这样怎么样？应该可以了吧！！

!?CM2;                                  打开在英雄信息场景中鼠标点 ...

这样写是不对的.CM2只能是!?CM2的触发器.
试试13楼的代码,我简化了.

独孤求败

独孤求败 发表于 2015-10-10 22:33
这样怎么样？应该可以了吧！！

!?CM2;                                  打开在英雄信息场景中鼠标点 ...

可惜好像不行……这样就成功了……


!?CM2;                                  打开在英雄信息场景中鼠标点击触发 适用于当前英雄HE-1命令
!!MA:U13/-1;                    [取消7to8升级]
!!MA:U27/-1;
!!MA:U41/-1;
!!MA:U55/-1;
!!MA:U69/-1;
!!MA:U83/-1;
!!MA:U97/-1;
!!MA:U111/-1;
!!MA:U131/-1;
!!MA:U127/166; [Storm Elementals to Air Messengers] *Conflux*[实现四元素升级]
!!MA:U125/165; [Magma Elementals to Earth Messengers] *Conflux*
!!MA:U129/164; [Energy Elementals to Fire Messengers] *Conflux*
!!MA:U123/167; [Ice Elementals to Water Messengers] *Conflux*
!!CM:I?y1 F?y2;                            Shift+鼠标左键   
!!HE-1&y1>=68/y1<=74/y2=1:D;               选定英雄的7个部队框68-74，调用部队升级界面D
!!CM&y1>=68/y1<=74/y2=1:R0;                选定英雄的7个部队框68-74，禁用系统标准反应R0


!$CM2;                                  结束在英雄信息场景中鼠标点击触发 适用于当前英雄HE-1命令
!!MA:U127/-1; [Remove Storm Elementals to Air Messengers] *Conflux*[取消四元素升级]
!!MA:U125/-1; [Remove Magma Elementals to Earth Messengers] *Conflux*
!!MA:U129/-1; [Remove Elementals to Fire Messengers] *Conflux*
!!MA:U123/-1; [Remove Ice Elementals to Water Messengers] *Conflux*

!!MA:U13/150; [Archangels to Supreme Archangels] *Castle Level 8*    [还原7to8升级]
!!MA:U27/151; [Gold Dragons to Diamond Dragons] *Rampart Level 8*
!!MA:U41/152; [Titans to Lords of Thunder] *Tower Level 8*
!!MA:U55/153; [Arch Devils to Antichrists] *Inferno Level 8*
!!MA:U69/154; [Ghost Dragons to Blood Dragons] *Necropolis Level 8*
!!MA:U83/155; [Black Dragons to Darkness Dragons] *Dungeon Level 8*
!!MA:U97/156; [Ancient Behemoths to Ghost Behemoths] *Stronghold Level 8*
!!MA:U111/157; [Chaos Hydras to Hell Hydras] *Fortress Level 8*
!!MA:U131/158; [Phoenixes to Sacred Phoenixes] *Conflux Level 8*      

独孤求败

贤知有您 发表于 2015-10-10 22:31
未测试,大概是这样.
!?CM2;
!!CM:I?y1 F?y2;

成功了，就是这个这个！！