论坛 › ERM公会 | ERM Guild › 弱弱问下这个选择框是用什么原理使英雄改名和改头像的？

碳妖 发表于 2012-8-25 16:32:53

弱弱问下这个选择框是用什么原理使英雄改名和改头像的？

erm新手不会啊

碳妖 发表于 2012-8-25 16:33:22

黑椒又不在;azhao;

碳妖 发表于 2012-8-25 16:51:50

现在没人鸟碳妖了么;azhao;

十三木人 发表于 2012-8-25 17:12:30

位数错了IF:D后面最多跟16个数据，你这里有17个

碳妖 发表于 2012-8-25 17:15:34

回复 4# 的帖子

能把安姆那图选头像填名字的完整脚本贴出来么，拜托了

碳妖 发表于 2012-8-25 17:21:31

框子是弄出来了，但是不知道后面的怎么写

[ 本帖最后由 碳妖 于 2012-8-25 17:22 编辑 ]

十三木人 发表于 2012-8-25 17:29:06

后面？什么后面
你要写什么

fly123 发表于 2012-8-25 17:57:29

!!VRz500:S^..\tob^;目录
!!VRy-12:S1 R1;
!!VRy-13:S3 R1;
!!VRy-14:S5 R1;
!!VRy-15:S7 R1;
!!VRz511:S^巫 妖 王 的 毁 灭 ☆外 传 - 1.36☆

-玩 家 个性化选择-^;
!!VRz501:S^请 教 英 雄 大 名^;
!!VRz502:S^选 择 你 喜 欢 的 英 雄 头 像^;
!!VRz503:S^%Z500\god-%Y-12.bmp^;
!!VRz504:S^%Z500\god-%Y-13.bmp^;
!!VRz505:S^%Z500\god-%Y-14.bmp^;
!!VRz506:S^%Z500\god-%Y-15.bmp^;
!!VRz507:S^我喜欢第一个,好酷,够爷们!^;
!!VRz508:S^第二个，漂亮MM!^;
!!VRz509:S^第三个好帅哦，我要!^;
!!VRz510:S^第四个美女好销魂，我的最爱!^;
!!IF:D50/511/501/502/503/504/505/506/////507/508/509/510;
!!IF:E500/50;
!!VRz512&v500>0:Sz1;
!!VRz512:H499;      

!!OW&v500>0:H-1/?v114/1;
!!IF:Wv114;
!!VRz537:S^..\bd^;目录
!!VRz513&v500=1:S^%Z537\%Y-12.pcx^;
!!VRz514&v500=1:S^%Z537\%Y-12s.pcx^;
!!VRz513&v500=2:S^%Z537\%Y-13.pcx^;
!!VRz514&v500=2:S^%Z537\%Y-13s.pcx^;
!!VRz513&v500=3:S^%Z537\%Y-14.pcx^;
!!VRz514&v500=3:S^%Z537\%Y-14s.pcx^;
!!VRz513&v500=4:S^%Z537\%Y-15.pcx^;
!!VRz514&v500=4:S^%Z537\%Y-15s.pcx^;

!!VRz555&v500=1:S^%Z500\god-%Y-12.bmp^;
!!VRz555&v500=2:S^%Z500\god-%Y-13.bmp^;
!!VRz555&v500=3:S^%Z500\god-%Y-14.bmp^;
!!VRz555&v500=4:S^%Z500\god-%Y-15.bmp^;
!!HEv114&v500>0:L5/z513/z514;
!!HEv114&499:B0/z512;
!!HEv114&v500=1:R2/0;
!!HEv114&v500=2:R2/1;
!!HEv114&v500=3:R2/0;
!!HEv114&v500=4:R2/1;

