在线急求！
我正在做个原创地图！现在只需要个可以把:密银,翡翠塔，宝物升级所，等等WOG功能激活的事件ERM（我直接用事件编辑的ERM只差这个东西了 这几个貌似在TDS中可以提取的到。翡翠塔肯定可以提取，其他两个，记不太清楚了 使用编辑器，多看看事件吧 秘银显示：ZVSE
!#UN:B0/1;
*** Display Mithril if Kingdom Overview Button is Right-clicked ***
!?CM0;
!!CM:R1;
!!CM:I?y1;
!!OW:R-1/7/?y2;
!!VRz-1:S^条。^;
!!VRz-1&y2=1:S^条。^;
!!IF&y1=3:Q1/7/y2/1^{秘银}
%Y2闪闪发光的秘银%Z-1^;
!!CM&y1=3:R0;
*** Display when Mithril is picked up ***
!?OB79/7;
!!HE-1:B0/?z1;
!!ARv998/v999/v1000:V?y1;
!!OW:R-1/7/?y2;
!!VRy2:+y1;
!!VRz2&y2=1:S^条^;
!!VRz2&y2>1:S^条^;
!!VRz3&y1=1:S^条^;
!!VRz3&y1>1:S^条^;
!!VRz4:S^%Y1^;
!!VRz4&y1=1:S^1条^;
!!IF&1000:Q1/7/y1/1^{Mithril}
%Z1 捡起 %Z4%Z3 闪闪发光的秘银。
{你现在总共有 %Y2 %Z2 秘银。}
(右击王国概况按钮，你可随时查看你所拥有的秘银概况。)^; 秘银矿：
ZVSE
!#TM91:S8/999/7/255;
!#VRz455:S^秘银矿 {未访问}^;
!#VRz456:S^秘银矿 {已访问}^;
!#HT63/27:P0/455;
!#HT63/27:P1/456;
!?TM94&1000;
!!UN:U63/27/?v2;
!!DO20000/1/v2/1&v2>0:P;
!?TM91&1000;
!!UN:U63/27/?v2;
!!DO20000/1/v2/1&v2>0:P;
!?FU20000;
!!UN:U63/27/x16/4;
!!VRv1:S3 R3;
!!PO4:Nv1;
!?OB63/27&1000;
!!PO998:N?v1;
!!FU&v1=1:E;
!!OW:R-1/7/dv1;
!!IF:Q1/7/v1/1^你得到一些秘银.^;
!!PO998:N1;
!?OB63/27&1000/v1=1;
!!VRz10:S^每周只可以生产一批秘银,请下周再来吧.^;
!!IF:D5/10;
!!IF:E1/5; 翡翠塔的我有，看附件。 翡翠塔：
ZVSE
ERMS_ScriptDate=20.5(May).2005
_WARNING_#1=IMPORTANT! This file is not in a plain text format. NEVER use any editor except ERM_S for making any kind of changes!
ERMS_PoweredBy=ERM Scripter v. 2004.6.29.918
** Emerald Tower Script Version 0.2 Created by Timothy Pulver
** Requires WoG version 3.57 or later using ERM version 2.6 or later.
** WoGify Name: script44.erm
** This script makes all green roofed towers in the game (object type 63,
** subtype 65) into Emerald Towers where the Wizard who dwells there will
** improve any creature type in your army for a price. The price is a lot of
** resources of a specific type, depending on the improvement. In addition,
** one of the creatures of the type being improved must also be left for the
** Wizard.
** The improvement number is usually a percentage of the existing score. For
** example, 50% growth bonus, or 25% attack bonus. In addition to standard
** stat improvements, new special abilities may be added. Special abilities
** all cost Mithril.
** Each Emerald Tower may only be visited once per day. A maximum of 12
** types of creatures may be improved in any game, but each creature type
** may have many improvements made to it. A creature cannot be improved
** during a "Week of" that creature type, if the "Week of Monsters" script
** is active.
------------------------------------------------------------------------
Permanent Variables: z816-z841, v1240-v1252 (not v1253--used by Garrison script))
Temporary Variables: v1-v7, v360-v369, z1-z9, z480-z490
Temporary Flags: 1-4
Functions: 10900-10911
Timers: 38
Dialogues: 3
-----------------------------------------------------------------------
!#VRv1240:S0;
!#VRz816:S^翡翠塔
(未访问)^;
!#VRz817:S^翡翠塔
(已访问)^;
!#HT63/65:P0/816;
!#HT63/65:P1/817;
!#TM38:S8/999/7/255;
-----------------------------------------------------------------------
!?TM38;
!!UN:U63/65/?v1;
!!DO10910/1/v1/1&v1>0:P;
-----------------------------------------------------------------------
!?FU10910;
!!UN:U63/65/x16/1;
!!POv1/v2/v3:N0;
-----------------------------------------------------------------------
!?OB63/65;
!!PO998:N?v1;
!!IF&v1=1/1000:M^{翡翠塔}
你敲了敲大门，一个小侏儒探出头来。
“走开！巫师没空理你！”小侏儒粗鲁地吼道，在你面前咣地关上了大门。^;
!?OB63/65&v1=0;
!!IF&1000:Q2/5/7/2^{翡翠塔}
你敲了敲大门，一个小侏儒探出头来。
“你和巫师预约过吗？”
门上的告示写着：
“凡与巫师预约需付7个宝石”
你要预约吗？^;
!!OW&2:R-1/5/?y1;
!!VRz9:S^^;
!!VRz9&2/y1<7:S^你没有足够的宝石。没有宝石，就不能预约。 ^;
!!IF&y1<7:V2/0;
!!OW&2:R-1/5/d-7;
!!IF&2/1000:M^小侏儒拿走宝石，然后引你入内。
巨大的大厅是阴暗的并布满蜘蛛网和成千上万布满灰尘的旧书。
在你能更多的窥探之前，巫师出现了，裹着长长而又平滑的长袍。^;
!!FU10900&2:P;
!!IF&-2/1000:M^“%Z9没有预约, 不能进去！” 侏儒吼道，在你面前咣地关上了大门。^;
-----------------------------------------------------------------------
!?FU10900;
!!FU10901:P;
!!VRz1:S^“呵呵，” 巫师问道。 “你想改造哪队生物？”^;
!!VRz2:S^我不想改变了。^;
!!IF&v1>0/1000:G1/367/0/1/480/481/482/483/484/485/486/2/0/0/0/0;
!!IF&v1=0/1000:M^“你没有带任何生物，我帮不了你。再见。”^;
!!VRv2:S0;
!!VRv2&v367=1:Sv360;
!!VRv2&v367=2:Sv361;
!!VRv2&v367=4:Sv362;
!!VRv2&v367=8:Sv363;
!!VRv2&v367=16:Sv364;
!!VRv2&v367=32:Sv365;
!!VRv2&v367=64:Sv366;
!!VRv2&v367=128:S-1;
!!IF:V4/1;
!!IF&v2=-1/1000:Q4^{巫师显得很恼火。}
“你不要我的服务？ 好吧！ 你赶紧走吧，别浪费我宝贵的时间了！”
你要离开翡翠塔吗？^;
!!UN&v2>=0:N3/3/v2/0;
!!UN&v2>=0:N3/4/v2/1;
!!IF&56/v170>=0/v170=v2/1000:Q4/21/v2/1^{巫师显得很不安。}
“现在是%Z3之周，影响了我的法力。我无法立即改造%Z4。请你下周再来吧。”
你要离开翡翠塔吗？^;
!!VRv2&56/v170>=0/v170=v2:S-1;
!!VRv6:S-1;
!!DO10908/1/v1240/1&v2>=0/v1240>0:P;
!!IF&v1240>=12/v6<0/v2>=0/1000:Q4^{巫师看起来很不安。}
“噢，不，这根本不行。在这片土地上%V1240 种族已经被改造过了。再要加强或者给它魔法能力都会引起未知后果而且很危险。我不会这样做的。”
你要离开翡翠塔吗？^;
!!VRv2&v1240>=12/v6<0:S-1;
!!FU10902&v2>=0:P;
!!FU10900&v2=-1/-4:P;
-----------------------------------------------------------------------
!?FU10901;
!!VRv1:S0;
!!VRv360:C-1/-1/-1/-1/-1/-1/-1;
!!VRz480:S^^;
!!VRz481:S^^;
!!VRz482:S^^;
!!VRz483:S^^;
!!VRz484:S^^;
!!VRz485:S^^;
!!VRz486:S^^;
!!HE-1:C0/0/?y1/?y2;
!!VRv1&y2>0:+1;
!!VRv360&y2>0:Sy1;
!!UN&y2>0:N3/480/y1/1;
!!HE-1:C0/1/?y1/?y2;
!!VRy4:S0;
!!VRy4&v1=1/y1=v360:S99;
!!VRv1&y2>0/y4<>99:+1;
!!VRy3&y2>0/y4<>99:S359 +v1;
!!VRy5&y2>0/y4<>99:S479 +v1;
!!UN&y2>0/y4<>99:N3/y5/y1/1;
!!VRvy3&y2>0/y4<>99:Sy1;
!!HE-1:C0/2/?y1/?y2;
!!VRy4:S0;
!!VRy4&v1>=1/y1=v360:S99;
!!VRy4&v1=2/y1=v361:S99;
!!VRv1&y2>0/y4<>99:+1;
!!VRy3&y2>0/y4<>99:S359 +v1;
!!VRy5&y2>0/y4<>99:S479 +v1;
!!UN&y2>0/y4<>99:N3/y5/y1/1;
!!VRvy3&y2>0/y4<>99:Sy1;
!!HE-1:C0/3/?y1/?y2;
!!VRy4:S0;
!!VRy4&v1>=1/y1=v360:S99;
!!VRy4&v1>=2/y1=v361:S99;
!!VRy4&v1=3/y1=v362:S99;
!!VRv1&y2>0/y4<>99:+1;
!!VRy3&y2>0/y4<>99:S359 +v1;
!!VRy5&y2>0/y4<>99:S479 +v1;
!!UN&y2>0/y4<>99:N3/y5/y1/1;
!!VRvy3&y2>0/y4<>99:Sy1;
!!HE-1:C0/4/?y1/?y2;
!!VRy4:S0;
!!VRy4&v1>=1/y1=v360:S99;
!!VRy4&v1>=2/y1=v361:S99;
!!VRy4&v1>=3/y1=v362:S99;
!!VRy4&v1=4/y1=v363:S99;
!!VRv1&y2>0/y4<>99:+1;
!!VRy3&y2>0/y4<>99:S359 +v1;
!!VRy5&y2>0/y4<>99:S479 +v1;
!!UN&y2>0/y4<>99:N3/y5/y1/1;
!!VRvy3&y2>0/y4<>99:Sy1;
!!HE-1:C0/5/?y1/?y2;
!!VRy4:S0;
!!VRy4&v1>=1/y1=v360:S99;
!!VRy4&v1>=2/y1=v361:S99;
!!VRy4&v1>=3/y1=v362:S99;
!!VRy4&v1>=4/y1=v363:S99;
!!VRy4&v1=5/y1=v364:S99;
!!VRv1&y2>0/y4<>99:+1;
!!VRy3&y2>0/y4<>99:S359 +v1;
!!VRy5&y2>0/y4<>99:S479 +v1;
!!UN&y2>0/y4<>99:N3/y5/y1/1;
!!VRvy3&y2>0/y4<>99:Sy1;
!!HE-1:C0/6/?y1/?y2;
!!VRy4:S0;
!!VRy4&v1>=1/y1=v360:S99;
!!VRy4&v1>=2/y1=v361:S99;
!!VRy4&v1>=3/y1=v362:S99;
!!VRy4&v1>=4/y1=v363:S99;
!!VRy4&v1>=5/y1=v364:S99;
!!VRy4&v1=6/y1=v365:S99;
!!VRv1&y2>0/y4<>99:+1;
!!VRy3&y2>0/y4<>99:S359 +v1;
!!VRy5&y2>0/y4<>99:S479 +v1;
!!UN&y2>0/y4<>99:N3/y5/y1/1;
!!VRvy3&y2>0/y4<>99:Sy1;
-----------------------------------------------------------------------
!?FU10902;
!!UN:N3/3/v2/0;
!!MA:Av2/?y1;
!!VRy2:Sy1 :4;
!!VRy2&y2=0:S1;
!!MA:Dv2/?y1;
!!VRy3:Sy1 :4;
!!VRy3&y3=0:S1;
!!MA:Ev2/?y1;
!!VRy4:Sy1 :4;
!!VRy4&y4=0:S1;
!!MA:Pv2/?y1;
!!VRy5:Sy1 :4;
!!VRy5&y5=0:S1;
!!MA:Sv2/?y1;
!!VRy6:Sy1 :4;
!!VRy6&y6=0:S1;
!!MA:Gv2/?y1;
!!VRy7:Sy1 :2;
!!VRy7&y7=0:S1;
!!MA:Nv2/?y8;
!!MA:Bv2/?y10;
!!VRz1:S^“你想怎样改造%Z3 ？”^;
!!VRz2:S^我不想改造了。^;
!!VRz480:S^+%Y2 攻击力，花费 15 硫磺^;
!!VRz481:S^+%Y3 防御力，花费 30 石头^;
!!VRz482:S^+%Y4 杀伤力，花费 10 宝石^;
!!VRz483:S^+%Y5 生命，花费 20 水晶^;
!!VRz484:S^+%Y6 速度，花费 30 水银^;
!!VRz485:S^+%Y7 生长率,花费 30 木头^;
!!VRz486&y8<24:S^24 只箭，花费 12000 黄金^;
!!VRz486|y8<1/y8>=24:S^^;
!!VRz487&y10>0:S^+1 施法次数每场战斗，花费 20 秘银^;
!!VRz487|y10<1/y10>12:S^^;
!!VRz488:S^一种新的特技^;
!!IF&1000:G1/368/0/1/480/481/482/483/484/485/486/487/488/2/0/0;
!!VRv3:S0;
!!VRv3&v368=1:S2;
!!VRv3&v368=2:S3;
!!VRv3&v368=4:S4;
!!VRv3&v368=8:S5;
!!VRv3&v368=16:S6;
!!VRv3&v368=32:S7;
!!VRv3&v368=64:S8;
!!VRv3&v368=128:S9;
!!VRv3&v368=256:S10;
!!VRv3&v368=512:S-1;
!!VRv5:S0;
!!FU10906&v3=10:P;
!!VRv4:S0;
!!FU10903&v3>1:P;
!!VRy9&v3>=2/v3<=7:Syv3;
!!FU10905&v4=1:Py9;
!!VRv1240&v4=1/v6<0:+1;
!!FU10909&v4=1:P;
!!PO998&v4=1:N1;
!!IF&v3=-1/1000:Q4^{巫师显得很恼火。}
“你不要我的服务？好吧！你赶紧走吧，别浪费我宝贵的时间！”
你要离开翡翠塔吗？^;
!!VRv3&v3>1/v4=0/-4:S-1;
!!FU10900&v3=-1/-4:P;
-----------------------------------------------------------------------
!?FU10903;
!!VRy1&v3=2:S3;
!!VRy2&v3=2:S15;
!!VRz1&v3=2:S^硫磺^;
!!VRy1&v3=3:S2;
!!VRy2&v3=3:S30;
!!VRz1&v3=3:S^石头^;
!!VRy1&v3=4:S5;
!!VRy2&v3=4:S10;
!!VRz1&v3=4:S^宝石^;
!!VRy1&v3=5:S4;
!!VRy2&v3=5:S20;
!!VRz1&v3=5:S^水晶^;
!!VRy1&v3=6:S1;
!!VRy2&v3=6:S30;
!!VRz1&v3=6:S^水银^;
!!VRy1&v3=7:S0;
!!VRy2&v3=7:S30;
!!VRz1&v3=7:S^木头^;
!!VRy1&v3=8:S6;
!!VRy2&v3=8:S12000;
!!VRz1&v3=8:S^金币^;
!!VRy1&v3=9:S7;
!!VRy2&v3=9:S20;
!!VRz1&v3=9:S^秘银^;
!!VRy1&v3=10:S7;
!!VRy2&v3=10/v5=1:S25;
!!VRy2&v3=10/v5=2:S15;
!!VRy2&v3=10/v5=3:S20;
!!VRy2&v3=10/v5=4:S15;
!!VRy2&v3=10/v5=5:S30;
!!VRy2&v3=10/v5=6:S25;
!!VRy2&v3=10/v5=7:S25;
!!VRy2&v3=10/v5=8:S20;
!!VRy2&v3=10/v5=9:S15;
!!VRy2&v3=10/v5=10:S15;
!!VRz1&v3=10:S^秘银^;
!!IF:V4/1;
!!OW:R-1/y1/?y3;
!!IF&y2>y3/1000:Q4/y1/y2/2^{巫师显得很恼火。}
“你没有足够的%Z1。快滚，别浪费我的时间！”
你要离开翡翠塔吗？^;
!!MA:Lv2/?y6;
!!VRy7&y6=0:S64;
!!VRy7&y6=1:S32;
!!VRy7&y6=2:S16;
!!VRy7&y6=3:S8;
!!VRy7&y6=4:S4;
!!VRy7&y6=5:S2;
!!VRy7&y6>=6:S1;
!!VRy7|v2=56/v2=57:S128;
!!VRz8&y7=1:Sz3;
!!VRz8&y7>1:Sz4;
!!VRz9&y7=1:S^^;
!!VRz9&y7>1:S^^;
!!IF:V3/0;
!!VRy5:S65536 *y7;
!!VRy5:+v2;
!!IF&y3>=y2/1000:Q3/21/y5/2^“除了%Y2个%Z1， 我还需要%Y7个%Z8祭神。 这些%Z8将不再回到你的部队。”
“你同意吗？”^;
!!VRv3&-3/y3>=y2:S-1;
!!VRv7:S0;
!!DO10904/0/6/1&3:P;
!!DO10911/0/6/1&v7>=y7/3:Py7;
!!IF&v7<y7/3:Q4/21/y5/2^{巫师显然很生气。}
“这些不够。我必须要有%Y7个%Z4才能完成仪式。你走吧，别在这里浪费我的时间，否则我把你们全部变成又老又丑的癞蛤蟆！”
你要离开翡翠塔吗？^;
!!UN&3:N3/4/v2/1;
!!IF&3/v7>=y7/1000:Q1/21/y5/y1/y2/1^侏儒拿了你%Y2个%Z1，带着%Y7个%Z4走下幽暗的长廊。%Z8回过头用恐惧的眼神望着你，轻声地啜泣，直到消失在黑暗的墓室深处。
“你可以走了，”巫师粗鲁地说道，“改造很快就会完成。”^;
!!VRy4&3/v7>=y7:Sy3 -y2;
!!OW&3/v7>=y7:R-1/y1/y4;
!!VRv4&3/v7>=y7:S1;
-----------------------------------------------------------------------
!?FU10904;
!!HE-1:C0/x16/?y1/?y2;
!!VRv7&y1=v2/y2>0:+y2;
-----------------------------------------------------------------------
!?FU10905;
!!MA&v3=2:Av2/dx1;
!!MA&v3=3:Dv2/dx1;
!!MA&v3=4:Ev2/dx1;
!!MA&v3=4:Mv2/dx1;
!!MA&v3=5:Pv2/dx1;
!!MA&v3=6:Sv2/dx1;
!!MA&v3=7:Gv2/dx1;
!!MA&v3=8:Nv2/24;
!!MA&v3=9:Bv2/d1;
!!FU10907&v3=10:P;
-----------------------------------------------------------------------
!?FU10906;
!!VRz480:S^^; !!VRz481:S^^; !!VRz482:S^^; !!VRz483:S^^; !!VRz484:S^^;
!!VRz485:S^^; !!VRz486:S^^; !!VRz487:S^^; !!VRz488:S^^; !!VRz489:S^^; !!VRz490:S^^;
!!MA:Xv2/?v369;
!!VRy1:Sv369;
!!VRy1:&2;
!!VRz480&y1=0:S^无视障碍(飞行)，花费 25 秘银^;
!!VRz480&y1=2:S^^;
!!VRy1:Sv369;
!!VRy1:&8;
!!VRz481&y1=0:S^攻击两格(龙息攻击)，花费 15 秘银^;
!!VRz481&y1=8:S^^;
!!VRy1:Sv369;
!!VRy1:&262144;
!!VRz482&y1=0:S^亡灵生物，花费 20 秘银^;
!!VRz482&y1=262144:S^^;
!!VRy1:Sv369;
!!VRy1:&131072;
!!VRz483&y1=0:S^不受士气影响，花费 15 秘银^;
!!VRz483&y1=131072:S^^;
!!VRy1:Sv369;
!!VRy1:&32768;
!!VRz484&y1=0:S^攻击两次，花费 30 秘银^;
!!VRz484&y1=32768:S^^;
!!VRy1:Sv369;
!!VRy1:&524288;
!!VRz485&y1=0:S^环击，花费 25 秘银^;
!!VRz485&y1=524288:S^^;
!!VRy1:Sv369;
!!VRy1:&65536;
!!VRz486&y1=0:S^攻击不受反击，花费 25 秘银^;
!!VRz486&y1=65536:S^^;
!!VRy1:Sv369;
!!VRy1:&1024;
!!VRz487&y1=0:S^免疫心智魔法，花费 20 秘银^;
!!VRz487&y1=1024:S^^;
!!VRy1:Sv369;
!!VRy1:&16384;
!!VRz488&y1=0:S^免疫火魔法，花费 15 秘银^;
!!VRz488&y1=16384:S^^;
!!VRy1:Sv369;
!!VRy2:Sv369;
!!VRy1:&4096; (Check No Close Combat Penalty)
!!VRy2:&4; (Check Shooter)
!!VRz489&y1=0/y2=4:S^近身攻击不受影响，花费 15 秘银^;
!!VRz489|y1=4096/y2=0:S^^;
!!VRz1:S^“你想给 %Z4 增加什么新的魔法能力？”^;
!!VRz2:S^我不想这样做了。^;
!!IF&1000:G1/368/0/1/480/481/482/483/484/485/486/487/488/489/2/0;
!!VRv5:S0;
!!VRv5&v368=1:S1;
!!VRv5&v368=2:S2;
!!VRv5&v368=4:S3;
!!VRv5&v368=8:S4;
!!VRv5&v368=16:S5;
!!VRv5&v368=32:S6;
!!VRv5&v368=64:S7;
!!VRv5&v368=128:S8;
!!VRv5&v368=256:S9;
!!VRv5&v368=512:S10;
!!VRv5&v368=1024:S-1;
!!VRv3&v5=-1:S-1;
-----------------------------------------------------------------------
!?FU10907;
!!MA&v5=1:Xv2/d2;
!!MA&v5=2:Xv2/d8;
!!MA&v5=3:Xv2/d262144;
!!MA&v5=4:Xv2/d131072;
!!MA&v5=5:Xv2/d32768;
!!MA&v5=6:Xv2/d524288;
!!MA&v5=7:Xv2/d65536;
!!MA&v5=8:Xv2/d1024;
!!MA&v5=9:Xv2/d16384;
!!MA&v5=10:Xv2/d4096;
-----------------------------------------------------------------------
!?FU10908;
!!VRy1:S1240 +x16;
!!VRv6&vy1=v2:Sx16;
!!VRx16&vy1=v2:S99;
-----------------------------------------------------------------------
!?FU10909;
!!VRy1:S1 R2;
!!UN:G1/v2/0/0;
!!UN:G1/v2/1/0;
!!VRy4:S1240 +v1240;
!!VRvy4&v6<0:Sv2;
!!VRy2&v6<0:Sv1240 *2;
!!VRy2&v6>0:Sv6 *2;
!!VRy2:+816;
!!VRy3:Sy2 +1;
!!UN:N3/6/v2/0;
!!UN:N3/7/v2/1;
!!VRz5&v3=2/y1=1:S^威猛^;
!!VRz5&v3=2/y1=2:S^强悍^;
!!VRz5&v3=2/y1=3:S^勇猛^;
!!VRz5&v3=3/y1=1:S^厚皮^;
!!VRz5&v3=3/y1=2:S^坚固^;
!!VRz5&v3=3/y1=3:S^坚固^;
!!VRz5&v3=4/y1=1:S^凶猛^;
!!VRz5&v3=4/y1=2:S^强劲^;
!!VRz5&v3=4/y1=3:S^凶恶^;
!!VRz5&v3=5/y1=1:S^强健^;
!!VRz5&v3=5/y1=2:S^健壮^;
!!VRz5&v3=5/y1=3:S^强壮^;
!!VRz5&v3=6/y1=1:S^敏捷^;
!!VRz5&v3=6/y1=2:S^极速^;
!!VRz5&v3=6/y1=3:S^迅捷^;
!!VRz5&v3=7/y1=1:S^多产^;
!!VRz5&v3=7/y1=2:S^高产^;
!!VRz5&v3=7/y1=3:S^盛产^;
!!VRz5&v3=8/y1=1:S^满箭^;
!!VRz5&v3=8/y1=2:S^满矢^;
!!VRz5&v3=8/y1=3:S^善射^;
!!VRz5&v3=9/y1=1:S^魔幻^;
!!VRz5&v3=9/y1=2:S^魔力^;
!!VRz5&v3=9/y1=3:S^神力^;
!!VRz5&v5=1/y1=1:S^飞行^;
!!VRz5&v5=1/y1=2:S^飞翔^;
!!VRz5&v5=1/y1=3:S^滑翔^;
!!VRz5&v5=2/y1=1:S^龙息^;
!!VRz5&v5=2/y1=2:S^长刀^;
!!VRz5&v5=2/y1=3:S^长剑^;
!!VRz5&v5=3/y1=1:S^亡灵^;
!!VRz5&v5=3/y1=2:S^不死^;
!!VRz5&v5=3/y1=3:S^失魂^;
!!VRz5&v5=4/y1=1:S^冷静^;
!!VRz5&v5=4/y1=2:S^无情c^;
!!VRz5&v5=4/y1=3:S^无欲^;
!!VRz5&v5=5/y1=1:S^亢奋^;
!!VRz5&v5=5/y1=2:S^狂怒^;
!!VRz5&v5=5/y1=3:S^狂暴^;
!!VRz5&v5=6/y1=1:S^环刀^;
!!VRz5&v5=6/y1=2:S^旋风^;
!!VRz5&v5=6/y1=3:S^环击^;
!!VRz5&v5=7/y1=1:S^无挡^;
!!VRz5&v5=7/y1=2:S^无反^;
!!VRz5&v5=7/y1=3:S^破竹^;
!!VRz5&v5=8/y1=1:S^志坚^;
!!VRz5&v5=8/y1=2:S^志强^;
!!VRz5&v5=8/y1=3:S^意坚^;
!!VRz5&v5=9/y1=1:S^御火^;
!!VRz5&v5=9/y1=2:S^抗火^;
!!VRz5&v5=9/y1=3:S^甘露^;
!!VRz5&v5=10/y1=1:S^近击^;
!!VRz5&v5=10/y1=2:S^肉搏^;
!!VRz5&v5=10/y1=3:S^武斗^;
!!VRzy2:S^%Z5 %Z6^;
!!UN:G1/v2/0/y2;
!!VRzy3:S^%Z5 %Z7^;
!!UN:G1/v2/1/y3;
-----------------------------------------------------------------------
!?FU10911;
!!HE-1:C0/x16/?y1/?y2;
!!HE-1&y1=v2/y2>0/y2<=x1:C0/x16/-1/0;
!!VRy4&y1=v2/y2>0/y2<=x1:Sx1 -y2;
!!VRy3&y1=v2/y2>x1:Sx1 *-1;
!!HE-1&y1=v2/y2>x1:C0/x16/d/dy3;
!!VRy4&y1=v2/y2>x1:S0;
!!VRx1&y1=v2/y2>0:Sy4;
** End of Script ** 宝物升级所的ERM好长。。。 谢谢各位兄弟姐妹的支持！ 我慢了吗 高人真多!
什么时候我也可列入高手之林? 云斯在这个帖子里已经内置了很多可以直接调用的脚本
http://bbs.h3wog.com/thread-11078-1-1.html
页:
[1]
