求教 看到编好的 erm代码 如何导入script .erm文件中？
在别的论坛看到如下代码但是不会导入到erm 的文件中求教ZVSE
ERMS_ScriptDate=6.3(March).2005
_WARNING_#1=IMPORTANT! This file is not in a plain text format. NEVER use any editor except ERM_S for making any kind of changes!
ERMS_PoweredBy=ERM Scripter v. 2004.6.29.918
** Dungeon of the Dragonmaster
** Wogify Name: script53.erm
** This strengthens all Dragon Utopias an a map. AI will visit normal DU but gets some extra bonuses.
** Requires ERM v2.80 or higher
** Version: 1.2
** Updated: May 12. 2004
** Made by Hermann the Weird
** Idea by Janus
** To use this code, copy it (from ZVSE to the end) into a global event, set day of first occurence
** to something after 600.
** v-Variables used: v8033, v8035-v8043
** Functions: 20001-20003
** Strings: z455-461
** Uses FU709 from script01 (map rules) to determine the strength of the DOTDM.
** Compatible with script57 (neutral units).
** This script will only give enabled artifacts (Map or WoG options).
** If all artifacts of one level are disabled, artifacts of other random levels will be given.
***** Check for WoGify option *****
!#UN:P53/?v1;
***** Setting hint text *****
!#VRz455&v1=1:Sz153000;
!#VRz456&v1=1:Sz153001;
!#HT25/-1&v1=1:T455;
***** Section for human attacker *****
!?OB25&1000;
!!UN:P53/?y-1;
!!FU&y-1=0:E;
!!VRv100:S1;
!!HE-1:P?v8040/?v8041/?v8042;
!!OBv8040/v8041/v8042:S;
!!HE-1:O?v8043;
***** Ask player for battle *****
!!IF:Q1/21/132/2/z153002;
!!FU&-1:E;
!!VRv8033:S0 R3 +1;
!!FU709:P15;
!!VRy-7&3:Sv8033 +9 *9999;
!!VRy-7&-3:Sv8033 *9999;
!!VRv8033:+1;
!!HE-1:Tv8040/v8041/v8042/132/y-7;
!!HE-1:O?y-2;
!!FU&v8043<>y-2:E;
!!DO20001/1/v8033/1:P8035/457;
!!DO20002/1/v8033/1:P8035;
***** Displaying relics *****
!!IF&v8033=2:Q1/8/v8035/8/v8036/1/z153003;
!!IF&v8033=3:Q1/8/v8035/8/v8036/8/v8037/1/z153004;
!!IF&v8033=4:N8/v8035/8/v8036/8/v8037/8/v8038;
!!IF&v8033=4:N^%Z153005^;
!!IF&v8033=5:N8/v8035/8/v8036/8/v8037/8/v8038/8/v8039;
!!IF&v8033=5:N^%Z153006^;
!!DO20003/1/3/1:P8035/457;
***** Displaying and passing minor/major artifacts *****
!!UN:P900/?y-3;
!!UN:P143/?y-4;
!!UN:P234/?y-5;
***** If Stack Experience and New Arts enabled *****
!!IF&y-3=1/y-4=1/y-5=0:N8/v8035/8/v8036/8/v8037/8/156;
!!IF&y-3=1/y-4=1/y-5=0:N^%Z153007^;
!!HE-1&y-3=1/y-4=1/y-5=0:A4/156;
***** If Stack Experience and New Arts not enabled *****
!!IF|y-3<>1/y-4<>1/y-5<>0:Q1/8/v8035/8/v8036/8/v8037/1/z153008;
!!HE-1:A4/v8035;
!!HE-1:A4/v8036;
!!HE-1:A4/v8037;
***** Preparing variables for money or experience *****
!!VRv8033:*500000;
!!VRy-8:Sv8033;
!!VRy-8::2;
***** Asking for money or experience *****
!!IF:Q1/6/v8033/17/y-8/7/z153009;
***** Displaying and passing money *****
!!IF&1:Q1/6/v8033/1/z153010;
!!OW&1:R-1/6/dv8033;
***** Displaying and passing experience *****
!!IF&-1:Q1/17/y-8/1/z153011;
!!HE-1&-1:Edy-8;
!!IF:M1/z153012;
***** End of section for human attacker *****
***** Section for AI attacker *****
!?OB25&-1000;
!!UN:P53/?y-1;
!!FU&y-1=0:E;
!!HE-1:P?v8040/?v8041/?v8042;
!!HE-1:O?v8043;
!$OB25&-1000;
!!UN:P53/?y-1;
!!FU&y-1=0:E;
!!HE-1:O?y-2;
!!FU&v8043<>y-2:E;
!!HE-1:Fd5/d5/d5/d5;
!!HE-1:Ed15000;
!!OW:R-1/6/d30000;
***** End of section for AI attacker *****
********** Function Section **********
!?FU20001;
!!UN:J6/16/?y1;
!!VRvx1:Sy1;
!!UN:N0/zx2/y1;
!!VRx1:+1;
!!VRx2:+1;
!?FU20002;
!!HE-1:A4/vx1;
!!VRx1:+1;
!?FU20003;
!!UN:J6/12/?y1;
!!VRvx1:Sy1;
!!UN:N0/zx2/y1;
!!VRx1:+1;
!!VRx2:+1; 在论坛中下载的erm对比了下貌似是格式应该如何导入？ 直接到游戏的官方脚本文件夹下(某MOD的DATA/S文件夹)
随便找一个后缀为 *.ERM的脚本文件.
复制出来,用文本编辑器打开清空,并把你的脚本放进去即可.
更改脚本文件的名字(WOG是需要SCRIPT开头+2个数字格式,ERA的脚本任意不重复即可)
ERM脚本文件的开头一定是 ZVSE 这个标识.
贤知有您 发表于 2014-12-9 09:20
直接到游戏的官方脚本文件夹下(某MOD的DATA/S文件夹)
随便找一个后缀为 *.ERM的脚本文件.
复制出来,用文 ...
你好还是同一个问题 我玩的是 wog2.58f我在data/s目录下 打开任意一个rem文件 看到的是下载的erm文件打开后的样子如下图 而我自己打开这样的文件然后复制帖子中的代码粘贴后 是下图自己粘贴的样子 貌似自己复制粘贴的无法生效 貌似这个脚本时改 龙之国的脚本.
也就是改原来script53.erm 脚本.
你应该直接改为 script53.erm并覆盖原文件 (记得备份).
然后开启ERM菜单的相关选项再测试. 麻烦帮我看一下我把下载来的 erm的压缩包和自己复制粘贴的erm压缩包都上传了 确实我复制别人的代码复制粘贴进文件之后就是无法生效 实在是形容不出来只好发文件上来麻烦帮忙看下 多谢
看起来这个脚本没啥问题.
你已把这个自己复制的脚本, 改名为 script53.erm 并覆盖了原来的吗? 覆盖了原来的53无法起效
不知道是我用的编辑模式不对还是别人做好的erm 在我的机子上如果只用 文本模式打开会发现其中代码没有分段 代码之间没有空格而我自己复制粘贴的有分行
页:
[1]