!!VRz530:S^..\Data\zvs\Lib1.res^;
!!VRz516:S^宠物选择^;
!!VRz517:S^选择你喜欢的宠物^;
!!VRz518:S^%Z530\NPC5.gif^;
!!VRz519:S^%Z530\NPC1.gif^;
!!VRz520:S^%Z530\NPC2.gif^;
!!VRz521:S^%Z530\NPC6.gif^;
!!VRz522:S^嗜杀者(特技神罚LV>55),80%魔法箭和30%闪电射击^;
!!VRz523:S^圣师(特技天佑LV>55),50%魔法箭射击^;
!!VRz524:S^圣堂守卫(特技断筋LV>55)60%魔法箭和30%冰射线射击^;
!!VRz525:S^食人魔领袖(特技软骨LV>55),50%魔法箭射击,(炮车*5+无视距离)^;
!!VRz526:S^战斗后获取金钱,会高级理财术.^;
!!VRz527:S^战场上召唤帐篷加倍,会高级航海术.帐篷能力加强^;
!!VRz528:S^魔力抽取,会高级学习术.^;
!!VRz529:S^高级(弹道术|炮术).召唤弩车,弩车加强,自带精准,无视距离,近身射击^;
!!IF:D9/516/0/517/518/519/520/521/522/523/524/525/522/523/524/525;
!!IF:F9/526/527/528/529/0;
!!IF:E1001/9;
!!VRv1002&v1001=1:S5;
!!VRv1002&v1001=2:S1;
!!VRv1002&v1001=3:S2;
!!VRv1002&v1001=4:S6;
!!COv114:Tv1002;
!!HEv114&v1002=5:S13/3;
!!HEv114&v1002=2:S21/3;
!!HEv114&v1002=1:S5/3;
!!HEv114&v1002=6:S10/2 S20/2;弹道术炮术

!!VRz531:S^%Z530\_AT_SP_1.bmp^;
!!VRz532:S^%Z530\_AT4=.bmp^;
!!VRz533:S^%Z530\_HP4=.bmp^;
!!VRz534:S^%Z530\_MP4=.bmp^;
!!VRz535:S^自带弹药车,射手弹药数加倍.伤害近战不减.弹药车属性加强^;
!!VRz536:S^自动获得3级战术,士气加2,运气加2.^;
!!VRz537:S^战场中自动出现转世重生魔法,帐篷学会偏移,魔法区域.自带护盾,属性加强^;
!!VRz538:S^随等级加魔法威力,减少受魔法伤害,攻击诅咒,野兵S-2,无魔镜,40%几率中蛊^;
!!VRz539:S^所有兵种自带气盾,30%几率劲射,特技(破天神箭)^;
!!VRz540:S^所有兵种每回合自动获得护盾、石肤术.30%几率狂暴,特技(独孤剑谱)^;
!!VRz541:S^自动学会超级转世重生.所有兵种40%几率净化,特技(神灵护佑)^;
!!VRz542:S^博德之盔MR+300%,雷神之锤+100%并让敌人无法放魔法,特技(灭世魔身)^;
!!VRz543:S^特 长 选 择^;
!!VRz544:S^请 选 择 主 角 的 特 长^;
!!VRz545:S^箭术特长,游戏开始有中级箭术.(鼠标指向图标显示补充说明).^;
!!VRz546:S^进攻特长,游戏开始有中级进攻术.(鼠标指向图标显示补充说明).^;
!!VRz547:S^冶疗特长,游戏开始有中级冶疗术.(鼠标指向图标显示补充说明).^;
!!VRz548:S^魔力特长,游戏开始中级魔力术.(鼠标指向图标显示补充说明).^;
!!IF:D15/543/0/544/531/532/533/534/535/536/537/538/545/546/547/548;
!!IF:F15/539/540/541/542/0;
!!IF:E1025/15;
!!VRv1055&v1025=1:S1;
!!VRv1055&v1025=2:S2;
!!VRv1055&v1025=3:S4;
!!VRv1055&v1025=4:S8;

!!HEv114&v1025=1:S1/2;
!!HEv114&v1025=2:S22/2;
!!HEv114&v1025=3:S27/2;
!!HEv114&v1025=4:S25/2;

!!HEv114&v1025=1:B2/2;
!!HEv114&v1025=2:B2/0;
!!HEv114&v1025=3:B2/1;
!!HEv114&v1025=4:B2/3;

!!HEv114&v1025=1:F2/2/1/1;
!!HEv114&v1025=2:F4/0/1/1;
!!HEv114&v1025=3:F1/1/2/2;
!!HEv114&v1025=4:F0/0/4/2;

