全特长英雄2012奥运版发布
作为一个万年潜水员兼资深伸手党，俺很高兴能够对论坛有所回馈，现发布全特长英雄2012奥运版。本篇的特点如下：
1.全自动，不用玩家手工修改指定英雄，只要是玩家控制的英雄就享有全特长加成。在英雄背叛玩家之后，所有特长失效，即使被敌人雇佣，敌人也只能得到一个副英雄。
2.玩家的战士型英雄获得额外20%伤害加成，法师型英雄魔法杀伤力为正常的3倍。
3.玩家非鬼族英雄获得招魂术外的所有技能，鬼族英雄加上100%招魂。
4.破魔特长，玩家英雄每级降低魔抗3%。破魔只在玩家放魔法时有效，有黑球的优点却没有黑球的弱点。
5玩家英雄具有免费的GELU和DRACON特长，3种射手之间可循环转换(英雄界面CTRL+左键)，.玩家英雄天生会飞/跳/回城魔法
缺点：
1.累加的抗魔能力只在敌人放魔法时有效，自己放魔法时的抗魔只有正常的高级抗魔(30%)。
2.英雄放地图魔法时，必须先打开英雄界面，否则添加飞/跳/回城无效。
代码如下：
;;全特长2012奥运版 作者：杨威利
;;特别感谢 克招(翻译ERM中文帮助) genman(原全特长作者，本篇参考了genman前辈的作品) lysfox(BT技能修改作者)
;;使用变量/函数： TM97,FU131,132,V97-99
;;作用： 玩家所有英雄具有全部辅助技能，及几乎所有有用的技能特长，和原英雄特长完美叠加
;; 玩家非鬼族英雄获得招魂术外的所有技能，鬼族英雄加上100%招魂。
;; 玩家英雄有破魔特长，降敌人3%/级魔抗
;; 玩家英雄具有免费的GELU和DRACON特长，3种射手之间可循环转换(英雄界面CTRL+左键)
;; 玩家英雄天生会飞/跳/回城魔法
!#TM97:S1/999/1/255; 每天触发
!?TM97&1000; 轮到玩家行动时执行
!!OW:H-1/97/0; 取玩家英雄数
!!DO132/1/v97/1:P; 以英雄数为循环
!?FU132;
!!OW:H-1/99/x16; 英雄编号存于V99
!!HEv99:E?y-1/?v98/1; 经验y-1等级v98
!!HEv99:S1/0 S6/0 S10/0 S11/0 S14/0 S15/0 S16/0 S17/0 S19/0 S22/0 S23/0 S26/0 S27/0 S12/0;取消战斗相关技能
!!HEv99:S13/3 S0/3 S3/3 S25/3 S27/3 S8/3 S20/3 S24/3 S9/9 S18/12 S21/19 S7/3 S2/3 S4/3 S5/3 S26/3; 给理财外交寻路侦察航海智慧神秘幸运教学炮术学习智力魔力急救
!!HEv99&v99>63/v99<80:S12/58; 鬼族英雄100%招魂
!!HEv99:W?y-21; 原移动力
!!VRy21:Sy-21*v98*15:1000+y-21; 按1.5%/等级计算增加的移动力
!!HEv99:Wy21; 增加移动力
!!HEv99:Gy21; 和每天开始时一致，以便挖宝
!!VRy-22:Sv98*500:20; 按5%/等级计算增加的金钱
!!HEv99:Y21/y-22/1/1; 增加金钱
!?BF&1000; 有玩家参与的战斗
!!OW:I-1/?v99; v99=0则进攻方为玩家，1则为AI
!!BA:H0/?y1 H1/?y2; y1进攻方英雄编号y2防御方英雄编号
!!VRv98:S0; 玩家英雄等级先清0
!!DO131/0/20/1&v99=0:Py1; 取进攻方英雄编号
!!DO131/21/41/1&v99=1/y2>-1:Py2; 取防御方英雄编号(如有英雄)
!?FU131;
!!VRv97:Sx1;
!!HEv97:B2/?y-2 E?y-1/?v98/1; 玩家英雄编号v97等级v98类型y-2
!!VRy-2:%2; y-2=0战士，1法师
!!HEv97:S1/3 S6/3 S10/8 S11/7 S14/3 S15/3 S16/3 S17/3 S19/6 S22/3 S23/3; 给战斗相关技能
!!BMx16:T?y-3; 怪物类型y-3
!!FU&y-3=145:E; 排除投石车
!!FU&y-3=147:E; 帐篷
!!FU&y-3=148:E; 弹药车
!!FU&y-3=149:E; 箭塔
!!BMx16:H?y-31; 每级增加部队5%的生命
!!VRy-31:*v98:20;
!!BMx16:Hdy-31;
!!BMx16:A?y-32; 每级增加部队2%的攻击
!!VRy-32:*v98:50;
!!BMx16:Ady-32;
!!BMx16:D?y-33; 每级增加部队2%的防御
!!VRy-33:*v98:50;
!!BMx16:Ddy-33;
!!BMx16:U1/?y-34; 每级增加部队2%的最低伤害
!!VRy34:Sy-34*v98:50+y-34;
!!VRy34&y-2=0:*12:10; 战士加20%伤害
!!BMx16:U1/y34;
!!BMx16:U2/?y-35; 每级增加部队2%的最高伤害
!!VRy35:Sy-35*v98:50+y-35;
!!VRy35&y-2=0:*12:10; 战士加20%伤害
!!BMx16:U2/y35;
!!BMx16:U3/?y-36;
!!VRy-36&y-2=0:*2; 战士箭数翻倍
!!BMx16:U3/?y-36;
!!VRy-37:Sv98:10; 每10级增加1点速度
!!BMx16&y-3<>146:Sdy-37;
!?MR0&1000; 产生魔法伤害
!!OW:I-1/?y-1; Y-1=0则当前为玩家，1则当前为AI
!!FU&y-1=1:E; AI放魔法则结束
!!HEv97:B2/?y-2;
!!VRy-2:%2; y-2=0战士，1法师
!!MR:D?y-21; 原伤害
!!VRy21:Sy-21*v98*15:1000+y-21; 按1.5%/等级增加的伤害
!!VRy21&y-2=1:*3; 法师伤害*3
!!MR:Dy21;
!?MR2&1000; 魔法抵抗
!!BG:Q?y-1; y-1=0攻击方1防御方
!!VRy11:Sv98*15:10+30; 按1.5%/等级增加的抗魔
!!VRy12:Sv98*3; 按3%/等级增加的破魔
!!VRy11&y11>99:S99; 抗魔封顶99%，防止AI不能魔法攻击而对自己放增益魔法
!!MR:F?y-2;
!!VRy12:Sy-2-y12;
!!VRy12&y12<0:S0;
!!MR&v99=0/y-1=1:Fy11; AI放魔法则抗魔
!!MR&v99=1/y-1=0:Fy11; AI放魔法则抗魔
!!MR&v99=0/y-1=0:Fy12; 玩家放魔法则破魔
!!MR&v99=1/y-1=1:Fy12; 玩家放魔法则破魔
!?MF1&1000; 产生物理伤害
!!BG:A?y1 Q?y2; y1=7射击，y2=0攻击方1防御方
!!MF:D?y-21 D?y-22 D?y-23; 原伤害
!!VRy21:Sy-21*v98:100; 按1%/等级减少的伤害
!!VRy-21:-y21; 减少伤害
!!VRy-21&y-21<1:S1;
!!MF&v99=0/y2=1:Fy-21; 攻击方为玩家时，防御方造成伤害时触发
!!MF&v99=1/y2=0:Fy-21; 攻击方为AI时，攻击方造成伤害时触发
!!VRy22:Sy-22*v98*15:1000; 按1.5%/等级增加的伤害(进攻术)
!!MF&v99=0/y2=0/y1<>7:Fdy22; 攻击方为玩家时，攻击方造成非射击伤害时触发
!!MF&v99=1/y2=1/y1<>7:Fdy22; 攻击方为AI时，防御方造成非射击伤害时触发
!!VRy23:Sy-23*v98*:40; 按2.5%/等级增加的伤害(箭术)
!!MF&v99=0/y2=0/y1=7:Fdy23; 攻击方为玩家时，攻击方造成射击伤害时触发
!!MF&v99=1/y2=1/y1=7:Fdy23; 攻击方为AI时，防御方造成射击伤害时触发
!?BA1&1000; 战斗结束时
!!HEv97:S1/0 S6/0 S10/0 S11/0 S14/0 S15/0 S16/0 S17/0 S19/0 S22/0 S23/0;取消战斗相关技能
!?MG0&1000; 玩家使用地图魔法
!!HE-1:S14/3 S15/3 S16/3 S17/3; 设置4系高级
!!HE-1:M6/1 M8/1 M9/1; 增加飞/跳/回城
!?MG1&1000;
!!HE-1:S14/0 S15/0 S16/0 S17/0; 取消4系
!!HE-1:M6/0 M8/0 M9/0; 取消飞/跳/回城
!?CM2; 英雄信息场景中鼠标点击触发
!!CM:I?y-1 F?y-2;
!!FU&y-2<>4:E; 非CTRL+左键点部队格则结束
!!FU&y-1<68:E;
!!FU&y-1>74:E;
!!VRy-1:-68; 转换为部队格数
!!HE-1:C0/y-1/?y11/?y12; 检查当前格部队编号及数量
!!FU&y12=0:E; 当前格无部队则结束
!!HE-1&y11=8:C0/y-1/136/d/0/5; DRACON特长
!!HE-1&y11=9:C0/y-1/136/d/0/5;
!!HE-1&y11=34:C0/y-1/136/d/0/5;
!!HE-1&y11=35:C0/y-1/136/d/0/5;
!!HE-1&y11=2:C0/y-1/137/d/0/5; GELU特长
!!HE-1&y11=3:C0/y-1/137/d/0/5;
!!HE-1&y11=18:C0/y-1/137/d/0/5;
!!HE-1&y11=19:C0/y-1/137/d/0/5;
!!HE-1&y11=137:C0/y-1/170/d/0/5; 幻影升极地
!!HE-1&y11=170:C0/y-1/171/d/0/5;
!!HE-1&y11=171:C0/y-1/137/d/0/5;
[ 本帖最后由 杨威利 于 2012-8-6 09:42 编辑 ] 这个太强了……用来过bt图倒是挺不错的。不过稍微提一下，鬼族英雄100%招魂那里，漏掉了150号英雄死亡骑士罗德哈特。
加一行：!!HEv99&v99=150:S12/58;
就可以了 天生会 二次元 这个太牛A了.
;kaun;
回复 2# 的帖子
多谢提醒赞一下楼主
原帖由 贤知有您 于 2012-8-6 10:14 发表 http://bbs.h3wog.com/images/common/back.gif天生会 二次元 这个太牛A了.
;kaun;
如果加个每天自动使用异次元回城，而且不耗魔，就更牛A了;kl; 。
回复 5# 的帖子
还可以加个强制 战争枷锁,战斗中敌人都不能逃跑,但自己却可以;kaun; 好东西啊 原帖由 贤知有您 于 2012-8-6 11:12 发表 http://bbs.h3wog.com/images/common/back.gif
还可以加个强制 战争枷锁,战斗中敌人都不能逃跑,但自己却可以
;kaun;
敌英雄逃跑时取消动作或强制投降;orz; 对了，有没有办法取消异次元的使用次数限制呢？就算不是后勤特也可以一天跑遍整个地图了
回复 9# 的帖子
感觉应该可以，但没试过，先激活英雄-施放魔法。回复 10# 的帖子
无限二次元..汗一个如果无限移动力再+飞行,那也是非常恐怖的. 汗汗，你们说的也太BT了吧，这个只是加强的脚本，会随着英雄成长增强的，这样比较有成就感。如果一开始就无敌了，一会儿就会索然无味，玩不下去了
PS 把气系技能改成8就可以不限次数次元门，一次好像只耗4的魔，只是这样会导致飞行不能用。有1%的机会，次元门有地方到不了，只有飞行能到，这时候就杯具了 把气系技能改成8就可以不限次数次元门
这样改方便点,好主意.
;jx; 悲剧倒不至于，反正能改到8也能改回到3，何况还有炽天之翼
不过真不知道元素系技能改高了也会有这种变化 速度还挺快的，前两天才找的参考脚本，今天就做出来了。 不知道有没有人做个测试.
所有技能从 0 改到 8时会出现什么情况.
比如沧版说过,战术改的更大,比对方的高出7级时,已经能全屏幕布阵了.
如果有鞋童列出来了,一定给加分!!
;tl;
回复 16# 的帖子
所有技能的特殊值都已经测出来了，就是俺特别感谢的那个牛人。4系只有8有用，其它技能的特殊值基本俺都写在脚本里了，你仔细找找就看到了回复 15# 的帖子
前2天就做出来了，周末在打亵渎顺便测试一下，中间改了好几次。 分体移植成功=_,=模块化真是好事情~~ 原帖由 十三木人 于 2012-8-6 12:48 发表 http://bbs.h3wog.com/images/common/back.gif
悲剧倒不至于，反正能改到8也能改回到3，何况还有炽天之翼
不过真不知道元素系技能改高了也会有这种变化
呵呵，幽灵型的气元素召唤，可以去试试。;oweojs;
页:
[1]
2
