一个好玩的指挥官erm增强
其实说来说去我觉得很多人都误解我意思了我本意是说，麻痹会削弱凝视的效果，因而才想到了这个该法……不否认我更喜欢最求“暴力”，但我的这个帖子的出发点就是很简单的想法：“没道理越学越弱吧？，但麻痹和凝视的同事拥有的确是越学越弱了，所以才想着能否改改”
首先声明，我不是作者……原作者是谁我也不知道了……
这个erm我个人感觉很有意思，比大多数指挥官增强都好玩，可惜一直被埋没，没有在太多的地方被提到
现在贴上来，大家可以试试，很有意思
注意，请自己把rar改为erm……因为我这边没有rar压缩文件，而论坛又限制上传类型，so……
另，哪位朋友可以帮忙改改，不知道wog的技能出现是否有顺序？我发现死亡凝视的效果似乎会被麻痹影响，只有死亡凝视时能瞪死好几个，但有了麻痹后就只能瞪死1~3个了，最要命的是经常先麻痹再凝视……能否改成先凝视后麻痹，或者干脆把麻痹换成毒液之类的不影响凝视效果的技能？（例如双倍？）
ZVSE
ERMS_PoweredBy=ERM Scripter v. 2004.6.29.918
ERMS_ScriptDate=13.5(May).2005
_WARNING_#1=IMPORTANT! This file is not in a plain text format. NEVER use any editor except ERM_S for making any kind of changes!
ERMS_PoweredBy=ERM Scripter v. 2004.6.29.918
** ENHANCED COMMANDERS - ERM script 51
** By Arstahd
** Version: 1.11 updated October 2 2004
** Updated September 15, 2004 to change local y variables in instructions to v variables
** Special Thanks to Hermann the Weird for help with bug fixing and script maintenance
** Note: Commander Enhancements are disabled for network human-to-human battles.
** Variables used:
** V variables: v7080-v7092 v7177, v7185
** Y variables: y1-y9
** Functions used: 7070-7074
** Timers used: none
*** commander stats are calculated to new formulae
** display will be inaccurate when hero levels up, re-open commander screen to update stat display, ignore skill descriptions
** attack - base 5 + 1/2 x level - skill adds +25%,+50%,+75%,+100%,+125%
** defence - base 5 + 1/2 x level - skill adds +25%,+50%,+75%,+100%,+125%
** hit points - base 30 + 15 x level - skill adds +25%,+50%,+75%,+100%,+125%
** damage - base 10 + 5 x level - skill adds +25%,+50%,+75%,+100%,+125%
** magic power - base 3 + 3 x skill level (Soul Eater & Astral Spirit: base 1 + 1 x skill level)
** magic resistance- base 0 + 10 x skill level
** speed - base 5 - skill adds normal bonus
** spell quantity - functions as normal (increased by magic power skill)
*** commanders each start with a special ability
** paladin - endless retaliation
** heirophant - magic mirror (fire shield)
** temple guardian - shoot
** succubus - fly
** soul eater - fear
** brute - no retaliation
** ogre leader - block
** shaman - 50% poison (death stare)
** astral spirit - ignore 50% defense
*** commander spells improved, most apply an additional spell (at adv. level) after they cast a spell
** paladin - cure/bless
** heirophant - shield/mirth
** temple guardian - prayer (precision removed)
** succubus - fire shield/bloodlust (displays Sacrifice animation)
** soul eater - animate dead (no change)
** brute - bloodlust/stoneskin
** ogre leader - stoneskin/counterstrike
** shaman - haste/fortune
** astral spirit - summon elemental (counterstrike removed)
*** commanders (except soul eater &astral spirit) are now living and can be resurrected (soul eater can still be raised with animate dead)
*** commanders are town based if bought, type depends on town not hero when you buy a new commander (dismiss old commander to buy a new one)
*** "Death Stare" ability replaced with 50% chance to cast Poison - attack or shoot
*** "Fire Shield" ability replaced with expert Magic Mirror
*** commander stones now give skills:
** opal - gives random special ability
** ruby - gives either +1 to Attack skill or Damage skill
** sapphire - gives either +1 to Defense skill or Hit Points skill
** emerald - gives either +1 to Magic skill or Speed skill
** initialization
!#UN:P51/?v7185;
!#UN:P186/?v7177;
!#UN:P3/?v1;
!#VRv7185&v1=1:S0;
!#CO-2&v7185=1:P1;
!#UN:B6/1;
** function to make commanders alive
!?FU7072;
!!MA:Xx16/?i;
!!VRi:+16;
!!VRi|x16=178/x16=187:-16;
!!MA:Xx16/i;
** end of function **
!#DO7072/174/191/1&v7185=1:P;
** end of initialization
** commander screen open trigger
!?CO0&v7185=1;
!!HE-1:N?y-1;
!!FU7070:Py-1;
** end of hero level trigger
** start of pre-battle trigger **
!?BA0&v7185=1/-998;
!!VRv7080:C-1/-1/-1/-1/-1/-1/-1/-1/-1/-1;
!!BA:H0/?v7083;
!!BA:H1/?v7085;
!!FU7070&v7083>-1:Pv7083;
!!FU7070&v7085>-1:Pv7085;
!!COv7083&v7083>-1:B0/?y-1 T?v7088;
!!COv7085&v7085>-1:B0/?y-2 T?v7089;
!!VRv7084&v7083>-1:Sy-1 &1;
!!VRv7086&v7085>-1:Sy-2 &1;
!!COv7083&v7083>-1/v7084=1:B1/0/1;
!!COv7085&v7085>-1/v7086=1:B1/0/1;
!!VRv7090&v7083>-1:Sy-1 &2;
!!VRv7091&v7085>-1:Sy-2 &2;
!!COv7083&v7083>-1/v7090=2:B1/1/1;
!!COv7085&v7085>-1/v7091=2:B1/1/1;
!!VRv9101&v7083>-1:Sy-1 &2048;
!!VRv9102&v7085>-1:Sy-2 &2048;
!!COv7083&v7083>-1/v9101=2048:B1/11/0;
!!COv7085&v7085>-1/v9102=2048:B1/11/0;
!!VRv9103&v7083>-1:Sy-1 &4;
!!VRv9104&v7085>-1:Sy-2 &4;
!!COv7083&v7083>-1/v9103=4:B1/2/1;
!!COv7085&v7085>-1/v9104=4:B1/2/1;
** end of function
---------------------------------------------------------------------
** pre-action trigger **
!?BG&v7185=1/-998;
!!BG:N?v7080 A?v7081 E?v7082;
!!BMv7082&v7082>-1:R?v7087;
!!BMv7080&v7080>-1:T?v7092;
!!VRy-2&v7092=182/v7081=10:S66 T3;
!!BMv7080&v7092=182/v7081=10:U4/y-2;
!!VRy-2&v7092=191/v7081=10:S66 T3;
!!BMv7080&v7092=191/v7081=10:U4/y-2;
** end of pre-action trigger **
===============================================================================
** post-action trigger **
!?BG1&v7185=1/-998;
!!BMv7080&v7080>-1:T?y-3 I?y-4;
!!FU7071&y-3>=174/y-3<=191/v7081=10:Pv7080/y-3;
!!BMv7082&v7082>-1:F?y-7 P?y-8;
!!VRy-10&y-3>=174/y-3<=191/v7081>=6/v7081<=7/v7084=1/y-4=0:S0 R99;
!!VRy-11&y-3>=174/y-3<=191/v7081>=6/v7081<=7/v7086=1/y-4=1:S0 R99;
!!FU7073&y-3>=174/y-3<=191/v7081>=6/v7081<=7/v7084=1/y-4=0/y-10<100:Py-7/y-8;
!!FU7073&y-3>=174/y-3<=191/v7081>=6/v7081<=7/v7086=1/y-4=1/y-11<100:Py-7/y-8;
!!BMv7080&v7092=182/v7081=10:U4/58;
!!BMv7080&v7092=191/v7081=10:U4/58;
** retaliation attack
!!BMv7082&v7082>-1:T?y-3 I?y-4 P?y-5;
!!BU&v7082>-1:Ey-5/?y-6;
!!BMv7080&v7080>-1:F?y-9;
!!VRy-9&v7080>-1:&65536;
!!BMv7080&v7080>-1:F?y-7 P?y-8;
!!VRy-10&y-3>=174/y-3<=191/v7081=6/v7084=1/v7087>0/y-4=0/y-6>-1/y-9=0:S0 R99;
!!VRy-11&y-3>=174/y-3<=191/v7081=6/v7086=1/v7087>0/y-4=1/y-6>-1/y-9=0:S0 R99;
!!FU7073&y-3>=174/y-3<=191/v7081=6/v7084=1/v7087>0/y-4=0/y-10<100/y-6>-1/y-9=0:Py-7/y-8;
!!FU7073&y-3>=174/y-3<=191/v7081=6/v7086=1/v7087>0/y-4=1/y-11<100/y-6>-1/y-9=0:Py-7/y-8;
!!BU:C?y-1;
!!COv7083&v7083>-1/v7084=1/y-1=1:B1/0/1;
!!COv7085&v7085>-1/v7086=1/y-1=1:B1/0/1;
** end of post-action trigger **
---------------------------------------------------------------
** post-action trigger **
!?BG1&v7185=1/-998;
!!BMv7080&v7080>-1:T?y-3 I?y-4;
!!FU7071&y-3>=174/y-3<=191/v7081=10:Pv7080/y-3;
!!BMv7082&v7082>-1:F?y-7 P?y-8;
!!VRy-10&y-3>=174/y-3<=191/v7081>=6/v7081<=7/v7090=2/y-4=0:S0 R99;
!!VRy-11&y-3>=174/y-3<=191/v7081>=6/v7081<=7/v7091=2/y-4=1:S0 R99;
!!FU7074&y-3>=174/y-3<=191/v7081>=6/v7081<=7/v7090=2/y-4=0/y-10<50:Py-7/y-8;
!!FU7074&y-3>=174/y-3<=191/v7081>=6/v7081<=7/v7091=2/y-4=1/y-11<50:Py-7/y-8;
!!BMv7080&v7092=182/v7081=10:U4/58;
!!BMv7080&v7092=191/v7081=10:U4/58;
** retaliation attack
!!BMv7082&v7082>-1:T?y-3 I?y-4 P?y-5;
!!BU&v7082>-1:Ey-5/?y-6;
!!BMv7080&v7080>-1:F?y-9;
!!VRy-9&v7080>-1:&65536;
!!BMv7080&v7080>-1:F?y-7 P?y-8;
!!VRy-10&y-3>=174/y-3<=191/v7081=6/v7090=2/v7087>0/y-4=0/y-6>-1/y-9=0:S0 R99;
!!VRy-11&y-3>=174/y-3<=191/v7081=6/v7091=2/v7087>0/y-4=1/y-6>-1/y-9=0:S0 R99;
!!FU7074&y-3>=174/y-3<=191/v7081=6/v7090=2/v7087>0/y-4=0/y-10<50/y-6>-1/y-9=0:Py-7/y-8;
!!FU7074&y-3>=174/y-3<=191/v7081=6/v7091=2/v7087>0/y-4=1/y-11<50/y-6>-1/y-9=0:Py-7/y-8;
!!BU:C?y-1;
!!COv7083&v7083>-1/v7090=2/y-1=1:B1/1/1;
!!COv7085&v7085>-1/v7091=2/y-1=1:B1/1/1;
** end of post-action trigger **
-----------------------------------
** post-action trigger **
!?BG1&v7185=1/-998;
!!BMv7080&v7080>-1:T?y-3 I?y-4;
!!FU7071&y-3>=174/y-3<=191/v7081=10:Pv7080/y-3;
!!BMv7082&v7082>-1:F?y-7 P?y-8;
!!VRy-10&y-3>=174/y-3<=191/v7081>=6/v7081<=7/v9101=2048/y-4=0:S0 R99;
!!VRy-11&y-3>=174/y-3<=191/v7081>=6/v7081<=7/v9102=2048/y-4=1:S0 R99;
!!FU9075&y-3>=174/y-3<=191/v7081>=6/v7081<=7/v9101=2048/y-4=0/y-10<40:Py-7/y-8;
!!FU9075&y-3>=174/y-3<=191/v7081>=6/v7081<=7/v9102=2048/y-4=1/y-11<60:Py-7/y-8;
!!BMv7080&v7092=182/v7081=10:U4/58;
!!BMv7080&v7092=191/v7081=10:U4/58;
** retaliation attack
!!BMv7082&v7082>-1:T?y-3 I?y-4 P?y-5;
!!BU&v7082>-1:Ey-5/?y-6;
!!BMv7080&v7080>-1:F?y-9;
!!VRy-9&v7080>-1:&65536;
!!BMv7080&v7080>-1:F?y-7 P?y-8;
!!VRy-10&y-3>=174/y-3<=191/v7081=6/v9101=2048/v7087>0/y-4=0/y-6>-1/y-9=0:S0 R99;
!!VRy-11&y-3>=174/y-3<=191/v7081=6/v9102=2048/v7087>0/y-4=1/y-6>-1/y-9=0:S0 R99;
!!FU9075&y-3>=174/y-3<=191/v7081=6/v9101=2048/v7087>0/y-4=0/y-10<40/y-6>-1/y-9=0:Py-7/y-8;
!!FU9075&y-3>=174/y-3<=191/v7081=6/v9102=2048/v7087>0/y-4=1/y-11<60/y-6>-1/y-9=0:Py-7/y-8;
!!BU:C?y-1;
!!COv7083&v7083>-1/v9101=2048/y-1=1:B1/11/1;
!!COv7085&v7085>-1/v9102=2048/y-1=1:B1/11/1;
** end of post-action trigger **
---------------------------------------------------------------------------
** post-action trigger **
!?BG1&v7185=1/-998;
!!BMv7080&v7080>-1:T?y-3 I?y-4;
!!FU7071&y-3>=174/y-3<=191/v7081=10:Pv7080/y-3;
!!BMv7082&v7082>-1:F?y-7 P?y-8;
!!VRy-10&y-3>=174/y-3<=191/v7081>=6/v7081<=7/v9103=4/y-4=0:S0 R99;
!!VRy-11&y-3>=174/y-3<=191/v7081>=6/v7081<=7/v9104=4/y-4=1:S0 R99;
!!FU9076&y-3>=174/y-3<=191/v7081>=6/v7081<=7/v9103=4/y-4=0/y-10<50:Py-7/y-8;
!!FU9076&y-3>=174/y-3<=191/v7081>=6/v7081<=7/v9104=4/y-4=1/y-11<50:Py-7/y-8;
!!BMv7080&v7092=182/v7081=10:U4/58;
!!BMv7080&v7092=191/v7081=10:U4/58;
** retaliation attack
!!BMv7082&v7082>-1:T?y-3 I?y-4 P?y-5;
!!BU&v7082>-1:Ey-5/?y-6;
!!BMv7080&v7080>-1:F?y-9;
!!VRy-9&v7080>-1:&65536;
!!BMv7080&v7080>-1:F?y-7 P?y-8;
!!VRy-10&y-3>=174/y-3<=191/v7081=6/v9103=4/v7087>0/y-4=0/y-6>-1/y-9=0:S0 R99;
!!VRy-11&y-3>=174/y-3<=191/v7081=6/v9104=4/v7087>0/y-4=1/y-6>-1/y-9=0:S0 R99;
!!FU9076&y-3>=174/y-3<=191/v7081=6/v9103=4/v7087>0/y-4=0/y-10<50/y-6>-1/y-9=0:Py-7/y-8;
!!FU9076&y-3>=174/y-3<=191/v7081=6/v9104=4/v7087>0/y-4=1/y-11<50/y-6>-1/y-9=0:Py-7/y-8;
!!BU:C?y-1;
!!COv7083&v7083>-1/v9103=4/y-1=1:B1/2/1;
!!COv7085&v7085>-1/v9104=4/y-1=1:B1/2/1;
** end of post-action trigger **
----------------------------------------------------------------
** function to cast poison x1=flags x2=position
!?FU7073;
!!VRx1:&16;
!!BG:N?y1;
!!BMy1:C78/x2/3/1/1;
!!BMy1:C80/x2/3/3/1;
!!VRi:S0 T4;
!!VRy12&i=0:S42;
!!VRy12&i=1:S45;
!!VRy12&i=2:S47;
!!VRy12&i=3:S54;
!!VRy12&i=4:S73;
!!BMy1:Cy12/x2/1/9/1;
** end of function **
** function to cast poison x1=flags x2=position
!?FU7074;
!!VRx1:&16;
!!BG:N?y1;
!!BMy1&x1<>16:C71/x2/1/9/1;
!!BMy1&x1=16:C75/x2/1/9/1;
** end of function **
** function to cast poison x1=flags x2=position
!?FU9075;
!!VRx1:&16;
!!BG:N?y1;
!!BMy1:C70/x2/1/5/1;
** end of function **
** function to cast poison x1=flags x2=position
!?FU9076;
!!VRx1:&16;
!!BG:N?y1;
!!VRi:S0 R99;
!!VRy12&i>=0/i<35:S16;
!!VRy12&i>=35/i<65:S17;
!!VRy12&i>=65/i<85:S57;
!!VRy12&i>=85/i<100:S18;
!!BMy1:Cy12/x2/2/9/1;
** end of function **
-----------------------------------------------------------------------------
==============================================================================
** post-buy commander trigger **
!?CO2&v7185=1/v7177<>1;
!!HE-1:P?y-1/?y-2/?y-3;
!!OBy-1/y-2/y-3:U?y-4;
!!CO-1:Ty-4;
** end of post-buy commander trigger **
** function to edit commander stats
!?FU7070; x1=hero number
!!COx1:X2/?y2 T?y5;
** attack - base 5 + 1/2 x level - skill adds +25%,+50%,+75%,+100%,+125%
!!COx1:S0/?y3;
!!VRy4&y3=0:Sy2 :2 +5;
!!VRy4&y3=1:Sy2 :2 +5 *125 :100 -2;
!!VRy4&y3=2:Sy2 :2 +5 *150 :100 -5;
!!VRy4&y3=3:Sy2 :2 +5 *175 :100 -9;
!!VRy4&y3=4:Sy2 :2 +5 *2 -15;
!!VRy4&y3=5:Sy2 :2 +5 *225 :100 -25;
!!COx1:P0/y4;
** defense - base 5 + 1/2 x level - skill adds +25%,+50%,+75%,+100%,+125%
!!COx1:S1/?y3;
!!VRy4&y3=0:Sy2 :2 +5;
!!VRy4&y3=1:Sy2 :2 +5 *125 :100 -4;
!!VRy4&y3=2:Sy2 :2 +5 *150 :100 -10;
!!VRy4&y3=3:Sy2 :2 +5 *175 :100 -18;
!!VRy4&y3=4:Sy2 :2 +5 *2 -30;
!!VRy4&y3=5:Sy2 :2 +5 *225 :100 -50;
!!COx1:P1/y4;
** hit points - base 30 + 15 x level - skill adds +25%,+50%,+75%,+100%,+125%
!!COx1:S2/?y3;
!!VRy4&y3=0:Sy2 *20 +40;
!!VRy4&y3=1:Sy2 *20 +40 *125 :110;
!!VRy4&y3=2:Sy2 *20 +40 *150 :125;
!!VRy4&y3=3:Sy2 *20 +40 *175 :145;
!!VRy4&y3=4:Sy2 *20 +40 *200 :170;
!!VRy4&y3=5:Sy2 *20 +40 *225 :200;
!!COx1:P2/y4;
** damage - base 10 + 5 x level - skill adds +25%,+50%,+75%,+100%,+125%
!!COx1:S3/?y3;
!!VRy4&y3=0:Sy2 *5 +10;
!!VRy4&y3=1:Sy2 *5 +10 *125 :110;
!!VRy4&y3=2:Sy2 *5 +10 *150 :125;
!!VRy4&y3=3:Sy2 *5 +10 *175 :145;
!!VRy4&y3=4:Sy2 *5 +10 *200 :170;
!!VRy4&y3=5:Sy2 *5 +10 *225 :200;
!!COx1:P3/y4;
** magic power - base 3 + 3 x skill level (Soul Eater: base 1 + 1 x skill level)
!!COx1:S4/?y3;
!!VRy6:Sy3 +1 *3;
!!VRy6&y5=4:Sy3 +1;
!!VRy6&y5=8:Sy3 +1;
!!VRy4&y3=0:Sy6;
!!VRy4&y3=1:Sy6 -1;
!!VRy4&y3=2:Sy6 -3;
!!VRy4&y3=3:Sy6 -7;
!!VRy4&y3=4:Sy6 -14;
!!VRy4&y3=5:Sy6 -29;
!!COx1:P4/y4;
** magic resistance - base 0 + 10 x skill level
!!VRy4&y3=0:S0;
!!VRy4&y3=1:S5;
!!VRy4&y3=2:S5;
!!VRy4&y3=3:S5;
!!VRy4&y3=4:S5;
!!VRy4&y3=5:S5;
!!COx1:P6/y4;
** speed - base 5 - skill adds normal bonus
!!COx1:P5/5;
** starting special bonus
!!COx1&y5=0:B1/13/1;
!!COx1&y5=1:B1/11/1;
!!COx1&y5=2:B1/4/1;
!!COx1&y5=3:B1/14/1;
!!COx1&y5=4:B1/1/1;
!!COx1&y5=5:B1/2/1;
!!COx1&y5=6:B1/3/1;
!!COx1&y5=7:B1/0/1;
!!COx1&y5=8:B1/7/1;
!!VRx1:+1;
** end of function
========================================================================
-----------------------------------------------------------------------
** object trigger - opal
!?OB101/7&v7185=1;
!!HE-1:N?y-1;
!!VRy-4:S0 T14;
!!VRz2&y-4=0:Sz151000;
!!VRz2&y-4=1:Sz151001;
!!VRz2&y-4=2:Sz151002;
!!VRz2&y-4=3:Sz151003;
!!VRz2&y-4=4:Sz151004;
!!VRz2&y-4=5:Sz151005;
!!VRz2&y-4=6:Sz151006;
!!VRz2&y-4=7:Sz151007;
!!VRz2&y-4=8:Sz151008;
!!VRz2&y-4=9:Sz151009;
!!VRz2&y-4=10:Sz151010;
!!VRz2&y-4=11:Sz151011;
!!VRz2&y-4=12:Sz151012;
!!VRz2&y-4=13:Sz151013;
!!VRz2&y-4=14:Sz151014;
!!COy-1:B1/y-4/?y-5 D?y-6 E?y-7 N?z1;
!!OB998&y-6=0/y-7=1:T101 U6;
!!COy-1&y-5=0/y-6=0/y-7=1:B1/y-4/1;
!!IF&y-5=0/y-6=0/y-7=1/1000:M1/z151015;
!!IF&y-5=1/1000:M1/z151016;
** end of object trigger
** object trigger - ruby
!?OB101/8&v7185=1;
!!HE-1:N?y-1;
!!COy-1:S0/?y-2 S3/?y-3 D?y-6 E?y-7 N?z1;
!!OB998&y-6=0/y-7=1:T101 U6;
!!COy-1&y-6=0/y-7=1/y-2>y-3:S3/d1;
!!COy-1&y-6=0/y-7=1/y-2<y-3:S0/d1;
!!VRy-4&y-6=0/y-7=1/y-2=y-3/y-2<5:S0 T99;
!!COy-1&y-6=0/y-7=1/y-2=y-3/y-2<5/y-4<50:S3/d1;
!!COy-1&y-6=0/y-7=1/y-2=y-3/y-2<5/y-4>49:S0/d1;
!!IF&1000/y-6=0/y-2>y-3:M1/z151017;
!!IF&1000/y-6=0/y-2<y-3:M1/z151018;
!!IF&1000/y-6=0/y-2=y-3/y-2<5/y-4<50:M1/z151019;
!!IF&1000/y-6=0/y-2=y-3/y-2<5/y-4>49:M1/z151020;
!!IF&1000/y-6=0/y-2=y-3/y-2>4:M1/z151021;
** end of object trigger
** object trigger - sapphire
!?OB101/9&v7185=1;
!!HE-1:N?y-1;
!!COy-1:S1/?y-2 S2/?y-3 D?y-6 E?y-7 N?z1;
!!OB998&y-6=0/y-7=1:T101 U6;
!!COy-1&y-6=0/y-7=1/y-2>y-3:S2/d1;
!!COy-1&y-6=0/y-7=1/y-2<y-3:S1/d1;
!!VRy-4&y-6=0/y-7=1/y-2=y-3/y-2<5:S0 T99;
!!COy-1&y-6=0/y-7=1/y-2=y-3/y-2<5/y-4<50:S2/d1;
!!COy-1&y-6=0/y-7=1/y-2=y-3/y-2<5/y-4>49:S1/d1;
!!IF&1000/y-6=0/y-2>y-3:M1/z151022;
!!IF&1000/y-6=0/y-2<y-3:M1/z151023;
!!IF&1000/y-6=0/y-2=y-3/y-2<5/y-4<50:M1/z151024;
!!IF&1000/y-6=0/y-2=y-3/y-2<5/y-4>49:M1/z151025;
!!IF&1000/y-6=0/y-2=y-3/y-2>4:M1/z151026;
** end of object trigger
** object trigger - emerald
!?OB101/10&v7185=1;
!!HE-1:N?y-1;
!!COy-1:S4/?y-2 S5/?y-3 D?y-6 E?y-7 N?z1;
!!OB998&y-6=0/y-7=1:T101 U6;
!!COy-1&y-6=0/y-7=1/y-2>y-3:S5/d1;
!!COy-1&y-6=0/y-7=1/y-2<y-3:S4/d1;
!!VRy-4&y-6=0/y-7=1/y-2=y-3/y-2<5:S0 T99;
!!COy-1&y-6=0/y-7=1/y-2=y-3/y-2<5/y-4<50:S5/d1;
!!COy-1&y-6=0/y-7=1/y-2=y-3/y-2<5/y-4>49:S4/d1;
!!IF&1000/y-6=0/y-2>y-3:M1/z151027;
!!IF&1000/y-6=0/y-2<y-3:M1/z151028;
!!IF&1000/y-6=0/y-2=y-3/y-2<5/y-4<50:M1/z151029;
!!IF&1000/y-6=0/y-2=y-3/y-2<5/y-4>49:M1/z151030;
!!IF&1000/y-6=0/y-2=y-3/y-2>4:M1/z151031;
** end of object trigger
宠物加强 script51
（宠物抗魔只到95%了）
在原有加强上加上一些效果
"降防"技能:加上了"驱散有益魔法","酸液腐蚀","随机状态魔法攻击(女巫)"------100%
"恐惧"技能:加上了"老化"(活的)和"中毒"(不活的)----------50%
"最大伤害"技能:加上了"随机攻击魔法攻击(闪电\冰箭)"------------50%
"回复血"技能:（屏蔽）
加上了"石化"-----------50%(有时会反击）
[ 本帖最后由 akgod 于 2011-9-7 06:35 编辑 ] 这个还算有意思，但是石化没有麻痹实惠，受伤害减半。老化和中毒则比恐惧实惠多了。 再接再厉！
回复 1# 的帖子
这个指挥官加强的ERM我们论坛上很早就有了啊。 论坛上早有了不假，但是貌似没有被推广过，现在的置顶帖里的集合或者指挥官erm增强都没这个 :nianjing: :nianjing: :nianjing: x先试试看 关于楼主提到的麻痹和死眼的问题。我试着解释一下：
首先，指挥官技能是硬编码，不过也可能通过辅助脚本对其进行修正，比如指挥官加强脚本里就将死眼改成中毒了。但总之是比较麻烦的。
其次，指挥官先出死眼还是麻痹，并没有先后顺序，而是每次攻击时计算概率，而不管是攻击一下或两下。有可能两次都死眼，也可能两次都麻痹，甚至两次都没反应。如果你非要硬性规定第一次100%死眼，第二次100%麻痹，这也太无耻了。
最后，我想说一下，作弊或近似作弊只会缩短游戏的生命力。不要把所有的技能都设计得太完美，留一点缺憾，才有取舍的乐趣。 唔....
lz既然跟我一样喜欢死眼
那我就把这个放出来把
原本开启"指挥官加强",会导致
火盾->魔法神镜 死眼->中毒
本erm将技能"射击"改为中毒(远程也可以触发)
保留火盾,同时增加魔法神镜
如果需要射击,可以开启修改器,给英雄添加宝物"搜寻之弓"
来达到远程的目的 原帖由 genman 于 2011-9-6 19:55 发表 http://bbs.h3wog.com/images/common/back.gif
唔....
lz既然跟我一样喜欢死眼
那我就把这个放出来把
原本开启"指挥官加强",会导致
火盾->魔法神镜 死眼->中毒
本erm将技能"射击"改为中毒(远程也可以触发)
保留火盾,同时增加魔法神镜
如果 ...
感谢楼上的朋友
这个erm是修改我放出的那个还是朋友你自己做的？具体效果都有什么啊 原帖由 songfx 于 2011-9-6 19:32 发表 http://bbs.h3wog.com/images/common/back.gif
关于楼主提到的麻痹和死眼的问题。
我试着解释一下：
首先，指挥官技能是硬编码，不过也可能通过辅助脚本对其进行修正，比如指挥官加强脚本里就将死眼改成中毒了。但总之是比较麻烦的。
其次，指挥官先出死眼 ...
感谢风侠的回复，其实有时候想得到是一回事，玩不玩是另外一回事了
wog好玩的地方就在于比h3有更多的选择性，我个人认为，作弊耍赖，也是一种选择 原帖由 akgod 于 2011-9-6 21:56 发表 http://bbs.h3wog.com/images/common/back.gif
感谢楼上的朋友
这个erm是修改我放出的那个还是朋友你自己做的？具体效果都有什么啊 他是原创作者。寻梦和召唤师是协助修改的。 原帖由 兽哥哥 于 2011-9-6 22:13 发表 http://bbs.h3wog.com/images/common/back.gif
他是原创作者。寻梦和召唤师是协助修改的。
恩，我的意思是，他的erm是否和这个一样的，打完有很多状态……因为指挥官增强太多了，所以我才想问详细些 原帖由 akgod 于 2011-9-6 21:57 发表 http://www.h3wog.com/images/common/back.gif
感谢风侠的回复，其实有时候想得到是一回事，玩不玩是另外一回事了
wog好玩的地方就在于比h3有更多的选择性，我个人认为，作弊耍赖，也是一种选择
有想法是挺好的。
不过我觉得这个想法不够创意，而是有点贪心。
我觉得与其这么纠结倒不如换个思路，让玩家随时可以在宠物界面指定宠物的附魔方式从下面四个选项里选择
1. 保持原始模式不变
2. 只允许死眼
3. 只允许麻痹
4. 如果学会双击或三击（残忍之斧），那么第一击为麻痹时，自动停止攻击
***********
自从有人写了魔法天尊的脚本，就有人纠结，想把这个脚本加入到TDS里，让英雄既拥有魔法天尊特长，又拥有原本的BT特长。
或者想将魔法天尊里的四特长集于一身。
我估计想要实现这些想法也不会很难，但意义不是很大。 原帖由 herohua9999 于 2011-9-7 03:59 发表 http://bbs.h3wog.com/images/common/back.gif
有想法是挺好的。
不过我觉得这个想法不够创意，而是有点贪心。
我觉得与其这么纠结倒不如换个思路，让玩家随时可以在宠物界面指定宠物的附魔方式从下面四个选项里选择
1. 保持原始模式不变
2. 只允许死眼
...
其实说来说去我觉得很多人都误解我意思了
我本意是说，麻痹会削弱凝视的效果，因而才想到了这个该法……不否认我更喜欢最求“暴力”，但我的这个帖子的出发点就是很简单的想法：“没道理越学越弱吧？，但麻痹和凝视的同事拥有的确是越学越弱了，所以才想着能否改改” 原帖由 兽哥哥 于 2011-9-6 22:13 发表 http://bbs.h3wog.com/images/common/back.gif
他是原创作者。寻梦和召唤师是协助修改的。
您太高看我了= =
应该说是多亏了寻梦人最初的脚本雏形
然后我修改而成
我放的那个指挥官脚本并没有任何数据上的强化
只是开启指挥官加强后会取消"火盾"和"死神之眼"
我觉得不妥
就改了回来,现在开启指挥官加强后仍然后这两个技能效果
其他的没有任何bt化
回复 7# 的帖子
顶风大，我就觉得，太完美反而变得不完美了。。。就是因为不完美，所以才能动力去追求完美！嘿嘿，有点矛盾的说法:lianhong: 原帖由 genman 于 2011-9-7 12:45 发表 http://bbs.h3wog.com/images/common/back.gif您太高看我了= =
应该说是多亏了寻梦人最初的脚本雏形
然后我修改而成
我放的那个指挥官脚本并没有任何数据上的强化
只是开启指挥官加强后会取消"火盾"和"死神之眼"
我觉得不妥
就改了回来,现在开启指 ...
哦，感谢你的erm，不过我更想的是把这个erm能修改完善一下……其实即使完善了，也远远达不到所谓的bt，无耻的地步……
页:
[1]
