论坛 › ERM公会 | ERM Guild › 使用这脚本方魔法是底部出现花屏

a3320956 发表于 2011-8-16 21:03:03

使用这脚本方魔法是底部出现花屏

ZVSE
ERMS_ScriptDate=16.8(August).2011
_WARNING_#1=IMPORTANT! This file is not in a plain text format. NEVER use any editor except ERM_S for making any kind of changes!
ERMS_PoweredBy=ERM Scripter v. 2004.6.29.918

!#VRz578:S^{狄美娜的祝福}^;
!#VRz579:S^{狄美娜的祝福}
炼金导师狄美娜的呕心之作。
英雄属性增加5点,部队30%抗魔
{在英雄施法后，能恢复5点魔法点} ^;
!#UN:A166/9/578;             名字
!#UN:A166/10/579;            描述
!#UN:A166/1/100000;         价值
!#UN:A166/3/16;
!#UN:A15/166/57/58/59;

!#UN:A166/4/-1;

!?AE1&v998=166;
!!HE-1:Fd5/d5/d5/d5;

!?AE0&v998=166;
!!HE-1:Fd-5/d-5/d-5/d-5;

!?BA0;
!!BA:H0/?v9555 H1/?v9560;

!?BG&1000;
!!BG:A?y3;
!!BU:T?y-1;
!!FU&y-1=1:E;
!!FU|y3<>1:E;
!!FU95&v9555>-1:P0/v9555;
!!FU95&v9560>-1:P1/v9560;

!?FU95;
!!FU|x1<0/x1>1/x2<0:E;
!!HEx2:A2/166/d/?x3;
!!FU&x3<1:E;
!!HEx2:I?y1;
!!VRy1:+5;
!!HEx2:Iy1;

寻梦人 发表于 2011-8-16 21:10:51

回复 1# 的帖子

原因是你动作时调用了英雄指数或魔法值!

兽哥哥 发表于 2011-8-16 21:34:54

跟精灵那个图正式版一样的。呵呵，寻梦解决应该是轻车熟路了。

a3320956 发表于 2011-8-16 21:35:21

回复 2# 的帖子

哦这样的
不能消除这问题吗？

寻梦人 发表于 2011-8-16 21:44:12

回复 4# 的帖子

换一个触发器试试:
用!?BR;

a3320956 发表于 2011-8-16 21:58:52

回复 5# 的帖子

没有恢复魔法的效果了

genman 发表于 2011-8-16 22:05:19

回复魔法很简单
用HEx:Id5/1
可以回复5点mana

寻梦人 发表于 2011-8-16 22:06:41

回复 6# 的帖子

!?MR0;

用这个应该可以,不过要是伤害魔法才有效!

a3320956 发表于 2011-8-16 22:16:26

回复 8# 的帖子

!?MR0;
!!BA:H0/?v9555 H1/?v9560;

!?BG&1000;
!!BG:A?y3;
!!BU:T?y-1;
!!FU&y-1=1:E;
!!FU|y3<>1:E;
!!FU95&v9555>-1:P0/v9555;
!!FU95&v9560>-1:P1/v9560;

一样花屏

寻梦人 发表于 2011-8-16 22:17:25

改后面的那个触发器!

a3320956 发表于 2011-8-16 22:18:50

回复 10# 的帖子

!!BA:H0/?v9555 H1/?v9560; 这个吗

寻梦人 发表于 2011-8-16 22:21:12

!?MR0;
!!BG:A?y3;
!!BU:T?y-1;
!!FU&y-1=1:E;
!!FU|y3<>1:E;
!!FU95&v9555>-1:P0/v9555;
!!FU95&v9560>-1:P1/v9560;

a3320956 发表于 2011-8-16 22:26:45

回复 12# 的帖子

!?MR0;
!!BG:A?y3;
!!BU:T?y-1;
!!FU&y-1=1:E;
!!FU|y3<>1:E;
!!FU95&v9555>-1:P0/v9555;
!!FU95&v9560>-1:P1/v9560;
;quq;还是花屏

克招 发表于 2011-8-16 22:43:41

erm盲教了也不会的，还是从最基础的学起。

寻梦人 发表于 2011-8-16 22:55:06

回复 13# 的帖子

那就应该没有什么好办法了!:lianhong: :lianhong: :lianhong: :lianhong:

a3320956 发表于 2011-8-16 23:00:35

回复 15# 的帖子

;cool;那还是不用恢复魔法了

fastarrow 发表于 2011-8-16 23:47:45

尝试在BF触发器里坚持是否装备宝物，并用v变量保存。
调用函数时用前面的v变量做条件。
后面的函数不再检查装备的宝物。

沧海一粟 发表于 2011-8-17 08:39:38

寻梦说得很对，出现花屏的原因是因为你这一句
!!HEx2:I?y1;
!!VRy1:+5;
!!HEx2:Iy1;
调用了英雄的魔法值造成的，你可以尝试用一下!?BG1;来写，也许能解决。
另外你的这一句
!!BU:T?y-1;
!!FU&y-1=1:E;
有什么意义呢？为什么要设置英雄有了战术就退出函数，好像没这个必要吧。

genman 发表于 2011-8-17 12:02:13

!!HEx2:Iy1;
lz,这句话改成
!!HEx2:Iy1/1;

保证你就不会花屏了
后面添加参数/1就是不重画界面

骷髅召唤师 发表于 2011-8-17 12:34:10

回复 1# 的帖子

ZVSE
ERMS_ScriptDate=16.8(August).2011
_WARNING_#1=IMPORTANT! This file is not in a plain text format. NEVER use any editor except ERM_S for making any kind of changes!
ERMS_PoweredBy=ERM Scripter v. 2004.6.29.918

!#VRz578:S^{狄美娜的祝福}^;
!#VRz579:S^{狄美娜的祝福}
炼金导师狄美娜的呕心之作。
英雄属性增加5点,部队30%抗魔
{在英雄施法后，能恢复5点魔法点} ^;
!#UN:A166/9/578;             名字
!#UN:A166/10/579;            描述
!#UN:A166/1/100000;         价值
!#UN:A166/3/16;
!#UN:A15/166/57/58/59;

!#UN:A166/4/-1;

!?AE1&v998=166;
!!HE-1:Fd5/d5/d5/d5;

!?AE0&v998=166;
!!HE-1:Fd-5/d-5/d-5/d-5;

!?BA0;
!!BA:H0/?v9555 H1/?v9560;

!?BG0&1000;
!!BG:A?y3;
!!BU:T?y-1;
!!FU&y-1=1:E;
!!FU|y3<>1:E;
!!FU95&v9555>-1:P0/v9555;
!!FU95&v9560>-1:P1/v9560;

!?FU95;
!!FU|x1<0/x1>1/x2<0:E;
!!HEx2:A2/166/d/?x3;
!!FU&x3<1:E;
!!HEx2:Id5/1;

查看完整版本: 使用这脚本方魔法是底部出现花屏