论坛 › ERM公会 | ERM Guild › 想在特殊地图里面增加侦察术的（意外事件、踩地雷）脚本

ming851127 发表于 2013-9-5 15:56:29

想在特殊地图里面增加侦察术的（意外事件、踩地雷）脚本

本帖最后由 ming851127 于 2013-9-9 11:56 编辑

最近在玩老地图，准备自己修改修改;jx;。
但是苦于ERM不会，想请大大帮忙将侦察术的意外事件脚本摘录出来，然后我把它做成事件放在地图中。只要侦察术的意外事件部分（我知道可能在03号文件中，但是不知道是哪一段。。。。。）谢谢啦！

贤知有您 发表于 2013-9-5 16:47:09

莫非楼主说的是 地雷系统.呵呵

a968574 发表于 2013-9-6 04:36:02

本帖最后由 a968574 于 2013-9-6 04:41 编辑

ZVSE
_WARNING_#1=IMPORTANT! This file is not in a plain text format. NEVER use any editor except ERM_S for making any kind of changes!
ERMS_PoweredBy=ERM Scripter v. 2004.6.29.918
ERMS_ScriptDate=8.2(February).2011

**廖化移动前触发***
!?HM95;
!!HE95:O?y-12;      获取廖化颜色
!!OW:C?y-13;          获取当前玩家
!!FU&y-12<>0/y-13<>0:E;廖化非色终止，当前不是红色终止
!!HE95:P?v201/?v202/?v203;   获取廖化坐标
!!FU&v201=0/v202=87/v203=0:E;
!!HE95:Ed/?v1;               获取廖化等级保存至v1
!!VRv1:+13;                  v1+13
!!UN:Sv201/v202/v203/0/v1;   打开的地图＝廖化等级+13
!!TRv201&v201>1/v202>1:T?y-15/d/d/d/d/d/d/d;检查坐标点地面类型
!!FU&y-15=8:E;                  地面为水域时终止

!!IF:W95;                      使用英雄变量
!!VRw4&y-15<>8:S0;            坐标非水域时w4赋值为0

!!HE95&y-15<>8:S3/?y-11;         获取廖化侦查术等级
!!FU7023&y-15<>8/y-11>0:Py-11;   调用函数FU7023

**侦察术函数**
**x1=侦察术等级
!?FU7023;
!!VRy3:S11 +x1;      [设置侦察术图片]
!!VRy4:S0;         [随机事件几率为0]
!!VRy4&x1=1:R719;    [随机事件几率为 3.3% (24/720)]
!!VRy4&x1=2:R479;    [随机事件几率为 5.0% (24/480)]
!!VRy4&x1=3:R239;    [随机事件几率为10.0% (24/240)]


!!IF95&1000/999/y4=1:Q2/20/y3/35/20/1^经过一个小池塘，廖化忽然发现一个仙子并且停下来和她聊天。这是一次令人愉快的交流，仙子允许他使用一些她的魔力。^;
!!HE95&y4=1:Id+20;         [给予20点魔法值]
!!VRr&y4=2:S1 R24 *100;    [随机 1 到 25 x 100]
!!IF95&1000/999/y4=2:Q2/20/y3/6/r/1^因为他的不可思议的找东西的技巧，廖化发现了被隐藏的黄金。^;
!!OW&y4=2:R0/6/dr;   [给予黄金]
!!VRs&y4=3:S0 R5;      [给予资源 0 to 5]
!!VRr&y4=3:S1 R2;      [随机数量 1 to 3]
!!VRr&y4=3/s=0:*2;   [木材双倍]
!!VRr&y4=3/s=2:*2;   [矿石双倍]
!!IF95&1000/999/y4=3:Q2/20/y3/s/r/1^由于他的热衷于观察技能，廖化发现了少量的资源。^;
!!OW&y4=3:R0/s/dr;   [给予资源]
!!VRs&y4=4:S0 R5;      [随机资源 0 to 5]
!!VRr&y4=4:S4 R2;      [随机数量 4 to 6]
!!VRr&y4=4/s=0:*2;   [木材双倍]
!!VRr&y4=4/s=2:*2;   [矿石双倍]
!!IF95&1000/999/y4=4:Q2/20/y3/s/r/1^经过勘测该地区，廖化发现了大量的资源。^;
!!OW&y4=4:R0/s/dr;   [给予资源]

