【求助】请达人解决：如何在非经验特技的自制技能中让攻击后魔法在对方还手前释放？
如题，目前有几个自制技能中的攻击后魔法都是在对方还手后才释放，我想要魔法在对方还手前释放要怎么做到呢？举下面这个例子，泰坦攻击后5*5范围内后群体闪电+概率失明，目前是主动攻击后对方还手后出闪电，如果我想让闪电和失明在还手前出要怎么改呢？
;7级兵
!?BG0&1000;
!!BG:A?y-1 N?y-2;
!!FU|y-2<0/y-2>41:E;
!!BMy-2:G62/?y-3/d G70/?y-4/d G74/?y-5/d G72/?y-6/d U3/?y-7;
!!BG|y-3>0/y-4>0/y-5>0:A8;
!!BG&y-6>0/y-7=0/y-1=8:A3;
!?BG0&1000; [动作前变量(007)]
!!VRv9970:C-1/-1/-1/-1/-1;
!!BG:A?v9970 N?v9971 E?v9972 Q?v9973;
!!BMv9971&v9971>-1:N?v9974;
!?BG1;
**宙斯之怒。泰坦巨人主动攻击后对5格范围内敌人施放闪电并25％几率失明对方（生命部队有效，且不考虑抗魔等属性）
!!BU:C?y19;
!!FU&y19=1:E;
!!FU|v9970<>6/v9971<0/v9972<0:E;
!!BG:D?y4;
!!BMv9971:T?y30 N?y31 I?y32;
!!BMv9972:T?y40 N?y41 I?y42;
!!FU&y30<>41:E;
**FU|y31<1:E; [若TT完全死亡,则不触发]
!!FU|y4<0/y4>186:E;
!!VRy-1:Sy4 :17 +1; [行]
!!VRy-2:Sy-1 -1 *-17 +y4 +1;[列]
!!VRy-3:Sv9974 *1; ***[每个TT2点力量]
!!if&y41>0:;
!!BMv9972:P?y43 F?i;
!!BMv9971:C17/y43/3/y-3/1;******
!!VRi:&16;
!!VRy1&i>0:S0 R99;
!!BMv9971&y1<25/i>0:C62/y43/1/3/1; ******
!!en:;
!!DO20000/21/41/1&v9971<21:P10000/v9971/v9972/y-1/y-2/5/y-3;
!!DO20000/0/20/1&v9971>20:P10000/v9971/v9972/y-1/y-2/5/y-3;
!!BG:N?y50;
!!BMy50&y50>-1:P?y51 C2/y51/0/0/0;
!?FU20000&x1=10000;
!!FU&x16=x3:E;
!!BMx16:T?y-8 N?y-9;
!!FU|y-8<0/y-9<1:E;
!!FU&y-8=149:E;
!!BMx16:P?y-10 F?i I?y10;
!!VRj:Si&1;
!!VRy-11:Sy-10 :17 +1;
!!VRy-12:Sy-11 -1 *-17 +y-10 +1;
!!VRy-13&j<>0/y10=0:Sy-12 +1;
!!VRy-13&j<>0/y10=1:Sy-12 -1;
!!VRy-31:Sx4 -y-11;
!!VRy-31&y-31<0:*-1;
!!VRy-32:Sx5 -y-12;
!!VRy-32&y-32<0:*-1;
!!VRy-33&j<>0:Sx5 -y-13;
!!VRy-33&j<>0/y-33<0:*-1;
!!VRy-32&j<>0/y-33<y-32:Sy-33;
!!FU|y-31>x6/y-32>x6:E;
!!BMx16:P?y43;
!!BMx2:C17/y43/3/y-3/1; ******
!!VRi:&16;
!!VRy1&i>0:S0 R99;
!!BMx2&y1<25/i>0:C62/y43/1/3/1; ***
[ 本帖最后由 titanzwh 于 2013-5-29 09:54 编辑 ]
出个馊主意……
换成伤害前触发;yowe; 伤害前触发的视觉感觉太不好了。回复 跟帖促繁荣 3# 的帖子
好吧……记得以前在怪物强化2的script50里有些命令是移除反击的，说不定用得上。没试过不清楚;ekow; 分情况讨论
1.我方攻击后敌人不会反击，用BG1对攻击堆栈施放魔法
2.攻击后敌人反击，使用MF1在敌人造成伤害前对敌人施放魔法
只能通过这种方式达成类似原版的攻击后施法，而且效果也不算太好
很久以前写过的，不是很完善不过可做参考
ZVSE
!?MF1&1000;
!!BG:N?v61;
!!BG:E?v62;
!!MF:N?y1;
!!BMv61:T?y3 N?y4;
!!BMv62:R?y2;
!!FU1900&y1=v61/y2>0:Pv61/v62;
!!IF&y2=0:V500/1;
!!IF&y2>0/y1=v61:V501/1;
!?FU1900;
!!VRy1:S0 R99;
!!FU&y1>10:E;形如这段的是概率
!!BMx1:T?y4 N?y5;
!!BMx2:T?y6 H?y7 N?y8;
!!VRy11:Sy5:5+1;
!!VRy11&y11>=y8:Sy8-1;
!!VRy12:Sy11*y7;
!!FU&y4<>1:E;1是戟兵代码
!!VRz-1:S^Deathblo.wav^;
!!SN:Pz-1;
!!BMx2:V73 Ky12;
!!BU:R;
!!UN:N3/-9/y4/1;
!!UN:N3/-10/y6/1;
!!VRz-8:S^{%Z-9杀死了%Y11个%Z-10}^;中括号内为文字部分，可以改成自己想要的，非中文部分别改
!!MM:Sz-8;
!!BMx2:N?y9;
!!MF:D?y10;
!!VRy-1:Sy10*y9:y8;
!!MF:Fy-1;
!?BG1&500;
!!IF:V500/0;
!!VRy1:S0 R99;
!!FU&y1>10:E;
!!BMv61:T?y4 N?y5;
!!BMv62:T?y6 H?y7 N?y8;
!!FU&y8<1:E;
!!VRy11:Sy5:5+1;
!!VRy12:Sy11*y7;
!!FU&y4<>1:E;1是戟兵代码
!!VRz-1:S^Deathblo.wav^;
!!SN:Pz-1;
!!BMv62:V73 Ky12;
!!BU:R;
!!UN:N3/-9/y4/1;
!!UN:N3/-10/y6/1;
!!VRz-8:S^{%Z-9杀死了%Y11个%Z-10}^;
!!MM:Sz-8;
!?BG1&501;
!!IF:V501/0;
!!VRy1:S0 R99;
!!FU&y1>10:E;
!!BMv61:T?y4 H?y5 N?y8;
!!BMv62:T?y6 N?y7;
!!FU&y8<1:E;
!!FU|y6<>1:E;1是戟兵代码
!!VRy11:Sy7:5+1;
!!VRy12:Sy11*y5;
!!VRz-1:S^Deathblo.wav^;
!!SN:Pz-1;
!!BMv61:V73 Ky12;
!!BU:R;
!!UN:N3/-9/y6/1;
!!UN:N3/-10/y4/1;
!!VRz-8:S^{%Z-9杀死了%Y11个%Z-10}^;
!!MM:Sz-8; 谢谢
页:
[1]
