ERM：AI行动力（清0）控制
大地图，如果AI英雄带的兵比较多，在AI行动时，沙漏经常会停在某个位置不动。有时候读档，动一下其他英雄还能跳过去，比较麻烦。不知道有没有ERM命令或ERA命令，直接可以快速结束电脑的回合注意：不能控制AI新招募的英雄！
ZVSE
_WARNING_#1=IMPORTANT! This file is not in a plain text format. NEVER use any editor except ERM_S for making any kind of changes!
;AI行动力控制
*变量：
*v3130（控制选择）,v3131（接收编号）
*v2700（英雄数量）,v2701~（保存英雄编号）
*flag: 812
*函数：FU1020
*用法：魔法书右键
!?CM2&999; 英雄信息界面
!!CM:I?y11 F?y12; *读取鼠标控制点y11检查鼠标动作 y12
!!CM&y11=19/y12=512:R0; *魔法书19 禁用右键512的标准反应
!!FU1020&y11=19/y12=512:P23; *右键512魔法书菜单---选择菜单
!?FU1020&x1=23; *AI行动力控制
!!FU&x1<>23:E;
!!VRz30:S^行动力控制选项^;
!!VRv55:S0;
!!VRz1:S^1.AI英雄行动力置0^; 1
!!VRz2:S^2.某家AI行动力置0^; 2
!!VRz3:S^3.所有AI行动力置0^; 4
!!VRz4:S^4.no^; 8
!!VRz5:S^退出^; 16
!!IF:G1/55/32/30/1/2/3/4/5/0;
!!VRx8:Sv55; !!VRv55:S0; !!FU&x8<1/x8>8:E;
!!IF&-812:V812/1; *flag812开启
!!VRv3130&x8=1:S1; !!FU1020&x8=1:P231;
!!VRv3130&x8=2:S2; !!FU1020&x8=2:P232;
!!VRv3130&x8=4:S3;
!!FU1020&x8=8:E;
!?FU1020&x1=231;
!!FU&x1<>231:E;
!!VRz9:S^AI英雄行动力置0^;
!!VRz22:S^请输入英雄编号(0-155):^;
!!IF:D2/9/22/0; !!IF:E10/2;!!VRx4:Vz1;*输入的内容将储存在z1中
!!IF|x4<0/x4>155:M^输入错误,请重新输入!^;!!FU|x4<0/x4>155:E;
!!VRv3131:Sx4; *保存英雄编号
!?FU1020&x1=232;
!!FU&x1<>232:E;
!!VRz9:S^某家AI行动力置0
注意：每回合只能控制一个AI！^;
!!VRz22:S^请输入玩家编号(0-7):^;
!!IF:D2/9/22/0; !!IF:E10/2;!!VRx4:Vz1;*输入的内容将储存在z1中
!!IF|x4<0/x4>7:M^输入错误,请重新输入!^;!!FU|x4<0/x4>7:E;
!!VRv3131:Sx4; *保存AI编号
!?FU1020&x1=233; *所有AI行动力置0
!!FU|x1<>233:E;!!DO1020/0/7/1:P2331; *遍历玩家
!?FU1020&x1=2331;
!!FU&x1<>2331:E; !!FU1020:P2321/x16;
!?FU1020&x1=2321; *玩家的英雄数量v2700和编号v2701~
!!FU&x1<>2321:E;
!!OW:Ix2/?y11/?y12; !!FU|y11=0/y12=1:E; *人类玩家0/失败的玩家1 退出
!!OW:Hx2/2700/0;!!FU&v2700<=0:E; *v2700英雄数量, 没有英雄 退出
!!DO1020/1/v2700/1:P2322/x2; *存储所有英雄编号
!?FU1020&x1=2322; *x2玩家编号x16第几个英雄--非英雄列表中的
!!FU&x1<>2322:E;
!!VRx9:S2700 +x16; *2701~[+v2700]
!!OW:Hx2/x9/x16; !!VRx10:Svx9; *x10 heronum完成AI英雄的遍历
!!HEx10:W?y1; !!VRy2:Sy1*-1; !!HEx10:Wdy2;*行动力清0
;--------------------时间事件
!?TM1&1000;
!!VRv3130&812:S0;!!VRv3131&812:S0; !!IF&812:V812/0; *AI行动力恢复
!?TM1&-1000/812;
!!FU1020:P230; *AI行动力置0
!?FU1020&x1=230; *AI行动力控制---tm1事件中选项
!!FU&x1<>230:E;
!!HEv3131&v3130=1:W?y1; !!VRy2&v3130=1:Sy1*-1; !!HEv3131&v3130=1:Wdy2;
!!FU1020&v3130=2:P2321/v3131;
!!FU1020&v3130=3:P233;
[ 本帖最后由 Castle 于 2013-8-3 15:05 编辑 ] 有的ERM强制将AI移动力清零，但是AI英雄玩城内城外或者双向门捉迷藏照样死机，然后又有了双向门扣移动力的ERM还有限制AI兵力多导致死机的ERM，但迄今为止还没有哪款ERM能百分百保证不会过天卡死。
LZ说的功能可能涉及游戏程序的硬编码吧，恐怕不易实现吧。 原帖由 灰狼王子 于 2013-8-3 00:12 发表 http://bbs.h3wog.com/images/common/back.gif
有的ERM强制将AI移动力清零，但是AI英雄玩城内城外或者双向门捉迷藏照样死机，然后又有了双向门扣移动力的ERM还有限制AI兵力多导致死机的ERM，但迄今为止还没有哪款ERM能百分百保证不会过天卡死。
LZ说的功能可能涉 ...
强制将AI移动力清零+清空双向门，我试试这个方法
谢谢 可以去试试，存在类似的问题。谢谢楼上的;ekow; 101 - WOG中文论坛BUG修正合集
*******************************************************************
防止AI死机脚本2012.12.23
*******************************************************************
;AI每访问一次双向碑耗100移动
!?OB45&-1000;
!!HE-1:W?y-1;
!!VRy-2:Sy-1 -100;
!!VRy-2&y-2<0:S0;
!!HE-1:Wy-2;
;AI每访问一次城镇耗100移动
!?OB98&-1000;
!!HE-1:W?y-1;
!!VRy-2:Sy-1 -100;
!!VRy-2&y-2<0:S0;
!!HE-1:Wy-2;
**END
添加脚本。。。。。。;orz;
页:
[1]