!!FU7019&y4=5:P;                              [调用函数function 7019 选择怪物]
!!MA&y4=5:Gs/?r;                              [得到一周的产量]
!!IF95&1000/999/y4=5/r=1:Q2/20/y3/21/s/1^经过他的观察，廖化发现一个 %Z704 愿意加入他的的部队。^;
!!IF95&1000/999/y4=5/r>1:Q2/20/y3/21/s/1^经过他的的观察，廖化发现一些 %Z705 愿意加入他的的部队。^;
!!HE95&1000/999/y4=5:Cs/r/-1/0/-1/0/-1/0/-1/0/-1/0/-1/0;[给予生物]

!!VRz4&1000/999/y4=6:S^捷径^;
!!UN&1000/999/y4=6:A98/9/4 A98/10/4;
!!IF95&1000/999/y4=6:Q2/20/y3/8/98/1^在了解了地理位置后，廖化发现了一条捷径可以缩短他部队的行军路程。^;
!!UN&1000/999/y4=6:A98/9/0 A98/10/0;
!!HE95&y4=6:Wd+400;                        [增加移动力]

!!VRz4&1000/999/y4=7:S^捷径^;
!!UN&1000/999/y4=7:A98/9/4 A98/10/4;
!!IF95&1000/999/y4=7:Q2/20/y3/8/98/1^在了解了地理位置后，廖化发现了一条捷径可以缩短他部队的行军路程。^;
!!UN&1000/999/y4=7:A98/9/0 A98/10/0;
!!HE95&y4=7:Wd+400;                        [增加移动力]

!!HE95&y4=8:E?y5/?y6;                  [获得英雄级别]
!!VRr&y4=8:Sy6 T20 *50;                  [(level + 0-20) x 50]
!!IF95&1000/999/y4=8:Q2/20/y3/17/r/1^在侦察过程中，廖化遇见了流浪的圣人。他们交谈了一会儿并交流了一下故事和经历。^;
!!HE95&y4=8:Edr;                           [给予经验值]

!!VRz4&1000/999/y4=9:S^捷径^;
!!UN&1000/999/y4=9:A98/9/4 A98/10/4;
!!IF95&1000/999/y4=9:Q2/20/y3/8/98/1^在了解了地理位置后，廖化发现了一条捷径可以缩短他部队的行军路程。^;
!!UN&1000/999/y4=9:A98/9/0 A98/10/0;
!!HE95&y4=9:Wd+400;                        [增加移动力]

!!VRz4&1000/999/y4=10:S^地区勘查^;
!!UN&1000/999/y4=10:A52/9/4 A52/10/4;
!!IF95&1000/999/y4=10:Q2/20/y3/8/52/1^廖化在山顶上发现了一个很好的观察位置，他借此机会勘测该地区。^;
!!UN&1000/999/y4=10:A52/9/0 A52/10/0;         
!!VRr&y4=10:S3 *x1 +16;               [区域]
!!UN&y4=10:Sv201/v202/v203/0/r;         [打开地图区域]

!!FU7019&y4=11:P;                     [调用 function 7019 to 选择怪物]
!!MA&y4=11:Vs/?r;
!!IF95&1000/999/y4=11:Q2/20/y3/21/s/2^听到一些噪音，廖化停下行军并向前侦察。就在这条路径上他发现了一群 %Z705。

你希望和这群 %Z705 战斗吗?^;
!!HE95&2/y4=11:Tv201/v202/v203/s/r;   [作战fight monsters]

!!FU7019&y4=12:P;                        
!!MA&y4=12:Hs/?r;                           
!!IF95&1000/999/y4=12:Q2/20/y3/21/s/2^一阵很大的骚动声警示着 廖化就在下一座山上有一大群 %Z705。

你希望和这群 %Z705 战斗吗？^;
!!HE95&2/y4=12:Tv201/v202/v203/s/r;   
!!UN:R1;                                    [刷新屏幕]

!!FU7019&y4=13:P;                        
!!MA&y4=13:Hs/?r;                           
!!IF95&1000/999/y4=13:Q2/20/y3/21/s/2^一阵很大的骚动声警示着 廖化就在下一座山上有一大群 %Z705。

你希望和这群 %Z705 战斗吗？^;
!!HE95&2/y4=13:Tv201/v202/v203/s/r;   
!!UN:R1;

!!FU7019&y4=14:P;                     [调用 function 7019 to 选择怪物]
!!MA&y4=14:Vs/?r;
!!IF95&1000/999/y4=14:Q2/20/y3/21/s/2^听到一些噪音，廖化停下行军并向前侦察。就在这条路径上他发现了一群 %Z705。

你希望和这群 %Z705 战斗吗?^;
!!HE95&2/y4=14:Tv201/v202/v203/s/r;   [作战fight monsters]

