达摩克利斯剑V3.0 (战斗前自动施法脚本)
原贴由 woodmelon 2006-3-26 10:10 发表于本论坛V3.0
1.修正生物银行战斗中会黑屏退出游戏的Bug.
2.修正开启战争机器模式I后,防御方有投石车时攻方无法自动施法的Bug.
3.请注意自动施法后如果施法图标显示不可按下,只要用鼠标点击英雄就可以继续当回合的施法了.
因为变量有限制,所以游戏中只能有一种这样的武器,不要改成几种来用
除非你把其中主要的变量替换掉再搞个新的
最下方有成品下载,强烈要求使用Script99.ERM的文件名...
ZVSE
ERMS_PoweredBy=ERM Scripter v. 2004.6.29.918
ERMS_ScriptDate=18.5(May).2006
**Ver. 3.0
**实现天使联盟或诅咒铠甲的自动施法功能脚本
**英雄装备组合剑后,战斗开始前自动施放祝福+加速+嗜血+幸运,持续10回合
**英雄必须装备魔法书，否则战斗中会弹出对话框提示无魔法书，并且无法施放魔法
**组合剑若放置于大地图,请不要为其添加守卫,切记!!!
**v5503--5505
**z900-901
**FU25011
**该组合剑由下面前四件宝物组合而成
*Hellstorm Helmet23 地狱王冠
*Breastplate Of Brimstone29 黄金甲
*Sword Of Hellfire11 地狱火剑
*Shield Of The Damned17 邪盾
*Sword of Damocles162 达摩克利斯剑
!?PI;
!!VRz900:S^Sword of Damocles^;
!!VRz901:S^{Sword of Damocles}
The mythical sword that was suspended by a thread over the head of Damocles in Greek legend.^;
!!UN:A162/2/4 A162/3/16 A162/9/900 A162/10/901;
!!UN:A31/162/11/17/23/29;
!?OB5/162&1000;
!!IF:M^%Z901^;
!!OBv998/v999/v1000:M-1/1/0;
!?BA52; 战斗开始时检查双方战术状态
!!BA:H0/?y10 H1/?y11; 双方英雄ID
!!HEy10:A2/162/d/?y12;
!!VRy13:S0;
!!VRv5503:C0/0; 标志置位
!!HEy11&y11>-1:A2/162/d/?y13; 检查双方英雄是否装备 Sword of Damocles
!!VRv5503&y12>0:+1; 攻方装备Sword of Damocles
!!VRv5503&y13>0:+2; 防方装备Sword of Damocles
!!FU&v5503=0:E;
!!HEy10:S19/?y12; 检查攻方是否有战术
!!HEy11&y11>-1:S19/?y13; 检查防方是否有战术
!!VRv5503&y12>0/y11<0:+4; 攻方有战术,防方无英雄
!!VRv5503&y11>-1/y12<>y13:+4; 双方都有英雄,但一方无战术或战术等级不相同
!?BF&v5503>0;
!!BU:E2/?y1; 判断是否是在生物银行中的战斗
!!VRv5503&y1>20:S0; 取消施法
!?BR&v5503>0/v997=0; 第一回合开始自动施法
!!VRv5504:+1; 战场计算0回合时的情况
!!VRv4&v5504=1:S1; 设置默认速度为1
!!UN&v5504=1:P54/?y11; 检查是否开启战争机器I
!!BU&v5504=1/y11=1:E119/?y12 E135/?y13; 检查投石车
!!VRy14&v5504=1:S0;
!!VRy14&v5504=1/y11=1/y12>-1:+2; 攻方有投石车
!!VRy14&v5504=1/y11=1/y13>-1:+1; 防方有投石车
!!VRy10&y11=1/y14>1:S0; 攻方有投石车则先攻
!!VRy10&y11=1/y14=1:S1; 攻方无,防方有投石车则先攻
!!DO25011/0/41/1&v5504=1/y14=0:P2/-1/-1;
!!VRy10&v5505<21/y14=0:S0; 无战争机器时检查兵种速度
!!VRy10&v5505>20/y14=0:S1;
!!VRv1:Cv5503/v5503/v5503;
!!VRv1:&1;
!!VRv2:&2;
!!VRv3:&4;
**战场有战术学时
!!FU25011&v5503>=5/y10=0:P0/v2/y10; 攻方装备Sword of Damocles,攻方先攻
!!FU25011&v5503>=6/y10=1:P1/v1/y10; 防方装备Sword of Damocles,防方先攻
!!VRv5504&v5503=5/y10=1:S3; 攻方装备Sword of Damocles,防方先攻
!!VRv5504&v5503=6/y10=0:S3; 防方装备Sword of Damocles,攻方先攻
!!DO25011/0/20/1&v5503=5/y10=0:P3/-1/-1; 检查各魔法状态
!!DO25011/21/41/1&v5503=6/y10=1:P3/-1/-1;
**战场无战术学时
!!FU&v3>0:E;
!!FU&v5504<2:E; 第一个0回合不触发
!!FU25011&v1>0/y10=0:P0/v2/y10; 攻方装备Sword of Damocles,攻方先攻
!!FU25011&v2>0/y10=1:P1/v1/y10; 防方装备Sword of Damocles,防方先攻
!!VRv5504&v5503=1/y10=1:S3; 攻方装备Sword of Damocles,防方先攻
!!VRv5504&v5503=2/y10=0:S3; 防方装备Sword of Damocles,攻方先攻
!!DO25011/0/20/1&v5503=1/y10=0:P3/-1/-1; 检查各魔法状态
!!DO25011/21/41/1&v5503=2/y10=1:P3/-1/-1;
!?BG0&v5504>2;
!!BG:A?y10; 检查动作英雄,堆栈动作
!!VRv5504|y10=2/y10=3/y10>=6:S4;
!?BG1&v5504=4;
!!BG:Q?y10 H?y11; 检查动作英雄,堆栈动作
!!VRv1:Cv5503/v5503/v5503/v5503;
!!VRv1:&1;
!!VRv2:&2;
!!VRv3:&8; 检查先攻方
!!VRv4:&16;
!!FU25011&y10=0/v1>0/v2=0:P0/0/-1; 防方高速部队行动完毕,轮到攻方动作
!!FU25011&y10=1/v1=0/v2>0:P1/0/-1; 攻方高速部队行动完毕,轮到防方动作
!!DO25011/0/20/1&y10=0/v1>0/v2=0:P3/0/-1; 检查各魔法状态
!!DO25011/21/41/1&y10=1/v1=0/v2>0:P3/0/-1;
!!FU25011&y10=0/v4>0:P0/0/-1; 防方高速部队行动完毕,轮到攻方动作
!!FU25011&y10=1/v3>0:P1/0/-1; 攻方高速部队行动完毕,轮到防方动作
!!DO25011/0/20/1&y10=0/v4>0:P3/0/-1; 检查各魔法状态
!!DO25011/21/41/1&y10=1/v3>0:P3/0/-1;
**x1=英雄ID x2=单方是否装备Sword of Damoclesx3=先攻方(-1为无效)
!?FU25011;
!!BMx16&x1=2:T?y10 N?y11;
!!BMx16&x1=2/y10>-1/y11>0:S?y12;
!!VRv5505&x1=2/y10>-1/y11>0/y12>v4:Sx16; 保存速度最快生物的堆栈
!!VRv4&x1=2/y10>-1/y11>0/y12>v4:Sy12; 计算速度最快的生物
!!FU&x1=2:E;
!!VRv5504&x1<2/x2>0/v5503>=3:S3; 双方均有Sword of Damocles
!!BHx1&x1<2:N?y13;
!!HEy13&x1<2:I?y14/1; 记录魔法点
!!BHx1&x1<2:C53/-1/3/0; Haste
!!BHx1&x1<2:C41/-1/3/0; Bless
!!BHx1&x1<2:C43/-1/3/0; Bloodlust
!!BHx1&x1<2:C51/-1/3/0; Fortune
!!HEy13&x1<2:Iy14/1; 还原魔法点
!!BHx1&x1<2:M0; 允许施法
!!VRv5503&x1<2/x2>0/x3=0:+8; 攻方先攻
!!VRv5503&x1<2/x2>0/x3=1:+16; 防方先攻
!!FU&x1<>3:E;
!!BMx16:T?y10 N?y11;
!!FU|y10<0/y11<1:E;
!!BMx16:G53/?y10/d;
!!BMx16&y10>0:G53/10/3;
!!BMx16:G41/?y10/d;
!!BMx16&y10>0:G41/10/3;
!!BMx16:G43/?y10/d;
!!BMx16&y10>0:G43/10/3;
!!BMx16:G51/?y10/d;
!!BMx16&y10>0:G51/10/3;
!!VRv5504&x2=0:S0; 看来主页又要改了
上面还是2.0的………… 这个我试用了很多次，打S地图没问题，不过打XL地图时，快速战斗还好，手动控制经常出错。 我就是遇到这问题了,自动打可以过,手动就出错 在驻地战斗时，英雄若有战术，会黑屏退出游戏，只能用快速作战 谢谢了~就是那个问题搞的黑屏了 钱钱钱,又是钱. 呵呵，挺好的宝物。。。。 用这个 英雄会没蓝的
页:
[1]
