史上最NB的英雄克隆脚本

fly123 · 发表于 2012-2-25 15:43:05

大家好，本人最近写了一个脚本，实现功能如下：

任何访问特定地点的英雄可以随意克隆地图里任意英雄的一切，包括宝物，经验，魔法，魔法值，技能，ADPK，带领的生物和生物经验，交换一追，二追，甚至

克隆特长,名字,性别,职业。并且可以在克隆之前预览克隆对象的信息，（包括姓名，职业，性别，经验值，属性。带领兵种信息，身上穿带宝物信息（这个只包括

身上的八个位置，不包括杂物篮）原因嘛，我不说，你也明白）因为这个脚本过于强大，所以我设定为要访问特定地点才可以进行克隆。
脚本分享如下：

ZVSE
!#VRz433:S^{克隆之家}^;
!#OB44/115/1:Hz433;
!?OB44/115/1&1000;
!!PO998:N?x1;
!!if&x1=1:;
!!IF:M^你已经克隆过了！^;
!!el:;
!!IF&1000:Q3^你来到了{克隆之家}。
这里据说可以随意克隆英雄的一切。
想试试吗?^;
!!IF&-3:M^{你决定不试验，悄悄的离开。}^;
!!if&3:;
!!VRy1:S0;!!VRx2:S-1;
!!VRz1:S^红色^;
!!VRz2:S^蓝色^;
!!VRz3:S^褐色^;
!!VRz4:S^绿色^;
!!VRz5:S^橙色^;
!!VRz6:S^紫色^;
!!VRz7:S^青色^;
!!VRz8:S^粉色^;
!!VRz9:S^取消^;
!!VRz10:S^请选择你想要克隆的英雄所属颜色^;
!!IF:G1/10/256/10/1/2/3/4/5/6/7/8/9;
!!VRy1:Sv10;!!VRv10:S0;
!!if&y1<>256:;
!!VRx2&y1=1:S0;!!VRx2&y1=2:S1;
!!VRx2&y1=4:S2;!!VRx2&y1=8:S3;
!!VRx2&y1=16:S4;!!VRx2&y1=32:S5;
!!VRx2&y1=64:S6;!!VRx2&y1=128:S7;
!!HE-1:N?x3;
!!if&x2>-1:;
!!FU312:P-1/x2/x3/1;
!!en:;
!?FU312;
!!if&x1=-1;
!!DO312/0/7/1:P-4/x2/x4;
!!VRz9:S^取消^;
!!VRz10:S^请选择你想要克隆的英雄^;
!!IF:G1/10/256/10/1/2/3/4/5/6/7/8/9;
!!if&v10<>256:;
!!VRvx4&v10=2:Sv2;
!!VRvx4&v10=4:Sv3;
!!VRvx4&v10=8:Sv4;
!!VRvx4&v10=16:Sv5;
!!VRvx4&v10=32:Sv6;
!!VRvx4&v10=64:Sv7;
!!VRvx4&v10=128:Sv8;
!!HEvx4:B0/?z11 B2/?y1 R2/?y-1;
!!HEvx4:E?y-2;
!!VRz-9&y1=0:S^骑士^;
!!VRz-9&y1=1:S^牧师^;
!!VRz-9&y1=2:S^巡逻兵^;
!!VRz-9&y1=3:S^德鲁伊^;
!!VRz-9&y1=4:S^炼金术士^;
!!VRz-9&y1=5:S^术士^;
!!VRz-9&y1=6:S^魔鬼^;
!!VRz-9&y1=7:S^异教徒^;
!!VRz-9&y1=8:S^死亡骑士^;
!!VRz-9&y1=9:S^巫师^;
!!VRz-9&y1=10:S^妖术师^;
!!VRz-9&y1=11:S^地下领主^;
!!VRz-9&y1=12:S^野蛮人^;
!!VRz-9&y1=13:S^战斗法师^;
!!VRz-9&y1=14:S^驯兽师^;
!!VRz-9&y1=15:S^女巫^;
!!VRz-9&y1=16:S^元素人^;
!!VRz-9&y1=17:S^元素使^;
!!HEvx4:F?y1/?y2/?y3/?y4 I?y5;
!!VRz-10&y-1=0:S^男^;
!!VRz-10&y-1=1:S^女^;
!!DO312/0/8/1:P-12/vx4;
!!VRz1&v57>6:S^头部宝物:%Z57^;!!VRz2&v58>6:S^肩部宝物:%Z58^;
!!VRz3&v59>6:S^颈部宝物:%Z59^;!!VRz4&v60>6:S^右手宝物:%Z60^;
!!VRz5&v61>6:S^左手宝物:%Z61^;!!VRz6&v62>6:S^胸部宝物:%Z62^;
!!VRz7&v63>6:S^右手戒指:%Z63^;!!VRz8&v64>6:S^左手戒指:%Z64^;
!!VRz9&v65>6:S^足部宝物:%Z65^;
!!VRz-7:S^{拥有宝物信息}
%Z1 %Z2
%Z3 %Z4
%Z5 %Z6
%Z7 %Z8
%Z9^;
!!DO312/0/6/1:P-9/vx4/50;
!!VRz-8:S^{旗下部队信息}
部队1 类型:%Z50 数量:%V50
部队2 类型:%Z51 数量:%V51
部队3 类型:%Z52 数量:%V52
部队4 类型:%Z53 数量:%V53
部队5 类型:%Z54 数量:%V54
部队6 类型:%Z55 数量:%V55
部队7 类型:%Z56 数量:%V56^;
!!VRz-10:S^姓名 %Z11 职业 %Z-9 性别 %Z-10 经验值 %Y-2
属性:攻击%Y1 防御%Y2 魔力%Y3 知识%Y4 魔法值%Y5
%Z-7
%Z-8^;
!!VRz10:S^{fly123}^;
!!UN:G1/152/0/10 G1/152/1/10;
!!IF:Q1/21/152/1^{交换对象信息}
%Z-10^;
!!UN:G1/152/0/0 G1/152/1/0;
!!IF:Q8^确定想要克隆?^;
!!if&8:;
!!FU312:P-2/vx4/x3;
!!PO998:N1;
!!en:;
!?FU312;
!!if&x1=-2:;
!!HEx2:E?y-5 I?x4; 克隆经验魔法值
!!HEx3:Ey-5 Ix4;
!!DO312/0/69/1:P-8/x2/x3; 克隆魔法
!!DO312/0/8/1:P-5/x2/x3; 克隆宝物
!!DO312/0/27/1:P-3/x2/x3; 克隆技能
!!HEx2:F?y-1/?y-2/?y-3/?y-4; 克隆ADPK
!!HEx3:Fy-1/y-2/y-3/y-4;
!!DO312/0/6/1:P-10/x2/x3;克隆生物和生物经验
!!IF:Q9^想要交换一追,二追?^;
!!if&9:;
!!FU312:P-6/x2/x3;
!!en:;
!!IF:Q10^想要克隆特长,名字,性别,职业?^;
!!if&10:;
!!FU312:P-11/x2/x3;
!!en:;
!?FU312;
!!if&x1=-3:;
!!HEx2:Sx16/?y16;
!!HEx3:Sx16/y16;
!!en:;
!!if&x1=-4:;
!!VRvx3:C0;
!!VRzx3:S^^;
!!OW:Ox2/x16/?vx3;
!!HEvx3:B0/?zx3;
!!VRx3:+1; 变量递增
!!en:;
!!if&x1=-5:;
!!HEx2:A1/?y14/x16;
!!HEx3&y14>6:A4/y14;
!!en:;
!?FU312;
!!if&x1=-6:;
!!FU312:P-7/x2/x3;
!!IF:Wx2;
!!if&w162<>-1/w160<>-1:;无同化生物或者无设置追随者则中止
!!FU25008:P5; 取二追ID
!!VRy22:Sv25;
!!VRv1:Cw160/w161/w162/w163/w164; 保存左边英雄二追资料
!!IF:Wx3;
!!if&w162<>-1/w160<>-1:;
!!FU25008:P5; 取二追ID
!!UN:N3/1/y22/0;
!!VRv6:Cw160/w161/w162/w163/w164; 保存右边英雄二追资料
!!VRy23:Sv25;
!!UN:N3/2/y23/0;
!!IF:Q2/21/y22/21/y23/2^你确定将二追 %Z1 经验值%V2 做交换二追 %Z2 经验值%V7?
^;
!!if&2:;
!!IF:Wx2;
!!VRw160:Sv6;
!!VRw161:Sv7;
!!VRw162:Sv8;
!!VRw163:Sv9;
!!VRw164:Sv10;
!!IF:Wx3;
!!VRw160:Sv1;
!!VRw161:Sv2;
!!VRw162:Sv3;
!!VRw163:Sv4;
!!VRw164:Sv5;
!!en:;
!?FU312;
!!if&x1=-7:;
!!IF:Wx2;
!!if&w118>-1/w119<>0:;
!!VRv1:Cw117/w118; 保存左边英雄一追资料
!!UN:N3/1/w118/0;
!!VRy20:Sw118;
!!IF:Wx3;
!!if&w118>-1/w119<>0:;
!!VRv3:Cw117/w118; 保存右边英雄一追资料
!!UN:N3/2/w118/0;
!!VRy21:Sw118;
!!IF:Q2/21/y20/21/y21/2^你确定将一追 %Z1 经验值%V1 做交换一追 %Z2 经验值%V3?
^;
!!if&2:;
!!IF:Wx2;
!!VRw117:Sv3;
!!VRw118:Sv4;
!!IF:Wx3;
!!VRw117:Sv1;
!!VRw118:Sv2;
!!en:;
!?FU312;
!!if&x1=-8:;
!!HEx2:Mx16/?y15;
!!HEx3&y15>0:Mx16/y15;
!!en:;
!!if&x1=-9:;
!!VRy1:Sx3 +59;
!!VRvx3:C0;
!!VRzx3:S^^;
!!HEx2:C0/x16/?vy1/?vx3;
!!UN:N3/x3/vy1/0;
!!VRx3:+1;
!!en:;
!!if&x1=-10:;
!!HEx2:C0/x16/?y1/?y2/?y3/?y4;
!!HEx3:C0/x16/y1/y2/y3/y4;
!!en:;
!!if&x1=-11:;
!!HEx2:B0/?z11 B2/?y1 R2/?y2;
!!VRz10:S^冒牌^;
!!VRz12:S^%Z10^+^%Z11^;
!!HEx3:B0/z12 B2/y1 R2/y2;
!!HEx2:X?y5/?y6/?y7/?y8/?y9/?y10/?y11;
!!HEx3:Xy5/y6/y7/y8/y9/y10/y11;
!!en:;
!!if&x1=-12:;
!!VRy14:Sx16+57;
!!VRy13:Sx16 +1;
!!VRvy14:C0;
!!VRzy13:S^^;!!VRzy14:S^^;
!!HEx2:A1/?vy14/x16;
!!UN&vy14>6:N0/y14/vy14;
!!en:;