碳妖 发表于 2012-8-25 18:33:15

回复 7# 的帖子

不会改名字和头像啊

碳妖 发表于 2012-8-25 18:35:53

大家帮我看看哪里出错了啊
ZVSE

!#VRz103:S^信息填写^;对话框文本
!#VRz104:S^请填写你的高姓大名^;
!#VRz105:S^请选择你的头像^;
!#VRz106:S^头像1^;
!#VRz107:S^头像2^;
!#VRz108:S^头像3^;
!#VRz109:S^头像4^;
!#VRz110&v100=1:S^../data/touxiang/tx00s.bmp^;头像位置
!#VRz111&v100=1:S^../data/touxiang/tx00l.bmp^;
!#VRz110&v100=2:S^../data/touxiang/tx01s.bmp^;
!#VRz111&v100=2:S^../data/touxiang/tx01l.bmp^;
!#VRz110&v100=3:S^../data/touxiang/tx02s.bmp^;
!#VRz111&v100=3:S^../data/touxiang/tx02l.bmp^;
!#VRz110&v100=4:S^../data/touxiang/tx03s.bmp^;
!#VRz111&v100=4:S^../data/touxiang/tx03l.bmp^;

!?PI;
!!IF:D1/103/104/105/14/15/16/17/106/107/108/109/106/107/108/109;信息填写框
!!IF:F1/106/107/108/109;
!!IF:E100/1;
!!HE144:B0/z1 B1/z1;大脸改名字
!!HE0:B0/z1 B1/z1;欧灵改名字
!!HE144:L1^%Z110^ L2^%Z111^;大脸改头像
!!HE0:L1^%Z110^ L2^%Z111^;欧灵改头像

碳妖 发表于 2012-8-25 18:36:56

回复 8# 的帖子

谢谢，不过看起来很乱

碳妖 发表于 2012-8-25 18:42:23

每次写出来的新东西都错误满天飞;azhao;

十三木人 发表于 2012-8-25 18:45:45

回复 8# 的帖子

图片格式要用.pcx
bmp肯定是不行的
还有建议把
!#VRz110&v100=1:S^../data/touxiang/tx00s.bmp^;头像位置
!#VRz111&v100=1:S^../data/touxiang/tx00l.bmp^;
!#VRz110&v100=2:S^../data/touxiang/tx01s.bmp^;
!#VRz111&v100=2:S^../data/touxiang/tx01l.bmp^;
!#VRz110&v100=3:S^../data/touxiang/tx02s.bmp^;
!#VRz111&v100=3:S^../data/touxiang/tx02l.bmp^;
!#VRz110&v100=4:S^../data/touxiang/tx03s.bmp^;
!#VRz111&v100=4:S^../data/touxiang/tx03l.bmp^;
这一段放到!!IF:E100后面，记得把!#改成!!
!#的优先度比较高，放前面的话无法读取v100

碳妖 发表于 2012-8-25 20:02:48

回复 13# 的帖子

哦，我去试试。头像能不能不用索引颜色直接用RGB啊？

碳妖 发表于 2012-8-25 20:11:54

名字能改了，但是头像依然显示错误

[ 本帖最后由 碳妖 于 2012-8-25 20:13 编辑 ]

碳妖 发表于 2012-8-25 20:18:31

它说这句错了
!!IF:F1/106/107/108/109;

碳妖 发表于 2012-8-25 20:25:12

我不明白了，IF:F错在哪里了？
!#VRz106:S^头像1^;
!#VRz107:S^头像2^;
!#VRz108:S^头像3^;
!#VRz109:S^头像4^;
!!IF:F10/106/107/108/109;

碳妖 发表于 2012-8-25 20:28:21

貌似安姆这图选头像没有用到IF:F呢

十三木人 发表于 2012-8-25 20:33:23

回复 17# 的帖子

你这个错的离谱好不
!!要接在!?后面，你却接在!#后面

fly123 发表于 2012-8-25 20:34:39

不能单独用IF：F，要和IF：E配合使用。
Setup information will not be saved when game is saved so always do setup immediately before using IF:E command.

查看完整版本: 弱弱问下这个选择框是用什么原理使英雄改名和改头像的？