!!VRr&y4=15:S1 R4;      [设置随机秘银数量]
!!VRr&r>50:S50;
!!IF95&1000/999/y4=15:Q2/20/y3/7/r/1^因为他的不可思议的找东西的技巧，廖化发现了被隐藏的秘银。^;
!!OW&y4=15:R0/7/dr;   [给予秘银]

!!VRr&y4=16:S1 R4;      [设置随机秘银数量]
!!VRr&r>50:S50;
!!IF95&1000/999/y4=16:Q2/20/y3/7/r/1^因为他的不可思议的找东西的技巧，廖化发现了被隐藏的秘银。^;
!!OW&y4=16:R0/7/dr;   [给予秘银]

!!FU7019&y4=17:P;       [调用 function 7019 to 选择怪物]
!!MA&y4=17:Vs/?r;
!!IF95&1000/999/y4=17:Q2/20/y3/21/s/2^听到一些噪音，廖化停下行军并向前侦察。就在这条路径上他发现了一群 %Z705。

你希望和这群 %Z705 战斗吗?^;
!!HE95&2/y4=17:Tv201/v202/v203/s/r;   [作战fight monsters]

!!FU7019&y4=18:P;                        
!!MA&y4=18:Hs/?r;                           
!!IF95&1000/999/y4=18:Q2/20/y3/21/s/2^一阵很大的骚动声警示着 廖化就在下一座山上有一大群 %Z705。

你希望和这群 %Z705 战斗吗？^;
!!HE95&2/y4=18:Tv201/v202/v203/s/r;   
!!UN:R1;                                    [刷新屏幕]

!!FU7019&y4=19:P;                        
!!MA&y4=19:Hs/?r;                           
!!IF95&1000/999/y4=19:Q2/20/y3/21/s/2^一阵很大的骚动声警示着 廖化就在下一座山上有一大群 %Z705。

你希望和这群 %Z705 战斗吗？^;
!!HE95&2/y4=19:Tv201/v202/v203/s/r;   
!!UN:R1;                                    [刷新屏幕]

!!FU7019&y4=20:P;                        
!!MA&y4=20:Hs/?r;                           
!!IF95&1000/999/y4=20:Q2/20/y3/21/s/2^一阵很大的骚动声警示着 廖化就在下一座山上有一大群 %Z705。

你希望和这群 %Z705 战斗吗？^;
!!HE95&2/y4=20:Tv201/v202/v203/s/r;   
!!UN:R1;                              [刷新屏幕]