复制代码

经本人测试此脚本在ERA2.0版本完全通过。欢迎大家进行测试，也顺便报告BUG.

fly123 · 发表于 2012-2-25 15:43:57

沙发自己坐。

欢迎大家进行测试，也顺便报告BUG.

龙巫妖 · 发表于 2012-2-25 15:48:10

太神了

必须收藏

兽哥哥 · 发表于 2012-2-25 15:50:51

看看特定地点是什么地方，试试看。

兽哥哥 · 发表于 2012-2-25 15:52:09

看看特定地点是什么地方，试试看。

fly123 · 发表于 2012-2-25 15:54:14

特定地点，你自己把坐标改一下就行。随便放一个什么建筑，当然最好是WOG新增建筑，或者是空白的建筑。

文兄 · 发表于 2012-2-25 16:02:22

原帖由 兽哥哥 于 2012-2-25 15:52 发表
看看特定地点是什么地方，试试看。

重发

文兄 · 发表于 2012-2-25 16:03:57

这个事很牛啊，但放到哪里呢
我对ERM根本不懂

fly123 · 发表于 2012-2-25 16:07:45

放在地图事件里，设置时间为500天就OK.

无心云 · 发表于 2012-2-25 16:14:20

不是吧，这个简直就生化武器啊

fly123 · 发表于 2012-2-25 20:07:16

