有WOG小组新ERM
我也不知怎的,竟然能找到来自WOG小组制作的新ERM(看图好像很多),我正在测试中................如果没问题的话,我就会上传的:lol: 现在可以用上吗 那个，其实WoG小组一直在创作新的为359准备的脚本，编号都到百位以外了，只是迫于小组规定，我是不能提前把脚本外泄的，不过 hero3 不是WoG小组成员，能被你找到脚本并发布出来，倒是件好事，呵呵。 等了这么久，一定有很多东西了。 云斯好久没有出来爆料些消息啦。 这些ERM我都有 Mithril SmelterZVSE
*Mithril Smelter
*Uses vars v1800-v1807
*Uses functions FU1800-FU1802
!#TM83:S2/999/7/255;Gives resource on day 2 every week,set up timer for 7 daily,replace 7 with 1 for daily,with 2 for two daily and so on...
!#VRz100:S^Mithril Smelter^;
!#HT63/27:T100;
!#VRv1800:S0; player 0
!#VRv1801:S0; player 1
!#VRv1802:S0; player 2
!#VRv1803:S0; player 3
!#VRv1804:S0; player 4
!#VRv1805:S0; player 5
!#VRv1806:S0; player 6
!#VRv1807:S0; player 7
!?OB63/27; If visited
!!PO998:O?i; get owner
!!HE-1:O?j; get hero owner
!!FU1800&i<>j:Pi/j; if not owner then change owner
!?FU1800;
!!PO998:Ox2; set new owner
!!IF&1000:Q1/7/0/1^{Mithril Smelter}
You gain control of a Mithril Smelter.It will provide you with one unit of mithril per day.^;
!!FU1801:Pj; hint text
!!VRy1:S8; default is no owner(y1=8)
!!VRy1&x1>-1/x1<8:S1800 +x1; if previous owner was a player then index to his var is y1
!!VRy2:S1800 +x2; index to visiting hero's var is y2
!!VRvy1&y1<>8:-1; decrease previous owner's var
!!VRvy2:+1; increase visitor's var
!?FU1801;
!!VRz100:S^Mithril Smelter ^; calc hint text into z100
!!VRz100&x1=0:+^Owned by red player (Mithril)^;
!!VRz100&x1=1:+^Owned by blue player (Mithril)^;
!!VRz100&x1=2:+^Owned by tan player (Mithril)^;
!!VRz100&x1=3:+^Owned by green player (Mithril)^;
!!VRz100&x1=4:+^Owned by orange player (Mithril)^;
!!VRz100&x1=5:+^Owned by purple player (Mithril)^;
!!VRz100&x1=6:+^Owned by teal player (Mithril)^;
!!VRz100&x1=7:+^Owned by pink player (Mithril)^;
!!OB998:H100; set hint text
!?TM83; timer trigger
!!DO1802/0/1/10:P; give mithril
!?FU1802;
!!VRi:Sx16; calc index
!!VRi:+1800; calc index
!!VRj:Svi; store in j for easier reference
!!OW:Rx16/7/dj; give mithril
*!OW:Rx16/7/?k; ? current mithril
*!VRk:+j; ? new mithril
*!OW:Rx16/7/j; store new mithril
Upgraded Hill fort
ZVSE
AUTO_PoweredBy=ERM Script Editor v.1.2.6.5
*/ Upgraded Hill Fort ERM script v1.1 --- wolfmah
*/ Requires WoG 3.55 or later
*/
*/ This script will allow you to any any creatures that have a new WoG
*/ counterparts. This mean, all level 7 upgrade can be upgrade into level 8,
*/ Zealots into War Zealots, Sharpshooters into Artic or Lava Sharpshooters
*/ and so on.
*/
*/ Object use : (map editor) 4th row - 3rd column in the Town section
*/
*/ To use this script, copy and paste it in a global event on a map, set it to
*/ never happen (minimum of 600 day) and uncheck all colours.
*/
*/ Variable and Function that CAN be re-used elsewhere :
*/Q110 - 111 - 113 - 115 - 117 - 119 - 121 - 123
*/v111 - 112 - 113 - 114 - 115 - 116 - 117 - 118 - 119 - 120 - 121 -
*/ 122 - 123 - 124
*/FU400 - 401 - 402
*/
*/ Variable and Function that CANNOT be re-used elsewhere :
*/ z400
*/ Set up hint text for "Upgraded Hill Fort" objects
!#VRz400:S^Upgraded Hill Fort^;
!#HT63/4:T400;
!?OB63/4;*/ Triggers when any Upgraded Hill Fort is visited
*/ Will be use to know if the hero got at least 1 creature that can be upgrade
!!IF:V111/0;
!!IF:V113/0;
!!IF:V115/0;
!!IF:V117/0;
!!IF:V119/0;
!!IF:V121/0;
!!IF:V123/0;
*/ Check monster
!!HE-1:C0/0/?v111/?v112;*/ Slot 1
!!HE-1:C0/1/?v113/?v114;*/ Slot 2
!!HE-1:C0/2/?v115/?v116;*/ Slot 3
!!HE-1:C0/3/?v117/?v118;*/ Slot 4
!!HE-1:C0/4/?v119/?v120;*/ Slot 5
!!HE-1:C0/5/?v121/?v122;*/ Slot 6
!!HE-1:C0/6/?v123/?v124;*/ Slot 7
*/ Check if the type of monster is ok
!!FU400:Pv111/0;
!!FU400:Pv113/1;
!!FU400:Pv115/2;
!!FU400:Pv117/3;
!!FU400:Pv119/4;
!!FU400:Pv121/5;
!!FU400:Pv123/6;
*/ remove monster who are not allowed
!!HE-1&-111:C0/0/0/0;
!!HE-1&-113:C0/1/0/0;
!!HE-1&-115:C0/2/0/0;
!!HE-1&-117:C0/3/0/0;
!!HE-1&-119:C0/4/0/0;
!!HE-1&-121:C0/5/0/0;
!!HE-1&-123:C0/6/0/0;
!!HE-1&1000:D;
*/ replace monster that were remove
!!HE-1&-111:C0/0/v111/v112;
!!HE-1&-113:C0/1/v113/v114;
!!HE-1&-115:C0/2/v115/v116;
!!HE-1&-117:C0/3/v117/v118;
!!HE-1&-119:C0/4/v119/v120;
!!HE-1&-121:C0/5/v121/v122;
!!HE-1&-123:C0/6/v123/v124;
!!FU402:P;
********************************************************************************
!?FU400;
*/ Check if the type of monster is ok
*/ x1 : Type of monster
*/ x2 : Slot of the monster
!!IF:V110/0;
!!IF&x1=6:V110/1; */ Swordsman
!!IF&x1=7:V110/1; */ Crusader
*/ Swordsman - Crusader | Paladin
!!FU401|x1=6/x1=7:Px1/174;
!!IF&x1=8:V110/1; */ Monk
!!IF&x1=9:V110/1; */ Zealot
*/ Monk - Zealot | War Zealot
!!FU401|x1=8/x1=9:Px1/169;
!!IF&x1=12:V110/1; */ Angel
!!IF&x1=13:V110/1; */ Archangel
*/ Angel - Archangel | Supreme Archangel
!!FU401|x1=12/x1=13:Px1/150;
!!IF&x1=24:V110/1; */ Unicorn
!!IF&x1=25:V110/1; */ War Unicorn
*/ Unicorn - War Unicorn | Nightmare
!!FU401|x1=24/x1=25:Px1/172;
!!IF&x1=26:V110/1; */ Green Dragon
!!IF&x1=27:V110/1; */ Gold Dragon
*/ Green Dragon - Gold Dragon | Diamond Dragon
!!FU401|x1=26/x1=27:Px1/151;
!!IF&x1=34:V110/1; */ Mage
!!IF&x1=35:V110/1; */ Arch Mage
*/ Mage - Arch Mage | Hierophant
!!FU401|x1=34/x1=35:Px1/175;
!!IF&x1=28:V110/1; */ Gremlin
!!IF&x1=29:V110/1; */ Master Gremlin
*/ Gremlin - Master Gremlin | Santa Gremlin
!!FU401|x1=28/x1=29:Px1/173;
!!IF&x1=40:V110/1; */ Giant
!!IF&x1=41:V110/1; */ Titan
*/ Giant - Titan | Lord of Thunder
!!FU401|x1=40/x1=41:Px1/152;
!!IF&x1=54:V110/1; */ Devil
!!IF&x1=55:V110/1; */ Arch Devil
*/ Devil - Arch Devil | Antichrist
!!FU401|x1=54/x1=55:Px1/153;
!!IF&x1=68:V110/1; */ Bone Dragon
!!IF&x1=69:V110/1; */ Ghost Dragon
*/ Bone Dragon - Ghost Dragon | Blood Dragon
!!FU401|x1=68/x1=69:Px1/154;
*/ Blood Dragon - Dracolich
!!FU401:P154/196;
*/ Dracolich - Blood Dragon
!!FU401:P196/154;
!!IF&x1=78:V110/1; */ Minotaur
!!IF&x1=79:V110/1; */ Minotaur King
*/ Minotaur - Minotaur King | Brute
!!FU401|x1=78/x1=79:Px1/179;
!!IF&x1=82:V110/1; */ Red Dragon
!!IF&x1=83:V110/1; */ Black Dragon
*/ Red Dragon - Black Dragon | Darkness Dragon
!!FU401|x1=82/x1=83:Px1/155;
!!IF&x1=90:V110/1; */ Ogre
!!IF&x1=91:V110/1; */ Ogre Mage
*/ Ogre - Ogre Mage | Ogre Leader
!!FU401|x1=90/x1=91:Px1/180;
!!IF&x1=96:V110/1; */ Behemoth
!!IF&x1=97:V110/1; */ Ancient Behemoth
*/ Behemoth - Ancient Behemoth | Ghost Behemoth
!!FU401|x1=96/x1=97:Px1/156;
!!IF&x1=110:V110/1;*/ Hydra
!!IF&x1=111:V110/1;*/ Chaos Hydra
*/ Hydra - Chaos Hydra | Hell Hydra
!!FU401|x1=110/x1=111:Px1/157;
!!IF&x1=130:V110/1;*/ Firebird
!!IF&x1=131:V110/1;*/ Phoenix
*/ Firebird - Phoenix | Sacred Phoenix
!!FU401|x1=130/x1=131:Px1/158;
!!IF&x1=137:V110/1;*/ Sharpshooter
*/ Sharpshooter - Artic Sharpshooter
!!FU401&x1=137:Px1/170;
*/ Artic Sharpshooter - Lava Sharpshooter
!!FU401&x1=137:P170/171;
*/ Lava Sharpshooter - Artic Sharpshooter
!!FU401&x1=137:P171/170;
!!IF&110/x2=0:V111/1;
!!IF&110/x2=1:V113/1;
!!IF&110/x2=2:V115/1;
!!IF&110/x2=3:V117/1;
!!IF&110/x2=4:V119/1;
!!IF&110/x2=5:V121/1;
!!IF&110/x2=6:V123/1;
********************************************************************************
*/ x1 : monster type
*/ x2 : monster type to upgrade to
!?FU401;
!!MA:Ux1/x2;
********************************************************************************
!?FU402;
!!FU401:P6/-1;
!!FU401:P7/-2;
!!FU401:P8/-1;
!!FU401:P9/-2;
!!FU401:P12/-1;
!!FU401:P13/-2;
!!FU401:P24/-1;
!!FU401:P25/-2;
!!FU401:P26/-1;
!!FU401:P27/-2;
!!FU401:P28/-1;
!!FU401:P29/-2;
!!FU401:P34/-1;
!!FU401:P35/-2;
!!FU401:P40/-1;
!!FU401:P41/-2;
!!FU401:P54/-1;
!!FU401:P55/-2;
!!FU401:P68/-1;
!!FU401:P69/-2;
!!FU401:P78/-1;
!!FU401:P79/-2;
!!FU401:P82/-1;
!!FU401:P83/-2;
!!FU401:P90/-1;
!!FU401:P91/-2;
!!FU401:P96/-1;
!!FU401:P97/-2;
!!FU401:P110/-1;
!!FU401:P111/-2;
!!FU401:P130/-1;
!!FU401:P131/-2;
!!FU401:P137/-2;
!!FU401:P154/-2;
!!FU401:P196/-2;
!!FU401:P170/-2;
!!FU401:P171/-2;
希望能早点出来,呵呵 由于上传容量限制，我发不了整个WOG组的ERM，先发一个让大家试试。 楼上发的虾米dd？ 好东西 虾米东西捏。。。说下咯 期待中 希望补丁能早点出:D: 你们的WOG选项怎么是中文的... 偶关心的是3.59中能不能使用中文.:lol: :lol: :lol: 比较期待地图冒险魔法 :): 还是等正式发布吧。。。