!!HE95&y4=21:E?y5/?y6; [获得英雄级别]
!!VRr&y4=21:Sy6 T20;   [(level + 0-20]
!!IF&y4=21:W95;
!!FU&w118=-1:E;
!!IF95&1000/999/y4=21:Q2/21/w118/17/r/1^在侦察过程中，廖化的追随者与一群怪物激战后获得了一些经验。^;
!!VRw117&y4=21:+r;

!!VRz4&1000/999/y4=22:S^捷径^;
!!UN&1000/999/y4=22:A98/9/4 A98/10/4;
!!IF95&1000/999/y4=22:Q2/20/y3/8/98/1^在了解了地理位置后，廖化发现了一条捷径可以缩短他部队的行军路程。^;
!!UN&1000/999/y4=22:A98/9/0 A98/10/0;
!!HE95&y4=22:Wd+400;                        [增加移动力]

!!HE95&y4=23:A2/6/?y5/?y6; 检查是否装备急救帐篷
!!FU&y6=0:E;               未装备帐篷时函数终止
!!UN:A6/9/0;
!!IF95&1000/999/y4=23/y6>0:Q2/8/6/1^在侦察过程中，廖化遇见一个巧匠，他神奇的手艺使廖化的医疗帐篷升了一级。^;
!!IF&y4=23:W95;            使用英雄变量
!!VRw82&y4=23:+1;

!!HE95&y4=24:A2/5/?y5/?y6; 检查是否装备弹药车
!!FU&y6=0:E;               未装备弹药车时函数终止
!!UN:A5/9/0;
!!IF95&1000/999/y4=24/y6>0:Q2/8/5/1^在侦察过程中，廖化遇见一个巧匠，他神奇的手艺使廖化的弹药车升了一级。^;
!!IF&y4=24:W95;            使用英雄变量
!!VRw83&y4=24:+1;
** 结束函数


***怪物选择函数***
!?FU7019;
!!VRs:S0 T173;                              
!!VRs&s>=132/s<=135:S0 T173;                  
!!VRs&s>=150/s<=158:S0 T173;                  
!!VRs&s>=145/s<=149:S0 T131;                  
!!VRs&s>=160/s<=163:S0 T131;                  
!!VRs&s=159:S171;                           
!!VRs&s=122:S171;                           
!!VRs&s=124:S171;                           
!!VRs&s=126:S171;                           
!!VRs&s=128:S171;                           

!!UN:N3/z704/s/0;                           
!!UN:N3/z705/s/1;                           
***函数结束
******************


**每回合触发**
**兵种获得护盾石肤**
!?BR|v37=95/v47=95;
!!DO189/0/20/1&v37=95/v997>-1:P;
!!DO189/21/41/1&v47=95/v997>-1:P;

!?FU189;
!!BMx16:T?y30 N?y31;
!!FU|y30<0/y31<1:E;
!!BMx16:M27/3/3 M46/3/3;

!?BG1|v37=95/v47=95;
!!FU&v37=95/v7502>20:E;
!!FU&v47=95/v7502<21:E;
!!FU|v7501<6/v7501>7:E;
!!VRy30:S0 R99;
!!VRy31&v37=95:Sv38 R10;
!!VRy31&v47=95:Sv48 R10;
!!VRy31&y31>15:S15;最高几率20%
!!FU&y30>y31:E;
!!FU7061:P62/3/6/2/2/v8507/v8502/0/1; 失明
******************

ming851127 发表于 2013-9-6 13:42:28

贤知有您 发表于 2013-9-5 16:47
莫非楼主说的是 地雷系统.呵呵

呵呵，差不多。但那时也有可以需要奖励的。;jx;

ming851127 发表于 2013-9-6 13:54:30

a968574 发表于 2013-9-6 04:36


谢啦，马上用用试试！

ming851127 发表于 2013-9-6 15:23:32

a968574 发表于 2013-9-6 04:36


老大，这个脚本不行啊。。。。。。。:shangxin:

ming851127 发表于 2013-9-6 15:50:29

好像是下面这段ERM，但是直接复制进时间里面不能起作用。
*************************************************************************
   Scouting
*************************************************************************

!?TM74;   

!!UN:P215/?y-1;   
!!FU&y-1<>1:E;   

!!OW:C?v907;   
!!DO650/0/155/1:P;   

** End of timer routine


!?FU650;   

!!HEx16:O?v900;   

!!VRv901:S0;   
!!HEx16&v900=v907:S3/?v901;   
!!VRv901&v901=3:S5;   
!!VRv901&v901=2:S3;   
!!HEx16:A2/52/0/?y1;   
!!HEx16:A2/53/0/?y2;   
!!VRv901&v901>0:+y1;   
!!VRv901&v901>0:+y2;   
!!IF:Wx16;   
!!OW:Iv900/?y-1;   
!!HEx16&y-1=0/v901>0/w43=0:C2/143/v901/1;   
!!HEx16&y-1=1/v901>0:C2/143/v901/0;   

** End of function to handle scouting for hero #x16


!?CM2;   

!!UN:P215/?y-1;   
!!FU&y-1<>1:E;   

!!IF:W-1;   

!!CM:I?y-1 S?y-5;   

!!FU&y-5<>14:E;   
!!FU|y-1<87/y-1>102:E;   

!!VRy-1|y-1=87/y-1=95:S1;   
!!VRy-1|y-1=88/y-1=96:S2;
!!VRy-1|y-1=89/y-1=97:S3;
!!VRy-1|y-1=90/y-1=98:S4;
!!VRy-1|y-1=91/y-1=99:S5;
!!VRy-1|y-1=92/y-1=100:S6;
!!VRy-1|y-1=93/y-1=101:S7;
!!VRy-1|y-1=94/y-1=102:S8;

!!HE-1:Sy-1/?y-2/1;   
!!FU&y-2<>3:E;   
!!CM:R0;   
!!HE-1:S3/?y-3;   

!!VRz-1:Sz103035+^.^;   
!!VRz-1&w43=1:Sz103036+^.^;
!!VRz-2:Sz103036;
!!VRz-2&w43=1:Sz103035;

** Ask for enabling/disabling rogues

** Basic scouting
!!IF&y-3=1:Q2/20/12/2/z103037;

** Advanced scouting
!!IF&y-3=2:Q2/20/13/2/z103038;

** Expert scouting
!!IF&y-3=3:Q2/20/14/2/z103039;

!!FU&-2:E;   

!!VRy-4:Sw43;
!!VRw43&y-4=1:S0;   
!!VRw43&y-4=0:S1;

** End of right click trigger for rogue enabling/disabling
-------------------------------------------------------------------------


请大大看看，谢谢！

贤知有您 发表于 2013-9-6 17:11:06

ming851127 发表于 2013-9-6 15:50
好像是下面这段ERM，但是直接复制进时间里面不能起作用。
********************************************* ...

这个脚本并不是你一楼说的 意外脚本.
只是有侦察术时,给英雄增加盗贼,以及查看野怪等情况的脚本.

另外这个脚本要在地图事件运行,需要在头部加入TM触发器触发
!#TM74:S1/999/1/255;

a968574 发表于 2013-9-6 20:57:51

时间紧急，首先我向你致谢,然后闪人

ming851127 发表于 2013-9-9 08:53:46

贤知有您 发表于 2013-9-6 17:11
这个脚本并不是你一楼说的 意外脚本.
只是有侦察术时,给英雄增加盗贼,以及查看野怪等情况的脚本.



增加盗贼、查看野怪，就这两个啊。那也就是说如果要有踩雷系统（遇野怪、增加随机怪兽）的话还要其他的脚本？大大有没有？能不能给我考一个，谢谢啦！;exp;

ming851127 发表于 2013-9-9 09:23:25

贤知有您 发表于 2013-9-6 17:11
这个脚本并不是你一楼说的 意外脚本.
只是有侦察术时,给英雄增加盗贼,以及查看野怪等情况的脚本.



我在标准的77个ERM中，绝大部分的文件是需要在游戏之前勾选的。如果在所有文件的前面加上下面的语句
!#TM74:S1/999/1/255;
是不是就不用勾选，全部自动开启使用啦啊？;hi;

贤知有您 发表于 2013-9-9 09:51:09

官方侦察术意外事件脚本是在 30 wog - enhanced secondary skills.erm (WOG版本是script 48)下.
但并不是单独的写法,和其它辅助技能增强混合来写的.抱歉我也没空分离.楼主倒可以研究下官方脚本的内容.

勾选与不勾选的语法不是这句来决定的.
比如勾选侦察术增强.
!!UN:P215/?y3;
!!UN:P212/?y4;
!!UN:P58/?y24;
你就算加了
!#TM74:S1/999/1/255;
也没用的.这句只是让TM时间触发器运行,但具体到 TM函数时受UN:P的是否勾选项目影响.
另外就是,勾选不勾选既然可以由脚本决定,脚本加载是按顺序的.你前头就算用脚本开启了,后面的脚本也一样能关闭掉.

ming851127 发表于 2013-9-9 11:08:25

本帖最后由 ming851127 于 2013-9-9 11:12 编辑

贤知有您 发表于 2013-9-9 09:51
官方侦察术意外事件脚本是在 30 wog - enhanced secondary skills.erm (WOG版本是script 48)下.
但并不是 ...
大大帮忙看看3L是不市针对一个特定英雄的脚本？能不能在他的基础上进行更改？谢谢！{:2_143:}是不是只要更改下面的语句就可以了？

[*]!?HM95;
[*]!!HE95:O?y-12;      获取廖化颜色
（另外，自己正在研究48号官方脚本，貌似很复杂{:2_173:}）

贤知有您 发表于 2013-9-9 11:31:58

ming851127 发表于 2013-9-9 11:08
大大帮忙看看3L是不市针对一个特定英雄的脚本？能不能在他的基础上进行更改？谢谢！是不是只要 ...

是针对95号英雄的.所有 HE95都要改成HM-1,包括触发器 !?HM95;
另外还有很多细节问题要改,除非楼主熟悉脚本,建议还是别改吧.
(例如关于英雄W变量部分, !!IF&y4=23:W95; 这里也是调用了95号英雄的.)

我记得有个踩地雷脚本的,但一时又找不出来.
跟3楼那个脚本差不多,不过应该不是针对某个英雄的.

ming851127 发表于 2013-9-9 11:56:01

贤知有您 发表于 2013-9-9 11:31
是针对95号英雄的.所有 HE95都要改成HM-1,包括触发器 !?HM95;
另外还有很多细节问题要改,除非楼主熟悉脚 ...

大大方便的时候帮帮忙啦:lianhong:

jjnling 发表于 2013-9-23 22:26:06

干脆直接老实猪9in1    地雷算了？？？

ming851127 发表于 2013-9-24 10:15:02

jjnling 发表于 2013-9-23 22:26
干脆直接老实猪9in1    地雷算了？？？

这是想用个踩地雷模式。。。。。。;hx;不想用其他的东东;exp;

查看完整版本: 想在特殊地图里面增加侦察术的（意外事件、踩地雷）脚本