求高手做个英雄功能，实现召唤石的效果
为了解决后期无聊的调兵，英雄可以一定的魔法值（20）点为代价，随地叫出召唤石功能，从城里面买召唤兵。但是价格会增加20%如果价格不增加的话，调整为50点魔法值。，或者没有代价也能召唤，价格提高20%
相信会大大提高对战的乐趣
[ 本帖最后由 脑虫 于 2012-8-26 18:40 编辑 ] 转发一个脚本是ASHERO4版主的。
发一个可以自由买兵种的脚本
在英雄界面右键点击士气图标后激活。能买除了战争机器和宠物外的所有兵种 。
ZVSE
ERMS_ScriptDate=8.1(January).2012
***时间触发器编号59***
***v3951变量*****
***函数20563，20564***
****右键点击英雄界面的士气图标激活****
***能买除了战争机器和宠物外的任何兵种***
***每天只能买3次****
***1级兵每次最多只能购买50个***
***2级兵每次最多只能购买30个***
***3级兵每次最多只能购买24个***
***4级兵每次最多只能购买20个***
***5级兵每次最多只能购买8个***
***6级兵每次最多只能购买4个***
***7级及7级兵以上每次最多只能购买1个***
!#TM59:S1/360/1/255;设定每天买的次数
!?TM59&1000;
!!VRv3951:S0;
!?CM2&1000;
!!CM:R1;
!!CM:S?v1 I?v2;
!!IF&v3951>2:M^您不能再买部队了。^;每天只能买3次
!!FU&v3951>2:E;
!!HE-1&v1=14/v2=116:N?y3 O?y10; 右键点击士气图标
!!FU20563&v1=14/v2=116:Py3/y10;
!?FU20563;
!!IF:Q10^您想购买部队吗？^;
!!IF&-10/1000:M^不了。^;
!!FU&-10:E;
!!VRv3951:+1;
!!VRz3:S^请输入部队的生物编号，{从0到196}.
例如大天为13，泰坦为41，大恶魔为55，比蒙为97，
圣龙为132.紫龙为134，蛮牛为103，8级部队从150到158.
（其中145到149为战争机器，174到191为宠物，
都不可以购买。）^;
!!VRz4:S^字母或者空白默认为0^;
!!VRz5:S^^;
!!IF:D2/3/4/5; 设置输入框
!!IF:E1/2; 选项至v1
!!FU&v1=-1:E;**VRz1:H2; 读取输入文本
!!VRy4:Vz1; 将文本转化为数值
!!IF&y4>144/y4<150:M^不能购买战争机器。^;
!!FU&y4>144/y4<150:E;
!!IF&y4>173/y4<192:M^不能购买宠物。^;
!!FU&y4>173/y4<192:E;
!!IF&y4>196/y4<0:M^没这个生物编号。^;
!!FU&y4>196/y4<0:E;
!!MA:Cy4/1/?y-5; 水银
!!MA:Cy4/3/?y-6; 硫磺
!!MA:Cy4/4/?y-7; 水晶
!!MA:Cy4/5/?y-8; 宝石
!!MA:Cy4/6/?y-9; 钱
!!VRy5:Sy-5*100:20+y-5;
!!VRy6:Sy-6*100:20+y-6;
!!VRy7:Sy-7*100:20+y-7;
!!VRy8:Sy-8*100:20+y-8;
!!VRy9:Sy-9*100:20+y-9;
!!VRy10:Sx1;英雄ID
!!VRy11:Sx2; 英雄所属
!!FU20564:Py4/y5/y6/y7/y8/y9/y10/y11;
!?FU20564;
!!VRz3:S^请输入购买部队的数量^;
!!VRz4:S^字母或者空白默认为0^;
!!VRz5:S^^;
!!IF:D2/3/4/5; 设置输入框
!!IF:E1/2; 选项至v1
!!FU&v1=-1:E;**VRz1:H2; 读取输入文本
!!VRy1:Vz1; 将文本转化为数值
!!IF&y1<=0:M^请不要输入火星文。^;
!!FU&y1<=0:E;
!!MA:Lx1/?y98; 取得购买兵种等级
!!VRy99&y98=0:S50; 1级兵为50个
!!VRy99&y98=1:S30; 2级兵为30个
!!VRy99&y98=2:S24; 3级兵为24个
!!VRy99&y98=3:S20; 4级兵为20个
!!VRy99&y98=4:S8; 5级兵为8个
!!VRy99&y98=5:S4; 6级兵为4个
!!VRy99&y98>=6:S1; 7级兵及以上为1个
!!IF&y1>y99:M^您购买兵种的数量超过上限了。^;
!!FU&y1>y99:E;
!!VRy2&x2>0:Sy1*x2; 水银
!!VRy3&x3>0:Sy1*x3; 硫磺
!!VRy4&x4>0:Sy1*x4; 水晶
!!VRy5&x5>0:Sy1*x5; 宝石
!!VRy6&x6>0:Sy1*x6; 钱
!!OW:Rx8/1/?y7; 玩家水银数量
!!OW:Rx8/3/?y8; 玩家硫磺数量
!!OW:Rx8/4/?y9; 玩家水晶数量
!!OW:Rx8/5/?y10; 玩家宝石数量
!!OW:Rx8/6/?y11; 玩家金钱数量
!!IF&1000/y7<y2:Q2/1/y2/1^{您的资源不够}。^;
!!FU&y7<y2:E;
!!IF&1000/y8<y3:Q2/3/y3/1^{您的资源不够}。^;
!!FU&y8<y3:E;
!!IF&1000/y9<y4:Q2/4/y4/1^{您的资源不够}。^;
!!FU&y9<y4:E;
!!IF&1000/y10<y5:Q2/5/y5/1^{您的资源不够}。^;
!!FU&y10<y5:E;
!!IF&1000/y11<y6:Q2/6/y6/1^{您的资源不够}。^;
!!FU&y11<y6:E;
!!IF:Q9^这将花费您{%Y2水银}，{%Y3硫磺}，{%Y4水晶}，
{%Y5宝石}和{%Y6金币}。您决定购买吗？^;
!!IF&-9/1000:M^不了。^;
!!FU&-9:E;
!!IF:Q1/21/x1/1^这是我无限的荣耀。^;
!!VRy12&x2>0:Sy2*-1; 水银
!!VRy13&x3>0:Sy3*-1; 硫磺
!!VRy14&x4>0:Sy4*-1; 水晶
!!VRy15&x5>0:Sy5*-1; 宝石
!!VRy16&x6>0:Sy6*-1; 钱
!!OW&y2>0:Rx8/1/dy12;
!!OW&y3>0:Rx8/3/dy13;
!!OW&y4>0:Rx8/4/dy14;
!!OW&y5>0:Rx8/5/dy15;
!!OW&y6>0:Rx8/6/dy16;
!!HEx7:Cx1/y1/-1/0/-1/0/-1/0/-1/0/-1/0/-1/0; ;orz; 这个，如何使用。。
回复 4# 的帖子
在英雄界面右键点击士气图标后激活。能买除了战争机器和宠物外的所有兵种 。 是不是保存成记事本然后改成任意编号的ERM，放到ERM目录下就能用了回复 6# 的帖子
这个不行，这个是事件版的，需要你在地图编辑器里面，添加到事件中。 ;juwe; 能不能改下，直接 使用。或者把召唤石换下触发条件，融合起来。 等下，要输入生物编号？？这肯定记不住的 一边打一边查ERM帮助上的生物编号吧，呵呵。 这个好，每次召兵很难，因为不会兵链哦 最好用 ERM_S 脚本编辑器,将文本全部复制进去,然后另存为 *.ERM文件.改成 SCRIPT**.erm (**是2位数字,参考S文件夹下的格式) 直接放到 S 文件夹下. (不要和已有的编号冲突)
WOG化地图应该能实现的.
页:
[1]