沧海。现在你的怪物强化进度怎样啦？

沧海一粟 · 发表于 2012-2-25 20:16:11

原帖由 fly123 于 2012-2-25 20:07 发表
沧海。现在你的怪物强化进度怎样啦？

内容太多了，不包括经验特技生物特技计划增加600+的怪物技能基本又不能重复，代码精简后最少预计都有6000行左右，想得脑子都晕了。

fly123 · 发表于 2012-2-25 20:17:12

我的进度也停止了。

沧海一粟 · 发表于 2012-2-25 20:23:42

原帖由 fly123 于 2012-2-25 20:17 发表
我的进度也停止了。

呵呵，慢慢来嘛，别停了啊，这东西一下子是完成不了的。我现在还是坚持每天最少写两至三个特技，有些刚想到的东西有时候真的很难写，等召唤师回来后就得再加速了。

无心云 · 发表于 2012-2-25 20:37:40

原帖由 沧海一粟 于 2012-2-25 20:23 发表

呵呵，慢慢来嘛，别停了啊，这东西一下子是完成不了的。我现在还是坚持每天最少写两至三个特技，有些刚想到的东西有时候真的很难写，等召唤师回来后就得再加速了。

两位大师辛苦了

这个别人职业的也要一个小组，你们只是业余个人搞搞，注意身体和脑细胞啊，哈哈，别心急，有状态就搞，没状态就去散散心好了
打球啊，抱小孩子都是好运动来着，当然抱老婆也是挺好的选择（不管别人的还是自己的

)

灰狼王子 · 发表于 2012-2-26 12:36:09

这个果然灰常之NB，记得巫妖王毁灭里在有个地方不是就有克隆自己的敌方英雄吗

821348193 · 发表于 2012-3-3 13:17:31

原帖由 无心云 于 2012-2-25 20:37 发表

两位大师辛苦了

这个别人职业的也要一个小组，你们只是业余个人搞搞，注意身体和脑细胞啊，哈哈，别心急，有状态就搞，没状态就去散散心好了
打球啊，抱小孩子都是好运动来着，当然抱老婆也是挺好的选择（ ...

太邪恶了吧

就一刀子 · 发表于 2012-3-3 13:32:32

好东西坚决要支持，虽然是新手

账号		自动登录	找回密码
密码			英雄注册\|Register

史上最NB的英雄克隆脚本

评分

相关帖子

回复 5# 的帖子

评分

退役版主

社区QQ达人

魅力之星

论坛守望者

版主勋章

金牌裁判

杰出贡献

TE联赛冠军

TE联赛季军

脚本测试狂

论坛元老