回复 19# 的帖子
三追早有了。。。。。回复 16# 的帖子
召魂术如果间接召魂其实还是比其它技能麻烦得多，因为你必须对已经出现的召魂技能做些什么，当然也是可以允许对它做些什么就是了，只是非高级技能相对地麻烦些处理就是。建议楼主还是写高级技能的改变吧，比如说斯强克高级召魂术召唤僵尸什么的，具体可参考我那威力加强版的鬼王斗篷召恐怖骑士的写法，鬼王也啰嗦，不写不知道原来鬼王是没有召魂术都可以召骷髅的。
[ 本帖最后由 沧海一粟 于 2013-1-14 14:57 编辑 ] 僵尸加强，自带酸液。
立刻无敌。
;hx;
当然斯强克的特长才具备，最好是它带领的僵尸，地图上移动，不降低英雄额外的移动力。
这样阿僵才能无敌。
回复 23# 的帖子
僵尸自带酸液，这是不错啊。而且移动不浪费地图点数。啧啧，游戏人的家果然是老玩家，一下就让我心动了。这样既不会变态，也很实用。我在最后的特长调整阶段会仔细考虑的。谢谢回复 24# 的帖子
怪物强化3好像也有，大爷啊~~~~回复 25# 的帖子
有没有其实没关系，开心就行回复 22# 的帖子
参照大家给的例子，我也做了个。不过我习惯了做函数，可能代码要多点。不过优点是可以随意套用。!?BR;!!FU&v997<>-1:E; 在-1回合进行操作 注意会运行在”英雄特长加强“的生物奖励之前
!!BA:H0/?y1; 进攻方英雄
!!BA:H1/?y2; 防守方英雄
*维得尼娜，招魂术鬼魂特长：招魂术招募到的生物为鬼魂
*英雄编号：78
*生物编号：鬼魂 159
!!FU10004:P4/y1/0/159/9601/9602/78;进攻方招魂术等级、招魂数v9601 v9602
!!FU10004:P4/y2/1/159/9603/9604/78;防守方招魂术等级、招魂数v9603 v9604
*** 函数编号：10004
*** 功能：实现伪招魂术
*** 遗憾：不计算灵塔和招魂塔 小弟实在没有找到计算方法
*** 算法：参考死亡阴影招魂大揭秘，每队敌军数*招魂比例取整。若敌怪物血
*** 比目标怪物低，就结果再乘以 敌怪物/目标怪物在取整。最后求和，
*** 至少要招募一个
*** 配合触发器：BR BA1
*** x1 = 功能编号1 x2 = 英雄编号 x3 = 0（进攻）/ 1（防守） x4 = 招魂生物ID
*** x5 = 保存招魂术等级的v变量索引 x6 = 保存招魂个数的 v变量索引
!?FU10004&x1=1;
!!FU&x2<=0:E; 英雄编号大于0
!!HEx2:S12/?y1; y1=招魂术等级
!!FU&y1=0:E; 没有招魂术退出
!!VRy2:+y1 *10; y2=招魂术招魂比例
!!HEx2:A2/130/?y3/?y4; y3废弃 y4=装备区鬼王斗篷数量
!!FU&y4=1:E; 有了鬼王斗篷，不需要本特长了，嘿嘿嘿嘿嘿嘿嘿
!!HEx2:A2/54/?y3/?y4; y3废弃 y4=装备区亡灵护身符数量
!!VRy2&y4=1:+5;
!!HEx2:A2/55/?y3/?y4; y3废弃 y4=装备区亡吸血鬼斗篷数量
!!VRy2&y4=1:+10;
!!HEx2:A2/56/?y3/?y4; y3废弃 y4=装备区亡死神靴数量
!!VRy2&y4=1:+15;
!!HEx2:X?y5/?y6/?y7/?y8/?y9/?y10/?y11; y5=英雄特技类型，y6=子选项 其他废弃
!!HEx2:E?y7/?y8; y7=英雄经验 y8=英雄等级数 其他废弃
!!VRy9:S0;
!!VRy9&y5=0/y6=12:+y8 *5 *y1 :10; y9=招魂术特长加成点
!!VRy9&y5=0/y6=12/y9=0:+1; 至少为1
!!VRy2:+y9;
!!VRy2&y2>100:S100; 当然，不能大于100，不能逆天了不是
!!VRvx5:S0;
!!VRvx6:S0;
!!VRvx5:+y1; vx3保存招魂术等级
!!HEx2:S12/0; 删除招魂术
!!VRy10:S0;
!!DO10004/21/41/1&x3=0:P2/x4/y2/x6;
!!DO10004/0/20/1&x3=1:P2/x4/y2/x6;
!!VRvx6&vx6=0:+1; 至少复活一个
!?FU10004&x1=2; x2=招魂生物 x3=招魂率 x4=招魂数量v变量下标，该变量用于累加
!!BMx16:T?y1; y1=怪物类型
!!FU&y1<0:E;不是生物或者战争工具退出
!!FU&y1>=145/y1<=149:E;
!!BMx16:B?y2; y2=怪物数量
!!BMx16:H?y3; y3=怪物血量
!!MA:Px2/?y4; y4=招魂怪物血量
!!VRy5:+y2 *x3 :100; 计算招魂量保存于y5
!!VRy5&y3<y4:*y3 :y4; 如果怪物血量小于招魂怪物就 x怪物血量 / 目标血量
!!VRvx4:+y5;
!?FU10004&x1=3; x2=招魂生物
!!BA:H0/?y1; 进攻方
!!BA:H1/?y2; 防守方
!!HEy1:O?y3; 检查进攻方英雄所属，为-1则战败
!!VRy4&y3>=0:S1; 进攻方获胜
!!VRy4&y3<0/y2>0:S2; 防守方获胜
!!VRy4&y3<0/y2=-2:S3; 怪物获胜
!!VRv9601:C?y5/?y6/?y7/?y8; 获取v变量并清空
!!VRv9601:C0/0/0/0;
!!FU&y4=3:E;怪物获胜退出
!!HEy1&y5>0:S12/y5; 归还招魂术
!!HEy2&y7>0:S12/y7;
!!HEy1&1000/y4=1:C2/x2/y6/1; 玩家参与
!!HEy2&1000/y4=2:C2/x2/y8/1;
!!HEy1&-1000/y4=1:C2/x2/y6/0; AI
!!HEy2&-1000/y4=2:C2/x2/y8/0;
!!UN:N4/-1/12; z-1=招魂术的名称（可能被改变）
!!UN:N3/-2/x2/1; z-2=招魂怪物名称
!!IF&1000/y4=1:Q51/21/x2/1^通过{%Z-1}，你的英雄能把{%Y6}个敌军阵亡者变成{%Z-2}^;
!!IF&1000/y4=2:Q51/21/x2/1^通过{%Z-1}，你的英雄能把{%Y8}个敌军阵亡者变成{%Z-2}^;
!!UN:R1;
!?FU10004&x1=4; 同子函数1，增加了x7=英雄编号，来限制招魂术
!!FU&x2<>x7:E;
!!FU10004:P1/x2/x3/x4/x5/x6;
!?FU10004&x1=5; 同子函数3，增加了x3=英雄编号，来限制招魂术
!!BA:H0/?y1; 进攻方
!!BA:H1/?y2; 防守方
!!FU&x3<>y1/x3<>y2:E;
!!FU10004:P3/x2;
!?BA1;
!!FU10004:P5/159/78;问题一：招魂塔和灵塔计算，有办法实现吗。我发现没有招魂塔加成我招募骷髅数量和电脑计算的基本一致，但是加上那个就比电脑还少了。有些郁闷。
回复 27# 的帖子
要计算招魂塔和灵塔，大概需要以下步骤1.该英雄所属颜色 （HE:O?)
2.历遍该颜色玩家在地图上所有城镇
3.计算墓园城镇中，关于招魂塔和灵塔的个数（CA:B?检测是否已建立）
4.按照计算方式来计算增加招魂比例。
历遍城镇的方法，可参照寻梦人版主的脚本
城堡生物巢穴自动升级脚本
http://www.h3wog.com/viewthread.php?tid=38461
[ 本帖最后由 贤知有您 于 2013-1-15 09:09 编辑 ]
回复 28# 的帖子
靠，版主神马问题都能解答。我有空了马上加进去。回复 28# 的帖子
改好了，灵塔和招魂塔招魂术加成，修正了一些BUG!?BR;!!FU&v997<>-1:E; 在-1回合进行操作 注意会运行在”英雄特长加强“的生物奖励之前
!!BA:H0/?y1; 进攻方英雄
!!BA:H1/?y2; 防守方英雄
*维得尼娜，招魂术鬼魂特长：招魂术招募到的生物为鬼魂
*英雄编号：78
*生物编号：鬼魂 159
!!FU10004:P4/y1/0/159/9601/9602/78;进攻方招魂术等级、招魂数v9601 v9602
!!FU10004:P4/y2/1/159/9603/9604/78;防守方招魂术等级、招魂数v9603 v9604
*** 函数编号：10004
*** 功能：实现伪招魂术
*** 遗憾：不计算灵塔和招魂塔 小弟实在没有找到计算方法
*** 算法：参考死亡阴影招魂大揭秘，每队敌军数*招魂比例取整。若敌怪物血
*** 比目标怪物低，就结果再乘以 敌怪物/目标怪物在取整。最后求和，
*** 至少要招募一个
*** 配合触发器：BR BA1
*** x1 = 功能编号1 x2 = 英雄编号 x3 = 0（进攻）/ 1（防守） x4 = 招魂生物ID
*** x5 = 保存招魂术等级的v变量索引 x6 = 保存招魂个数的 v变量索引
!?FU10004&x1=1;
!!FU&x2<=0:E; 英雄编号大于0
!!HEx2:S12/?y1; y1=招魂术等级
!!FU&y1=0:E; 没有招魂术退出
!!VRy2:+y1 *10; y2=招魂术招魂比例
!!HEx2:A2/130/?y3/?y4; y3废弃 y4=装备区鬼王斗篷数量
!!FU&y4=1:E; 有了鬼王斗篷，不需要本特长了，嘿嘿嘿嘿嘿嘿嘿
!!HEx2:A2/54/?y3/?y4; y3废弃 y4=装备区亡灵护身符数量
!!VRy2&y4=1:+5;
!!HEx2:A2/55/?y3/?y4; y3废弃 y4=装备区亡吸血鬼斗篷数量
!!VRy2&y4=1:+10;
!!HEx2:A2/56/?y3/?y4; y3废弃 y4=装备区亡死神靴数量
!!VRy2&y4=1:+15;
!!HEx2:X?y5/?y6/?y7/?y8/?y9/?y10/?y11; y5=英雄特技类型，y6=子选项 其他废弃
!!HEx2:E?y7/?y8; y7=英雄经验 y8=英雄等级数 其他废弃
!!VRy9:S0;
!!VRy9&y5=0/y6=12:+y8 *5 *y1 :10; y9=招魂术特长加成点
!!VRy9&y5=0/y6=12/y9=0:+1; 至少为1
!!VRy2:+y9;
!!HEx2:O?y10; y10英雄所属玩家
!!OW:Wy10/?y11; y11=玩家城镇数量
!!VRy11:-1; -1才能是正确的下标
!!VRvx5:S0;
!!DO10004/0/y11/1:P6/x5;招魂塔加成和灵塔加成
!!VRy2:+vx5;
!!VRy2&y2>100:S100; 当然，不能大于100，不能逆天了不是
!!VRvx5:S0;
!!VRvx6:S0;
!!VRvx5:+y1; vx3保存招魂术等级
!!HEx2:S12/0; 删除招魂术
!!DO10004/21/41/1&x3=0:P2/x4/y2/x6;
!!DO10004/0/20/1&x3=1:P2/x4/y2/x6;
!!VRvx6&vx6=0:+1; 至少复活一个
!?FU10004&x1=2; x2=招魂生物 x3=招魂率 x4=招魂数量v变量下标，该变量用于累加
!!BMx16:T?y1; y1=怪物类型
!!FU&y1<0:E;不是生物或者战争工具退出
!!FU&y1>=145/y1<=149:E;
!!BMx16:B?y2; y2=怪物数量
!!BMx16:H?y3; y3=怪物血量
!!MA:Px2/?y4; y4=招魂怪物血量
!!VRy5:+y2 *x3 :100; 计算招魂量保存于y5
!!VRy5&y3<y4:*y3 :y4; 如果怪物血量小于招魂怪物就 x怪物血量 / 目标血量
!!VRvx4:+y5;
!?FU10004&x1=3; x2=招魂生物
!!BA:H0/?y1; 进攻方
!!BA:H1/?y2; 防守方
!!HEy1:O?y3; 检查进攻方英雄所属，为-1则战败
!!VRy4&y3>=0:S1; 进攻方获胜
!!VRy4&y3<0/y2>0:S2; 防守方获胜
!!VRy4&y3<0/y2=-2:S3; 怪物获胜
!!VRv9601:C?y5/?y6/?y7/?y8; 获取v变量并清空
!!VRv9601:C0/0/0/0;
!!FU&y4=3:E;怪物获胜退出
!!HEy1&y5>0:S12/y5; 归还招魂术
!!HEy2&y7>0:S12/y7;
!!HEy1&1000/y4=1:C2/x2/y6/1; 玩家参与
!!HEy2&1000/y4=2:C2/x2/y8/1;
!!HEy1&-1000/y4=1:C2/x2/y6/0; AI
!!HEy2&-1000/y4=2:C2/x2/y8/0;
!!UN:N4/-1/12; z-1=招魂术的名称（可能被改变）
!!UN:N3/-2/x2/1; z-2=招魂怪物名称
!!VRy9&y4=1:+y1;
!!VRy9&y4=2:+y2;
!!HEy9:O?y10;
!!OW:Iy10/?y11;
!!IF&1000/y11=0:Q51/21/x2/1^通过{%Z-1}，你的英雄能把{%Y6}个敌军阵亡者变成{%Z-2}^;
!!UN:R1;
!?FU10004&x1=4; 同子函数1，增加了x7=英雄编号，来限制招魂术
!!FU&x2<>x7:E;
!!FU10004:P1/x2/x3/x4/x5/x6;
!?FU10004&x1=5; 同子函数3，增加了x3=英雄编号，来限制招魂术
!!BA:H0/?y1; 进攻方
!!BA:H1/?y2; 防守方
!!FU&x3<>y1/x3<>y2:E;
!!FU10004:P3/x2;
!?FU10004&x1=6; 计算招魂塔和灵塔的累积招魂加成 x2=v变量的索引
!!CA0/x16:T?y1;
!!CA0/x16&y1=4:B3/21; 招魂塔是否建立
!!VRvx2&1:+5;
!!CA0/x16&y1=4:B3/26; 是否建造了奇迹
!!VRvx2&1:+20;
!?BA1;
!!FU10004:P5/159/78;
回复 30# 的帖子
楼主有编程基础，上手很快啊。我倒希望楼主运用编程能力，创作一个DLL接口
使得生物能够连续攻击大于3次。
那才叫爽，以前有个SOD的英雄作弊器，就是允许生物攻击超过3次以上的。
;go;
回复 31# 的帖子
接口一般要他提供了。我玩的ERA是2.3的，有插件功能，是些DLL。对了，版主会不会添加生物，我那个一直没搞定，想添加个生物来着，真可惜。
页:
1
[2]
