〔分享〕暗黑塔的erm（必须配合WOG自定义设置文件共同使用）
说明：暗黑之塔:
1、可修改生物经验特技的建筑，WOG化时地图上的水车(Water Wheel)有20%机率转化为暗黑塔，每周只能访问一次。
2、只能增加经验特技，不能替换、修改原有技能（防止无赖打法，例如把圣龙的特技全部换成垃圾技能……）；生物最多8个经验，如果已有8个 则无法修改。
3、某种生物只要修改，全地图所有生物全部变动，但是二追例外。
4、必须拥有所有资源30个才能进行增加，增加普通技能不需要耗费秘银，bt的技能需要秘银。
5、重要！必须配合论坛发布的wog自定义设置文件才能使用，否则只能访问一次！
呃，我把代码贴出，做成script90.erm使用。ps：未做大规模测试，可能有未知bug存在。
ZVSE
_WARNING_#1=IMPORTANT! This file is not in a plain text format. NEVER use any editor except ERM_S for making any kind of changes!
ERMS_ScriptName=Script90
ERMS_ScriptAuthor=woodmelon
ERMS_ScriptVersion=1.0.0
ERMS_ScriptDate=3.1(January).2009
ERMS_ScriptERMVersion=2.70
ERMS_ScriptLanguage=中文(中国) or 中文(简体) (native)
ERMS_ScriptUsedVariables=z950-z951
ERMS_ScriptUsedFunctions=FU25013
ERMS_PoweredBy=ERM Scripter v. 2004.6.29.918
ERMS_Script by woodmelon
**ERM WoG Option Numbers: 701
**暗黑之塔: 可修改生物经验特技的建筑
**WOG化时地图上的水车(Water Wheel)有20%机率转化为暗黑塔
**每周只能访问一次
**FU25013
**z950,z951
**TM19 第一天触发
**TM38 每周触发
!#UN:P701/?y-1;
!#TM19&y-1=1:S1/1/1/255;
!#TM38&y-1=1:S8/999/7/255;
!#VRz950&y-1=1:S^暗黑塔（闪烁着神秘光芒）^;
!#VRz951&y-1=1:S^暗黑塔（大门紧闭）^;
!#HT63/63&y-1=1:P0/950;
!#HT63/63&y-1=1:P1/951;
!?TM19&1000;
!!UN:P701/?y-1;
!!FU&y-1=0:E;
!!UN:U109/-1/?v4; 计算水车数量
!!DO25013/1/v4/1&v4>0:P0;
!?FU25013;
!!FU&x1<>0:E;
!!VRv1&x16=1:S-1; 迅速计算
!!UN:U109/-1/-1/1; 取水车的坐标
!!VRy1:S0 R99;
!!FU&y1>19:E; 20%机率转化为暗黑塔
!!UN:Ov1/v2/v3/1; 删除水车
!!UN:Iv1/v2/v3/63/63/63/63/-1/0; 放置暗黑塔
!?TM38&1000;
!!UN:P701/?y-1;
!!FU&y-1=0:E;
!!UN:U63/63/?v4; 计算暗黑塔数量
!!DO25013/1/v4/1&v4>0:P1;
!?FU25013;
!!FU&x1<>1:E;
!!VRv1&x16=1:S-1; 迅速计算
!!UN:U63/63/-1/1; 取暗黑塔的坐标
!!PO1:N0; 恢复未访问状态
!?OB63/63&1000;
!!UN:P701/?y-1;
!!FU&y-1=0:E;
!?TM38&1000;
!!UN:U63/63/?v1;
!!DO20022/1/v1/1&v1>0:P;
!?FU20022;
!!UN:U63/63/x16/1;
!!PO998:N0;
!?OB63/63&1000;
!!PO998:N?v1;
!!FU&v1=1:E;
!!VRz1:S^增加生物特技,同时会改变地图上所有同类生物^;
!!VRz2:S^增加一个特技至少花费每种资源各30,要开始吗?^;
!!IF:D2/1//2////////////;
!!IF:F2/////1;
!!IF:E2/2;
!!FU&v2<>5:E;
!!OW:R-1/0/?y-1;
!!OW:R-1/1/?y-2;
!!OW:R-1/2/?y-3;
!!OW:R-1/3/?y-4;
!!OW:R-1/4/?y-5;
!!OW:R-1/5/?y-6;
!!OW:R-1/7/?v1016;
!!VRz10|y-1<30/y-2<30/y-3<30/y-4<30/y-5<30/y-6<30:S^穷鬼，资源不够吧！^;
!!IF|y-1<30/y-2<30/y-3<30/y-4<30/y-5<30/y-6<30:D5/10;
!!IF|y-1<30/y-2<30/y-3<30/y-4<30/y-5<30/y-6<30:E1/5;
!!FU20013&y-1>=30/y-2>=30/y-3>=30/y-4>=30/y-5>=30/y-6>=30:P;
!?OB63/63&1000/v1=1;
!!VRz10:S^塔大门紧闭，你悻悻离去!^;
!!IF:D5/10;
!!IF:E1/5;
!$OB63/63&1000;
!!VRv300:C0/0;
!!VRv1016:S0;
!!VRv1018:C0/0;
!?FU20013;
!!VRz1:S^^;
!!VRz2:S^^;
!!VRz3:S^^;
!!VRz4:S^^;
!!VRz5:S^^;
!!VRz6:S^^;
!!VRz7:S^^;
!!VRz8:S^请选择你要改造的生物^;
!!VRz9:S^退出系统^;
!!DO20012/0/6/1:P;
!!IF:G1/300/256/8/1/2/3/4/5/6/7/9;
!!VRy3&v300=1:S0;
!!VRy3&v300=2:S1;
!!VRy3&v300=4:S2;
!!VRy3&v300=8:S3;
!!VRy3&v300=16:S4;
!!VRy3&v300=32:S5;
!!VRy3&v300=64:S6;
!!HE-1&v300<128:C0/y3/?v1018/?y2;
!!EAv1018&v300<128:F0/?v1019;
!!UN&v1019=-1/v300<128:N3/10/v1018/0;
!!VRz10&v1019=-1/v300<128:S^%Z10已经没有空闲的技能位置,无法增加特技!^;
!!IF&v1019=-1/v300<128:D5/10;
!!IF&v1019=-1/v300<128:E1/5;
!!FU20013&v1019=-1/v300<128:P;
!!FU20014&v1019>0/v300<128:P;
!!VRv300:S5000;
!?FU20012;
!!HE-1:C0/x16/?y1/?y2;
!!UN&x16=0/y1>-1:N3/1/y1/0;
!!UN&x16=1/y1>-1:N3/2/y1/0;
!!UN&x16=2/y1>-1:N3/3/y1/0;
!!UN&x16=3/y1>-1:N3/4/y1/0;
!!UN&x16=4/y1>-1:N3/5/y1/0;
!!UN&x16=5/y1>-1:N3/6/y1/0;
!!UN&x16=6/y1>-1:N3/7/y1/0;
!?FU20014;
!!VRz1:S^特殊能力^;
!!VRz2:S^远程特技^;
!!VRz3:S^自带有益魔法^;
!!VRz4:S^魔法免疫^;
!!VRz5:S^攻击后施法^;
!!VRz6:S^上级菜单^;
!!VRz7:S^退出系统^;
!!VRz8:S^选择你要增加的特技范围^;
!!IF:G1/300/128/8/1/2/3/4/5/6/7;
!!FU20015&v300=1:P;
!!FU20016&v300=2:P;
!!FU20017&v300=4:P;
!!FU20018&v300=8:P;
!!FU20019&v300=16:P;
!!FU20013&v300=32:P;
!!VRv300:S5000;
!?FU20015;
!!VRz1:S^降低目标防御 <比蒙特长>^;
!!VRz2:S^反击次数 <皇家狮鹫特长>^;
!!VRz3:S^冲锋 <骑士特长>^;
!!VRz4:S^复活 <凤凰特长>^;
!!VRz5:S^偏移 <减少物理伤害>^;
!!VRz6:S^双倍伤害 <暗黑特长>^;
!!VRz7:S^施法次数^;
!!VRz8:S^复制克隆体(10秘银)^;
!!VRz9:S^攻击后返回(10秘银) <鹰身女巫特长>^;
!!VRz10:S^格档(20秘银) <龙巫妖特长>^;
!!VRz11:S^上级菜单^;
!!VRz12:S^退出系统^;
!!VRz13:S^选择你要增加的特技^;
!!IF:G1/300/4096/13/1/2/3/4/5/6/7/8/9/10/11/12;
!!EAv1018&v300=1:Bv1019/1/98/37/0/5/10/15/20/25/30/35/40/45/50;
!!EAv1018&v300=2:Bv1019/1/82/43/0/0/1/2/3/4/5/6/7/8/9;
!!EAv1018&v300=4:Bv1019/1/102/99/0/0/0/0/0/1/1/1/1/1/1;
!!EAv1018&v300=8:Bv1019/1/102/114/0/0/0/0/0/1/1/1/1/1/1;
!!EAv1018&v300=16:Bv1019/1/76/74/0/0/5/10/15/20/30/35/40/45/50;
!!EAv1018&v300=32:Bv1019/1/101/61/0/0/5/10/15/20/30/35/40/45/50;
!!EAv1018&v300=64:Bv1019/1/80/43/0/0/0/0/1/1/1/1/2/2/2;
!!EAv1018&v300=128:Bv1019/1/108/v1018/0/2/4/6/8/10/12/14/16/18/20;
!!OW&v300=128/v1016>=10:R-1/7/d-10;
!!IF&v300=128/v1016>=10:M^你的部下获得了新能力!^;
!!FU20021&v300=128/v1016>=10:P;
!!IF&v300=128/v1016<10:M^没有秘银的穷光蛋，滚!^;
!!FU20015&v300=128/v1016<10:P;
!!EAv1018&v300=256:Bv1019/1/102/98/0/0/0/0/0/1/1/1/1/1/1;
!!OW&v300=256/v1016>=10:R-1/7/d-5;
!!IF&v300=256/v1016>=10:M^Done!That's too easy!^;
!!FU20021&v300=256/v1016>=10:P;
!!IF&v300=256/v1016<10:M^Not enough Mithril!^;
!!FU20015&v300=256/v1016<10:P;
!!EAv1018&v300=512/v1016>=20:Bv1019/1/66/61/0/0/0/0/0/5/10/15/20/25/30;
!!OW&v300=512/v1016>=20:R-1/7/d-20;
!!IF&v300=512/v1016>=20:M^你的部下获得了新能力!^;
!!FU20021&v300=512/v1016>=20:P;
!!IF&v300=512/v1016<20:M^没有秘银的穷光蛋，滚!^;
!!FU20015&v300=512/v1016<20:P;
!!IF&v300<128:M^你的部下获得了新能力!^;
!!FU20021&v300<128:P;
!!FU20014&v300=1024:P;
!!VRv300:S5000;
!?FU20016;
!!MA:Xv1018/?y1;
!!VRy1:&4;
!!UN&y1=0:N3/10/v1018/0;
!!VRz10&y1=0:S^%Z10并不能远程攻击!^;
!!IF&y1=0:D5/10;
!!IF&y1=0:E1/5;
!!FU20014&y1=0:P;
!!FU&y1=0:E;
!!VRz1:S^无视距离^;
!!VRz2:S^无视障碍^;
!!VRz3:S^近身射击^;
!!VRz4:S^自带精准^;
!!VRz5:S^上级菜单^;
!!VRz6:S^退出系统^;
!!VRz7:S^选择你要增加的特技^;
!!IF:G1/300/64/7/1/2/3/4/5/6;
!!EAv1018&v300=1:Bv1019/1/105/61/0/0/0/0/0/1/1/1/1/1/1;
!!EAv1018&v300=2:Bv1019/1/111/61/0/0/0/0/0/1/1/1/1/1/1;
!!EAv1018&v300=4:Bv1019/1/102/115/0/0/0/0/0/1/1/1/1/1/1;
!!EAv1018&v300=8:Bv1019/1/115/44/0/0/1/1/1/2/2/2/3/3/3;
!!FU20014&v300=16:P;
!!VRv300&v300=16:S5000;
!!IF&v300<16:M^你的部下获得了新能力!^;
!!FU20021&v300<16:P;
!!VRv300:S5000;
!?FU20017;
!!VRz1:S^护盾^;
!!VRz2:S^气盾^;
!!VRz3:S^火盾^;
!!VRz4:S^祝福^;
!!VRz5:S^嗜血^;
!!VRz6:S^振奋^;
!!VRz7:S^石肤^;
!!VRz8:S^祈祷^;
!!VRz9:S^加速^;
!!VRz10:S^屠龙^;
!!VRz11:S^上级菜单^;
!!VRz12:S^退出系统^;
!!VRz13:S^选择你要增加的特技^;
!!IF:G1/300/4096/13/1/2/3/4/5/6/7/8/9/10/11/12;
!!VRv301&v300=1:S27;
!!VRv301&v300=2:S28;
!!VRv301&v300=4:S29;
!!VRv301&v300=8:S41;
!!VRv301&v300=16:S43;
!!VRv301&v300=32:S49;
!!VRv301&v300=64:S46;
!!VRv301&v300=128:S48;
!!VRv301&v300=256:S53;
!!VRv301&v300=512:S55;
!!EAv1018&v300<1024:Bv1019/1/115/v301/0/0/1/1/1/2/2/2/3/3/3;
!!IF&v300<1024:M^你的部下获得了新能力!^;
!!FU20021&v300<1024:P;
!!FU20014&v300=1024:P;
!!VRv300:S5000;
!?FU20018;
!!VRz1:S^免疫有益魔法驱散^;
!!VRz2:S^免疫一级有害魔法^;
!!VRz3:S^免疫1~2级有害魔法(5秘银)^;
!!VRz4:S^免疫1~3级有害魔法(10秘银)^;
!!VRz5:S^免疫1~4级有害魔法(15秘银)^;
!!VRz6:S^免疫直接伤害魔法(20秘银)^;
!!VRz7:S^免疫所有有害魔法(25秘银)^;
!!VRz8:S^上级菜单^;
!!VRz9:S^退出系统^;
!!VRz10:S^选择你要增加的特技^;
!!IF:G1/300/512/10/1/2/3/4/5/6/7/8/9;
!!VRv301&v300=1:S78;
!!VRv301&v300=2:S49;
!!VRv301&v300=4:S50;
!!VRv301&v300=8:S51;
!!VRv301&v300=16:S52;
!!VRv301&v300=32:S68;
!!VRv301&v300=64:S53;
!!EAv1018&v300<4:Bv1019/1/119/v301/0/0/0/0/0/1/1/1/1/1/1;
!!IF&v300<4:M^你的部下获得了新能力!^;
!!FU20021&v300<4:P;
!!VRy5&v300=4:S5;
!!VRy5&v300=8:S10;
!!VRy5&v300=16:S15;
!!VRy5&v300=32:S20;
!!VRy5&v300=64:S25;
!!VRy6&v300>2:Sy5 *-1;
!!EAv1018&v300>2/v300<128/v1016>=y5:Bv1019/1/119/v301/0/0/0/0/0/1/1/1/1/1/1;
!!OW&v300>2/v300<128/v1016>=y5:R-1/7/dy6;
!!IF&v300>2/v300<128/v1016>=y5:M^你的部下获得了新能力!^;
!!FU20021&v300>2/v300<128/v1016>=y5:P;
!!IF&v300>2/v300<128/v1016<y5:M^没有秘银的穷光蛋，滚!^;
!!FU20018&v300>2/v1016<y5:P;
!!FU20014&v300=128:P;
!!VRv300:S5000;
!?FU20019;
!!VRz1:S^老化(20秘银)^;
!!VRz2:S^发狂^;
!!VRz3:S^麻痹(5秘银)^;
!!VRz4:S^驱散有益魔法^;
!!VRz5:S^失明^;
!!VRz6:S^石化^;
!!VRz7:S^中毒^;
!!VRz8:S^酸液^;
!!VRz9:S^诅咒^;
!!VRz10:S^克隆^;
!!VRz11:S^缠绕(20秘银)^;
!!VRz12:S^上级菜单^;
!!VRz13:S^选择你要增加的特技^;
!!IF:G1/300/4096/13/1/2/3/4/5/6/7/8/9/10/11/12;
!!VRv301&v300=2:S59;
!!VRv301&v300=8:S78;
!!VRv301&v300=16:S62;
!!VRv301&v300=32:S70;
!!VRv301&v300=64:S71;
!!VRv301&v300=128:S80;
!!VRv301&v300=256:S42;
!!VRv301&v300=512:S65;
!!EAv1018&v300=1/v1016>=20:Bv1019/1/99/75/0/0/5/10/15/20/30/35/40/45/50;
!!OW&v300=1/v1016>=20:R-1/7/d-20;
!!IF&v300=1/v1016>=20:M^你的部下获得了新能力!^;
!!FU20021&v300=1/v1016>=20:P;
!!IF&v300=1/v1016<20:M^没有秘银的穷光蛋，滚!^;
!!FU20019&v300=1/v1016<20:P;
!!EAv1018&v300=4/v1016>=5:Bv1019/1/97/74/0/0/5/10/15/20/30/35/40/45/50;
!!OW&v300=4/v1016>=5:R-1/7/d-5;
!!IF&v300=4/v1016>=5:M^你的部下获得了新能力!^;
!!FU20021&v300=4/v1016>=5:P;
!!IF&v300=4/v1016<5:M^没有秘银的穷光蛋，滚!^;
!!FU20019&v300=4/v1016<5:P;
!!EAv1018&v300=1024/v1016>=20:Bv1019/1/97/72/5/10/15/20/30/35/40/45/50/55/60;
!!OW&v300=1024/v1016>=20:R-1/7/d-20;
!!IF&v300=1024/v1016>=20:M^你的部下获得了新能力!^;
!!FU20021&v300=1024/v1016>=20:P;
!!IF&v300=1024/v1016<20:M^没有秘银的穷光蛋，滚!^;
!!FU20019&v300=1024/v1016<20:P;
!!EAv1018&v300<1024/v300<>1/v300<>4:Bv1019/1/97/v301/0/0/5/10/15/20/30/35/40/45/50;
!!IF&v300<1024/v300<>1/v300<>4:M^你的部下获得了新能力!^;
!!FU20021&v300<1024/v300<>1/v300<>4:P;
!!FU20014&v300=2048:P;
!!VRv300:S5000;
!?FU20021;
!!OW:R-1/0/d-30;
!!OW:R-1/1/d-30;
!!OW:R-1/2/d-30;
!!OW:R-1/3/d-30;
!!OW:R-1/4/d-30;
!!OW:R-1/5/d-30;
!!PO998:N1;
[ 本帖最后由 dboyv 于 2009-1-3 10:31 编辑 ] 我记得论坛里有过暗黑塔的脚本，和你这个差别较大，你这个看起来像翡翠塔的功能吧？ :shangxin: 我不会ERM,刚才把你的代码复制粘贴成SCRIPT88.ERM.再在地图那事件设置500天,然后开始玩游戏,每次进暗黑学次特技,都要消耗30X2的资源(特技选好,又会出现原来暗黑殿的技能.所以好象学次技能消耗2次资源).这些我都认了,可是游戏玩到第2周就会出现ERM语法错误,无法继续
我很喜欢缠绕这个技能,LZ能不能做下懒人版的ERM,我下载玩 谢谢:shangxin: 原帖由 cscppo 于 2009-1-2 23:11 发表 http://bbs.h3wog.com/images/common/back.gif
:shangxin: 我不会ERM,刚才把你的代码复制粘贴成SCRIPT88.ERM.再在地图那事件设置500天,然后开始玩游戏,每次进暗黑学次特技,都要消耗30X2的资源(特技选好,又会出现原来暗黑殿的技能.所以好象学次技能消耗2次资源).这 ...
楼上好有趣啊，哇哈哈～;sl; ;sl; 原帖由 songfx 于 2009-1-2 23:31 发表 http://bbs.h3wog.com/images/common/back.gif
楼上好有趣啊，哇哈哈～;sl; ;sl;
:nianjing: 我蹲墙角画圈圈诅咒你 :dajie: 帮我写个有缠绕的暗黑殿吧 谢谢:shangxin: 我错了,不画圈圈,画狗咬人
我刚才想去置顶下载什么ERM编辑器看看,可是都显示网页过期,没的下;cool;
[ 本帖最后由 cscppo 于 2009-1-3 01:23 编辑 ] 宝物典当行里有这个功能的。再地下按钮右键 原帖由 songfx 于 2008-12-28 19:18 发表 http://bbs.h3wog.com/images/common/back.gif
我记得论坛里有过暗黑塔的脚本，和你这个差别较大，你这个看起来像翡翠塔的功能吧？
论坛里面那个好像是没有加限制的。可以任意替换技能；呃，我这个是原来没有汉化的358f的自定义erm，来源是木瓜的tds；你说的那个我没印象，不知道是什么样子的:lianhong: 原帖由 cscppo 于 2009-1-2 23:11 发表 http://bbs.h3wog.com/images/common/back.gif
:shangxin: 我不会ERM,刚才把你的代码复制粘贴成SCRIPT88.ERM.再在地图那事件设置500天,然后开始玩游戏,每次进暗黑学次特技,都要消耗30X2的资源(特技选好,又会出现原来暗黑殿的技能.所以好象学次技能消耗2次资源).这 ...
之所以两次，是因为你有了这个脚本，又在地图里面放了；我现在已经详细说明如何正确使用了。 原帖由 dboyv 于 2009-1-3 10:36 发表 http://bbs.h3wog.com/images/common/back.gif
之所以两次，是因为你有了这个脚本，又在地图里面放了；我现在已经详细说明如何正确使用了。
我以前下了打包增强的ERM,其中script11.erm是梦之殿堂,script90.erm是暗黑塔,我看2个ERM的功能介绍好象一样,可是我覆盖11的时候不添加90的暗黑殿有效,可是把11改回原ERM,只添加script90.erm却毫无效果,暗黑殿还是老虎机.
现在好象是只有script11.erm要覆盖才有效,你的ERM我改为script90也和原来的一样的待 请问ＷＯＧ自定义设置文件哪里下载？我原来就安装了358F中文版.昨天看帖子说没这个设置是补丁没下全,所以就把补丁全下了安装,没想到现在进游戏好多东西变英文了,郁闷,只好删掉,重新安装了358F中文版以及中文安装修复包．我没找到ＷＯＧ自定义设置文件,只找到新游戏单机那的WOG设置菜单.
我刚才试着改了下技能,
ZVSE
!#EA132:B10/1/66/61/100/100/100/100/100/100/100/100/100/100/100/;
!#EA132:B11/1/99/75/100/100/100/100/100/100/100/100/100/100/100/;
!#EA132:B12/1/99/71/100/100/100/100/100/100/100/100/100/100/100/;
发现第一个格档100%有用,老化和中毒如果只设置一个的话,也都有效果,反击时候魔法没效果.但是2个魔法一起设置的话,只出现老化.可是我的2追打怪的时候,老化和中毒经常一次攻击都出现?
而我最想要的束缚,我一个个试好象代码是72.可是设置成100.也没一个怪会被缠绕,就是想欺负半人马都不可以...悲哀
[ 本帖最后由 cscppo 于 2009-1-3 20:58 编辑 ] :nianjing: 不是我不想学,论坛的搜索问题太离谱了
我经常这个时候搜索这个字眼,能查到东西,过一个小时用同样的字眼查东西,居然会显示查无相关内容..还有长晕大侠的空间也不能进,好象一个月没整理就不行.而ERM教程说的软件,要么下载页面无效,要么进去下载的文件版本和教的不一样..
新人菜鸟;cool;拜上 ZVSE
!#EA63:B6/1/98/61/5/20/30/40/50/60/70/80/90/100/100/;
!#EA63:B7/1/75/72/100/100/100/100/100/100/100/100/100/100/100/;
!#EA63:B8/1/101/61/0/10/20/30/40/50/60/70/80/90/100/;
!#EA63:B9/1/97/71/100/100/100/100/100/100/100/100/100/100/100/;
!#EA63:B10/1/99/75/100/100/100/100/100/100/100/100/100/100/100/;
!#EA63:B11/1/106/56/100/100/100/100/100/100/100/100/100/100/100/;
:nianjing: 刚试了 终于缠绕成功，反击也必中毒．攻前也必孤注一掷...只是我下载了自定义设置，你的暗黑塔和马蹬照样没效果，残念..暗黑塔只有11的那个可以使用<另我都是直接在地图添加梦之殿堂和马镫.不是由水车变的 不知道有关系没> 原帖由 cscppo 于 2009-1-3 20:34 发表 http://bbs.h3wog.com/images/common/back.gif
我经常这个时候搜索这个字眼,能查到东西,过一个小时用同样的字眼查东西,居然会显示查无相关内容..
这个，最好是手动选择搜索范围，指定搜索整个论坛。 原帖由 cscppo 于 2009-1-3 19:19 发表 http://bbs.h3wog.com/images/common/back.gif
我以前下了打包增强的ERM,其中script11.erm是梦之殿堂,script90.erm是暗黑塔,我看2个ERM的功能介绍好象一样,可是我覆盖11的时候不添加90的暗黑殿有效,可是把11改回原ERM,只添加script90.erm却毫无效果,暗黑殿还是老 ...
脚本11号就用中文版自带的，然后这个是90号；下了自定义设置把暗黑塔勾选，就木问题了。我最近一直在用:deyi:
页:
[1]
