寻找翡翠塔可重复使用erm。。。
3x升级3.58f自动把原来的删光了。。。 1、进入时不要宝石
2、8级兵种升级不会用掉生物
3、不会花费秘银
4、升级时花费很少
5、升级时攻、防、伤、命、速、生长率提升100%
ZVSE
_WARNING_#1=IMPORTANT! This file is not in a plain text format. NEVER use any editor except ERM_S
for making any kind of changes!
ERMS_PoweredBy=ERM Scripter v. 2003.2.18.2257
** Emerald Tower Script Version 0.2 Created by Timothy Pulver
** Requires WoG version 3.57 or later using ERM version 2.6 or later.
** WoGify Name: script44.erm
** This script makes all green roofed towers in the game (object type 63,
** subtype 65) into Emerald Towers where the Wizard who dwells there will
** improve any creature type in your army for a price. The price is a lot of
** resources of a specific type, depending on the improvement. In addition,
** one of the creatures of the type being improved must also be left for the
** Wizard.
** The improvement number is usually a percentage of the existing score. For
** example, 50% growth bonus, or 25% attack bonus. In addition to standard
** stat improvements, new special abilities may be added. Special abilities
** all cost Mithril.
** Each Emerald Tower may only be visited once per day. A maximum of 12
** types of creatures may be improved in any game, but each creature type
** may have many improvements made to it. A creature cannot be improved
** during a "Week of" that creature type, if the "Week of Monsters" script
** is active.
------------------------------------------------------------------------
Permanent Variables: z816-z841, v1240-v1252 (not v1253--used by Garrison script))
Temporary Variables: v1-v7, v360-v369, z1-z9, z480-z490
Temporary Flags: 1-4
Functions: 10900-10911
Timers: 38
Dialogues: 3
-----------------------------------------------------------------------
!#VRv1240:S0;
!#VRz816:S^Emerald Tower
(Not Visited)^;
!#VRz817:S^Emerald Tower
(Visited)^;
!#HT63/65:P0/816;
!#HT63/65:P1/817;
!#TM38:S8/999/7/255;
-----------------------------------------------------------------------
!?TM38;
!!UN:U63/65/?v1;
!!DO10910/1/v1/1&v1>0:P;
-----------------------------------------------------------------------
!?FU10910;
!!UN:U63/65/x16/1;
!!POv1/v2/v3:N0;
-----------------------------------------------------------------------
!?OB63/65;
!!PO998:N?v1;
!!IF&v1=1/1000:M^{Emerald Tower}
You knock on the gate and a small gnomish man answers.
"Go away! The Wizard's busy!" shouts the rude little gnome, slamming the gate in your face.^;
!?OB63/65&v1=0;
!!IF&1000:Q2/5/7/2^{Emerald Tower}
You knock on the gate and a small gnomish man answers.
"Do you have an appointment with the Wizard?"
A sign above the door reads:
'APPOINTMENTS WITH THE WIZARD BOOKED FOR SEVEN GEMS'
Do you book an appointment?^;
!!OW&2:R-1/5/?y1;
!!VRz9:S^^;
!!VRz9&2/y1<0:S^You don't have enough gems. No gems, no appointment. ^;
!!IF&y1<0:V2/0;
!!OW&2:R-1/5/d-0;
!!IF&2/1000:M^The gnomish man takes the gems, glares at you and then
ushers you inside. The enormous foyer is gloomy and full of weird
paraphernalia, spider webs, and thousands of old dusty tomes.
Before you can poke about too much, the Wizard appears, dressed in
long flowing robes.^;
!!FU10900&2:P;
!!IF&-2/1000:M^"%Z9No appointment, no entrance!" shouts the gnome, rudely slamming the gate in
your face.^;
-----------------------------------------------------------------------
!?FU10900;
!!FU10901:P;
!!VRz1:S^"Hmmph," says the Wizard. "What species do you wish to improve?"^;
!!VRz2:S^Nothing. I've changed my mind.^;
!!IF&v1>0/1000:G1/367/0/1/480/481/482/483/484/485/486/2/0/0/0/0;
!!IF&v1=0/1000:M^"You have no creatures with you so I'm afraid I can't help you. Goodbye."^;
!!VRv2:S0;
!!VRv2&v367=1:Sv360;
!!VRv2&v367=2:Sv361;
!!VRv2&v367=4:Sv362;
!!VRv2&v367=8:Sv363;
!!VRv2&v367=16:Sv364;
!!VRv2&v367=32:Sv365;
!!VRv2&v367=64:Sv366;
!!VRv2&v367=128:S-1;
!!IF:V4/1;
!!IF&v2=-1/1000:Q4^{The Wizard seems annoyed.}
"You don't need my services? Fine! Then go away and stop wasting my precious time!"
Do you leave the Emerald Tower?^;
!!UN&v2>=0:N3/3/v2/0;
!!UN&v2>=0:N3/4/v2/1;
!!IF&56/v170>=0/v170=v2/1000:Q4/21/v2/1^{The Wizard appears agitated.}
"This is a Week of the %Z3 and that interferes with my magic. I'm unable to enchant %Z4 right
now. Return next week."
Do you leave the Emerald Tower?^;
!!VRv2&56/v170>=0/v170=v2:S-1;
!!VRv6:S-1;
!!DO10908/1/v1240/1&v2>=0/v1240>0:P;
!!IF&v1240>=12/v6<0/v2>=0/1000:Q4^{The Wizard looks perturbed.}
"Oh no, this won't do at all. %V1240 species have already been enchanted in this land. Any more
and the magic will become unstable and very dangerous. I will not do it! Bring me a species
already enchanted and I can safely enchant it further, but do not ask me to enchant a new one."
Do you leave the Emerald Tower?^;
!!VRv2&v1240>=12/v6<0:S-1;
!!FU10902&v2>=0:P;
!!FU10900&v2=-1/-4:P;
-----------------------------------------------------------------------
!?FU10901;
!!VRv1:S0;
!!VRv360:C-1/-1/-1/-1/-1/-1/-1;
!!VRz480:S^^;
!!VRz481:S^^;
!!VRz482:S^^;
!!VRz483:S^^;
!!VRz484:S^^;
!!VRz485:S^^;
!!VRz486:S^^;
!!HE-1:C0/0/?y1/?y2;
!!VRv1&y2>0:+1;
!!VRv360&y2>0:Sy1;
!!UN&y2>0:N3/480/y1/1;
!!HE-1:C0/1/?y1/?y2;
!!VRy4:S0;
!!VRy4&v1=1/y1=v360:S99;
!!VRv1&y2>0/y4<>99:+1;
!!VRy3&y2>0/y4<>99:S359 +v1;
!!VRy5&y2>0/y4<>99:S479 +v1;
!!UN&y2>0/y4<>99:N3/y5/y1/1;
!!VRvy3&y2>0/y4<>99:Sy1;
!!HE-1:C0/2/?y1/?y2;
!!VRy4:S0;
!!VRy4&v1>=1/y1=v360:S99;
!!VRy4&v1=2/y1=v361:S99;
!!VRv1&y2>0/y4<>99:+1;
!!VRy3&y2>0/y4<>99:S359 +v1;
!!VRy5&y2>0/y4<>99:S479 +v1;
!!UN&y2>0/y4<>99:N3/y5/y1/1;
!!VRvy3&y2>0/y4<>99:Sy1;
!!HE-1:C0/3/?y1/?y2;
!!VRy4:S0;
!!VRy4&v1>=1/y1=v360:S99;
!!VRy4&v1>=2/y1=v361:S99;
!!VRy4&v1=3/y1=v362:S99;
!!VRv1&y2>0/y4<>99:+1;
!!VRy3&y2>0/y4<>99:S359 +v1;
!!VRy5&y2>0/y4<>99:S479 +v1;
!!UN&y2>0/y4<>99:N3/y5/y1/1;
!!VRvy3&y2>0/y4<>99:Sy1;
!!HE-1:C0/4/?y1/?y2;
!!VRy4:S0;
!!VRy4&v1>=1/y1=v360:S99;
!!VRy4&v1>=2/y1=v361:S99;
!!VRy4&v1>=3/y1=v362:S99;
!!VRy4&v1=4/y1=v363:S99;
!!VRv1&y2>0/y4<>99:+1;
!!VRy3&y2>0/y4<>99:S359 +v1;
!!VRy5&y2>0/y4<>99:S479 +v1;
!!UN&y2>0/y4<>99:N3/y5/y1/1;
!!VRvy3&y2>0/y4<>99:Sy1;
!!HE-1:C0/5/?y1/?y2;
!!VRy4:S0;
!!VRy4&v1>=1/y1=v360:S99;
!!VRy4&v1>=2/y1=v361:S99;
!!VRy4&v1>=3/y1=v362:S99;
!!VRy4&v1>=4/y1=v363:S99;
!!VRy4&v1=5/y1=v364:S99;
!!VRv1&y2>0/y4<>99:+1;
!!VRy3&y2>0/y4<>99:S359 +v1;
!!VRy5&y2>0/y4<>99:S479 +v1;
!!UN&y2>0/y4<>99:N3/y5/y1/1;
!!VRvy3&y2>0/y4<>99:Sy1;
!!HE-1:C0/6/?y1/?y2;
!!VRy4:S0;
!!VRy4&v1>=1/y1=v360:S99;
!!VRy4&v1>=2/y1=v361:S99;
!!VRy4&v1>=3/y1=v362:S99;
!!VRy4&v1>=4/y1=v363:S99;
!!VRy4&v1>=5/y1=v364:S99;
!!VRy4&v1=6/y1=v365:S99;
!!VRv1&y2>0/y4<>99:+1;
!!VRy3&y2>0/y4<>99:S359 +v1;
!!VRy5&y2>0/y4<>99:S479 +v1;
!!UN&y2>0/y4<>99:N3/y5/y1/1;
!!VRvy3&y2>0/y4<>99:Sy1;
-----------------------------------------------------------------------
!?FU10902;
!!UN:N3/3/v2/0;
!!MA:Av2/?y1;
!!VRy2:Sy1 :1;
!!VRy2&y2=0:S1;
!!MA:Dv2/?y1;
!!VRy3:Sy1 :1;
!!VRy3&y3=0:S1;
!!MA:Ev2/?y1;
!!VRy4:Sy1 :1;
!!VRy4&y4=0:S1;
!!MA:Pv2/?y1;
!!VRy5:Sy1 :1;
!!VRy5&y5=0:S1;
!!MA:Sv2/?y1;
!!VRy6:Sy1 :1;
!!VRy6&y6=0:S1;
!!MA:Gv2/?y1;
!!VRy7:Sy1 :1;
!!VRy7&y7=0:S1;
!!MA:Nv2/?y8;
!!MA:Bv2/?y10;
!!VRz1:S^"How would you like the %Z3 species improved?"^;
!!VRz2:S^Forget it. I've changed my mind.^;
!!VRz480:S^+%Y2 ATTACK for 0 Sulfur^;
!!VRz481:S^+%Y3 DEFENSE for 0 Ore^;
!!VRz482:S^+%Y4 DAMAGE for 0 Gems^;
!!VRz483:S^+%Y5 HEALTH for 0 Crystal^;
!!VRz484:S^+%Y6 SPEED for 0 Mercury^;
!!VRz485:S^+%Y7 GROWTH for 0 Wood^;
!!VRz486&y8<24:S^24 SHOTS for 120 Gold^;
!!VRz486|y8<1/y8>=24:S^^;
!!VRz487&y10>0:S^+1 SPELL CASTING (per combat) for 20 Mithril^;
!!VRz487|y10<1/y10>12:S^^;
!!VRz488:S^A new SPECIAL ability^;
!!IF&1000:G1/368/0/1/480/481/482/483/484/485/486/487/488/2/0/0;
!!VRv3:S0;
!!VRv3&v368=1:S2;
!!VRv3&v368=2:S3;
!!VRv3&v368=4:S4;
!!VRv3&v368=8:S5;
!!VRv3&v368=16:S6;
!!VRv3&v368=32:S7;
!!VRv3&v368=64:S8;
!!VRv3&v368=128:S9;
!!VRv3&v368=256:S10;
!!VRv3&v368=512:S-1;
!!VRv5:S0;
!!FU10906&v3=10:P;
!!VRv4:S0;
!!FU10903&v3>1:P;
!!VRy9&v3>=2/v3<=7:Syv3;
!!FU10905&v4=1:Py9;
!!VRv1240&v4=1/v6<0:+1;
!!FU10909&v4=1:P;
!!PO998&v4=1:N1;
!!IF&v3=-1/1000:Q4^{The Wizard seems annoyed.}
"You don't need my services? Fine! Then go away and stop wasting my precious time!"
Do you leave the Emerald Tower?^;
!!VRv3&v3>1/v4=0/-4:S-1;
!!FU10900&v3=-1/-4:P;
-----------------------------------------------------------------------
!?FU10903;
!!VRy1&v3=2:S3;
!!VRy2&v3=2:S0;
!!VRz1&v3=2:S^sulfur^;
!!VRy1&v3=3:S2;
!!VRy2&v3=3:S0;
!!VRz1&v3=3:S^ore^;
!!VRy1&v3=4:S5;
!!VRy2&v3=4:S0;
!!VRz1&v3=4:S^gems^;
!!VRy1&v3=5:S4;
!!VRy2&v3=5:S0;
!!VRz1&v3=5:S^crystal^;
!!VRy1&v3=6:S1;
!!VRy2&v3=6:S0;
!!VRz1&v3=6:S^mercury^;
!!VRy1&v3=7:S0;
!!VRy2&v3=7:S0;
!!VRz1&v3=7:S^wood^;
!!VRy1&v3=8:S6;
!!VRy2&v3=8:S120;
!!VRz1&v3=8:S^gold^;
!!VRy1&v3=9:S7;
!!VRy2&v3=9:S0;
!!VRz1&v3=9:S^mithril^;
!!VRy1&v3=10:S7;
!!VRy2&v3=10/v5=1:S0;
!!VRy2&v3=10/v5=2:S0;
!!VRy2&v3=10/v5=3:S0;
!!VRy2&v3=10/v5=4:S0;
!!VRy2&v3=10/v5=5:S0;
!!VRy2&v3=10/v5=6:S0;
!!VRy2&v3=10/v5=7:S0;
!!VRy2&v3=10/v5=8:S0;
!!VRy2&v3=10/v5=9:S0;
!!VRy2&v3=10/v5=10:S0;
!!VRz1&v3=10:S^mithril^;
!!IF:V4/1;
!!OW:R-1/y1/?y3;
!!IF&y2>y3/1000:Q4/y1/y2/2^{The Wizard seems annoyed.}
"You don't have enough %Z1. Go away and stop wasting my time!"
Do you leave the Emerald Tower?^;
!!MA:Lv2/?y6;
!!VRy7&y6=0:S64;
!!VRy7&y6=1:S32;
!!VRy7&y6=2:S16;
!!VRy7&y6=3:S8;
!!VRy7&y6=4:S4;
!!VRy7&y6=5:S2;
!!VRy7&y6>=6:S1;
!!VRy7|v2=56/v2=57:S128;
!!VRz8&y7=1:Sz3;
!!VRz8&y7>1:Sz4;
!!VRz9&y7=1:S^s^;
!!VRz9&y7>1:S^^;
!!IF:V3/0;
!!VRy5:S65536 *y7;
!!VRy5:+v2;
!!IF&y3>=y2/1000:Q3/21/y5/2^"In addition to the %Y2 %Z1, I'll need %Y7 %Z8 for the magic ritual.
The %Z8 won't be returning to your army after."
"Agreed?"^;
!!VRv3&-3/y3>=y2:S-1;
!!VRv7:S0;
!!DO10904/0/6/1&3:P;
!!DO10911/0/6/1&v7>=y7/3:P0;
!!IF&v7<y7/3:Q4/21/y5/2^{The Wizard seems irritated.}
"This just isn't enough. I must have %Y7 of your %Z4 to complete the ritual. Now go away and stop
wasting my time or I'll turn you all into warty old toads!"
Do you leave the Emerald Tower?^;
!!UN&3:N3/4/v2/1;
!!IF&3/v7>=y7/1000:Q1/21/y5/y1/y2/1^The gnome takes your payment of %Y2 %Z1 and leads %Y7 of your
%Z4 away down a dark hallway. The %Z8 turn%Z9 to look at you with frightened eyes and whimper%Z9
softly before vanishing from sight into the gloomy depths of the sorcerer's lair.
"You can leave now," says the Wizard, brusquely. "The enchantment will be completed shortly."^;
!!VRy4&3/v7>=y7:Sy3 -y2;
!!OW&3/v7>=y7:R-1/y1/y4;
!!VRv4&3/v7>=y7:S1;
-----------------------------------------------------------------------
!?FU10904;
!!HE-1:C0/x16/?y1/?y2;
!!VRv7&y1=v2/y2>0:+y2;
-----------------------------------------------------------------------
!?FU10905;
!!MA&v3=2:Av2/dx1;
!!MA&v3=3:Dv2/dx1;
!!MA&v3=4:Ev2/dx1;
!!MA&v3=4:Mv2/dx1;
!!MA&v3=5:Pv2/dx1;
!!MA&v3=6:Sv2/dx1;
!!MA&v3=7:Gv2/dx1;
!!MA&v3=8:Nv2/24;
!!MA&v3=9:Bv2/d1;
!!FU10907&v3=10:P;
-----------------------------------------------------------------------
!?FU10906;
!!VRz480:S^^; !!VRz481:S^^; !!VRz482:S^^; !!VRz483:S^^; !!VRz484:S^^;
!!VRz485:S^^; !!VRz486:S^^; !!VRz487:S^^; !!VRz488:S^^; !!VRz489:S^^; !!VRz490:S^^;
!!MA:Xv2/?v369;
!!VRy1:Sv369;
!!VRy1:&2;
!!VRz480&y1=0:S^Ignore Obstacles (Flying) for 25 Mithril^;
!!VRz480&y1=2:S^^;
!!VRy1:Sv369;
!!VRy1:&8;
!!VRz481&y1=0:S^Extended 2-hex Attack Depth (Breath attack) for 15 Mithril^;
!!VRz481&y1=8:S^^;
!!VRy1:Sv369;
!!VRy1:&262144;
!!VRz482&y1=0:S^Undead for 20 Mithril^;
!!VRz482&y1=262144:S^^;
!!VRy1:Sv369;
!!VRy1:&131072;
!!VRz483&y1=0:S^Unaffected by Morale for 15 Mithril^;
!!VRz483&y1=131072:S^^;
!!VRy1:Sv369;
!!VRy1:&32768;
!!VRz484&y1=0:S^Two Attacks for 30 Mithril^;
!!VRz484&y1=32768:S^^;
!!VRy1:Sv369;
!!VRy1:&524288;
!!VRz485&y1=0:S^Attack all Adjacent Creatures for 25 Mithril^;
!!VRz485&y1=524288:S^^;
!!VRy1:Sv369;
!!VRy1:&65536;
!!VRz486&y1=0:S^No Retaliation for 25 Mithril^;
!!VRz486&y1=65536:S^^;
!!VRy1:Sv369;
!!VRy1:&1024;
!!VRz487&y1=0:S^Immune to Mind Spells for 20 Mithril^;
!!VRz487&y1=1024:S^^;
!!VRy1:Sv369;
!!VRy1:&16384;
!!VRz488&y1=0:S^Immune to Fire Spells for 15 Mithril^;
!!VRz488&y1=16384:S^^;
!!VRy1:Sv369;
!!VRy2:Sv369;
!!VRy1:&4096; (Check No Close Combat Penalty)
!!VRy2:&4; (Check Shooter)
!!VRz489&y1=0/y2=4:S^No Close Combat Penalty for 15 Mithril^;
!!VRz489|y1=4096/y2=0:S^^;
!!VRz1:S^"What new ability do you wish to bestow upon %Z4?"^;
!!VRz2:S^Forget it. I've changed my mind.^;
!!IF&1000:G1/368/0/1/480/481/482/483/484/485/486/487/488/489/2/0;
!!VRv5:S0;
!!VRv5&v368=1:S1;
!!VRv5&v368=2:S2;
!!VRv5&v368=4:S3;
!!VRv5&v368=8:S4;
!!VRv5&v368=16:S5;
!!VRv5&v368=32:S6;
!!VRv5&v368=64:S7;
!!VRv5&v368=128:S8;
!!VRv5&v368=256:S9;
!!VRv5&v368=512:S10;
!!VRv5&v368=1024:S-1;
!!VRv3&v5=-1:S-1;
-----------------------------------------------------------------------
!?FU10907;
!!MA&v5=1:Xv2/d2;
!!MA&v5=2:Xv2/d8;
!!MA&v5=3:Xv2/d262144;
!!MA&v5=4:Xv2/d131072;
!!MA&v5=5:Xv2/d32768;
!!MA&v5=6:Xv2/d524288;
!!MA&v5=7:Xv2/d65536;
!!MA&v5=8:Xv2/d1024;
!!MA&v5=9:Xv2/d16384;
!!MA&v5=10:Xv2/d4096;
-----------------------------------------------------------------------
!?FU10908;
!!VRy1:S1240 +x16;
!!VRv6&vy1=v2:Sx16;
!!VRx16&vy1=v2:S99;
-----------------------------------------------------------------------
!?FU10909;
!!VRy1:S1 R2;
!!UN:G1/v2/0/0;
!!UN:G1/v2/1/0;
!!VRy4:S1240 +v1240;
!!VRvy4&v6<0:Sv2;
!!VRy2&v6<0:Sv1240 *2;
!!VRy2&v6>0:Sv6 *2;
!!VRy2:+816;
!!VRy3:Sy2 +1;
!!UN:N3/6/v2/0;
!!UN:N3/7/v2/1;
!!VRz5&v3=2/y1=1:S^Mean^;
!!VRz5&v3=2/y1=2:S^Mighty^;
!!VRz5&v3=2/y1=3:S^Fierce^;
!!VRz5&v3=3/y1=1:S^Thick-skinned^;
!!VRz5&v3=3/y1=2:S^Steadfast^;
!!VRz5&v3=3/y1=3:S^Toughened^;
!!VRz5&v3=4/y1=1:S^Sharp and Pointy^;
!!VRz5&v3=4/y1=2:S^Powerful^;
!!VRz5&v3=4/y1=3:S^Dangerous^;
!!VRz5&v3=5/y1=1:S^Bulky^;
!!VRz5&v3=5/y1=2:S^Sturdy^;
!!VRz5&v3=5/y1=3:S^Reinforced^;
!!VRz5&v3=6/y1=1:S^Speedy^;
!!VRz5&v3=6/y1=2:S^Fast^;
!!VRz5&v3=6/y1=3:S^Quick^;
!!VRz5&v3=7/y1=1:S^Fertile^;
!!VRz5&v3=7/y1=2:S^Prolific^;
!!VRz5&v3=7/y1=3:S^Promiscuous^;
!!VRz5&v3=8/y1=1:S^Loaded^;
!!VRz5&v3=8/y1=2:S^Well-stocked^;
!!VRz5&v3=8/y1=3:S^Energized^;
!!VRz5&v3=9/y1=1:S^Enchanted^;
!!VRz5&v3=9/y1=2:S^Magical^;
!!VRz5&v3=9/y1=3:S^Mystical^;
!!VRz5&v5=1/y1=1:S^Floating^;
!!VRz5&v5=1/y1=2:S^Airborne^;
!!VRz5&v5=1/y1=3:S^Flying^;
!!VRz5&v5=2/y1=1:S^Garlic Breath^;
!!VRz5&v5=2/y1=2:S^Bad Breath^;
!!VRz5&v5=2/y1=3:S^Dragon Breath^;
!!VRz5&v5=3/y1=1:S^Dead^;
!!VRz5&v5=3/y1=2:S^Undead^;
!!VRz5&v5=3/y1=3:S^Soulless^;
!!VRz5&v5=4/y1=1:S^Unflappable^;
!!VRz5&v5=4/y1=2:S^Stoic^;
!!VRz5&v5=4/y1=3:S^Imperturbable^;
!!VRz5&v5=5/y1=1:S^Energetic^;
!!VRz5&v5=5/y1=2:S^Furious^;
!!VRz5&v5=5/y1=3:S^Frenzied^;
!!VRz5&v5=6/y1=1:S^Snappy^;
!!VRz5&v5=6/y1=2:S^Deadly^;
!!VRz5&v5=6/y1=3:S^Ferocious^;
!!VRz5&v5=7/y1=1:S^Vicious^;
!!VRz5&v5=7/y1=2:S^Overwhelming^;
!!VRz5&v5=7/y1=3:S^Savage^;
!!VRz5&v5=8/y1=1:S^Stubborn^;
!!VRz5&v5=8/y1=2:S^Strong-willed^;
!!VRz5&v5=8/y1=3:S^Strong-minded^;
!!VRz5&v5=9/y1=1:S^Soggy^;
!!VRz5&v5=9/y1=2:S^Non-Combustible^;
!!VRz5&v5=9/y1=3:S^Fire Resistant^;
!!VRz5&v5=10/y1=1:S^Fist Fighting^;
!!VRz5&v5=10/y1=2:S^Brawling^;
!!VRz5&v5=10/y1=3:S^Sparring^;
!!VRzy2:S^%Z5 %Z6^;
!!UN:G1/v2/0/y2;
!!VRzy3:S^%Z5 %Z7^;
!!UN:G1/v2/1/y3;
-----------------------------------------------------------------------
!?FU10911;
!!HE-1:C0/x16/?y1/?y2;
!!HE-1&y1=v2/y2>0/y2<=x1:C0/x16/-1/0;
!!VRy4&y1=v2/y2>0/y2<=x1:Sx1 -y2;
!!VRy3&y1=v2/y2>x1:Sx1 *-1;
!!HE-1&y1=v2/y2>x1:C0/x16/d/dy3;
!!VRy4&y1=v2/y2>x1:S0;
!!VRx1&y1=v2/y2>0:Sy4;
** End of Script ** 怎么替换原来的呢~！
几号啊~！
;hero; 下载ERM转换器将以上ERM代码制作成ERM，改名成75号以后任意ERM 怎么给个这样的东西啊，难看。
我给个老点的吧。earthling_061201里的（估计，忘了）
翡翠塔是script44.erm，记得备份原文件。 谢谢~！shenbing100拉~！
;good; ;lihong; ;lihong; 正好我也需要 急需这样的东东啊！;deyi; ;deyi; ;good; 感谢，急需。 good;
44
ZVSEERMS_ScriptDate=12.10(October).2006
_WARNING_#1=IMPORTANT! This file is not in a plain text format. NEVER use any editor except ERM_S for making any kind of changes!
ERMS_PoweredBy=ERM Scripter v. 2004.10.5.945
** Emerald Tower Script Version 1.31 Created by Timothy Pulver
** with thanks to Steve Hanna for extra naming ideas
** Requires WoG version 3.58f or later using ERM version 2.7 or later.
** WoGify Name: script44.erm
** Last Updated: October 12, 2006
** Previously Updated: August 22, 2005
** This script makes all golden-green roofed towers in the game (object type 63,
** subtype 65) into Emerald Towers where the Wizard who dwells there will
** improve any creature type in your army for a price. The price is a lot of
** resources of a specific type, depending on the improvement. In addition,
** one of the creatures of the type being improved must also be left for the
** Wizard.
** The improvement number is usually a percentage of the existing score. For
** example, 50% growth bonus, or 25% health bonus. In addition to standard
** stat improvements, new special abilities may be added. Special abilities
** all cost mithril.
** Each Emerald Tower may only be visited once per week. A maximum of 12
** types of creatures may be improved in any game, but each creature type
** may have many improvements made to it. A creature cannot be improved
** during a "Week of" that creature type, if the "Week of Monsters" script
** is active.
** The AI can also use the Emerald Tower but not quite the same way that
** a human player can. Instead, each AI player may get one free random
** upgrade for the AI's most valuable stack when an AI visits the tower.
** If the ability can't be granted for any reason, no bonus is given the AI
** for that particular visit.
** Version 1.3 adds limits to the number of special ability "Mithril"
** upgrades that may be bought for each creature type in order to
** prevent "super" creatures of high level that can annihilate everything.
** Therefore, lower level creatures may be given more upgrades than
** higher level creatures, as shown below.
**Maximum # of Special "Mithril" Abilities per creature type:
** Level1: 7 abilities
** Level2: 6 abilities
** Level3: 5 abilities
** Level4: 4 abilities
** Level5: 3 abilities
** Level6: 2 abilities
** Level 7+: 1 abilities
** Version 1.31 corrects a name change bug that occurred if the AI visits and
** was offered a special ability the creature couldn't get or already had.
------------------------------------------------------------------------
Permanent Variables: z816-z841, v470-v481, v1240-v1252, v1270-v1271
Temporary Variables: v1-v7, v360-v369, z1-z9, z480-z490
Temporary Flags: 1-5
Functions: FU10900-FU10912
Custom Dialogue #s: DG3
-----------------------------------------------------------------------
!#UN:P44/?v1;
!#VRv550&v1=1:C1/2/4/8/16/32/64/128/256/512;
!#UN&v1=1:B0/1;
!#VRv1240&v1=1:S0;
!#VRz816&v1=1:Sz144000;
!#VRz817&v1=1:Sz144001;
!#HT63/65&v1=1:P0/816;
!#HT63/65&v1=1:P1/817;
-----------------------------------------------------------------------
!?TM2&$day$>7/$weekday$=$monday$/$once$=1;
!!UN:P44/?y-1;
!!FU&y-1<>1:E;
!!UN:U63/65/?y-2;
!!VRv1:S-1;
!!DO10910/1/y-2/1&y-2>0:P;
-----------------------------------------------------------------------
!?FU10910;
!!UN:U63/65/-1/1;
!!POv1/v2/v3:N0;
!!PMv1/v2/v3:V1;
-----------------------------------------------------------------------
!?OB63/65;
!!UN:P44/?y-1;
!!FU&y-1<>1:E;
!!IF:V5/0;
!!PM998:S4;
!!OW:C?v2;
!!VRv2:+1;
!!FU$bit$:Pv2;
!!VRv2:Sy-100;
!!VRv3:Sv1271 &v2;
!!VRv1270:S0;
!!PO998:N?v1;
!!IF&v1=1/1000:M1/z144002; ["Go away, wizard is busy" text]
!!FU|v1=1/v2=v3:E;
!!IF&1000:Q2/5/7/2/z144003; ["Do you have an appointment?" text]
!!IF&-1000:V2/1;
!!OW&2:R-1/5/?y-2;
!!VRz9:S^^;
!!VRz9&2/y-2<7:Sz144004; ["Not enough gems" text]
!!IF&y-2<7/1000:V2/0;
!!OW&2/1000:R-1/5/d-7;
!!VRz1:Sz144005; ["You enter and the wizard appears" text]
!!VRz-1:Sz144006;
!!VRz2:S^../data/p/s044_emerald.gif^;
!!VRz3:Sz144007; ["The Wizard"]
!!UN:J8/6/^s044_emerald.gif^;
!!IF&1000/1:D3/1/0/0/2/0/0/0/3/0/0/0/0/0/0/0;
!!IF&1000/1:F3/0/0/0/0/0;
!!IF&2/1000/1:E1/3;
!!IF&2/1000/-1:M^%Z-1^;
!!FU10900&2:P;
!!IF&-2/1000:M1/z144008; ["No appointement, no entrance" text]
-----------------------------------------------------------------------
!?FU10900;
!!FU10901&1000:P;
!!VRz1:Sz144009; ["What species do you want to improve" text]
!!VRz2:Sz144010; ["None, I changed my mind" text]
!!VRv367:S0;
!!IF&v1>0/1000:G1/367/128/1/480/481/482/483/484/485/486/2/0/0/0/0;
!!IF&v1=0/1000:M1/z144011; ["You have no creatures" text]
!!VRv2:S0;
!!VRv2&v367=1:Sv360;
!!VRv2&v367=2:Sv361;
!!VRv2&v367=4:Sv362;
!!VRv2&v367=8:Sv363;
!!VRv2&v367=16:Sv364;
!!VRv2&v367=32:Sv365;
!!VRv2&v367=64:Sv366;
!!VRv2&v367=128:S-1;
!!DO10912/0/6/1&-1000:P;
!!IF:V4/1;
!!IF&v2=-1/1000:Q4/z144012; ["If you don't need my services then go away" text]
!!UN&v2>=0:N3/3/v2/0;
!!UN&v2>=0:N3/4/v2/1;
!!IF&56/v170>=0/v170=v2/1000:Q4/21/v2/2/z144013; ["Sorry, but that's a 'week of' monster" text]
!!VRv2&56/v170>=0/v170=v2:S-1;
!!VRv6:S-1;
!!DO10908/1/v1240/1&v2>=0/v1240>0:P;
!!IF&v1240>=12/v6<0/v2>=0/1000:Q4/z144014; ["Sorry but there's already 12 species enchanted" text]
!!VRv2&v1240>=12/v6<0:S-1;
!!FU10902&v2>=0:P;
!!FU10900&v2=-1/-4/1000:P;
!!IF&4/-5/v1270=0/v1270<>100/1000:Q1/5/6/1/z144015; ["You didn't buy anything so here's a refund" text]
!!OW&4/-5/v1270=0/v1270<>100/1000:R-1/5/d6;
!!IF&4/-5/v1270=0/v1270<>100/1000:V5/1;
!!IF&4/-5/v1270=100/1000:Q1/5/6/1/z144016; ["You didn't buy much so here's a refund" text]
!!OW&4/-5/v1270=100/1000:R-1/5/d6;
!!IF&4/-5/v1270=100/1000:V5/1;
-----------------------------------------------------------------------
!?FU10901;
!!VRv1:S0;
!!VRv360:C-1/-1/-1/-1/-1/-1/-1;
!!VRz480:S^^;
!!VRz481:S^^;
!!VRz482:S^^;
!!VRz483:S^^;
!!VRz484:S^^;
!!VRz485:S^^;
!!VRz486:S^^;
!!HE-1:C0/0/?y1/?y2;
!!VRv1&y2>0:+1;
!!VRv360&y2>0:Sy1;
!!UN&y2>0:N3/480/y1/1;
!!HE-1:C0/1/?y1/?y2;
!!VRy4:S0;
!!VRy4&v1=1/y1=v360:S99;
!!VRv1&y2>0/y4<>99:+1;
!!VRy3&y2>0/y4<>99:S359 +v1;
!!VRy5&y2>0/y4<>99:S479 +v1;
!!UN&y2>0/y4<>99:N3/y5/y1/1;
!!VRvy3&y2>0/y4<>99:Sy1;
!!HE-1:C0/2/?y1/?y2;
!!VRy4:S0;
!!VRy4&v1>=1/y1=v360:S99;
!!VRy4&v1=2/y1=v361:S99;
!!VRv1&y2>0/y4<>99:+1;
!!VRy3&y2>0/y4<>99:S359 +v1;
!!VRy5&y2>0/y4<>99:S479 +v1;
!!UN&y2>0/y4<>99:N3/y5/y1/1;
!!VRvy3&y2>0/y4<>99:Sy1;
!!HE-1:C0/3/?y1/?y2;
!!VRy4:S0;
!!VRy4&v1>=1/y1=v360:S99;
!!VRy4&v1>=2/y1=v361:S99;
!!VRy4&v1=3/y1=v362:S99;
!!VRv1&y2>0/y4<>99:+1;
!!VRy3&y2>0/y4<>99:S359 +v1;
!!VRy5&y2>0/y4<>99:S479 +v1;
!!UN&y2>0/y4<>99:N3/y5/y1/1;
!!VRvy3&y2>0/y4<>99:Sy1;
!!HE-1:C0/4/?y1/?y2;
!!VRy4:S0;
!!VRy4&v1>=1/y1=v360:S99;
!!VRy4&v1>=2/y1=v361:S99;
!!VRy4&v1>=3/y1=v362:S99;
!!VRy4&v1=4/y1=v363:S99;
!!VRv1&y2>0/y4<>99:+1;
!!VRy3&y2>0/y4<>99:S359 +v1;
!!VRy5&y2>0/y4<>99:S479 +v1;
!!UN&y2>0/y4<>99:N3/y5/y1/1;
!!VRvy3&y2>0/y4<>99:Sy1;
!!HE-1:C0/5/?y1/?y2;
!!VRy4:S0;
!!VRy4&v1>=1/y1=v360:S99;
!!VRy4&v1>=2/y1=v361:S99;
!!VRy4&v1>=3/y1=v362:S99;
!!VRy4&v1>=4/y1=v363:S99;
!!VRy4&v1=5/y1=v364:S99;
!!VRv1&y2>0/y4<>99:+1;
!!VRy3&y2>0/y4<>99:S359 +v1;
!!VRy5&y2>0/y4<>99:S479 +v1;
!!UN&y2>0/y4<>99:N3/y5/y1/1;
!!VRvy3&y2>0/y4<>99:Sy1;
!!HE-1:C0/6/?y1/?y2;
!!VRy4:S0;
!!VRy4&v1>=1/y1=v360:S99;
!!VRy4&v1>=2/y1=v361:S99;
!!VRy4&v1>=3/y1=v362:S99;
!!VRy4&v1>=4/y1=v363:S99;
!!VRy4&v1>=5/y1=v364:S99;
!!VRy4&v1=6/y1=v365:S99;
!!VRv1&y2>0/y4<>99:+1;
!!VRy3&y2>0/y4<>99:S359 +v1;
!!VRy5&y2>0/y4<>99:S479 +v1;
!!UN&y2>0/y4<>99:N3/y5/y1/1;
!!VRvy3&y2>0/y4<>99:Sy1;
-----------------------------------------------------------------------
!?FU10902;
!!UN:N3/3/v2/0;
!!VRy2:S5; [+5 Attack bonus: y2]
!!VRy3:S5; [+5 Defense bonus: y3]
!!MA:Ev2/?y1;
!!VRy4:Sy1 :4;
!!VRy4&y4=0:S1;
!!MA:Pv2/?y1;
!!VRy5:Sy1 :4;
!!VRy5&y5=0:S1;
!!MA:Sv2/?y1;
!!VRy6:Sy1 :4;
!!VRy6&y6=0:S1;
!!MA:Gv2/?y1;
!!VRy7:Sy1 :2;
!!VRy7&y7=0:S1;
!!MA:Nv2/?y8;
!!MA:Bv2/?y10;
!!VRy15&y10>0:S5;
!!VRy15|v2=13/v2=150:S20;
!!VRz-2|v2=13/v2=150:Sz144126;
!!VRy15|v2=131/v2=158:S18;
!!VRz-2|v2=131/v2=158:Sz144127;
!!VRy15&v2=51:S10;
!!VRz-2&v2=51:Sz144128;
!!VRy15&v2=37:S8;
!!VRz-2&v2=37:Sz144129;
!!VRy15&v2=134:S5;
!!VRz-2&v2=134:Sz144130;
!!VRy15&v2=91:S3;
!!VRz-2&v2=91:Sz144131;
!!VRy15|v2=123/v2=125/v2=127/v2=129:S2;
!!VRz-2&v2=123:Sz144132;
!!VRz-2&v2=125:Sz144133;
!!VRz-2&v2=127:Sz144134;
!!VRz-2&v2=129:Sz144135;
!!VRy15|v2=152/v2=173:S0;
!!VRz1:Sz144017; ["How would like this species improved?" text]
!!VRz2:Sz144018; ["Forget it, I've changed my mind" text]
!!VRz480:Sz144019;
!!VRz481:Sz144020;
!!VRz482:Sz144021;
!!VRz483:Sz144022;
!!VRz484:Sz144023;
!!VRz485:Sz144024;
!!VRz486:S^^;
!!UN:P900/?y13;
!!EAv2:F0/?y16;
!!EAv2:F102/83/?y17;
!!VRy14&y16<>y17/y8<24/y13=1:S99;
!!VRz486&y8>0/y8<24/v2<>14/v2<>15|y14=99:Sz144025;
!!VRz487&y10>0/y15>0:Sz144026; [+1 spell casting]
!!VRz487|y10<1/y10>12:S^^;
!!MA:Lv2/?y18;
!!VRy19&v6>0:S469 +v6;
!!VRy20&v6>0:Svy19;
!!VRy21:S7 -y18;
!!VRz488:Sz144027;
!!VRz488&v6>0/y20>=y21:S^^;
!!IF&1000:G1/368/512/1/480/481/482/483/484/485/486/487/488/2/0/0;
*
!!VRv3:S0;
!!VRv3&v368=1:S2;
!!VRv3&v368=2:S3;
!!VRv3&v368=4:S4;
!!VRv3&v368=8:S5;
!!VRv3&v368=16:S6;
!!VRv3&v368=32:S7;
!!VRv3&v368=64:S8;
!!VRv3&v368=128:S9;
!!VRv3&v368=256:S10;
!!VRv3&v368=512:S-1;
!!VRv3&-1000:S2 R6;
!!VRv3&-1000/v3=8:S10;
!!VRv5:S0;
!!FU10906&v3=10:P;
!!VRv4:S0;
!!FU10903&v3>1/1000:Py15;
!!VRv4&v3>1/-1000:S1;
!!VRy9&v3>=2/v3<=7:Syv3;
!!FU10905&v4=1:Py9;
!!VRv1240&v4=1/v6<0:+1;
!!FU10909&v4=1:P;
!!PO998&v4=1:N1;
!!IF&v3=-1/1000:Q4/z144028;
!!VRv3&v3>1/v4=0/-4/1000:S-1;
!!FU10900&v3=-1/-4/1000:P;
!!OW:C?y11;
!!VRy12:S550 +y11;
!!VRv1271&-1000/v3>0:+vy12;
-----------------------------------------------------------------------
!?FU10903;
!!VRy1&v3=2:S3;
!!VRy2&v3=2:S15;
!!VRz1&v3=2:Sz144029;
!!VRy1&v3=3:S2;
!!VRy2&v3=3:S30;
!!VRz1&v3=3:Sz144030;
!!VRy1&v3=4:S5;
!!VRy2&v3=4:S20;
!!VRz1&v3=4:Sz144031;
!!VRy1&v3=5:S4;
!!VRy2&v3=5:S20;
!!VRz1&v3=5:Sz144032;
!!VRy1&v3=6:S1;
!!VRy2&v3=6:S20;
!!VRz1&v3=6:Sz144033;
!!VRy1&v3=7:S0;
!!VRy2&v3=7:S75;
!!VRz1&v3=7:Sz144034;
!!VRy1&v3=8:S6;
!!VRy2&v3=8:S1000;
!!VRz1&v3=8:Sz144035;
!!VRy1&v3=9:S7;
!!VRy2&v3=9:Sx1;
!!VRz1&v3=9:Sz144036;
!!VRy1&v3=10:S7;
!!VRy2&v3=10/v5=1:S20;
!!VRy2&v3=10/v5=2:S10;
!!VRy2&v3=10/v5=3:S10;
!!VRy2&v3=10/v5=4:S5;
!!VRy2&v3=10/v5=5:S25;
!!VRy2&v3=10/v5=6:S20;
!!VRy2&v3=10/v5=7:S15;
!!VRy2&v3=10/v5=8:S5;
!!VRy2&v3=10/v5=9:S10;
!!VRy2&v3=10/v5=10:S10;
!!VRz1&v3=10:Sz144036;
!!IF:V4/1;
!!OW:R-1/y1/?y3;
!!IF&y2>y3/1000:Q4/y1/y2/2/z144037;
!!MA:Gv2/?y6;
!!VRy10:Sy6 :2;
!!VRy7:Sy6 +y10;
!!VRy7|v2=56/v2=57:S48;
!!VRz8&y7=1:Sz3;
!!VRz8&y7>1:Sz4;
!!VRz9&y7=1:Sz144038;
!!VRz9&y7>1:S^^;
!!IF:V3/0;
!!VRy5:S65536 *y7;
!!VRy5:+v2;
!!IF&y3>=y2/1000:Q3/21/y5/2/z144039;
!!VRv3&-3/y3>=y2:S-1;
!!VRv7:S0;
!!DO10904/0/6/1&3:P;
!!DO10911/0/6/1&v7>=y7/3:Py7;
!!IF&v7<y7/3/1000:Q4/21/y5/2/z144040;
!!UN&3:N3/4/v2/1;
!!IF&3/v7>=y7/1000:Q1/21/y5/y1/y2/1/z144041;
!!VRy4&3/v7>=y7:Sy3 -y2;
!!OW&3/v7>=y7:R-1/y1/y4;
!!VRv4&3/v7>=y7:S1;
!!VRv1270&v4=1/v3<>8:+1;
!!VRv1270&v4=1/v3=8/v1270=0:S100;
-----------------------------------------------------------------------
!?FU10904;
!!HE-1:C0/x16/?y1/?y2;
!!VRv7&y1=v2/y2>0:+y2;
-----------------------------------------------------------------------
!?FU10905;
!!MA&v3=2:Av2/dx1;
!!MA&v3=3:Dv2/dx1;
!!MA&v3=4:Ev2/dx1;
!!MA&v3=4:Mv2/dx1;
!!MA&v3=5:Pv2/dx1;
!!MA&v3=6:Sv2/dx1;
!!MA&v3=7:Gv2/dx1;
!!MA&v3=8:Nv2/24;
!!MA&v3=9:Bv2/d1;
!!FU10907&v3=10:P;
-----------------------------------------------------------------------
!?FU10906;
!!VRz480:S^^; !!VRz481:S^^; !!VRz482:S^^; !!VRz483:S^^; !!VRz484:S^^;
!!VRz485:S^^; !!VRz486:S^^; !!VRz487:S^^; !!VRz488:S^^; !!VRz489:S^^; !!VRz490:S^^;
!!MA:Xv2/?v369;
!!VRy3&-1000:S1 R9;
!!VRy4&-1000:S-1;
!!VRy1:Sv369;
!!VRy1:&2;
!!VRz480&y1=0:Sz144042;
!!VRz480&y1=2:S^^;
!!VRy4&-1000/y3=1/y1=0:S1;
!!VRy1:Sv369;
!!VRy1:&8;
!!VRy5:Sv369;
!!VRy5:&524288;
!!VRz481&y1=0/y5=0:Sz144043;
!!VRz481|y1=8/y5=524288:S^^;
!!VRy4&-1000/y3=2/y1=0/y5=0:S2;
!!VRy1:Sv369;
!!VRy1:&262144;
!!VRz482&y1=0:Sz144044;
!!VRz482&y1=262144:S^^;
!!VRy4&-1000/y3=3/y1=0:S3;
!!VRy1:Sv369;
!!VRy1:&131072;
!!VRz483&y1=0:Sz144045;
!!VRz483&y1=131072:S^^;
!!VRy4&-1000/y3=4/y1=0:S4;
!!VRy1:Sv369;
!!VRy1:&32768;
!!VRz484&y1=0:Sz144046;
!!VRz484&y1=32768:S^^;
!!VRy4&-1000/y3=5/y1=0:S5;
!!VRy1:Sv369;
!!VRy1:&524288;
!!VRy5:Sv369;
!!VRy5:&8;
!!VRz485&y1=0/y5=0:Sz144047;
!!VRz485|y1=524288/y5=8/v2=63/v2=159:S^^;
!!VRy4&-1000/y3=6/y1=0/y5=0/v2<>63/v2<>159:S6;
!!VRy1:Sv369;
!!VRy1:&65536;
!!VRz486&y1=0:Sz144048;
!!VRz486&y1=65536:S^^;
!!VRy4&-1000/y3=7/y1=0:S7;
!!VRy1:Sv369;
!!VRy1:&1024;
!!VRz487&y1=0:Sz144049;
!!VRz487&y1=1024:S^^;
!!VRy4&-1000/y3=8/y1=0:S8;
!!VRy1:Sv369;
!!VRy1:&16384;
!!VRz488&y1=0:Sz144050;
!!VRz488&y1=16384:S^^;
!!VRy4&-1000/y3=9/y1=0:S9;
!!VRy1:Sv369;
!!VRy2:Sv369;
!!VRy1:&4096; (Check No Close Combat Penalty)
!!VRy2:&4; (Check Shooter)
!!VRz489&y1=0/y2=4:Sz144051;
!!VRz489|y1=4096/y2=0:S^^;
!!VRy4&-1000/y3=10/y1=0/y2=4:S10;
!!VRz1:Sz144052;
!!VRz2:Sz144053;
!!IF&1000:G1/368/1024/1/480/481/482/483/484/485/486/487/488/489/2/0;
!!VRv5:S0;
!!VRv5&v368=1:S1;
!!VRv5&v368=2:S2;
!!VRv5&v368=4:S3;
!!VRv5&v368=8:S4;
!!VRv5&v368=16:S5;
!!VRv5&v368=32:S6;
!!VRv5&v368=64:S7;
!!VRv5&v368=128:S8;
!!VRv5&v368=256:S9;
!!VRv5&v368=512:S10;
!!VRv5&v368=1024:S-1;
!!VRv5&-1000:Sy4;
!!VRv3&v5=-1:S-1;
-----------------------------------------------------------------------
!?FU10907&v5>=1/v5<=10;
!!VRy2&v5=1:S2;
!!VRy2&v5=2:S8;
!!VRy2&v5=3:S262144;
!!VRy2&v5=4:S131072;
!!VRy2&v5=5:S32768;
!!VRy2&v5=6:S524288;
!!VRy2&v5=7:S65536;
!!VRy2&v5=8:S1024;
!!VRy2&v5=9:S16384;
!!VRy2&v5=10:S4096;
!!MA:Xv2/?y1;
!!VRy1:|y2;
!!MA:Xv2/y1;
*
!!VRy3&v6>0:S469 +v6;
!!VRy3&v6<0:S469 +v1240 +1;
*
!!VRvy3:+1;
-----------------------------------------------------------------------
!?FU10908;
!!VRy1:S1240 +x16;
!!VRv6&vy1=v2:Sx16;
!!VRx16&vy1=v2:S99;
-----------------------------------------------------------------------
!?FU10909;
!!VRy1:S1 R3;
!!UN:G1/v2/0/0;
!!UN:G1/v2/1/0;
!!VRy4:S1240 +v1240;
!!VRvy4&v6<0:Sv2;
!!VRy2&v6<0:Sv1240 *2;
!!VRy2&v6>0:Sv6 *2;
!!VRy2:+816;
!!VRy3:Sy2 +1;
!!UN:N3/6/v2/0;
!!UN:N3/7/v2/1;
!!VRz5&v3=2/y1=1:Sz144054;
!!VRz5&v3=2/y1=2:Sz144055;
!!VRz5&v3=2/y1=3:Sz144056;
!!VRz5&v3=2/y1=4:Sz144057;
!!VRz5&v3=3/y1=1:Sz144058;
!!VRz5&v3=3/y1=2:Sz144059;
!!VRz5&v3=3/y1=3:Sz144060;
!!VRz5&v3=3/y1=4:Sz144061;
!!VRz5&v3=4/y1=1:Sz144062;
!!VRz5&v3=4/y1=2:Sz144063;
!!VRz5&v3=4/y1=3:Sz144064;
!!VRz5&v3=4/y1=4:Sz144065;
!!VRz5&v3=5/y1=1:Sz144066;
!!VRz5&v3=5/y1=2:Sz144067;
!!VRz5&v3=5/y1=3:Sz144068;
!!VRz5&v3=5/y1=4:Sz144069;
!!VRz5&v3=6/y1=1:Sz144070;
!!VRz5&v3=6/y1=2:Sz144071;
!!VRz5&v3=6/y1=3:Sz144072;
!!VRz5&v3=6/y1=4:Sz144073;
!!VRz5&v3=7/y1=1:Sz144074;
!!VRz5&v3=7/y1=2:Sz144075;
!!VRz5&v3=7/y1=3:Sz144076;
!!VRz5&v3=7/y1=4:Sz144077;
!!VRz5&v3=8/y1=1:Sz144078;
!!VRz5&v3=8/y1=2:Sz144079;
!!VRz5&v3=8/y1=3:Sz144080;
!!VRz5&v3=8/y1=4:Sz144081;
!!VRz5&v3=9/y1=1:Sz144082;
!!VRz5&v3=9/y1=2:Sz144083;
!!VRz5&v3=9/y1=3:Sz144084;
!!VRz5&v3=9/y1=4:Sz144085;
!!VRz5&v5=1/y1=1:Sz144086;
!!VRz5&v5=1/y1=2:Sz144087;
!!VRz5&v5=1/y1=3:Sz144088;
!!VRz5&v5=1/y1=4:Sz144089;
!!VRz5&v5=2/y1=1:Sz144090;
!!VRz5&v5=2/y1=2:Sz144091;
!!VRz5&v5=2/y1=3:Sz144092;
!!VRz5&v5=2/y1=4:Sz144093;
!!VRz5&v5=3/y1=1:Sz144094;
!!VRz5&v5=3/y1=2:Sz144095;
!!VRz5&v5=3/y1=3:Sz144096;
!!VRz5&v5=3/y1=4:Sz144097;
!!VRz5&v5=4/y1=1:Sz144098;
!!VRz5&v5=4/y1=2:Sz144099;
!!VRz5&v5=4/y1=3:Sz144100;
!!VRz5&v5=4/y1=4:Sz144101;
!!VRz5&v5=5/y1=1:Sz144102;
!!VRz5&v5=5/y1=2:Sz144103;
!!VRz5&v5=5/y1=3:Sz144104;
!!VRz5&v5=5/y1=4:Sz144105;
!!VRz5&v5=6/y1=1:Sz144106;
!!VRz5&v5=6/y1=2:Sz144107;
!!VRz5&v5=6/y1=3:Sz144108;
!!VRz5&v5=6/y1=4:Sz144109;
!!VRz5&v5=7/y1=1:Sz144110;
!!VRz5&v5=7/y1=2:Sz144111;
!!VRz5&v5=7/y1=3:Sz144112;
!!VRz5&v5=7/y1=4:Sz144113;
!!VRz5&v5=8/y1=1:Sz144114;
!!VRz5&v5=8/y1=2:Sz144115;
!!VRz5&v5=8/y1=3:Sz144116;
!!VRz5&v5=8/y1=4:Sz144117;
!!VRz5&v5=9/y1=1:Sz144118;
!!VRz5&v5=9/y1=2:Sz144119;
!!VRz5&v5=9/y1=3:Sz144120;
!!VRz5&v5=9/y1=4:Sz144121;
!!VRz5&v5=10/y1=1:Sz144122;
!!VRz5&v5=10/y1=2:Sz144123;
!!VRz5&v5=10/y1=3:Sz144124;
!!VRz5&v5=10/y1=4:Sz144125;
!!VRzy2:S^%Z5 %Z6^;
!!UN:G1/v2/0/y2;
!!VRzy3:S^%Z5 %Z7^;
!!UN:G1/v2/1/y3;
-----------------------------------------------------------------------
!?FU10911;
!!HE-1:C0/x16/?y1/?y2;
!!HE-1&y1=v2/y2>0/y2<=x1:C0/x16/-1/0;
!!VRy4&y1=v2/y2>0/y2<=x1:Sx1 -y2;
!!VRy3&y1=v2/y2>x1:Sx1 *-1;
!!HE-1&y1=v2/y2>x1:C0/x16/d/dy3/0/3;
!!VRy4&y1=v2/y2>x1:S0;
!!VRx1&y1=v2/y2>0:Sy4;
-----------------------------------------------------------------------
!?FU10912;
!!HE-1:C0/x16/?y1/?y2;
!!VRy3:S0;
!!MA&y1>=0/y2>0:Iy1/?y3;
!!VRy4&y3>0:Sy3 *y2;
!!VRv2&y4>x1:Sy1;
!!VRx1&y4>x1:Sy4;
** End of Script ** 为什么我把它放在了S文件下的44还是不能使用啊？我的翡翠塔怎么不能用啊？请指教。谢谢！ 亲自测试，貌似不能使用。连翡翠塔这个建筑也不能用了（直接下载下来更换了44，然后建筑直接进去没反应了。。。。。），求指教。。。。。。。
页:
[1]
